qcsrc/common/notifications/all.qh

   1 #pragma once
   2
   3 #include <common/command/_mod.qh>
   4
   5 #include <common/constants.qh>
   6 #include <common/teams.qh>
   7 #include <common/util.qh>
   8
   9 /** main types/groups of notifications */
  10 ENUMCLASS(MSG)
  11         /** "Global" AND "personal" announcer messages */
  12         CASE(MSG, ANNCE)
  13         /** "Global" information messages */
  14         CASE(MSG, INFO)
  15         /** "Personal" centerprint messages */
  16         CASE(MSG, CENTER)
  17         /** Subcall MSG_INFO and/or MSG_CENTER notifications */
  18         CASE(MSG, MULTI)
  19         /** Choose which subcall wrapper to activate */
  20         CASE(MSG, CHOICE)
  21         /** Kill centerprint message @deprecated */
  22         CASE(MSG, CENTER_KILL)
  23 ENUMCLASS_END(MSG)
  24
  25 string Get_Notif_TypeName(MSG net_type)
  26 {
  27         switch (net_type)
  28         {
  29                 case MSG_ANNCE: return "MSG_ANNCE";
  30                 case MSG_INFO: return "MSG_INFO";
  31                 case MSG_CENTER: return "MSG_CENTER";
  32                 case MSG_MULTI: return "MSG_MULTI";
  33                 case MSG_CHOICE: return "MSG_CHOICE";
  34         }
  35         LOG_WARNF("Get_Notif_TypeName(%d): Improper net type!", ORDINAL(net_type));
  36         return "";
  37 }
  38
  39 ENUMCLASS(CPID)
  40         CASE(CPID, ASSAULT_ROLE)
  41         CASE(CPID, ROUND)
  42         CASE(CPID, CAMPCHECK)
  43         CASE(CPID, CTF_CAPSHIELD)
  44         CASE(CPID, CTF_LOWPRIO)
  45         CASE(CPID, CTF_PASS)
  46         CASE(CPID, STALEMATE)
  47         CASE(CPID, NADES)
  48         CASE(CPID, IDLING)
  49         CASE(CPID, ITEM)
  50         CASE(CPID, PREVENT_JOIN)
  51         CASE(CPID, KEEPAWAY)
  52         CASE(CPID, KEEPAWAY_WARN)
  53         CASE(CPID, KEYHUNT)
  54         CASE(CPID, KEYHUNT_OTHER)
  55         CASE(CPID, LMS)
  56         CASE(CPID, MISSING_TEAMS)
  57         CASE(CPID, MISSING_PLAYERS)
  58         CASE(CPID, INSTAGIB_FINDAMMO)
  59         CASE(CPID, MOTD)
  60         CASE(CPID, NIX)
  61         CASE(CPID, ONSLAUGHT)
  62         CASE(CPID, ONS_CAPSHIELD)
  63         CASE(CPID, OVERTIME)
  64         CASE(CPID, POWERUP)
  65         CASE(CPID, RACE_FINISHLAP)
  66         CASE(CPID, TEAMCHANGE)
  67         CASE(CPID, TIMEOUT)
  68         CASE(CPID, VEHICLES)
  69         CASE(CPID, VEHICLES_OTHER)
  70         /** always last */
  71         CASE(CPID, LAST)
  72 ENUMCLASS_END(CPID)
  73
  74 USING(Notification, entity);
  75
  76 // used for notification system multi-team identifiers
  77 #define APP_TEAM_NUM(num, prefix) ((num == NUM_TEAM_1) ? prefix##_RED : ((num == NUM_TEAM_2) ? prefix##_BLUE : ((num == NUM_TEAM_3) ? prefix##_YELLOW : prefix##_PINK)))
  78 #define APP_NUM(num, prefix) ((num) ? APP_TEAM_NUM(num, prefix) : prefix##_NEUTRAL)
  79
  80 #define EIGHT_VARS_TO_VARARGS_VARLIST \
  81         VARITEM(1, 0, s1) \
  82         VARITEM(2, 0, XPD(s1, s2)) \
  83         VARITEM(3, 0, XPD(s1, s2, s3)) \
  84         VARITEM(4, 0, XPD(s1, s2, s3, s4)) \
  85         VARITEM(0, 1, f1) \
  86         VARITEM(1, 1, XPD(s1, f1)) \
  87         VARITEM(2, 1, XPD(s1, s2, f1)) \
  88         VARITEM(3, 1, XPD(s1, s2, s3, f1)) \
  89         VARITEM(4, 1, XPD(s1, s2, s3, s4, f1)) \
  90         VARITEM(0, 2, XPD(f1, f2)) \
  91         VARITEM(1, 2, XPD(s1, f1, f2)) \
  92         VARITEM(2, 2, XPD(s1, s2, f1, f2)) \
  93         VARITEM(3, 2, XPD(s1, s2, s3, f1, f2)) \
  94         VARITEM(4, 2, XPD(s1, s2, s3, s4, f1, f2)) \
  95         VARITEM(0, 3, XPD(f1, f2, f3)) \
  96         VARITEM(1, 3, XPD(s1, f1, f2, f3)) \
  97         VARITEM(2, 3, XPD(s1, s2, f1, f2, f3)) \
  98         VARITEM(3, 3, XPD(s1, s2, s3, f1, f2, f3)) \
  99         VARITEM(4, 3, XPD(s1, s2, s3, s4, f1, f2, f3)) \
 100         VARITEM(0, 4, XPD(f1, f2, f3, f4)) \
 101         VARITEM(1, 4, XPD(s1, f1, f2, f3, f4)) \
 102         VARITEM(2, 4, XPD(s1, s2, f1, f2, f3, f4)) \
 103         VARITEM(3, 4, XPD(s1, s2, s3, f1, f2, f3, f4)) \
 104         VARITEM(4, 4, XPD(s1, s2, s3, s4, f1, f2, f3, f4))
 105
 106 void Destroy_All_Notifications();
 107 void Create_Notification_Entity(entity notif,
 108         float var_default,
 109         float var_cvar,
 110         MSG typeId,
 111         string namestring);
 112 void Create_Notification_Entity_Annce(entity notif,
 113                                                                                 float var_cvar,
 114                                                                                 string namestring,
 115                                                                                 /* MSG_ANNCE */
 116                                                                                 float channel,
 117                                                                                 string snd,
 118                                                                                 float vol,
 119                                                                                 float position);
 120
 121 void Create_Notification_Entity_InfoCenter(entity notif,
 122                                                                                         float var_cvar,
 123                                                                                         string namestring,
 124                                                                                         int strnum,
 125                                                                                         int flnum,
 126                                                                                         /* MSG_INFO & MSG_CENTER */
 127                                                                                         string args,
 128                                                                                         string hudargs,
 129                                                                                         string icon,
 130                                                                                         CPID cpid,
 131                                                                                         string durcnt,
 132                                                                                         string normal,
 133                                                                                         string gentle);
 134
 135 void Create_Notification_Entity_Multi(entity notif,
 136                                                                                 float var_cvar,
 137                                                                                 string namestring,
 138                                                                                 /* MSG_MULTI */
 139                                                                                 Notification anncename,
 140                                                                                 Notification infoname,
 141                                                                                 Notification centername);
 142
 143 void Create_Notification_Entity_Choice(entity notif,
 144                                                                                 float var_cvar,
 145                                                                                 string namestring,
 146                                                                                 /* MSG_CHOICE */
 147                                                                                 float challow_def,
 148                                                                                 float challow_var,
 149                                                                                 MSG chtype,
 150                                                                                 Notification optiona,
 151                                                                                 Notification optionb);
 152
 153 void Dump_Notifications(int fh, bool alsoprint);
 154
 155 GENERIC_COMMAND(dumpnotifs, "Dump all notifications into notifications_dump.txt")
 156 {
 157         switch (request)
 158         {
 159                 case CMD_REQUEST_COMMAND:
 160                 {
 161                         #ifdef GAMEQC
 162                         string filename = argv(1);
 163                         bool alsoprint = false;
 164                         if (filename == "")
 165                         {
 166                                 filename = "notifications_dump.cfg";
 167                                 alsoprint = false;
 168                         }
 169                         else if (filename == "-")
 170                         {
 171                                 filename = "notifications_dump.cfg";
 172                                 alsoprint = true;
 173                         }
 174                         int fh = fopen(filename, FILE_WRITE);
 175                         if (fh >= 0)
 176                         {
 177                                 Dump_Notifications(fh, alsoprint);
 178                                 LOG_INFOF("Dumping notifications... File located in ^2data/data/%s^7.\n", filename);
 179                                 fclose(fh);
 180                         }
 181                         else
 182                         {
 183                                 LOG_INFOF("^1Error: ^7Could not open file '%s'!\n", filename);
 184                         }
 185                         #else
 186                         LOG_INFO(_("Notification dump command only works with cl_cmd and sv_cmd.\n"));
 187                         #endif
 188                         return;
 189                 }
 190                 default:
 191                 case CMD_REQUEST_USAGE:
 192                 {
 193                         LOG_INFO(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " dumpnotifs [filename]"));
 194                         LOG_INFO("  Where 'filename' is the file to write (default is notifications_dump.cfg),\n");
 195                         LOG_INFO("  if supplied with '-' output to console as well as default,\n");
 196                         LOG_INFO("  if left blank, it will only write to default.\n");
 197                         return;
 198                 }
 199         }
 200 }
 201
 202 float autocvar_notification_debug = false;
 203 #ifdef NOTIFICATIONS_DEBUG
 204 void Debug_Notification(string input)
 205 {
 206         switch (autocvar_notification_debug)
 207         {
 208                 case 1: { LOG_TRACE(input); break; }
 209                 case 2: { LOG_INFO(input); break; }
 210         }
 211 }
 212 #endif
 213
 214 void Local_Notification(MSG net_type, Notification net_name, ...count);
 215 /** glue for networking, forwards to `Local_Notification` */
 216 void Local_Notification_WOVA(
 217         MSG net_type, Notification net_name,
 218         float stringcount, float floatcount,
 219         string s1, string s2, string s3, string s4,
 220         float f1, float f2, float f3, float f4);
 221
 222 #ifdef CSQC
 223 string prev_soundfile;
 224 float prev_soundtime;
 225 #endif
 226
 227 #ifdef SVQC
 228 IntrusiveList g_notifications;
 229 STATIC_INIT(g_notifications) { g_notifications = IL_NEW(); }
 230 #endif
 231
 232 #ifdef SVQC
 233 ENUMCLASS(NOTIF)
 234         /** send to one client and their spectators */
 235         CASE(NOTIF, ONE)
 236         /** send ONLY to one client */
 237         CASE(NOTIF, ONE_ONLY)
 238         /** send only to X team and their spectators */
 239         CASE(NOTIF, TEAM)
 240         /** send only to X team and their spectators, except for Y person and their spectators */
 241         CASE(NOTIF, TEAM_EXCEPT)
 242         /** send to everyone */
 243         CASE(NOTIF, ALL)
 244         /** send to everyone except X person and their spectators */
 245         CASE(NOTIF, ALL_EXCEPT)
 246 ENUMCLASS_END(NOTIF)
 247
 248 string Get_Notif_BroadcastName(NOTIF broadcast)
 249 {
 250         switch (broadcast)
 251         {
 252                 case NOTIF_ONE: return "NOTIF_ONE";
 253                 case NOTIF_ONE_ONLY: return "NOTIF_ONE_ONLY";
 254                 case NOTIF_ALL_EXCEPT: return "NOTIF_ALL_EXCEPT";
 255                 case NOTIF_ALL: return "NOTIF_ALL";
 256                 case NOTIF_TEAM: return "NOTIF_TEAM";
 257                 case NOTIF_TEAM_EXCEPT: return "NOTIF_TEAM_EXCEPT";
 258         }
 259         LOG_WARNF("Get_Notif_BroadcastName(%d): Improper broadcast!", broadcast);
 260         return "";
 261 }
 262
 263 void Kill_Notification(
 264         NOTIF broadcast, entity client,
 265         MSG net_type, CPID net_name);
 266 void Send_Notification(
 267         NOTIF broadcast, entity client,
 268         MSG net_type, Notification net_name,
 269         ...count);
 270 void Send_Notification_WOVA(
 271         NOTIF broadcast, entity client,
 272         MSG net_type, Notification net_name,
 273         float stringcount, float floatcount,
 274         string s1, string s2, string s3, string s4,
 275         float f1, float f2, float f3, float f4);
 276 void Send_Notification_WOCOVA(
 277         NOTIF broadcast, entity client,
 278         MSG net_type, Notification net_name,
 279         string s1, string s2, string s3, string s4,
 280         float f1, float f2, float f3, float f4);
 281 #endif
 282
 283 // ===========================
 284 //  Special CVAR Declarations
 285 // ===========================
 286
 287 // MAKE SURE THIS IS ALWAYS SYNCHRONIZED WITH THE DUMP
 288 // NOTIFICATIONS FUNCTION IN THE .QC FILE!
 289
 290 #define NOTIF_ADD_AUTOCVAR(name,default) float autocvar_notification_##name = default;
 291
 292 float autocvar_notification_show_location = false;
 293 string autocvar_notification_show_location_string = ""; //_(" at the %s");
 294 float autocvar_notification_show_sprees = true;
 295 float autocvar_notification_show_sprees_info = 3; // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 296 float autocvar_notification_show_sprees_info_newline = true;
 297 float autocvar_notification_show_sprees_info_specialonly = true;
 298 float autocvar_notification_errors_are_fatal = true;
 299 float autocvar_notification_lifetime_runtime = 0.5;
 300 float autocvar_notification_lifetime_mapload = 10;
 301
 302 #ifdef SVQC
 303 .float FRAG_VERBOSE;
 304 void Notification_GetCvars(entity this);
 305 float autocvar_notification_server_allows_location = 1; // 0 = no, 1 = yes
 306 #else
 307 float autocvar_notification_item_centerprinttime = 1.5;
 308
 309 // 0 = no, 1 = yes, 2 = forced on for all MSG_INFO notifs
 310 // DISABLED IN CODE, BUT ENABLED IN CONFIG FOR COMPATIBILITY WITH OLD CLIENTS
 311 float autocvar_notification_allow_chatboxprint = 0;
 312
 313 float autocvar_notification_show_sprees_center = true;
 314 float autocvar_notification_show_sprees_center_specialonly = true;
 315 #endif
 316
 317
 318 // ============================
 319 //  Notification Argument List
 320 // ============================
 321 /*
 322  These arguments get replaced with the Local_Notification_sprintf
 323  and other such functions found in all.qc to supply data
 324  from networked notifications to their usage in sprintf... It
 325  allows for more dynamic data to be inferred by the local
 326  notification parser, so that the server does not have to network
 327  anything too crazy on a per-client/per-situation basis.
 328
 329  Pay attention to the CSQC/SVQC relations, some of these are redefined
 330  in slightly different ways for different programs, this is because the
 331  server does a more conservative approach to the notifs than the client.
 332
 333  All arguments are swapped into strings, so be sure that your
 334  sprintf usage matches with proper %s placement.
 335
 336  Argument descriptions:
 337         s1-s4: string arguments to be literally swapped into sprintf
 338         s2loc: s2 string of locations of deaths or other events
 339         s3loc: s3 string of locations of deaths or other events
 340         f1-f4: float arguments expanded into strings to be swapped into sprintf
 341         f1p2dec: f1 float to string with 2 decimal places
 342         f2p2dec: f2 float to string with 2 decimal places
 343         f2primsec: f2 float primary or secondary selection for weapons
 344         f3primsec: f3 float primary or secondary selection for weapons
 345         f1secs: count_seconds of f1
 346         f1points: point or points depending on f1
 347         f1ord: count_ordinal of f1
 348         f1time: process_time of f1
 349         f1race_time: mmssss of f1
 350         f2race_time: mmssss of f2
 351         race_col: color of race time/position (i.e. good or bad)
 352         race_diff: show time difference between f2 and f3
 353         missing_teams: show which teams still need players
 354         pass_key: find the keybind for "passing" or "dropping" in CTF game mode
 355         nade_key: find the keybind for nade throwing
 356         frag_ping: show the ping of a player
 357         frag_stats: show health/armor/ping of a player
 358         frag_pos: show score status and position in the match of a player
 359         spree_cen: centerprint notif for kill spree/how many kills they have
 360         spree_inf: info notif for kill spree/how many kills they have
 361         spree_end: placed at the end of murder messages to show ending of sprees
 362         spree_lost: placed at the end of suicide messages to show losing of sprees
 363         item_wepname: return full name of a weapon from weaponid
 364         item_wepammo: ammo display for weapon from string
 365         item_centime: amount of time to display weapon message in centerprint
 366         item_buffname: return full name of a buff from buffid
 367         death_team: show the full name of the team a player is switching from
 368         minigame1_name: return human readable name of a minigame from its id(s1)
 369         minigame1_d: return descriptor name of a minigame from its id(s1)
 370 */
 371
 372 const float NOTIF_MAX_ARGS = 7;
 373 const float NOTIF_MAX_HUDARGS = 2;
 374 const float NOTIF_MAX_DURCNT = 2;
 375
 376 string arg_slot[NOTIF_MAX_ARGS];
 377
 378 const float ARG_CS_SV_HA = 1; // enabled on CSQC, SVQC, and Hudargs
 379 const float ARG_CS_SV_DC = 2; // enabled on CSQC, SVQC, and durcnt centerprint
 380 const float ARG_CS_SV = 3; // enabled on CSQC and SVQC
 381 const float ARG_CS = 4; // unique result to CSQC
 382 const float ARG_SV = 5; // unique result to SVQC
 383 const float ARG_DC = 6; // unique result to durcnt/centerprint
 384
 385 // todo possible idea.... declare how many floats/strings each arg needs, and then dynamically increment the input
 386 // this way, we don't need to have duplicates like i.e. s2loc and s3loc?
 387
 388 string BUFF_NAME(int i);
 389
 390 #define NOTIF_ARGUMENT_LIST \
 391         ARG_CASE(ARG_CS_SV_HA,  "s1",            s1) \
 392         ARG_CASE(ARG_CS_SV_HA,  "s2",            s2) \
 393         ARG_CASE(ARG_CS_SV_HA,  "s3",            s3) \
 394         ARG_CASE(ARG_CS_SV_HA,  "s4",            s4) \
 395         ARG_CASE(ARG_CS_SV,     "s2loc",         ((autocvar_notification_show_location && (s2 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s2) : "")) \
 396         ARG_CASE(ARG_CS_SV,     "s3loc",         ((autocvar_notification_show_location && (s3 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s3) : "")) \
 397         ARG_CASE(ARG_CS_SV_DC,  "f1",            ftos(f1)) \
 398         ARG_CASE(ARG_CS_SV_DC,  "f2",            ftos(f2)) \
 399         ARG_CASE(ARG_CS_SV,     "f3",            ftos(f3)) \
 400         ARG_CASE(ARG_CS_SV,     "f4",            ftos(f4)) \
 401         ARG_CASE(ARG_CS_SV,     "f1p2dec",       ftos_decimals(f1/100, 2)) \
 402         ARG_CASE(ARG_CS_SV,     "f2p2dec",       ftos_decimals(f2/100, 2)) \
 403         ARG_CASE(ARG_CS,        "f2primsec",     (f2 ? _("secondary") : _("primary"))) \
 404         ARG_CASE(ARG_CS,        "f3primsec",     (f3 ? _("secondary") : _("primary"))) \
 405         ARG_CASE(ARG_CS,        "f1secs",        count_seconds(f1)) \
 406         ARG_CASE(ARG_CS,        "f1points",      (f1 == 1 ? _("point") : _("points"))) \
 407         ARG_CASE(ARG_CS_SV,     "f1ord",         count_ordinal(f1)) \
 408         ARG_CASE(ARG_CS,        "f1time",        process_time(2, f1)) \
 409         ARG_CASE(ARG_CS_SV_HA,  "f1race_time",   mmssss(f1)) \
 410         ARG_CASE(ARG_CS_SV_HA,  "f2race_time",   mmssss(f2)) \
 411         ARG_CASE(ARG_CS_SV_HA,  "f3race_time",   mmssss(f3)) \
 412         ARG_CASE(ARG_CS_SV,     "race_col",      CCR(((f1 == 1) ? "^F1" : "^F2"))) \
 413         ARG_CASE(ARG_CS_SV,     "race_diff",     ((f2 > f3) ? sprintf(CCR("^1[+%s]"), mmssss(f2 - f3)) : sprintf(CCR("^2[-%s]"), mmssss(f3 - f2)))) \
 414         ARG_CASE(ARG_CS,        "missing_teams", notif_arg_missing_teams(f1)) \
 415         ARG_CASE(ARG_CS,        "pass_key",      getcommandkey(_("drop flag"), "+use")) \
 416         ARG_CASE(ARG_CS,        "nade_key",      getcommandkey(_("throw nade"), "dropweapon")) \
 417         ARG_CASE(ARG_CS,        "frag_ping",     notif_arg_frag_ping(true, f2)) \
 418         ARG_CASE(ARG_CS,        "frag_stats",    notif_arg_frag_stats(f2, f3, f4)) \
 419         /*ARG_CASE(ARG_CS,      "frag_pos",      ((Should_Print_Score_Pos(f1)) ? sprintf("\n^BG%s", Read_Score_Pos(f1)) : ""))*/ \
 420         ARG_CASE(ARG_CS,        "spree_cen",     (autocvar_notification_show_sprees ? notif_arg_spree_cen(f1) : "")) \
 421         ARG_CASE(ARG_CS_SV,     "spree_inf",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(1, input, s2, f2) : "")) \
 422         ARG_CASE(ARG_CS_SV,     "spree_end",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(-1, "", "", f1) : "")) \
 423         ARG_CASE(ARG_CS_SV,     "spree_lost",    (autocvar_notification_show_sprees ? notif_arg_spree_inf(-2, "", "", f1) : "")) \
 424         ARG_CASE(ARG_CS_SV,     "item_wepname",  Weapons_from(f1).m_name) \
 425         ARG_CASE(ARG_CS_SV,     "item_buffname", BUFF_NAME(f1)) \
 426         ARG_CASE(ARG_CS_SV,     "f3buffname",    BUFF_NAME(f3)) \
 427         ARG_CASE(ARG_CS_SV,     "item_wepammo",  (s1 != "" ? sprintf(_(" with %s"), s1) : "")) \
 428         ARG_CASE(ARG_DC,        "item_centime",  ftos(autocvar_notification_item_centerprinttime)) \
 429         ARG_CASE(ARG_SV,        "death_team",    Team_ColoredFullName(f1)) \
 430         ARG_CASE(ARG_CS,        "death_team",    Team_ColoredFullName(f1 - 1)) \
 431         ARG_CASE(ARG_CS_SV_HA,  "minigame1_name",find(NULL,netname,s1).descriptor.message) \
 432         ARG_CASE(ARG_CS_SV_HA,  "minigame1_d",   find(NULL,netname,s1).descriptor.netname)
 433
 434 #define NOTIF_HIT_MAX(count,funcname) MACRO_BEGIN { \
 435         if(sel_num == count) { backtrace(sprintf("%s: Hit maximum arguments!\n", funcname)); break; } \
 436 } MACRO_END
 437 #define NOTIF_HIT_UNKNOWN(token,funcname) { backtrace(sprintf("%s: Hit unknown token in selected string! '%s'\n", funcname, selected)); break; }
 438
 439 #define KILL_SPREE_LIST \
 440         SPREE_ITEM(3, 03, _("TRIPLE FRAG! "), _("%s^K1 made a TRIPLE FRAG! %s^BG"), _("%s^K1 made a TRIPLE SCORE! %s^BG")) \
 441         SPREE_ITEM(5, 05, _("RAGE! "), _("%s^K1 unlocked RAGE! %s^BG"), _("%s^K1 made FIVE SCORES IN A ROW! %s^BG")) \
 442         SPREE_ITEM(10, 10, _("MASSACRE! "), _("%s^K1 started a MASSACRE! %s^BG"), _("%s^K1 made TEN SCORES IN A ROW! %s^BG")) \
 443         SPREE_ITEM(15, 15, _("MAYHEM! "), _("%s^K1 executed MAYHEM! %s^BG"), _("%s^K1 made FIFTEEN SCORES IN A ROW! %s^BG")) \
 444         SPREE_ITEM(20, 20, _("BERSERKER! "), _("%s^K1 is a BERSERKER! %s^BG"), _("%s^K1 made TWENTY SCORES IN A ROW! %s^BG")) \
 445         SPREE_ITEM(25, 25, _("CARNAGE! "), _("%s^K1 inflicts CARNAGE! %s^BG"), _("%s^K1 made TWENTY FIVE SCORES IN A ROW! %s^BG")) \
 446         SPREE_ITEM(30, 30, _("ARMAGEDDON! "), _("%s^K1 unleashes ARMAGEDDON! %s^BG"), _("%s^K1 made THIRTY SCORES IN A ROW! %s^BG"))
 447
 448 #ifdef CSQC
 449 string notif_arg_frag_ping(bool newline, float fping)
 450 {
 451         string s = newline ? "\n" : " ";
 452         if (fping < 0)
 453                 return sprintf(CCR(_("%s(^F1Bot^BG)")), s);
 454         else
 455                 return sprintf(CCR(_("%s(Ping ^F1%d^BG)")), s, fping);
 456 }
 457
 458 string notif_arg_frag_stats(float fhealth, float farmor, float fping)
 459 {
 460         string s = notif_arg_frag_ping(false, fping);
 461         if (fhealth > 1)
 462                 return sprintf(CCR(_("\n(Health ^1%d^BG / Armor ^2%d^BG)%s")), fhealth, farmor, s);
 463         else
 464                 return sprintf(CCR(_("\n(^F4Dead^BG)%s")), s);
 465 }
 466
 467 string notif_arg_missing_teams(float f1)
 468 {
 469         return sprintf("%s%s%s%s",
 470                 ((f1 & BIT(0)) ? sprintf("%s%s", Team_ColoredFullName(NUM_TEAM_1), (f1 & (BIT(1) | BIT(2) | BIT(3)) ? ", " : "")) : ""),
 471                 ((f1 & BIT(1)) ? sprintf("%s%s", Team_ColoredFullName(NUM_TEAM_2), (f1 & (         BIT(2) | BIT(3)) ? ", " : "")) : ""),
 472                 ((f1 & BIT(2)) ? sprintf("%s%s", Team_ColoredFullName(NUM_TEAM_3), (f1 & (                  BIT(3)) ? ", " : "")) : ""),
 473                 ((f1 & BIT(3)) ?                 Team_ColoredFullName(NUM_TEAM_4)                                                 : "")
 474         );
 475 }
 476
 477 string notif_arg_spree_cen(float spree)
 478 {
 479         // 0 = off, 1 = target (but only for first victim) and attacker
 480         if(autocvar_notification_show_sprees_center)
 481         {
 482                 if(spree > 1)
 483                 {
 484                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 485                                 case counta: { return normal_or_gentle(center, sprintf(_("%d score spree! "), spree)); }
 486
 487                         switch(spree)
 488                         {
 489                                 KILL_SPREE_LIST
 490                                 default:
 491                                 {
 492                                         if (!autocvar_notification_show_sprees_center_specialonly)
 493                                         {
 494                                                 return
 495                                                         sprintf(
 496                                                                 normal_or_gentle(
 497                                                                         _("%d frag spree! "),
 498                                                                         _("%d score spree! ")
 499                                                                 ),
 500                                                                 spree);
 501                                         }
 502                                         else { return ""; } // don't show spree information if it isn't an achievement
 503                                 }
 504                         }
 505
 506                         #undef SPREE_ITEM
 507                 }
 508                 else if(spree == -1) // first blood
 509                 {
 510                         return normal_or_gentle(_("First blood! "), _("First score! "));
 511                 }
 512                 else if(spree == -2) // first victim
 513                 {
 514                         return normal_or_gentle(_("First victim! "), _("First casualty! "));
 515                 }
 516         }
 517         return "";
 518 }
 519 #endif
 520
 521 string notif_arg_spree_inf(float type, string input, string player, float spree)
 522 {
 523         switch(type)
 524         {
 525                 case 1: // attacker kill spree
 526                 {
 527                         // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 528                         // this conditional (& 2) is true for 2 and 3
 529                         if(autocvar_notification_show_sprees_info & 2)
 530                         {
 531                                 #ifdef CSQC
 532                                 string spree_newline =
 533                                         ( autocvar_notification_show_sprees_info_newline ?
 534                                                 ((substring(input, 0, 1) == "\{3}") ? "\n\{3}" : "\n") : "" );
 535                                 #else
 536                                 string spree_newline =
 537                                         (autocvar_notification_show_sprees_info_newline ? "\n" : "");
 538                                 #endif
 539
 540                                 if(spree > 1)
 541                                 {
 542                                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 543                                                 case counta: { return sprintf(CCR(normal_or_gentle(normal, gentle)), player, spree_newline); }
 544
 545                                         switch(spree)
 546                                         {
 547                                                 KILL_SPREE_LIST
 548                                                 default:
 549                                                 {
 550                                                         if (!autocvar_notification_show_sprees_info_specialonly)
 551                                                         {
 552                                                                 return
 553                                                                         sprintf(
 554                                                                                 CCR(normal_or_gentle(
 555                                                                                         _("%s^K1 has %d frags in a row! %s^BG"),
 556                                                                                         _("%s^K1 made %d scores in a row! %s^BG")
 557                                                                                 )),
 558                                                                                 player,
 559                                                                                 spree,
 560                                                                                 spree_newline
 561                                                                         );
 562                                                         }
 563                                                         else { return ""; } // don't show spree information if it isn't an achievement
 564                                                 }
 565                                         }
 566
 567                                         #undef SPREE_ITEM
 568                                 }
 569                                 else if(spree == -1) // firstblood
 570                                 {
 571                                         return
 572                                                 sprintf(
 573                                                         CCR(normal_or_gentle(
 574                                                                 _("%s^K1 drew first blood! %s^BG"),
 575                                                                 _("%s^K1 got the first score! %s^BG")
 576                                                         )),
 577                                                         player,
 578                                                         spree_newline
 579                                                 );
 580                                 }
 581                         }
 582                         break;
 583                 }
 584
 585                 case -1: // kill spree ended
 586                 {
 587                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 588                         {
 589                                 return
 590                                         sprintf(normal_or_gentle(
 591                                                 _(", ending their %d frag spree"),
 592                                                 _(", ending their %d score spree")
 593                                                 ),
 594                                                 spree
 595                                         );
 596                         }
 597                         break;
 598                 }
 599
 600                 case -2: // kill spree lost
 601                 {
 602                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 603                         {
 604                                 return
 605                                         sprintf(normal_or_gentle(
 606                                                 _(", losing their %d frag spree"),
 607                                                 _(", losing their %d score spree")
 608                                                 ),
 609                                                 spree
 610                                         );
 611                         }
 612                         break;
 613                 }
 614         }
 615         return "";
 616 }
 617
 618
 619 // ====================================
 620 //  Initialization/Create Declarations
 621 // ====================================
 622
 623 // common notification entity values
 624 .int nent_default;
 625 .bool nent_enabled;
 626 .MSG nent_type;
 627 .string nent_name;
 628 .int nent_stringcount;
 629 .int nent_floatcount;
 630
 631 // MSG_ANNCE entity values
 632 .int nent_channel;
 633 .string nent_snd;
 634 .float nent_vol;
 635 .float nent_position;
 636
 637 // MSG_INFO and MSG_CENTER entity values
 638 .string nent_args; // used by both
 639 .string nent_hudargs; // used by info
 640 .string nent_icon; // used by info
 641 .CPID nent_cpid; // used by center
 642 .string nent_durcnt; // used by center
 643 .string nent_string; // used by both
 644
 645 // MSG_MULTI entity values
 646 .entity nent_msgannce;
 647 .entity nent_msginfo;
 648 .entity nent_msgcenter;
 649
 650 // MSG_CHOICE entity values
 651 .float nent_challow_def;
 652 .float nent_challow_var;
 653 .entity nent_optiona;
 654 .entity nent_optionb;
 655
 656 // networked notification entity values
 657 #ifdef SVQC
 658 .NOTIF nent_broadcast;
 659 #endif
 660 .entity nent_client;
 661 .MSG nent_net_type;
 662 .float nent_net_name;
 663 .string nent_strings[4];
 664 .float nent_floats[4];
 665
 666 #define ACVNN(name) autocvar_notification_##name
 667
 668 REGISTRY(Notifications, BITS(11))
 669 REGISTER_REGISTRY(Notifications)
 670 REGISTRY_SORT(Notifications); STATIC_INIT(Notifications) { FOREACH(Notifications, true, it.m_id = i); }
 671 REGISTRY_CHECK(Notifications)
 672
 673 const int NOTIF_CHOICE_MAX = 50;
 674 int nent_choice_count = 0;
 675 .int nent_choice_idx;
 676 .int msg_choice_choices[NOTIF_CHOICE_MAX]; // set on each player containing MSG_CHOICE choices
 677 // initialization error detection
 678 bool notif_error;
 679 bool notif_global_error;
 680
 681 STATIC_INIT_LATE(Notif_Choices) {
 682         int c = 0;
 683         FOREACH(Notifications, it.nent_type == MSG_CHOICE, { c++; });
 684         if (c > NOTIF_CHOICE_MAX) {
 685                 LOG_FATALF("Too many MSG_CHOICE notifications (%d)", c);
 686         }
 687 }
 688
 689 Notification Get_Notif_Ent(MSG net_type, int net_name)
 690 {
 691         Notification it = _Notifications_from(net_name, NULL);
 692         if (it.nent_type != net_type) {
 693                 LOG_WARNF("Get_Notif_Ent(%s (%d), %s (%d)): Improper net type '%s'!",
 694                         Get_Notif_TypeName(net_type), net_type,
 695                         it.registered_id, net_name,
 696                         Get_Notif_TypeName(it.nent_type)
 697                 );
 698                 return NULL;
 699         }
 700         return it;
 701 }
 702
 703 #define MSG_ANNCE_NOTIF(name, default, sound, channel, volume, position) \
 704         MSG_ANNCE_NOTIF_(ANNCE_##name, default, sound, channel, volume, position)
 705 #define MSG_ANNCE_NOTIF_(name, default, sound, channel, volume, position) \
 706         NOTIF_ADD_AUTOCVAR(name, default) \
 707         REGISTER(Notifications, name, m_id, new_pure(msg_annce_notification)) { \
 708                 Create_Notification_Entity      (this, default, ACVNN(name), MSG_ANNCE, strtoupper(#name)); \
 709                 Create_Notification_Entity_Annce(this, ACVNN(name), strtoupper(#name), \
 710                         channel,   /* channel  */ \
 711                         sound,     /* snd      */ \
 712                         volume,    /* vol      */ \
 713                         position); /* position */ \
 714         }
 715
 716 #define MSG_INFO_NOTIF(name, default, strnum, flnum, args, hudargs, icon, normal, gentle) \
 717         MSG_INFO_NOTIF_(INFO_##name, default, strnum, flnum, args, hudargs, icon, normal, gentle)
 718 #define MSG_INFO_NOTIF_(name, default, strnum, flnum, args, hudargs, icon, normal, gentle) \
 719         NOTIF_ADD_AUTOCVAR(name, default) \
 720         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 721                 Create_Notification_Entity           (this, default, ACVNN(name), MSG_INFO, strtoupper(#name)); \
 722                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
 723                         args,     /* args    */ \
 724                         hudargs,  /* hudargs */ \
 725                         icon,     /* icon    */ \
 726                         CPID_Null,/* cpid    */ \
 727                         "",       /* durcnt  */ \
 728                         normal,   /* normal  */ \
 729                         gentle);  /* gentle  */ \
 730         }
 731
 732 .string nent_iconargs;
 733 #define MULTIICON_INFO(name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 734         MULTIICON_INFO_(INFO_##name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle)
 735 #define MULTIICON_INFO_(name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 736         NOTIF_ADD_AUTOCVAR(name, default) \
 737         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 738                 Create_Notification_Entity           (this, default, ACVNN(name), MSG_INFO, strtoupper(#name)); \
 739                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
 740                         args,     /* args    */ \
 741                         hudargs,  /* hudargs */ \
 742                         icon,     /* icon    */ \
 743                         CPID_Null,/* cpid    */ \
 744                         "",       /* durcnt  */ \
 745                         normal,   /* normal  */ \
 746                         gentle);  /* gentle  */ \
 747                 this.nent_iconargs = iconargs; \
 748         }
 749
 750 #define MSG_CENTER_NOTIF(name, default, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 751         MSG_CENTER_NOTIF_(CENTER_##name, default, strnum, flnum, args, cpid, durcnt, normal, gentle)
 752 #define MSG_CENTER_NOTIF_(name, default, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 753         NOTIF_ADD_AUTOCVAR(name, default) \
 754         REGISTER(Notifications, name, m_id, new_pure(msg_center_notification)) { \
 755                 Create_Notification_Entity           (this, default, ACVNN(name), MSG_CENTER, strtoupper(#name)); \
 756                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
 757                         args,    /* args    */ \
 758                         "",      /* hudargs */ \
 759                         "",      /* icon    */ \
 760                         cpid,    /* cpid    */ \
 761                         durcnt,  /* durcnt  */ \
 762                         normal,  /* normal  */ \
 763                         gentle); /* gentle  */ \
 764         }
 765
 766 #define MSG_MULTI_NOTIF(name, default, anncename, infoname, centername) \
 767         NOTIF_ADD_AUTOCVAR(name, default) \
 768         REGISTER(Notifications, name, m_id, new_pure(msg_multi_notification)) { \
 769                 Create_Notification_Entity      (this, default, ACVNN(name), MSG_MULTI, strtoupper(#name)); \
 770                 Create_Notification_Entity_Multi(this, ACVNN(name), strtoupper(#name), \
 771                         anncename,   /* anncename  */ \
 772                         infoname,    /* infoname   */ \
 773                         centername); /* centername */ \
 774         }
 775
 776 #define MSG_CHOICE_NOTIF(name, default, challow, chtype, optiona, optionb) \
 777         MSG_CHOICE_NOTIF_(CHOICE_##name, default, challow, chtype, optiona, optionb)
 778 #define MSG_CHOICE_NOTIF_(name, default, challow, chtype, optiona, optionb) \
 779         NOTIF_ADD_AUTOCVAR(name, default) \
 780         NOTIF_ADD_AUTOCVAR(name##_ALLOWED, challow) \
 781         REGISTER(Notifications, name, m_id, new_pure(msg_choice_notification)) { \
 782                 this.nent_choice_idx = nent_choice_count++; \
 783                 Create_Notification_Entity       (this, default, ACVNN(name), MSG_CHOICE, strtoupper(#name)); \
 784                 Create_Notification_Entity_Choice(this, ACVNN(name), strtoupper(#name), \
 785                         challow,                                 /* challow_def */ \
 786                         autocvar_notification_##name##_ALLOWED,  /* challow_var */ \
 787                         chtype,                                  /* chtype      */ \
 788                         optiona,                                 /* optiona     */ \
 789                         optionb);                                /* optionb     */ \
 790         }
 791
 792 REGISTRY_BEGIN(Notifications)
 793 {
 794         notif_global_error = false;
 795 }
 796
 797 REGISTRY_END(Notifications)
 798 {
 799         if (!notif_global_error) return;
 800         // shit happened... stop the loading of the program now if this is unacceptable
 801         if (autocvar_notification_errors_are_fatal)
 802                 LOG_FATAL("Notification initialization failed! Read above and fix the errors!");
 803         else
 804                 LOG_SEVERE("Notification initialization failed! Read above and fix the errors!");
 805 }
 806
 807 #include "all.inc"