qcsrc/common/notifications/all.qh

   1 #pragma once
   2
   3 #include <common/command/_mod.qh>
   4
   5 #include <common/constants.qh>
   6 #include <common/teams.qh>
   7 #include <common/util.qh>
   8
   9 /** main types/groups of notifications */
  10 ENUMCLASS(MSG)
  11         /** "Global" AND "personal" announcer messages */
  12         CASE(MSG, ANNCE)
  13         /** "Global" information messages */
  14         CASE(MSG, INFO)
  15         /** "Personal" centerprint messages */
  16         CASE(MSG, CENTER)
  17         /** Subcall MSG_INFO and/or MSG_CENTER notifications */
  18         CASE(MSG, MULTI)
  19         /** Choose which subcall wrapper to activate */
  20         CASE(MSG, CHOICE)
  21         /** Kill centerprint message @deprecated */
  22         CASE(MSG, CENTER_KILL)
  23 ENUMCLASS_END(MSG)
  24
  25 string Get_Notif_TypeName(MSG net_type)
  26 {
  27         switch (net_type)
  28         {
  29                 case MSG_ANNCE: return "MSG_ANNCE";
  30                 case MSG_INFO: return "MSG_INFO";
  31                 case MSG_CENTER: return "MSG_CENTER";
  32                 case MSG_MULTI: return "MSG_MULTI";
  33                 case MSG_CHOICE: return "MSG_CHOICE";
  34         }
  35         LOG_WARNF("Get_Notif_TypeName(%d): Improper net type!", ORDINAL(net_type));
  36         return "";
  37 }
  38
  39 ENUMCLASS(CPID)
  40         CASE(CPID, ASSAULT_ROLE)
  41         CASE(CPID, ROUND)
  42         CASE(CPID, CAMPCHECK)
  43         CASE(CPID, CTF_CAPSHIELD)
  44         CASE(CPID, CTF_LOWPRIO)
  45         CASE(CPID, CTF_PASS)
  46         CASE(CPID, STALEMATE)
  47         CASE(CPID, NADES)
  48         CASE(CPID, IDLING)
  49         CASE(CPID, ITEM)
  50         CASE(CPID, PREVENT_JOIN)
  51         CASE(CPID, KEEPAWAY)
  52         CASE(CPID, KEEPAWAY_WARN)
  53         CASE(CPID, KEYHUNT)
  54         CASE(CPID, KEYHUNT_OTHER)
  55         CASE(CPID, LMS)
  56         CASE(CPID, MISSING_TEAMS)
  57         CASE(CPID, MISSING_PLAYERS)
  58         CASE(CPID, INSTAGIB_FINDAMMO)
  59         CASE(CPID, MOTD)
  60         CASE(CPID, NIX)
  61         CASE(CPID, ONSLAUGHT)
  62         CASE(CPID, ONS_CAPSHIELD)
  63         CASE(CPID, OVERTIME)
  64         CASE(CPID, POWERUP)
  65         CASE(CPID, RACE_FINISHLAP)
  66         CASE(CPID, TEAMCHANGE)
  67         CASE(CPID, TIMEOUT)
  68         CASE(CPID, VEHICLES)
  69         CASE(CPID, VEHICLES_OTHER)
  70         /** always last */
  71         CASE(CPID, LAST)
  72 ENUMCLASS_END(CPID)
  73
  74 USING(Notification, entity);
  75
  76 // used for notification system multi-team identifiers
  77 #define APP_TEAM_NUM(num, prefix) ((num == NUM_TEAM_1) ? prefix##_RED : ((num == NUM_TEAM_2) ? prefix##_BLUE : ((num == NUM_TEAM_3) ? prefix##_YELLOW : prefix##_PINK)))
  78 /** @deprecated use APP_TEAM_NUM */
  79 #define APP_TEAM_ENT(ent, prefix) APP_TEAM_NUM(ent.team, prefix)
  80
  81 #define EIGHT_VARS_TO_VARARGS_VARLIST \
  82         VARITEM(1, 0, s1) \
  83         VARITEM(2, 0, XPD(s1, s2)) \
  84         VARITEM(3, 0, XPD(s1, s2, s3)) \
  85         VARITEM(4, 0, XPD(s1, s2, s3, s4)) \
  86         VARITEM(0, 1, f1) \
  87         VARITEM(1, 1, XPD(s1, f1)) \
  88         VARITEM(2, 1, XPD(s1, s2, f1)) \
  89         VARITEM(3, 1, XPD(s1, s2, s3, f1)) \
  90         VARITEM(4, 1, XPD(s1, s2, s3, s4, f1)) \
  91         VARITEM(0, 2, XPD(f1, f2)) \
  92         VARITEM(1, 2, XPD(s1, f1, f2)) \
  93         VARITEM(2, 2, XPD(s1, s2, f1, f2)) \
  94         VARITEM(3, 2, XPD(s1, s2, s3, f1, f2)) \
  95         VARITEM(4, 2, XPD(s1, s2, s3, s4, f1, f2)) \
  96         VARITEM(0, 3, XPD(f1, f2, f3)) \
  97         VARITEM(1, 3, XPD(s1, f1, f2, f3)) \
  98         VARITEM(2, 3, XPD(s1, s2, f1, f2, f3)) \
  99         VARITEM(3, 3, XPD(s1, s2, s3, f1, f2, f3)) \
 100         VARITEM(4, 3, XPD(s1, s2, s3, s4, f1, f2, f3)) \
 101         VARITEM(0, 4, XPD(f1, f2, f3, f4)) \
 102         VARITEM(1, 4, XPD(s1, f1, f2, f3, f4)) \
 103         VARITEM(2, 4, XPD(s1, s2, f1, f2, f3, f4)) \
 104         VARITEM(3, 4, XPD(s1, s2, s3, f1, f2, f3, f4)) \
 105         VARITEM(4, 4, XPD(s1, s2, s3, s4, f1, f2, f3, f4))
 106
 107 void Destroy_All_Notifications();
 108 void Create_Notification_Entity(entity notif,
 109         float var_default,
 110         float var_cvar,
 111         MSG typeId,
 112         string namestring);
 113 void Create_Notification_Entity_Annce(entity notif,
 114                                                                                 float var_cvar,
 115                                                                                 string namestring,
 116                                                                                 /* MSG_ANNCE */
 117                                                                                 float channel,
 118                                                                                 string snd,
 119                                                                                 float vol,
 120                                                                                 float position);
 121
 122 void Create_Notification_Entity_InfoCenter(entity notif,
 123                                                                                         float var_cvar,
 124                                                                                         string namestring,
 125                                                                                         int strnum,
 126                                                                                         int flnum,
 127                                                                                         /* MSG_INFO & MSG_CENTER */
 128                                                                                         string args,
 129                                                                                         string hudargs,
 130                                                                                         string icon,
 131                                                                                         CPID cpid,
 132                                                                                         string durcnt,
 133                                                                                         string normal,
 134                                                                                         string gentle);
 135
 136 void Create_Notification_Entity_Multi(entity notif,
 137                                                                                 float var_cvar,
 138                                                                                 string namestring,
 139                                                                                 /* MSG_MULTI */
 140                                                                                 Notification anncename,
 141                                                                                 Notification infoname,
 142                                                                                 Notification centername);
 143
 144 void Create_Notification_Entity_Choice(entity notif,
 145                                                                                 float var_cvar,
 146                                                                                 string namestring,
 147                                                                                 /* MSG_CHOICE */
 148                                                                                 float challow_def,
 149                                                                                 float challow_var,
 150                                                                                 MSG chtype,
 151                                                                                 Notification optiona,
 152                                                                                 Notification optionb);
 153
 154 void Dump_Notifications(int fh, bool alsoprint);
 155
 156 GENERIC_COMMAND(dumpnotifs, "Dump all notifications into notifications_dump.txt")
 157 {
 158         switch (request)
 159         {
 160                 case CMD_REQUEST_COMMAND:
 161                 {
 162                         #ifdef GAMEQC
 163                         string filename = argv(1);
 164                         bool alsoprint = false;
 165                         if (filename == "")
 166                         {
 167                                 filename = "notifications_dump.cfg";
 168                                 alsoprint = false;
 169                         }
 170                         else if (filename == "-")
 171                         {
 172                                 filename = "notifications_dump.cfg";
 173                                 alsoprint = true;
 174                         }
 175                         int fh = fopen(filename, FILE_WRITE);
 176                         if (fh >= 0)
 177                         {
 178                                 Dump_Notifications(fh, alsoprint);
 179                                 LOG_INFOF("Dumping notifications... File located in ^2data/data/%s^7.\n", filename);
 180                                 fclose(fh);
 181                         }
 182                         else
 183                         {
 184                                 LOG_INFOF("^1Error: ^7Could not open file '%s'!\n", filename);
 185                         }
 186                         #else
 187                         LOG_INFO(_("Notification dump command only works with cl_cmd and sv_cmd.\n"));
 188                         #endif
 189                         return;
 190                 }
 191                 default:
 192                 case CMD_REQUEST_USAGE:
 193                 {
 194                         LOG_INFO(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " dumpnotifs [filename]"));
 195                         LOG_INFO("  Where 'filename' is the file to write (default is notifications_dump.cfg),\n");
 196                         LOG_INFO("  if supplied with '-' output to console as well as default,\n");
 197                         LOG_INFO("  if left blank, it will only write to default.\n");
 198                         return;
 199                 }
 200         }
 201 }
 202
 203 float autocvar_notification_debug = false;
 204 #ifdef NOTIFICATIONS_DEBUG
 205 void Debug_Notification(string input)
 206 {
 207         switch (autocvar_notification_debug)
 208         {
 209                 case 1: { LOG_TRACE(input); break; }
 210                 case 2: { LOG_INFO(input); break; }
 211         }
 212 }
 213 #endif
 214
 215 void Local_Notification(MSG net_type, Notification net_name, ...count);
 216 /** glue for networking, forwards to `Local_Notification` */
 217 void Local_Notification_WOVA(
 218         MSG net_type, Notification net_name,
 219         float stringcount, float floatcount,
 220         string s1, string s2, string s3, string s4,
 221         float f1, float f2, float f3, float f4);
 222
 223 #ifdef CSQC
 224 string prev_soundfile;
 225 float prev_soundtime;
 226 #endif
 227
 228 #ifdef SVQC
 229 IntrusiveList g_notifications;
 230 STATIC_INIT(g_notifications) { g_notifications = IL_NEW(); }
 231 #endif
 232
 233 #ifdef SVQC
 234 ENUMCLASS(NOTIF)
 235         /** send to one client and their spectators */
 236         CASE(NOTIF, ONE)
 237         /** send ONLY to one client */
 238         CASE(NOTIF, ONE_ONLY)
 239         /** send only to X team and their spectators */
 240         CASE(NOTIF, TEAM)
 241         /** send only to X team and their spectators, except for Y person and their spectators */
 242         CASE(NOTIF, TEAM_EXCEPT)
 243         /** send to everyone */
 244         CASE(NOTIF, ALL)
 245         /** send to everyone except X person and their spectators */
 246         CASE(NOTIF, ALL_EXCEPT)
 247 ENUMCLASS_END(NOTIF)
 248
 249 string Get_Notif_BroadcastName(NOTIF broadcast)
 250 {
 251         switch (broadcast)
 252         {
 253                 case NOTIF_ONE: return "NOTIF_ONE";
 254                 case NOTIF_ONE_ONLY: return "NOTIF_ONE_ONLY";
 255                 case NOTIF_ALL_EXCEPT: return "NOTIF_ALL_EXCEPT";
 256                 case NOTIF_ALL: return "NOTIF_ALL";
 257                 case NOTIF_TEAM: return "NOTIF_TEAM";
 258                 case NOTIF_TEAM_EXCEPT: return "NOTIF_TEAM_EXCEPT";
 259         }
 260         LOG_WARNF("Get_Notif_BroadcastName(%d): Improper broadcast!", broadcast);
 261         return "";
 262 }
 263
 264 void Kill_Notification(
 265         NOTIF broadcast, entity client,
 266         MSG net_type, CPID net_name);
 267 void Send_Notification(
 268         NOTIF broadcast, entity client,
 269         MSG net_type, Notification net_name,
 270         ...count);
 271 void Send_Notification_WOVA(
 272         NOTIF broadcast, entity client,
 273         MSG net_type, Notification net_name,
 274         float stringcount, float floatcount,
 275         string s1, string s2, string s3, string s4,
 276         float f1, float f2, float f3, float f4);
 277 void Send_Notification_WOCOVA(
 278         NOTIF broadcast, entity client,
 279         MSG net_type, Notification net_name,
 280         string s1, string s2, string s3, string s4,
 281         float f1, float f2, float f3, float f4);
 282 #endif
 283
 284 // ===========================
 285 //  Special CVAR Declarations
 286 // ===========================
 287
 288 // MAKE SURE THIS IS ALWAYS SYNCHRONIZED WITH THE DUMP
 289 // NOTIFICATIONS FUNCTION IN THE .QC FILE!
 290
 291 #define NOTIF_ADD_AUTOCVAR(name,default) float autocvar_notification_##name = default;
 292
 293 float autocvar_notification_show_location = false;
 294 string autocvar_notification_show_location_string = ""; //_(" at the %s");
 295 float autocvar_notification_show_sprees = true;
 296 float autocvar_notification_show_sprees_info = 3; // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 297 float autocvar_notification_show_sprees_info_newline = true;
 298 float autocvar_notification_show_sprees_info_specialonly = true;
 299 float autocvar_notification_errors_are_fatal = true;
 300 float autocvar_notification_lifetime_runtime = 0.5;
 301 float autocvar_notification_lifetime_mapload = 10;
 302
 303 #ifdef SVQC
 304 .float FRAG_VERBOSE;
 305 void Notification_GetCvars(entity this);
 306 float autocvar_notification_server_allows_location = 1; // 0 = no, 1 = yes
 307 #else
 308 float autocvar_notification_item_centerprinttime = 1.5;
 309
 310 // 0 = no, 1 = yes, 2 = forced on for all MSG_INFO notifs
 311 // DISABLED IN CODE, BUT ENABLED IN CONFIG FOR COMPATIBILITY WITH OLD CLIENTS
 312 float autocvar_notification_allow_chatboxprint = 0;
 313
 314 float autocvar_notification_show_sprees_center = true;
 315 float autocvar_notification_show_sprees_center_specialonly = true;
 316 #endif
 317
 318
 319 // ============================
 320 //  Notification Argument List
 321 // ============================
 322 /*
 323  These arguments get replaced with the Local_Notification_sprintf
 324  and other such functions found in all.qc to supply data
 325  from networked notifications to their usage in sprintf... It
 326  allows for more dynamic data to be inferred by the local
 327  notification parser, so that the server does not have to network
 328  anything too crazy on a per-client/per-situation basis.
 329
 330  Pay attention to the CSQC/SVQC relations, some of these are redefined
 331  in slightly different ways for different programs, this is because the
 332  server does a more conservative approach to the notifs than the client.
 333
 334  All arguments are swapped into strings, so be sure that your
 335  sprintf usage matches with proper %s placement.
 336
 337  Argument descriptions:
 338         s1-s4: string arguments to be literally swapped into sprintf
 339         s2loc: s2 string of locations of deaths or other events
 340         s3loc: s3 string of locations of deaths or other events
 341         f1-f4: float arguments expanded into strings to be swapped into sprintf
 342         f1p2dec: f1 float to string with 2 decimal places
 343         f2p2dec: f2 float to string with 2 decimal places
 344         f2primsec: f2 float primary or secondary selection for weapons
 345         f3primsec: f3 float primary or secondary selection for weapons
 346         f1secs: count_seconds of f1
 347         f1points: point or points depending on f1
 348         f1ord: count_ordinal of f1
 349         f1time: process_time of f1
 350         f1race_time: mmssss of f1
 351         f2race_time: mmssss of f2
 352         race_col: color of race time/position (i.e. good or bad)
 353         race_diff: show time difference between f2 and f3
 354         missing_teams: show which teams still need players
 355         pass_key: find the keybind for "passing" or "dropping" in CTF game mode
 356         frag_ping: show the ping of a player
 357         frag_stats: show health/armor/ping of a player
 358         frag_pos: show score status and position in the match of a player
 359         spree_cen: centerprint notif for kill spree/how many kills they have
 360         spree_inf: info notif for kill spree/how many kills they have
 361         spree_end: placed at the end of murder messages to show ending of sprees
 362         spree_lost: placed at the end of suicide messages to show losing of sprees
 363         item_wepname: return full name of a weapon from weaponid
 364         item_wepammo: ammo display for weapon from string
 365         item_centime: amount of time to display weapon message in centerprint
 366         item_buffname: return full name of a buff from buffid
 367         death_team: show the full name of the team a player is switching from
 368         minigame1_name: return human readable name of a minigame from its id(s1)
 369         minigame1_d: return descriptor name of a minigame from its id(s1)
 370 */
 371
 372 const float NOTIF_MAX_ARGS = 7;
 373 const float NOTIF_MAX_HUDARGS = 2;
 374 const float NOTIF_MAX_DURCNT = 2;
 375
 376 string arg_slot[NOTIF_MAX_ARGS];
 377
 378 const float ARG_CS_SV_HA = 1; // enabled on CSQC, SVQC, and Hudargs
 379 const float ARG_CS_SV_DC = 2; // enabled on CSQC, SVQC, and durcnt centerprint
 380 const float ARG_CS_SV = 3; // enabled on CSQC and SVQC
 381 const float ARG_CS = 4; // unique result to CSQC
 382 const float ARG_SV = 5; // unique result to SVQC
 383 const float ARG_DC = 6; // unique result to durcnt/centerprint
 384
 385 // todo possible idea.... declare how many floats/strings each arg needs, and then dynamically increment the input
 386 // this way, we don't need to have duplicates like i.e. s2loc and s3loc?
 387
 388 string BUFF_NAME(int i);
 389
 390 #define NOTIF_ARGUMENT_LIST \
 391         ARG_CASE(ARG_CS_SV_HA,  "s1",            s1) \
 392         ARG_CASE(ARG_CS_SV_HA,  "s2",            s2) \
 393         ARG_CASE(ARG_CS_SV_HA,  "s3",            s3) \
 394         ARG_CASE(ARG_CS_SV_HA,  "s4",            s4) \
 395         ARG_CASE(ARG_CS_SV,     "s2loc",         ((autocvar_notification_show_location && (s2 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s2) : "")) \
 396         ARG_CASE(ARG_CS_SV,     "s3loc",         ((autocvar_notification_show_location && (s3 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s3) : "")) \
 397         ARG_CASE(ARG_CS_SV_DC,  "f1",            ftos(f1)) \
 398         ARG_CASE(ARG_CS_SV_DC,  "f2",            ftos(f2)) \
 399         ARG_CASE(ARG_CS_SV,     "f3",            ftos(f3)) \
 400         ARG_CASE(ARG_CS_SV,     "f4",            ftos(f4)) \
 401         ARG_CASE(ARG_CS_SV,     "f1p2dec",       ftos_decimals(f1/100, 2)) \
 402         ARG_CASE(ARG_CS_SV,     "f2p2dec",       ftos_decimals(f2/100, 2)) \
 403         ARG_CASE(ARG_CS,        "f2primsec",     (f2 ? _("secondary") : _("primary"))) \
 404         ARG_CASE(ARG_CS,        "f3primsec",     (f3 ? _("secondary") : _("primary"))) \
 405         ARG_CASE(ARG_CS,        "f1secs",        count_seconds(f1)) \
 406         ARG_CASE(ARG_CS,        "f1points",      (f1 == 1 ? _("point") : _("points"))) \
 407         ARG_CASE(ARG_CS_SV,     "f1ord",         count_ordinal(f1)) \
 408         ARG_CASE(ARG_CS,        "f1time",        process_time(2, f1)) \
 409         ARG_CASE(ARG_CS_SV_HA,  "f1race_time",   mmssss(f1)) \
 410         ARG_CASE(ARG_CS_SV_HA,  "f2race_time",   mmssss(f2)) \
 411         ARG_CASE(ARG_CS_SV_HA,  "f3race_time",   mmssss(f3)) \
 412         ARG_CASE(ARG_CS_SV,     "race_col",      CCR(((f1 == 1) ? "^F1" : "^F2"))) \
 413         ARG_CASE(ARG_CS_SV,     "race_diff",     ((f2 > f3) ? sprintf(CCR("^1[+%s]"), mmssss(f2 - f3)) : sprintf(CCR("^2[-%s]"), mmssss(f3 - f2)))) \
 414         ARG_CASE(ARG_CS,        "missing_teams", notif_arg_missing_teams(f1)) \
 415         ARG_CASE(ARG_CS,        "pass_key",      getcommandkey(_("drop flag"), "+use")) \
 416         ARG_CASE(ARG_CS,        "frag_ping",     notif_arg_frag_ping(true, f2)) \
 417         ARG_CASE(ARG_CS,        "frag_stats",    notif_arg_frag_stats(f2, f3, f4)) \
 418         /*ARG_CASE(ARG_CS,      "frag_pos",      ((Should_Print_Score_Pos(f1)) ? sprintf("\n^BG%s", Read_Score_Pos(f1)) : ""))*/ \
 419         ARG_CASE(ARG_CS,        "spree_cen",     (autocvar_notification_show_sprees ? notif_arg_spree_cen(f1) : "")) \
 420         ARG_CASE(ARG_CS_SV,     "spree_inf",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(1, input, s2, f2) : "")) \
 421         ARG_CASE(ARG_CS_SV,     "spree_end",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(-1, "", "", f1) : "")) \
 422         ARG_CASE(ARG_CS_SV,     "spree_lost",    (autocvar_notification_show_sprees ? notif_arg_spree_inf(-2, "", "", f1) : "")) \
 423         ARG_CASE(ARG_CS_SV,     "item_wepname",  Weapons_from(f1).m_name) \
 424         ARG_CASE(ARG_CS_SV,     "item_buffname", BUFF_NAME(f1)) \
 425         ARG_CASE(ARG_CS_SV,     "f3buffname",    BUFF_NAME(f3)) \
 426         ARG_CASE(ARG_CS_SV,     "item_wepammo",  (s1 != "" ? sprintf(_(" with %s"), s1) : "")) \
 427         ARG_CASE(ARG_DC,        "item_centime",  ftos(autocvar_notification_item_centerprinttime)) \
 428         ARG_CASE(ARG_SV,        "death_team",    Team_ColoredFullName(f1)) \
 429         ARG_CASE(ARG_CS,        "death_team",    Team_ColoredFullName(f1 - 1)) \
 430         ARG_CASE(ARG_CS_SV_HA,  "minigame1_name",find(NULL,netname,s1).descriptor.message) \
 431         ARG_CASE(ARG_CS_SV_HA,  "minigame1_d",   find(NULL,netname,s1).descriptor.netname)
 432
 433 #define NOTIF_HIT_MAX(count,funcname) MACRO_BEGIN { \
 434         if(sel_num == count) { backtrace(sprintf("%s: Hit maximum arguments!\n", funcname)); break; } \
 435 } MACRO_END
 436 #define NOTIF_HIT_UNKNOWN(token,funcname) { backtrace(sprintf("%s: Hit unknown token in selected string! '%s'\n", funcname, selected)); break; }
 437
 438 #define KILL_SPREE_LIST \
 439         SPREE_ITEM(3, 03, _("TRIPLE FRAG! "), _("%s^K1 made a TRIPLE FRAG! %s^BG"), _("%s^K1 made a TRIPLE SCORE! %s^BG")) \
 440         SPREE_ITEM(5, 05, _("RAGE! "), _("%s^K1 unlocked RAGE! %s^BG"), _("%s^K1 made FIVE SCORES IN A ROW! %s^BG")) \
 441         SPREE_ITEM(10, 10, _("MASSACRE! "), _("%s^K1 started a MASSACRE! %s^BG"), _("%s^K1 made TEN SCORES IN A ROW! %s^BG")) \
 442         SPREE_ITEM(15, 15, _("MAYHEM! "), _("%s^K1 executed MAYHEM! %s^BG"), _("%s^K1 made FIFTEEN SCORES IN A ROW! %s^BG")) \
 443         SPREE_ITEM(20, 20, _("BERSERKER! "), _("%s^K1 is a BERSERKER! %s^BG"), _("%s^K1 made TWENTY SCORES IN A ROW! %s^BG")) \
 444         SPREE_ITEM(25, 25, _("CARNAGE! "), _("%s^K1 inflicts CARNAGE! %s^BG"), _("%s^K1 made TWENTY FIVE SCORES IN A ROW! %s^BG")) \
 445         SPREE_ITEM(30, 30, _("ARMAGEDDON! "), _("%s^K1 unleashes ARMAGEDDON! %s^BG"), _("%s^K1 made THIRTY SCORES IN A ROW! %s^BG"))
 446
 447 #ifdef CSQC
 448 string notif_arg_frag_ping(bool newline, float fping)
 449 {
 450         string s = newline ? "\n" : " ";
 451         if (fping < 0)
 452                 return sprintf(CCR(_("%s(^F1Bot^BG)")), s);
 453         else
 454                 return sprintf(CCR(_("%s(Ping ^F1%d^BG)")), s, fping);
 455 }
 456
 457 string notif_arg_frag_stats(float fhealth, float farmor, float fping)
 458 {
 459         string s = notif_arg_frag_ping(false, fping);
 460         if (fhealth > 1)
 461                 return sprintf(CCR(_("\n(Health ^1%d^BG / Armor ^2%d^BG)%s")), fhealth, farmor, s);
 462         else
 463                 return sprintf(CCR(_("\n(^F4Dead^BG)%s")), s);
 464 }
 465
 466 string notif_arg_missing_teams(float f1)
 467 {
 468         return sprintf("%s%s%s%s",
 469                 ((f1 & BIT(0)) ? sprintf("%s%s", Team_ColoredFullName(NUM_TEAM_1), (f1 & (BIT(1) | BIT(2) | BIT(3)) ? ", " : "")) : ""),
 470                 ((f1 & BIT(1)) ? sprintf("%s%s", Team_ColoredFullName(NUM_TEAM_2), (f1 & (         BIT(2) | BIT(3)) ? ", " : "")) : ""),
 471                 ((f1 & BIT(2)) ? sprintf("%s%s", Team_ColoredFullName(NUM_TEAM_3), (f1 & (                  BIT(3)) ? ", " : "")) : ""),
 472                 ((f1 & BIT(3)) ?                 Team_ColoredFullName(NUM_TEAM_4)                                                 : "")
 473         );
 474 }
 475
 476 string notif_arg_spree_cen(float spree)
 477 {
 478         // 0 = off, 1 = target (but only for first victim) and attacker
 479         if(autocvar_notification_show_sprees_center)
 480         {
 481                 if(spree > 1)
 482                 {
 483                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 484                                 case counta: { return normal_or_gentle(center, sprintf(_("%d score spree! "), spree)); }
 485
 486                         switch(spree)
 487                         {
 488                                 KILL_SPREE_LIST
 489                                 default:
 490                                 {
 491                                         if (!autocvar_notification_show_sprees_center_specialonly)
 492                                         {
 493                                                 return
 494                                                         sprintf(
 495                                                                 normal_or_gentle(
 496                                                                         _("%d frag spree! "),
 497                                                                         _("%d score spree! ")
 498                                                                 ),
 499                                                                 spree);
 500                                         }
 501                                         else { return ""; } // don't show spree information if it isn't an achievement
 502                                 }
 503                         }
 504
 505                         #undef SPREE_ITEM
 506                 }
 507                 else if(spree == -1) // first blood
 508                 {
 509                         return normal_or_gentle(_("First blood! "), _("First score! "));
 510                 }
 511                 else if(spree == -2) // first victim
 512                 {
 513                         return normal_or_gentle(_("First victim! "), _("First casualty! "));
 514                 }
 515         }
 516         return "";
 517 }
 518 #endif
 519
 520 string notif_arg_spree_inf(float type, string input, string player, float spree)
 521 {
 522         switch(type)
 523         {
 524                 case 1: // attacker kill spree
 525                 {
 526                         // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 527                         // this conditional (& 2) is true for 2 and 3
 528                         if(autocvar_notification_show_sprees_info & 2)
 529                         {
 530                                 #ifdef CSQC
 531                                 string spree_newline =
 532                                         ( autocvar_notification_show_sprees_info_newline ?
 533                                                 ((substring(input, 0, 1) == "\{3}") ? "\n\{3}" : "\n") : "" );
 534                                 #else
 535                                 string spree_newline =
 536                                         (autocvar_notification_show_sprees_info_newline ? "\n" : "");
 537                                 #endif
 538
 539                                 if(spree > 1)
 540                                 {
 541                                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 542                                                 case counta: { return sprintf(CCR(normal_or_gentle(normal, gentle)), player, spree_newline); }
 543
 544                                         switch(spree)
 545                                         {
 546                                                 KILL_SPREE_LIST
 547                                                 default:
 548                                                 {
 549                                                         if (!autocvar_notification_show_sprees_info_specialonly)
 550                                                         {
 551                                                                 return
 552                                                                         sprintf(
 553                                                                                 CCR(normal_or_gentle(
 554                                                                                         _("%s^K1 has %d frags in a row! %s^BG"),
 555                                                                                         _("%s^K1 made %d scores in a row! %s^BG")
 556                                                                                 )),
 557                                                                                 player,
 558                                                                                 spree,
 559                                                                                 spree_newline
 560                                                                         );
 561                                                         }
 562                                                         else { return ""; } // don't show spree information if it isn't an achievement
 563                                                 }
 564                                         }
 565
 566                                         #undef SPREE_ITEM
 567                                 }
 568                                 else if(spree == -1) // firstblood
 569                                 {
 570                                         return
 571                                                 sprintf(
 572                                                         CCR(normal_or_gentle(
 573                                                                 _("%s^K1 drew first blood! %s^BG"),
 574                                                                 _("%s^K1 got the first score! %s^BG")
 575                                                         )),
 576                                                         player,
 577                                                         spree_newline
 578                                                 );
 579                                 }
 580                         }
 581                         break;
 582                 }
 583
 584                 case -1: // kill spree ended
 585                 {
 586                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 587                         {
 588                                 return
 589                                         sprintf(normal_or_gentle(
 590                                                 _(", ending their %d frag spree"),
 591                                                 _(", ending their %d score spree")
 592                                                 ),
 593                                                 spree
 594                                         );
 595                         }
 596                         break;
 597                 }
 598
 599                 case -2: // kill spree lost
 600                 {
 601                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 602                         {
 603                                 return
 604                                         sprintf(normal_or_gentle(
 605                                                 _(", losing their %d frag spree"),
 606                                                 _(", losing their %d score spree")
 607                                                 ),
 608                                                 spree
 609                                         );
 610                         }
 611                         break;
 612                 }
 613         }
 614         return "";
 615 }
 616
 617
 618 // ====================================
 619 //  Initialization/Create Declarations
 620 // ====================================
 621
 622 // common notification entity values
 623 .int nent_default;
 624 .bool nent_enabled;
 625 .MSG nent_type;
 626 .string nent_name;
 627 .int nent_stringcount;
 628 .int nent_floatcount;
 629
 630 // MSG_ANNCE entity values
 631 .int nent_channel;
 632 .string nent_snd;
 633 .float nent_vol;
 634 .float nent_position;
 635
 636 // MSG_INFO and MSG_CENTER entity values
 637 .string nent_args; // used by both
 638 .string nent_hudargs; // used by info
 639 .string nent_icon; // used by info
 640 .CPID nent_cpid; // used by center
 641 .string nent_durcnt; // used by center
 642 .string nent_string; // used by both
 643
 644 // MSG_MULTI entity values
 645 .entity nent_msgannce;
 646 .entity nent_msginfo;
 647 .entity nent_msgcenter;
 648
 649 // MSG_CHOICE entity values
 650 .float nent_challow_def;
 651 .float nent_challow_var;
 652 .entity nent_optiona;
 653 .entity nent_optionb;
 654
 655 // networked notification entity values
 656 #ifdef SVQC
 657 .NOTIF nent_broadcast;
 658 #endif
 659 .entity nent_client;
 660 .MSG nent_net_type;
 661 .float nent_net_name;
 662 .string nent_strings[4];
 663 .float nent_floats[4];
 664
 665 #define ACVNN(name) autocvar_notification_##name
 666
 667 REGISTRY(Notifications, BITS(11))
 668 REGISTER_REGISTRY(Notifications)
 669 REGISTRY_SORT(Notifications); STATIC_INIT(Notifications) { FOREACH(Notifications, true, it.m_id = i); }
 670 REGISTRY_CHECK(Notifications)
 671
 672 const int NOTIF_CHOICE_MAX = 50;
 673 int nent_choice_count = 0;
 674 .int nent_choice_idx;
 675 .int msg_choice_choices[NOTIF_CHOICE_MAX]; // set on each player containing MSG_CHOICE choices
 676 // initialization error detection
 677 bool notif_error;
 678 bool notif_global_error;
 679
 680 STATIC_INIT_LATE(Notif_Choices) {
 681         int c = 0;
 682         FOREACH(Notifications, it.nent_type == MSG_CHOICE, { c++; });
 683         if (c > NOTIF_CHOICE_MAX) {
 684                 LOG_FATALF("Too many MSG_CHOICE notifications (%d)", c);
 685         }
 686 }
 687
 688 Notification Get_Notif_Ent(MSG net_type, int net_name)
 689 {
 690         Notification it = _Notifications_from(net_name, NULL);
 691         if (it.nent_type != net_type) {
 692                 LOG_WARNF("Get_Notif_Ent(%s (%d), %s (%d)): Improper net type '%s'!",
 693                         Get_Notif_TypeName(net_type), net_type,
 694                         it.registered_id, net_name,
 695                         Get_Notif_TypeName(it.nent_type)
 696                 );
 697                 return NULL;
 698         }
 699         return it;
 700 }
 701
 702 #define MSG_ANNCE_NOTIF(name, default, sound, channel, volume, position) \
 703         MSG_ANNCE_NOTIF_(ANNCE_##name, default, sound, channel, volume, position)
 704 #define MSG_ANNCE_NOTIF_(name, default, sound, channel, volume, position) \
 705         NOTIF_ADD_AUTOCVAR(name, default) \
 706         REGISTER(Notifications, name, m_id, new_pure(msg_annce_notification)) { \
 707                 Create_Notification_Entity      (this, default, ACVNN(name), MSG_ANNCE, strtoupper(#name)); \
 708                 Create_Notification_Entity_Annce(this, ACVNN(name), strtoupper(#name), \
 709                         channel,   /* channel  */ \
 710                         sound,     /* snd      */ \
 711                         volume,    /* vol      */ \
 712                         position); /* position */ \
 713         }
 714
 715 #define MSG_INFO_NOTIF(name, default, strnum, flnum, args, hudargs, icon, normal, gentle) \
 716         MSG_INFO_NOTIF_(INFO_##name, default, strnum, flnum, args, hudargs, icon, normal, gentle)
 717 #define MSG_INFO_NOTIF_(name, default, strnum, flnum, args, hudargs, icon, normal, gentle) \
 718         NOTIF_ADD_AUTOCVAR(name, default) \
 719         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 720                 Create_Notification_Entity           (this, default, ACVNN(name), MSG_INFO, strtoupper(#name)); \
 721                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
 722                         args,     /* args    */ \
 723                         hudargs,  /* hudargs */ \
 724                         icon,     /* icon    */ \
 725                         CPID_Null,/* cpid    */ \
 726                         "",       /* durcnt  */ \
 727                         normal,   /* normal  */ \
 728                         gentle);  /* gentle  */ \
 729         }
 730
 731 .string nent_iconargs;
 732 #define MULTIICON_INFO(name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 733         MULTIICON_INFO_(INFO_##name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle)
 734 #define MULTIICON_INFO_(name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 735         NOTIF_ADD_AUTOCVAR(name, default) \
 736         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 737                 Create_Notification_Entity           (this, default, ACVNN(name), MSG_INFO, strtoupper(#name)); \
 738                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
 739                         args,     /* args    */ \
 740                         hudargs,  /* hudargs */ \
 741                         icon,     /* icon    */ \
 742                         CPID_Null,/* cpid    */ \
 743                         "",       /* durcnt  */ \
 744                         normal,   /* normal  */ \
 745                         gentle);  /* gentle  */ \
 746                 this.nent_iconargs = iconargs; \
 747         }
 748
 749 #define MSG_CENTER_NOTIF(name, default, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 750         MSG_CENTER_NOTIF_(CENTER_##name, default, strnum, flnum, args, cpid, durcnt, normal, gentle)
 751 #define MSG_CENTER_NOTIF_(name, default, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 752         NOTIF_ADD_AUTOCVAR(name, default) \
 753         REGISTER(Notifications, name, m_id, new_pure(msg_center_notification)) { \
 754                 Create_Notification_Entity           (this, default, ACVNN(name), MSG_CENTER, strtoupper(#name)); \
 755                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
 756                         args,    /* args    */ \
 757                         "",      /* hudargs */ \
 758                         "",      /* icon    */ \
 759                         cpid,    /* cpid    */ \
 760                         durcnt,  /* durcnt  */ \
 761                         normal,  /* normal  */ \
 762                         gentle); /* gentle  */ \
 763         }
 764
 765 #define MSG_MULTI_NOTIF(name, default, anncename, infoname, centername) \
 766         NOTIF_ADD_AUTOCVAR(name, default) \
 767         REGISTER(Notifications, name, m_id, new_pure(msg_multi_notification)) { \
 768                 Create_Notification_Entity      (this, default, ACVNN(name), MSG_MULTI, strtoupper(#name)); \
 769                 Create_Notification_Entity_Multi(this, ACVNN(name), strtoupper(#name), \
 770                         anncename,   /* anncename  */ \
 771                         infoname,    /* infoname   */ \
 772                         centername); /* centername */ \
 773         }
 774
 775 #define MSG_CHOICE_NOTIF(name, default, challow, chtype, optiona, optionb) \
 776         MSG_CHOICE_NOTIF_(CHOICE_##name, default, challow, chtype, optiona, optionb)
 777 #define MSG_CHOICE_NOTIF_(name, default, challow, chtype, optiona, optionb) \
 778         NOTIF_ADD_AUTOCVAR(name, default) \
 779         NOTIF_ADD_AUTOCVAR(name##_ALLOWED, challow) \
 780         REGISTER(Notifications, name, m_id, new_pure(msg_choice_notification)) { \
 781                 this.nent_choice_idx = nent_choice_count++; \
 782                 Create_Notification_Entity       (this, default, ACVNN(name), MSG_CHOICE, strtoupper(#name)); \
 783                 Create_Notification_Entity_Choice(this, ACVNN(name), strtoupper(#name), \
 784                         challow,                                 /* challow_def */ \
 785                         autocvar_notification_##name##_ALLOWED,  /* challow_var */ \
 786                         chtype,                                  /* chtype      */ \
 787                         optiona,                                 /* optiona     */ \
 788                         optionb);                                /* optionb     */ \
 789         }
 790
 791 REGISTRY_BEGIN(Notifications)
 792 {
 793         notif_global_error = false;
 794 }
 795
 796 REGISTRY_END(Notifications)
 797 {
 798         if (!notif_global_error) return;
 799         // shit happened... stop the loading of the program now if this is unacceptable
 800         if (autocvar_notification_errors_are_fatal)
 801                 LOG_FATAL("Notification initialization failed! Read above and fix the errors!");
 802         else
 803                 LOG_SEVERE("Notification initialization failed! Read above and fix the errors!");
 804 }
 805
 806 #include "all.inc"