qcsrc/common/notifications.qc

   1 // ================================================
   2 //  Unified notification system, written by Samual
   3 //  Last updated: February, 2013
   4 // ================================================
   5
   6 #ifndef MENUQC
   7 entity Get_Notif_Ent(float net_type, float net_name)
   8 {
   9         switch(net_type)
  10         {
  11                 case MSG_INFO: return msg_info_notifs[net_name - 1];
  12                 case MSG_CENTER: return msg_center_notifs[net_name - 1];
  13                 case MSG_WEAPON: return msg_weapon_notifs[net_name - 1];
  14                 case MSG_DEATH: return msg_death_notifs[net_name - 1];
  15         }
  16         backtrace(sprintf("Get_Notif_Ent(%d, %d): Improper net type!\n", net_type, net_name));
  17         return world;
  18 }
  19
  20 string Get_Notif_Name(float net_type, float net_name)
  21 {
  22         entity e = Get_Notif_Ent(net_type, net_name);
  23         if(e) { return e.nent_name; }
  24         backtrace(sprintf("Get_Notif_Name(%d, %d): Could not find entity!\n", net_type, net_name));
  25         return "";
  26 }
  27
  28 float Get_Notif_Infval(float net_type, float net_name)
  29 {
  30         entity e = Get_Notif_Ent(net_type, net_name);
  31         if(e) { return e.nent_infoname; }
  32         backtrace(sprintf("Get_Notif_Infval(%d, %d): Could not find entity!\n", net_type, net_name));
  33         return NO_MSG;
  34 }
  35
  36 float Get_Notif_Cenval(float net_type, float net_name)
  37 {
  38         entity e = Get_Notif_Ent(net_type, net_name);
  39         if(e) { return e.nent_centername; }
  40         backtrace(sprintf("Get_Notif_Cenval(%d, %d): Could not find entity!\n", net_type, net_name));
  41         return NO_MSG;
  42 }
  43
  44 float Get_Notif_Strnum(float net_type, float net_name)
  45 {
  46         entity e = Get_Notif_Ent(net_type, net_name);
  47         if(e) { return e.nent_stringcount; }
  48         backtrace(sprintf("Get_Notif_Strnum(%d, %d): Could not find entity!\n", net_type, net_name));
  49         return NO_MSG;
  50 }
  51
  52 float Get_Notif_Flnum(float net_type, float net_name)
  53 {
  54         entity e = Get_Notif_Ent(net_type, net_name);
  55         if(e) { return e.nent_floatcount; }
  56         backtrace(sprintf("Get_Notif_Flnum(%d, %d): Could not find entity!\n", net_type, net_name));
  57         return NO_MSG;
  58 }
  59 #endif // ifndef MENUQC
  60
  61
  62 // ===============================
  63 //  Frontend Notification Pushing
  64 // ===============================
  65
  66 void Dump_Notifications(float fh, float alsoprint)
  67 {
  68         float MSG_INFO_NOTIFS = 0, MSG_CENTER_NOTIFS = 0, MSG_WEAPON_NOTIFS = 0, MSG_DEATH_NOTIFS = 0;
  69
  70         #define NOTIF_WRITE(type,name,text) { \
  71                 ++##type##_NOTIFS; \
  72                 notif_msg = sprintf("seta %s 1 // %s - %s\n", name, #type, strreplace("\n", "\\n", text)); \
  73                 fputs(fh, notif_msg); \
  74                 if(alsoprint) { print(strreplace("^", "^^", notif_msg)); } }
  75
  76         #ifndef MENUQC
  77         string notif_msg;
  78         float i;
  79         entity e;
  80
  81         for(i = 0; i < NOTIF_INFO_COUNT; ++i) {
  82                 e = Get_Notif_Ent(MSG_INFO, i);
  83                 NOTIF_WRITE(MSG_INFO, e.nent_name, e.nent_string); }
  84
  85         for(i = 0; i < NOTIF_CENTER_COUNT; ++i) {
  86                 e = Get_Notif_Ent(MSG_CENTER, i);
  87                 NOTIF_WRITE(MSG_CENTER, e.nent_name, e.nent_string); }
  88
  89         for(i = 0; i < NOTIF_WEAPON_COUNT; ++i) {
  90                 e = Get_Notif_Ent(MSG_WEAPON, i);
  91                 NOTIF_WRITE(MSG_WEAPON, e.nent_name, sprintf("infoname: %s, centername: %s",
  92                         Get_Notif_Name(MSG_INFO, Get_Notif_Infval(MSG_WEAPON, i)),
  93                         Get_Notif_Name(MSG_CENTER, Get_Notif_Cenval(MSG_WEAPON, i)) ) ); }
  94
  95         for(i = 0; i < NOTIF_DEATH_COUNT; ++i) {
  96                 e = Get_Notif_Ent(MSG_DEATH, i);
  97                 NOTIF_WRITE(MSG_DEATH, e.nent_name, sprintf("infoname: %s, centername: %s",
  98                         Get_Notif_Name(MSG_INFO, Get_Notif_Infval(MSG_DEATH, i)),
  99                         Get_Notif_Name(MSG_CENTER, Get_Notif_Cenval(MSG_DEATH, i)) ) ); }
 100
 101         #endif
 102
 103         print(sprintf("Notification counts: MSG_INFO = %d, MSG_CENTER = %d, MSG_WEAPON = %d, MSG_DEATH = %d\n",
 104                 MSG_INFO_NOTIFS, MSG_CENTER_NOTIFS, MSG_WEAPON_NOTIFS, MSG_DEATH_NOTIFS));
 105
 106         return;
 107         #undef NOTIF_WRITE
 108 }
 109
 110 #ifndef MENUQC
 111 string Local_Notification_sprintf(string input, string args,
 112         string s1, string s2, string s3, string s4,
 113         float f1, float f2, float f3, float f4)
 114 {
 115         #ifdef NOTIFICATIONS_DEBUG
 116         dprint(sprintf("Local_Notification_sprintf('%s^7', '%s', %s, %s);\n",
 117                 strreplace("\n", "\\n", input), args,
 118                 sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4),
 119                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)));
 120         #endif
 121
 122         string selected, remaining = args;
 123         float sel_num = 0;
 124
 125         #ifdef CSQC
 126         string tmp_s;
 127         #endif
 128
 129         if((remaining != "") && (input != ""))
 130         {
 131                 arg_slot[0] = ""; arg_slot[1] = ""; arg_slot[2] = ""; arg_slot[3] = ""; arg_slot[4] = ""; arg_slot[5] = ""; arg_slot[6] = "";
 132                 for(;remaining;)
 133                 {
 134                         selected = car(remaining); remaining = cdr(remaining);
 135                         if(sel_num == 7) { backtrace("Local_Notification_sprintf: Hit maximum arguments!\n"); break; }
 136                         switch(strtolower(selected))
 137                         {
 138                                 #define ARG_CASE(prog,selected,result) \
 139                                         #ifdef CSQC \
 140                                         #if (prog == ARG_BOTH) || (prog == ARG_CSQC) \
 141                                                 case selected: { arg_slot[sel_num] = result; ++sel_num; break; } \
 142                                         #endif \
 143                                         #else \
 144                                         #if (prog == ARG_BOTH) || (prog == ARG_SVQC) \
 145                                                 case selected: { arg_slot[sel_num] = result; ++sel_num; break; } \
 146                                         #endif \
 147                                         #endif
 148                                 NOTIF_ARGUMENT_LIST
 149                                 #undef ARG_CASE
 150                                 default: { backtrace(sprintf("Local_Notification_sprintf: Hit unknown token in selected string! '%s'\n", selected)); break; }
 151                         }
 152                 }
 153                 return sprintf(input, arg_slot[0], arg_slot[1], arg_slot[2], arg_slot[3], arg_slot[4], arg_slot[5], arg_slot[6]);
 154         }
 155
 156         return "";
 157 }
 158
 159 #ifdef CSQC
 160 void Local_Notification_HUD_Notify_Push(string icon, string hudargs, string s1, string s2)
 161 {
 162         string selected, remaining = hudargs;
 163         float sel_num = 0;
 164         arg_slot[0] = ""; arg_slot[1] = "";
 165         if(remaining != "")
 166         {
 167                 for(;remaining;)
 168                 {
 169                         selected = car(remaining); remaining = cdr(remaining);
 170                         if(sel_num == 2) { backtrace("Local_Notification_HUD_Notify_Push: Hit maximum arguments!\n"); break; }
 171                         switch(strtolower(selected))
 172                         {
 173                                 #define ARG_CASE(selected,result) case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
 174                                 ARG_CASE("s1", s1)
 175                                 ARG_CASE("s2", s2)
 176                                 #undef ARG_CASE
 177                                 default: { backtrace(sprintf("Local_Notification_HUD_Notify_Push: Hit unknown token in selected string! '%s'\n", selected)); break; }
 178                         }
 179                 }
 180         }
 181         HUD_Notify_Push(icon, arg_slot[0], arg_slot[1]);
 182 }
 183 #endif
 184
 185 void Local_Notification(float net_type, float net_name, ...count)
 186 {
 187         // check supplied type and name for errors
 188         #define CHECKARG_TYPENAME(type) case MSG_##type##: \
 189                 { if(!net_name || (net_name > NOTIF_##type##_COUNT)) \
 190                 { checkargs = sprintf("Improper name: %d!", net_name); } break; }
 191         string checkargs = "";
 192         switch(net_type)
 193         {
 194                 CHECKARG_TYPENAME(INFO)
 195                 CHECKARG_TYPENAME(CENTER)
 196                 CHECKARG_TYPENAME(WEAPON)
 197                 CHECKARG_TYPENAME(DEATH)
 198                 default: { checkargs = sprintf("Improper type: %d!", checkargs, net_type); break; }
 199         }
 200         #undef CHECKARG_TYPENAME
 201         if(checkargs != "") { backtrace(sprintf("Incorrect usage of Local_Notification: %s\n", checkargs)); return; }
 202
 203         entity notif = Get_Notif_Ent(net_type, net_name);
 204         if not(notif) { backtrace("Local_Notification: Could not find notification entity! (This wasn't caught by usage check?...)\n"); return; }
 205         if not(notif.nent_enabled) { print("Local_Notification: Entity was disabled...\n"); return; }
 206
 207         if((notif.nent_stringcount + notif.nent_floatcount) > count)
 208                 { backtrace(sprintf(strcat("Not enough arguments for Local_Notification! stringcount(%d) + floatcount(%d) > count(%d)\n",
 209                 "Check the notification definition and function call for accuracy...?\n"), notif.nent_stringcount, notif.nent_floatcount, count)); return; }
 210         else if((notif.nent_stringcount + notif.nent_floatcount) < count)
 211                 { backtrace(sprintf(strcat("Too many arguments for Local_Notification! stringcount(%d) + floatcount(%d) < count(%d)\n",
 212                 "Check the notification definition and function call for accuracy...?\n"), notif.nent_stringcount, notif.nent_floatcount, count)); return; }
 213
 214         string s1 = ((0 < notif.nent_stringcount) ? ...(0, string) : "");
 215         string s2 = ((1 < notif.nent_stringcount) ? ...(1, string) : "");
 216         string s3 = ((2 < notif.nent_stringcount) ? ...(2, string) : "");
 217         string s4 = ((3 < notif.nent_stringcount) ? ...(3, string) : "");
 218         float f1 = ((notif.nent_stringcount < count) ? ...(notif.nent_stringcount, float) : NO_FL_ARG);
 219         float f2 = (((notif.nent_stringcount + 1) < count) ? ...((notif.nent_stringcount + 1), float) : NO_FL_ARG);
 220         float f3 = (((notif.nent_stringcount + 2) < count) ? ...((notif.nent_stringcount + 2), float) : NO_FL_ARG);
 221         float f4 = (((notif.nent_stringcount + 3) < count) ? ...((notif.nent_stringcount + 3), float) : NO_FL_ARG);
 222
 223         #ifdef NOTIFICATIONS_DEBUG
 224         dprint(sprintf("Local_Notification(%d, %s, %s, %s);\n",
 225                 net_type, notif.nent_name,
 226                 sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4),
 227                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)));
 228         #endif
 229
 230         switch(net_type)
 231         {
 232                 case MSG_INFO:
 233                 {
 234                         print(Local_Notification_sprintf(notif.nent_string, notif.nent_args,
 235                                 s1, s2, s3, s4, f1, f2, f3, f4));
 236                         #ifdef CSQC
 237                         if(notif.nent_icon != "") { Local_Notification_HUD_Notify_Push(notif.nent_icon, notif.nent_hudargs, s1, s2); }
 238                         #endif
 239                         break;
 240                 }
 241
 242                 #ifdef CSQC
 243                 case MSG_CENTER:
 244                 {
 245                         centerprint_generic(notif.nent_cpid,
 246                                 Local_Notification_sprintf(notif.nent_string, notif.nent_args,
 247                                 s1, s2, s3, s4, f1, f2, f3, f4), 0, 0);
 248                         break;
 249                 }
 250                 #endif
 251
 252                 case MSG_WEAPON:
 253                 case MSG_DEATH:
 254                 {
 255                         if(notif.nent_infoname)
 256                         if(msg_info_notifs[notif.nent_infoname - 1].nent_enabled)
 257                         {
 258                                 Local_Notification_Without_VarArgs(MSG_INFO, notif.nent_infoname,
 259                                         Get_Notif_Strnum(MSG_INFO, notif.nent_infoname),
 260                                         Get_Notif_Flnum(MSG_INFO, notif.nent_infoname),
 261                                         s1, s2, s3, s4, f1, f2, f3, f4);
 262                         }
 263                         #ifdef CSQC
 264                         if(notif.nent_centername)
 265                         if(msg_center_notifs[notif.nent_centername - 1].nent_enabled)
 266                         {
 267                                 Local_Notification_Without_VarArgs(MSG_CENTER, notif.nent_centername,
 268                                         Get_Notif_Strnum(MSG_CENTER, notif.nent_centername),
 269                                         Get_Notif_Flnum(MSG_CENTER, notif.nent_centername),
 270                                         s1, s2, s3, s4, f1, f2, f3, f4);
 271                         }
 272                         #endif
 273                         break;
 274                 }
 275         }
 276 }
 277
 278 void Local_Notification_Without_VarArgs(float net_type, float net_name,
 279         float stringcount, float floatcount,
 280         string s1, string s2, string s3, string s4,
 281         float f1, float f2, float f3, float f4)
 282 {
 283         #define VARITEM(stringc,floatc,args) if((stringcount == stringc) && (floatcount == floatc)) { Local_Notification(net_type, net_name, args); return; }
 284         EIGHT_VARS_TO_VARARGS_VARLIST
 285         #undef VARITEM
 286
 287         Local_Notification(net_type, net_name); // some notifications don't have any arguments at all
 288 }
 289
 290
 291 // =========================
 292 //  Notification Networking
 293 // =========================
 294
 295 #ifdef CSQC
 296 void Read_Notification(float is_new)
 297 {
 298         float net_type = ReadByte();
 299         float net_name = ReadShort();
 300
 301         entity notif = Get_Notif_Ent(net_type, net_name);
 302         if not(notif) { print("Read_Notification: Could not find notification entity!\n"); return; }
 303         if not(notif.nent_enabled) { print("Read_Notification: Entity was disabled but networked anyway?!?...\n"); return; }
 304
 305         string s1 = ((0 < notif.nent_stringcount) ? ReadString() : "");
 306         string s2 = ((1 < notif.nent_stringcount) ? ReadString() : "");
 307         string s3 = ((2 < notif.nent_stringcount) ? ReadString() : "");
 308         string s4 = ((3 < notif.nent_stringcount) ? ReadString() : "");
 309         float f1 = ((0 < notif.nent_floatcount) ? ReadLong() : NO_FL_ARG);
 310         float f2 = ((1 < notif.nent_floatcount) ? ReadLong() : NO_FL_ARG);
 311         float f3 = ((2 < notif.nent_floatcount) ? ReadLong() : NO_FL_ARG);
 312         float f4 = ((3 < notif.nent_floatcount) ? ReadLong() : NO_FL_ARG);
 313
 314         #ifdef NOTIFICATIONS_DEBUG
 315         dprint(sprintf("Read_Notification(%d) at %f: net_name = %s.\n", is_new, time, notif.nent_name));
 316         #endif
 317
 318         if(is_new) { Local_Notification_Without_VarArgs(net_type, net_name, notif.nent_stringcount, notif.nent_floatcount, s1, s2, s3, s4, f1, f2, f3, f4); }
 319 }
 320 #endif
 321
 322 #ifdef SVQC
 323 void Notification_Remove()
 324 {
 325         float i;
 326         for(i = 0; i < 4; ++i) { if(self.nent_strings[i]) { strunzone(self.nent_strings[i]); } }
 327         remove(self);
 328 }
 329
 330 float Write_Notification(entity client, float sf)
 331 {
 332         float i, send = FALSE;
 333
 334         switch(self.nent_broadcast)
 335         {
 336                 case NOTIF_ONE: { if((client == self.nent_client) || (client.classname == STR_SPECTATOR && client.enemy == self.nent_client)) { send = TRUE; } break; }
 337                 case NOTIF_ONE_ONLY: { if(client == self.nent_client) { send = TRUE; } break; }
 338                 case NOTIF_TEAM: { if((client.team == self.nent_client.team) || (client.classname == STR_SPECTATOR && client.enemy.team == self.nent_client.team)) { send = TRUE; } break; }
 339                 case NOTIF_TEAM_EXCEPT: { if(((client != self.nent_client) && (client.team == self.nent_client.team) && !(client.classname == STR_SPECTATOR && client.enemy == self.nent_client))) { send = TRUE; } break; }
 340                 case NOTIF_ANY: { send = TRUE; break; }
 341                 case NOTIF_ANY_EXCEPT: { if((client != self.nent_client) && !(client.classname == STR_SPECTATOR && client.enemy == self.nent_client)) { send = TRUE; } break; }
 342                 default: { send = FALSE; break; }
 343         }
 344
 345         if(send)
 346         {
 347                 WriteByte(MSG_ENTITY, ENT_CLIENT_NOTIFICATION);
 348                 WriteByte(MSG_ENTITY, self.nent_net_type);
 349                 WriteShort(MSG_ENTITY, self.nent_net_name);
 350                 for(i = 0; i < self.nent_stringcount; ++i) { WriteString(MSG_ENTITY, self.nent_strings[i]); }
 351                 for(i = 0; i < self.nent_floatcount; ++i) { WriteLong(MSG_ENTITY, self.nent_floats[i]); }
 352         }
 353
 354         return send;
 355 }
 356
 357 void Send_Notification(float broadcast, entity client,
 358         float net_type, float net_name, ...count)
 359 {
 360         // check supplied broadcast, target, type, and name for errors
 361         #define CHECKARG_TYPENAME(type) case MSG_##type##: \
 362                 { if(!net_name || (net_name > NOTIF_##type##_COUNT)) \
 363                 { checkargs = sprintf("Improper name: %d!", net_name); } break; }
 364         string checkargs = "";
 365         switch(net_type)
 366         {
 367                 CHECKARG_TYPENAME(INFO)
 368                 CHECKARG_TYPENAME(CENTER)
 369                 CHECKARG_TYPENAME(WEAPON)
 370                 CHECKARG_TYPENAME(DEATH)
 371                 default: { checkargs = sprintf("Improper type: %d!", checkargs, net_type); break; }
 372         }
 373         #undef CHECKARG_TYPENAME
 374         if(checkargs != "") { checkargs = strcat(checkargs, " "); }
 375         switch(broadcast)
 376         {
 377                 case NOTIF_ONE:
 378                 case NOTIF_ONE_ONLY: { if(clienttype(client) == CLIENTTYPE_NOTACLIENT) { checkargs = sprintf("%sNo client provided!", checkargs); } break; }
 379                 case NOTIF_ANY_EXCEPT: { if(clienttype(client) == CLIENTTYPE_NOTACLIENT) { checkargs = sprintf("%sException can't be a non-client!", checkargs); } break; }
 380                 case NOTIF_ANY: { if(client) { checkargs = sprintf("%sEntity provided when world was required!", checkargs); } break; }
 381                 case NOTIF_TEAM:
 382                 case NOTIF_TEAM_EXCEPT:
 383                 {
 384                         if not(teamplay) { checkargs = sprintf("%sTeamplay not active!", checkargs); }
 385                         else if(clienttype(client) == CLIENTTYPE_NOTACLIENT)
 386                         {
 387                                 if(broadcast == NOTIF_TEAM) { checkargs = sprintf("%sNo client provided!", checkargs); }
 388                                 else { checkargs = sprintf("%sException can't be a non-client!", checkargs); }
 389                         }
 390                         break;
 391                 }
 392                 default: { checkargs = sprintf("%sImproper broadcast: %d!", checkargs, broadcast); break; }
 393         }
 394         if(checkargs != "") { backtrace(sprintf("Incorrect usage of Send_Notification: %s\n", checkargs)); return; }
 395
 396         // retreive counts for the arguments of this notification
 397         entity notif = Get_Notif_Ent(net_type, net_name);
 398         if not(notif) { backtrace("Send_Notification: Could not find notification entity! (This wasn't caught by usage check?...)\n"); return; }
 399         if not(notif.nent_enabled) { print("Send_Notification: Entity was disabled...\n"); return; }
 400
 401         if((notif.nent_stringcount + notif.nent_floatcount) > count)
 402                 { backtrace(sprintf(strcat("Not enough arguments for Send_Notification! stringcount(%d) + floatcount(%d) > count(%d)\n",
 403                 "Check the notification definition and function call for accuracy...?\n"), notif.nent_stringcount, notif.nent_floatcount, count)); return; }
 404         else if((notif.nent_stringcount + notif.nent_floatcount) < count)
 405                 { backtrace(sprintf(strcat("Too many arguments for Send_Notification! stringcount(%d) + floatcount(%d) < count(%d)\n",
 406                 "Check the notification definition and function call for accuracy...?\n"), notif.nent_stringcount, notif.nent_floatcount, count)); return; }
 407
 408         #ifdef NOTIFICATIONS_DEBUG
 409         dprint(sprintf("Send_Notification(%d, %d, %s, stringcount: %d, floatcount: %d, varargs: %d);\n",
 410                 broadcast, net_type, notif.nent_name, notif.nent_stringcount, notif.nent_floatcount, count));
 411         #endif
 412
 413         entity net_notif = spawn();
 414         net_notif.nent_broadcast = broadcast;
 415         net_notif.nent_client = client;
 416         net_notif.nent_net_type = net_type;
 417         net_notif.nent_net_name = net_name;
 418         net_notif.nent_stringcount = notif.nent_stringcount;
 419         net_notif.nent_floatcount = notif.nent_floatcount;
 420
 421         float i;
 422         for(i = 0; i < net_notif.nent_stringcount; ++i) { net_notif.nent_strings[i] = strzone(...(i, string)); }
 423         for(i = 0; i < net_notif.nent_floatcount; ++i) { net_notif.nent_floats[i] = ...((net_notif.nent_stringcount + i), float); }
 424
 425         net_notif.think = Notification_Remove;
 426         net_notif.nextthink = (time + 0.5);
 427
 428         Net_LinkEntity(net_notif, FALSE, 0, Write_Notification);
 429
 430         if((!server_is_local) && (broadcast == NOTIF_ANY || broadcast == NOTIF_ANY_EXCEPT) && (net_type != MSG_CENTER))
 431                 { Local_Notification_Without_VarArgs(net_type, net_name, notif.nent_stringcount, notif.nent_floatcount,
 432                         IFSTR(0), IFSTR(1), IFSTR(2), IFSTR(3), IFFL(0), IFFL(1), IFFL(2), IFFL(3)); }
 433 }
 434
 435 void Send_Notification_Without_VarArgs(float broadcast, entity client,
 436         float net_type, float net_name,
 437         float stringcount, float floatcount,
 438         string s1, string s2, string s3, string s4,
 439         float f1, float f2, float f3, float f4)
 440 {
 441         #define VARITEM(stringc,floatc,args) if((stringcount == stringc) && (floatcount == floatc)) { Send_Notification(broadcast, client, net_type, net_name, args); return; }
 442         EIGHT_VARS_TO_VARARGS_VARLIST
 443         #undef VARITEM
 444
 445         Send_Notification(broadcast, client, net_type, net_name); // some notifications don't have any arguments at all
 446 }
 447
 448 void Send_Notification_Legacy_Wrapper(float broadcast, entity client,
 449         float net_type, float net_name,
 450         string s1, string s2,
 451         float f1, float f2, float f3)
 452 {
 453         float stringcount = Get_Notif_Strnum(net_type, net_name);
 454         float floatcount = Get_Notif_Flnum(net_type, net_name);
 455         Send_Notification_Without_VarArgs(broadcast, client, net_type, net_name, stringcount, floatcount, s1, s2, "", "", f1, f2, f3, NO_FL_ARG);
 456 }
 457
 458
 459 // =============================
 460 //  LEGACY NOTIFICATION SYSTEMS
 461 // =============================
 462
 463 void Send_CSQC_Centerprint_Generic(entity e, float id, string s, float duration, float countdown_num)
 464 {
 465         if ((clienttype(e) == CLIENTTYPE_REAL) && (e.flags & FL_CLIENT))
 466         {
 467                 msg_entity = e;
 468                 WRITESPECTATABLE_MSG_ONE({
 469                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 470                         WriteByte(MSG_ONE, TE_CSQC_CENTERPRINT_GENERIC);
 471                         WriteByte(MSG_ONE, id);
 472                         WriteString(MSG_ONE, s);
 473                         if (id != 0 && s != "")
 474                         {
 475                                 WriteByte(MSG_ONE, duration);
 476                                 WriteByte(MSG_ONE, countdown_num);
 477                         }
 478                 });
 479         }
 480 }
 481 void Send_CSQC_Centerprint_Generic_Expire(entity e, float id)
 482 {
 483         Send_CSQC_Centerprint_Generic(e, id, "", 1, 0);
 484 }
 485 #endif // ifdef SVQC
 486 #endif // ifndef MENUQC