qcsrc/common/notifications.qc

   1 // ================================================
   2 //  Unified notification system, written by Samual
   3 //  Last updated: February, 2013
   4 // ================================================
   5
   6 #ifndef MENUQC
   7 string arg_slot[8];
   8 string Fill_Notif_Args(string args, string input,
   9         string s1, string s2, string s3, string s4,
  10         float f1, float f2, float f3, float f4)
  11 {
  12         dprint(sprintf("Fill_Notif_Args('%s', '%s', %s, %s, %s, %s, %d, %d, %d, %d);\n",
  13                 args, input, s1, s2, s3, s4, f1, f2, f3, f4));
  14
  15         string selected, remaining = args;
  16         float sel_num = 0;
  17
  18         #ifdef CSQC
  19         string tmp_s;
  20         #endif
  21
  22         if((remaining != "") && (input != ""))
  23         {
  24                 for(;remaining;)
  25                 {
  26                         selected = car(remaining); remaining = cdr(remaining);
  27
  28                         switch(strtolower(selected))
  29                         {
  30                                 #define ADD_ARG_CASE(selected,result) case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
  31
  32                                 ADD_ARG_CASE("s1", s1)
  33                                 ADD_ARG_CASE("s2", s2)
  34                                 ADD_ARG_CASE("s3", s3)
  35                                 ADD_ARG_CASE("s4", s4)
  36                                 ADD_ARG_CASE("f1", ftos(f1))
  37                                 ADD_ARG_CASE("f2", ftos(f2))
  38                                 ADD_ARG_CASE("f3", ftos(f3))
  39                                 ADD_ARG_CASE("f4", ftos(f4))
  40
  41                                 #ifdef CSQC // CSQC replacements
  42                                 ADD_ARG_CASE("pass_key",                ((((tmp_s = getcommandkey("pass", "+use")) != "pass") && !(strstrofs(tmp_s, "not bound", 0) >= 0)) ? sprintf(CCR(_(" ^F1(Press %s)")), tmp_s) : ""))
  43                                 ADD_ARG_CASE("frag_ping",               ((f2 != BOT_PING) ? sprintf(CCR(_("\n(Ping ^2%d^BG)")), f2) : ""))
  44                                 ADD_ARG_CASE("frag_stats",              sprintf(CCR(_("\n(Health ^1%d^BG / Armor ^2%d^BG)%s")), f1, f2, ((f3 != BOT_PING) ? sprintf(CCR(_(" (Ping ^2%d^BG)")), f3) : "")))
  45                                 //ADD_ARG_CASE("frag_pos",              ((Should_Print_Score_Pos(f1)) ? sprintf("\n^BG%s", Read_Score_Pos(f1)) : ""))
  46                                 ADD_ARG_CASE("spree_cen",               (((f1 == 3) || (f1 == 5) || (f1 == 10) || (f1 == 15) || (f1 == 20) || (f1 == 25) || (f1 == 30)) ? sprintf(normal_or_gentle(_("%d frag spree! "), _("%d score spree! ")), f1) : ""))
  47                                 ADD_ARG_CASE("spree_inf",               (((f1 == 3) || (f1 == 5) || (f1 == 10) || (f1 == 15) || (f1 == 20) || (f1 == 25) || (f1 == 30)) ? sprintf(normal_or_gentle(_("%d frag spree! "), _("%d score spree! ")), f1) : ""))
  48                                 ADD_ARG_CASE("spree_end",               ((f1 >= 3) ? sprintf(normal_or_gentle(_(", ending their %d frag spree"), _(", ending their %d score spree")), f1) : ""))
  49                                 ADD_ARG_CASE("spree_lost",              ((f1 >= 3) ? sprintf(normal_or_gentle(_(", losing their %d frag spree"), _(", losing their %d score spree")), f1) : ""))
  50                                 ADD_ARG_CASE("death_team",              Team_ColoredFullName(f1 - 1))
  51                                 ADD_ARG_CASE("weapon_name",     ftos(f1)) // weaponorder[f1].netname
  52
  53                                 #else // SVQC replacements
  54                                 ADD_ARG_CASE("spree_inf",               (((f1 == 3) || (f1 == 5) || (f1 == 10) || (f1 == 15) || (f1 == 20) || (f1 == 25) || (f1 == 30)) ? sprintf(normal_or_gentle(_("%d frag spree! "), _("%d score spree! ")), f1) : ""))
  55                                 ADD_ARG_CASE("spree_end",               ((f1 >= 3) ? sprintf(normal_or_gentle(_(", ending their %d frag spree"), _(", ending their %d score spree")), f1) : ""))
  56                                 ADD_ARG_CASE("spree_lost",              ((f1 >= 3) ? sprintf(normal_or_gentle(_(", losing their %d frag spree"), _(", losing their %d score spree")), f1) : ""))
  57                                 ADD_ARG_CASE("death_team",              Team_ColoredFullName(f1))
  58                                 ADD_ARG_CASE("weapon_name",             ftos(f1)) // weaponorder[f1].netname
  59                                 #endif
  60
  61                                 #undef ADD_ARG_CASE
  62                                 default: { print("Hit unknown token in selected string! '", selected, "'\n"); break; }
  63                         }
  64                         if(sel_num == 7) { print("Hit maximum arguments!\n"); break; }
  65                 }
  66
  67                 return sprintf(input, arg_slot[0], arg_slot[1], arg_slot[2], arg_slot[3], arg_slot[4], arg_slot[5], arg_slot[6], arg_slot[7]);
  68         }
  69
  70         return "";
  71 }
  72
  73 entity Get_Notif_Ent(float net_type, float net_name)
  74 {
  75         switch(net_type)
  76         {
  77                 case MSG_INFO: return msg_info_notifs[net_name - 1];
  78                 case MSG_CENTER: return msg_center_notifs[net_name - 1];
  79                 case MSG_WEAPON: return msg_weapon_notifs[net_name - 1];
  80                 case MSG_DEATH: return msg_death_notifs[net_name - 1];
  81         }
  82         backtrace(sprintf("Get_Notif_Ent(%d, %d): Improper net type!\n", net_type, net_name));
  83         return world;
  84 }
  85
  86 string Get_Notif_Name(float net_type, float net_name)
  87 {
  88         entity e = Get_Notif_Ent(net_type, net_name);
  89         if(e) { return e.nent_name; }
  90         backtrace(sprintf("Get_Notif_Name(%d, %d): Could not find entity!\n", net_type, net_name));
  91         return "";
  92 }
  93
  94 float Get_Notif_Infval(float net_type, float net_name)
  95 {
  96         entity e = Get_Notif_Ent(net_type, net_name);
  97         if(e) { return e.nent_infoname; }
  98         backtrace(sprintf("Get_Notif_Infval(%d, %d): Could not find entity!\n", net_type, net_name));
  99         return NO_MSG;
 100 }
 101
 102 float Get_Notif_Cenval(float net_type, float net_name)
 103 {
 104         entity e = Get_Notif_Ent(net_type, net_name);
 105         if(e) { return e.nent_centername; }
 106         backtrace(sprintf("Get_Notif_Cenval(%d, %d): Could not find entity!\n", net_type, net_name));
 107         return NO_MSG;
 108 }
 109
 110 float Get_Notif_Strnum(float net_type, float net_name)
 111 {
 112         entity e = Get_Notif_Ent(net_type, net_name);
 113         if(e) { return e.nent_stringcount; }
 114         backtrace(sprintf("Get_Notif_Strnum(%d, %d): Could not find entity!\n", net_type, net_name));
 115         return NO_MSG;
 116 }
 117
 118 float Get_Notif_Flnum(float net_type, float net_name)
 119 {
 120         entity e = Get_Notif_Ent(net_type, net_name);
 121         if(e) { return e.nent_floatcount; }
 122         backtrace(sprintf("Get_Notif_Flnum(%d, %d): Could not find entity!\n", net_type, net_name));
 123         return NO_MSG;
 124 }
 125 #endif // ifndef MENUQC
 126
 127
 128 // ===============================
 129 //  Frontend Notification Pushing
 130 // ===============================
 131
 132 void Dump_Notifications(float fh, float alsoprint)
 133 {
 134         float MSG_INFO_NOTIFS = 0, MSG_CENTER_NOTIFS = 0, MSG_WEAPON_NOTIFS = 0, MSG_DEATH_NOTIFS = 0;
 135
 136         #define NOTIF_WRITE(type,name,text) { \
 137                 ++##type##_NOTIFS; \
 138                 notif_msg = sprintf("seta %s 1 // %s - %s\n", name, #type, strreplace("\n", "\\n", text)); \
 139                 fputs(fh, notif_msg); \
 140                 if(alsoprint) { print(strreplace("^", "^^", notif_msg)); } }
 141
 142         #ifndef MENUQC
 143         string notif_msg;
 144         float i;
 145         entity e;
 146
 147         for(i = 0; i < NOTIF_INFO_COUNT; ++i) { e = Get_Notif_Ent(MSG_INFO, i); NOTIF_WRITE(MSG_INFO, e.nent_name, e.nent_normal); }
 148         for(i = 0; i < NOTIF_CENTER_COUNT; ++i) { e = Get_Notif_Ent(MSG_CENTER, i); NOTIF_WRITE(MSG_CENTER, e.nent_name, e.nent_normal); }
 149         for(i = 0; i < NOTIF_WEAPON_COUNT; ++i) { e = Get_Notif_Ent(MSG_WEAPON, i); NOTIF_WRITE(MSG_WEAPON, e.nent_name,
 150                 sprintf("infoname: %s, centername: %s", Get_Notif_Name(MSG_INFO, Get_Notif_Infval(MSG_WEAPON, i)), Get_Notif_Name(MSG_CENTER, Get_Notif_Cenval(MSG_WEAPON, i)))); }
 151         for(i = 0; i < NOTIF_DEATH_COUNT; ++i) { e = Get_Notif_Ent(MSG_DEATH, i); NOTIF_WRITE(MSG_DEATH, e.nent_name,
 152                 sprintf("infoname: %s, centername: %s", Get_Notif_Name(MSG_INFO, Get_Notif_Infval(MSG_DEATH, i)), Get_Notif_Name(MSG_CENTER, Get_Notif_Cenval(MSG_DEATH, i)))); }
 153         #endif
 154
 155         print(sprintf("Notification counts: MSG_INFO = %d, MSG_CENTER = %d, MSG_WEAPON = %d, MSG_DEATH = %d\n",
 156                 MSG_INFO_NOTIFS, MSG_CENTER_NOTIFS, MSG_WEAPON_NOTIFS, MSG_DEATH_NOTIFS));
 157
 158         return;
 159         #undef NOTIF_WRITE
 160 }
 161
 162 #ifndef MENUQC
 163 #ifdef CSQC
 164 void HUD_Notify_Push(string icon, string attacker, string victim)
 165 {
 166         if(icon != "")
 167         {
 168                 --kn_index;
 169                 if (kn_index == -1) { kn_index = KN_MAX_ENTRIES-1; }
 170                 killnotify_times[kn_index] = time;
 171
 172                 // icon
 173                 if(killnotify_icon[kn_index]) { strunzone(killnotify_icon[kn_index]); }
 174                 killnotify_icon[kn_index] = strzone(icon);
 175
 176                 // attacker
 177                 if(killnotify_attackers[kn_index]) { strunzone(killnotify_attackers[kn_index]); }
 178                 killnotify_attackers[kn_index] = strzone(attacker);
 179
 180                 // victim
 181                 if(killnotify_victims[kn_index]) { strunzone(killnotify_victims[kn_index]); }
 182                 killnotify_victims[kn_index] = strzone(victim);
 183         }
 184 }
 185 #endif // ifdef CSQC
 186
 187 void Local_Notification(float net_type, float net_name, ...count)
 188 {
 189         // check supplied type and name for errors
 190         #ifdef NOTIFICATIONS_DEBUG
 191         {
 192                 #define CHECKARG_TYPENAME(type) case MSG_##type##: \
 193                         { if(!net_name || (net_name > NOTIF_##type##_COUNT)) \
 194                         { checkargs = sprintf("Improper name: %d!", net_name); } break; }
 195
 196                 string checkargs = "";
 197                 switch(net_type)
 198                 {
 199                         CHECKARG_TYPENAME(INFO)
 200                         CHECKARG_TYPENAME(CENTER)
 201                         CHECKARG_TYPENAME(WEAPON)
 202                         CHECKARG_TYPENAME(DEATH)
 203
 204                         default: { checkargs = sprintf("Improper type: %d!", checkargs, net_type); break; }
 205                 }
 206                 #undef CHECKARG_TYPENAME
 207
 208                 if(checkargs != "") { backtrace(sprintf("Incorrect usage of Local_Notification: %s\n", checkargs)); return; }
 209         }
 210         #endif
 211
 212         float stringcount = Get_Notif_Strnum(net_type, net_name);
 213         float floatcount = Get_Notif_Flnum(net_type, net_name);
 214
 215         string s1 = ((0 < stringcount) ? ...(0, string) : NO_STR_ARG);
 216         string s2 = ((1 < stringcount) ? ...(1, string) : NO_STR_ARG);
 217         string s3 = ((2 < stringcount) ? ...(2, string) : NO_STR_ARG);
 218         string s4 = ((3 < stringcount) ? ...(3, string) : NO_STR_ARG);
 219         float f1 = ((stringcount < count) ? ...(stringcount, float) : NO_FL_ARG);
 220         float f2 = (((stringcount + 1) < count) ? ...((stringcount + 1), float) : NO_FL_ARG);
 221         float f3 = (((stringcount + 2) < count) ? ...((stringcount + 2), float) : NO_FL_ARG);
 222         float f4 = (((stringcount + 3) < count) ? ...((stringcount + 3), float) : NO_FL_ARG);
 223
 224         #ifdef NOTIFICATIONS_DEBUG
 225         {
 226                 dprint(sprintf("Local_Notification(%d, %s, %s, %s, %s, %s, %d, %d, %d, %d);\n",
 227                         net_type, Get_Notif_Name(net_type, net_name),
 228                         s1, s2, s3, s4, f1, f2, f3, f4));
 229
 230                 if((stringcount + floatcount) > count)
 231                         { backtrace(sprintf("Not enough arguments for Local_Notification! stringcount(%d) + floatcount(%d) > count(%d) \
 232                         \nCheck the notification definition and function call for accuracy...?\n", stringcount, floatcount, count)); return; }
 233                 else if((stringcount + floatcount) < count)
 234                         { backtrace(sprintf("Too many arguments for Local_Notification! stringcount(%d) + floatcount(%d) < count(%d) \
 235                         \nCheck the notification definition and function call for accuracy...?\n", stringcount, floatcount, count)); return; }
 236         }
 237         #endif
 238
 239
 240         switch(net_type)
 241         {
 242                 case MSG_INFO:
 243                 {
 244                         #define MSG_INFO_NOTIF(name,strnum,flnum,args,hudargs,icon,normal,gentle) \
 245                                 case name: { CHECK_AUTOCVAR(name) \
 246                                 { \
 247                                         print(sprintf(CCR(normal_or_gentle(normal, gentle)), args)); \
 248                                         #ifdef CSQC \
 249                                                 if(icon != "") { HUD_Notify_Push(icon, hudargs); } \
 250                                         #endif \
 251                                 } return; }
 252
 253                         NOTIF_SWITCH_LIST(MSG_INFO, net_name, return)
 254
 255                         #undef MSG_INFO_NOTIF
 256                         break;
 257                 }
 258                 #ifdef CSQC
 259                 case MSG_CENTER:
 260                 {
 261                         #define MSG_CENTER_NOTIF(name,strnum,flnum,args,cpid,durcnt,normal,gentle) \
 262                                 case name: { CHECK_AUTOCVAR(name) \
 263                                 { \
 264                                         centerprint_generic(HANDLE_CPID(cpid), sprintf(CCR(normal_or_gentle(normal, gentle)), args), durcnt); \
 265                                 } return; }
 266
 267                         NOTIF_SWITCH_LIST(MSG_CENTER, net_name, return)
 268
 269                         #undef MSG_CENTER_NOTIF
 270                         break;
 271                 }
 272                 #endif
 273                 case MSG_WEAPON:
 274                 {
 275                         #define MSG_WEAPON_NOTIF(name,infoname,centername) \
 276                                 case name: { CHECK_AUTOCVAR(name) \
 277                                 { \
 278                                         #if infoname != NO_MSG \
 279                                                 Local_Notification_Without_VarArgs(MSG_INFO, infoname, \
 280                                                         Get_Notif_Strnum(MSG_INFO, infoname), \
 281                                                         Get_Notif_Flnum(MSG_INFO, infoname), \
 282                                                         s1, s2, s3, s4, f1, f2, f3, f4); \
 283                                         #endif \
 284                                         #ifdef CSQC \
 285                                                 #if centername != NO_MSG \
 286                                                         Local_Notification_Without_VarArgs(MSG_CENTER, centername, \
 287                                                                 Get_Notif_Strnum(MSG_CENTER, centername), \
 288                                                                 Get_Notif_Flnum(MSG_CENTER, centername), \
 289                                                                 s1, s2, s3, s4, f1, f2, f3, f4); \
 290                                                 #endif \
 291                                         #endif \
 292                                 } return; }
 293
 294                         NOTIF_SWITCH_LIST(MSG_WEAPON, net_name, return)
 295
 296                         #undef MSG_WEAPON_NOTIF
 297                         break;
 298                 }
 299                 case MSG_DEATH:
 300                 {
 301                         #define MSG_DEATH_NOTIF(name,infoname,centername) \
 302                                 case name: { CHECK_AUTOCVAR(name) \
 303                                 { \
 304                                         #if infoname != NO_MSG \
 305                                                 Local_Notification_Without_VarArgs(MSG_INFO, infoname, \
 306                                                         Get_Notif_Strnum(MSG_INFO, infoname), \
 307                                                         Get_Notif_Flnum(MSG_INFO, infoname), \
 308                                                         s1, s2, s3, s4, f1, f2, f3, f4); \
 309                                         #endif \
 310                                         #ifdef CSQC \
 311                                                 #if centername != NO_MSG \
 312                                                         Local_Notification_Without_VarArgs(MSG_CENTER, centername, \
 313                                                                 Get_Notif_Strnum(MSG_CENTER, centername), \
 314                                                                 Get_Notif_Flnum(MSG_CENTER, centername), \
 315                                                                 s1, s2, s3, s4, f1, f2, f3, f4); \
 316                                                 #endif \
 317                                         #endif \
 318                                 } return; }
 319
 320                         NOTIF_SWITCH_LIST(MSG_DEATH, net_name, return)
 321
 322                         #undef MSG_DEATH_NOTIF
 323                         break;
 324                 }
 325         }
 326 }
 327
 328 void Local_Notification_Without_VarArgs(float net_type, float net_name,
 329         float stringcount, float floatcount,
 330         string s1, string s2, string s3, string s4,
 331         float f1, float f2, float f3, float f4)
 332 {
 333         #define VARITEM(stringc,floatc,args) if((stringcount == stringc) && (floatcount == floatc)) { Local_Notification(net_type, net_name, args); return; }
 334         EIGHT_VARS_TO_VARARGS_VARLIST
 335         #undef VARITEM
 336
 337         Local_Notification(net_type, net_name); // some notifications don't have any arguments at all
 338 }
 339
 340
 341 // =========================
 342 //  Notification Networking
 343 // =========================
 344
 345 #ifdef CSQC
 346 void Read_Notification(float is_new)
 347 {
 348         float net_type = ReadByte();
 349         float net_name = ReadShort();
 350
 351         float stringcount = Get_Notif_Strnum(net_type, net_name);
 352         float floatcount = Get_Notif_Flnum(net_type, net_name);
 353
 354         string s1 = ((stringcount >= 1) ? ReadString() : NO_STR_ARG);
 355         string s2 = ((stringcount >= 2) ? ReadString() : NO_STR_ARG);
 356         string s3 = ((stringcount >= 3) ? ReadString() : NO_STR_ARG);
 357         string s4 = ((stringcount == 4) ? ReadString() : NO_STR_ARG);
 358         float f1 = ((floatcount >= 1) ? ReadLong() : NO_FL_ARG);
 359         float f2 = ((floatcount >= 2) ? ReadLong() : NO_FL_ARG);
 360         float f3 = ((floatcount >= 3) ? ReadLong() : NO_FL_ARG);
 361         float f4 = ((floatcount == 4) ? ReadLong() : NO_FL_ARG);
 362
 363         #ifdef NOTIFICATIONS_DEBUG
 364                 dprint(sprintf("Read_Notification(%d) at %f: net_name = %s.\n", is_new, time, Get_Notif_Name(net_type, net_name)));
 365         #endif
 366
 367         if(is_new) { Local_Notification_Without_VarArgs(net_type, net_name, stringcount, floatcount, s1, s2, s3, s4, f1, f2, f3, f4); }
 368 }
 369 #endif
 370
 371 #ifdef SVQC
 372 void Notification_Remove()
 373 {
 374         float i;
 375         for(i = 0; i < 4; ++i) { if(self.nent_strings[i]) { strunzone(self.nent_strings[i]); } }
 376         remove(self);
 377 }
 378
 379 float Write_Notification(entity client, float sf)
 380 {
 381         float i, send = FALSE;
 382
 383         switch(self.nent_broadcast)
 384         {
 385                 case NOTIF_ONE: { if((client == self.nent_client) || (client.classname == STR_SPECTATOR && client.enemy == self.nent_client)) { send = TRUE; } break; }
 386                 case NOTIF_ONE_ONLY: { if(client == self.nent_client) { send = TRUE; } break; }
 387                 case NOTIF_TEAM: { if((client.team == self.nent_client.team) || (client.classname == STR_SPECTATOR && client.enemy.team == self.nent_client.team)) { send = TRUE; } break; }
 388                 case NOTIF_TEAM_EXCEPT: { if(((client != self.nent_client) && (client.team == self.nent_client.team) && !(client.classname == STR_SPECTATOR && client.enemy == self.nent_client))) { send = TRUE; } break; }
 389                 case NOTIF_ANY: { send = TRUE; break; }
 390                 case NOTIF_ANY_EXCEPT: { if((client != self.nent_client) && !(client.classname == STR_SPECTATOR && client.enemy == self.nent_client)) { send = TRUE; } break; }
 391                 default: { send = FALSE; break; }
 392         }
 393
 394         if(send)
 395         {
 396                 WriteByte(MSG_ENTITY, ENT_CLIENT_NOTIFICATION);
 397                 WriteByte(MSG_ENTITY, self.nent_net_type);
 398                 WriteShort(MSG_ENTITY, self.nent_net_name);
 399                 for(i = 0; i < self.nent_stringcount; ++i) { WriteString(MSG_ENTITY, self.nent_strings[i]); }
 400                 for(i = 0; i < self.nent_floatcount; ++i) { WriteLong(MSG_ENTITY, self.nent_floats[i]); }
 401         }
 402
 403         return send;
 404 }
 405
 406 void Send_Notification(float broadcast, entity client,
 407         float net_type, float net_name, ...count)
 408 {
 409         // check supplied broadcast, target, type, and name for errors
 410         #ifdef NOTIFICATIONS_DEBUG
 411         {
 412                 #define CHECKARG_TYPENAME(type) case MSG_##type##: \
 413                         { if(!net_name || (net_name > NOTIF_##type##_COUNT)) \
 414                         { checkargs = sprintf("Improper name: %d!", net_name); } break; }
 415
 416                 string checkargs = "";
 417                 switch(net_type)
 418                 {
 419                         CHECKARG_TYPENAME(INFO)
 420                         CHECKARG_TYPENAME(CENTER)
 421                         CHECKARG_TYPENAME(WEAPON)
 422                         CHECKARG_TYPENAME(DEATH)
 423
 424                         default: { checkargs = sprintf("Improper type: %d!", checkargs, net_type); break; }
 425                 }
 426                 #undef CHECKARG_TYPENAME
 427
 428                 if(checkargs != "") { checkargs = strcat(checkargs, " "); }
 429                 switch(broadcast)
 430                 {
 431                         case NOTIF_ONE:
 432                         case NOTIF_ONE_ONLY: { if(clienttype(client) == CLIENTTYPE_NOTACLIENT) { checkargs = sprintf("%sNo client provided!", checkargs); } break; }
 433                         case NOTIF_ANY_EXCEPT: { if(clienttype(client) == CLIENTTYPE_NOTACLIENT) { checkargs = sprintf("%sException can't be a non-client!", checkargs); } break; }
 434                         case NOTIF_ANY: { if(client) { checkargs = sprintf("%sEntity provided when world was required!", checkargs); } break; }
 435
 436                         case NOTIF_TEAM:
 437                         case NOTIF_TEAM_EXCEPT:
 438                         {
 439                                 if not(teamplay) { checkargs = sprintf("%sTeamplay not active!", checkargs); }
 440                                 else if(clienttype(client) == CLIENTTYPE_NOTACLIENT)
 441                                 {
 442                                         if(broadcast == NOTIF_TEAM) { checkargs = sprintf("%sNo client provided!", checkargs); }
 443                                         else { checkargs = sprintf("%sException can't be a non-client!", checkargs); }
 444                                 }
 445                                 break;
 446                         }
 447
 448                         default: { checkargs = sprintf("%sImproper broadcast: %d!", checkargs, broadcast); break; }
 449                 }
 450
 451                 if(checkargs != "") { backtrace(sprintf("Incorrect usage of Send_Notification: %s\n", checkargs)); return; }
 452         }
 453         #endif
 454
 455         // retreive counts for the arguments of this notification
 456         float stringcount = Get_Notif_Strnum(net_type, net_name);
 457         float floatcount = Get_Notif_Flnum(net_type, net_name);
 458
 459         #ifdef NOTIFICATIONS_DEBUG
 460         {
 461                 dprint(sprintf("Send_Notification(%d, %d, %s, stringcount: %d, floatcount: %d, varargs: %d);\n",
 462                         broadcast, net_type, Get_Notif_Name(net_type, net_name), stringcount, floatcount, count));
 463
 464                 if((stringcount + floatcount) > count)
 465                         { backtrace(sprintf(strcat("Not enough arguments for Send_Notification! stringcount(%d) + floatcount(%d) > count(%d)\n",
 466                         "Check the notification definition and function call for accuracy...?\n"), stringcount, floatcount, count)); return; }
 467                 else if((stringcount + floatcount) < count)
 468                         { backtrace(sprintf(strcat("Too many arguments for Send_Notification! stringcount(%d) + floatcount(%d) < count(%d)\n",
 469                         "Check the notification definition and function call for accuracy...?\n"), stringcount, floatcount, count)); return; }
 470         }
 471         #endif
 472
 473         entity notif = spawn();
 474         notif.nent_broadcast = broadcast;
 475         notif.nent_client = client;
 476         notif.nent_net_type = net_type;
 477         notif.nent_net_name = net_name;
 478         notif.nent_stringcount = stringcount;
 479         notif.nent_floatcount = floatcount;
 480
 481         float i;
 482
 483         for(i = 0; i < stringcount; ++i) { notif.nent_strings[i] = strzone(...(i, string)); }
 484         for(i = 0; i < floatcount; ++i) { notif.nent_floats[i] = ...((stringcount + i), float); }
 485
 486         notif.think = Notification_Remove;
 487         notif.nextthink = (time + 0.5);
 488
 489         Net_LinkEntity(notif, FALSE, 0, Write_Notification);
 490
 491         if((!server_is_local) && (broadcast == NOTIF_ANY || broadcast == NOTIF_ANY_EXCEPT) && (net_type != MSG_CENTER))
 492                 { Local_Notification_Without_VarArgs(net_type, net_name, stringcount, floatcount,
 493                         IFSTR(0), IFSTR(1), IFSTR(2), IFSTR(3), IFFL(0), IFFL(1), IFFL(2), IFFL(3)); }
 494 }
 495
 496 void Send_Notification_Without_VarArgs(float broadcast, entity client,
 497         float net_type, float net_name,
 498         float stringcount, float floatcount,
 499         string s1, string s2, string s3, string s4,
 500         float f1, float f2, float f3, float f4)
 501 {
 502         #define VARITEM(stringc,floatc,args) if((stringcount == stringc) && (floatcount == floatc)) { Send_Notification(broadcast, client, net_type, net_name, args); return; }
 503         EIGHT_VARS_TO_VARARGS_VARLIST
 504         #undef VARITEM
 505
 506         Send_Notification(broadcast, client, net_type, net_name); // some notifications don't have any arguments at all
 507 }
 508
 509 void Send_Notification_Legacy_Wrapper(float broadcast, entity client,
 510         float net_type, float net_name,
 511         string s1, string s2,
 512         float f1, float f2, float f3)
 513 {
 514         float stringcount = Get_Notif_Strnum(net_type, net_name);
 515         float floatcount = Get_Notif_Flnum(net_type, net_name);
 516         Send_Notification_Without_VarArgs(broadcast, client, net_type, net_name, stringcount, floatcount, s1, s2, NO_STR_ARG, NO_STR_ARG, f1, f2, f3, NO_FL_ARG);
 517 }
 518
 519
 520 // =============================
 521 //  LEGACY NOTIFICATION SYSTEMS
 522 // =============================
 523
 524 void Send_CSQC_Centerprint_Generic(entity e, float id, string s, float duration, float countdown_num)
 525 {
 526         if ((clienttype(e) == CLIENTTYPE_REAL) && (e.flags & FL_CLIENT))
 527         {
 528                 msg_entity = e;
 529                 WRITESPECTATABLE_MSG_ONE({
 530                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 531                         WriteByte(MSG_ONE, TE_CSQC_CENTERPRINT_GENERIC);
 532                         WriteByte(MSG_ONE, id);
 533                         WriteString(MSG_ONE, s);
 534                         if (id != 0 && s != "")
 535                         {
 536                                 WriteByte(MSG_ONE, duration);
 537                                 WriteByte(MSG_ONE, countdown_num);
 538                         }
 539                 });
 540         }
 541 }
 542 void Send_CSQC_Centerprint_Generic_Expire(entity e, float id)
 543 {
 544         Send_CSQC_Centerprint_Generic(e, id, "", 1, 0);
 545 }
 546 #endif // ifdef SVQC
 547 #endif // ifndef MENUQC