qcsrc/common/notifications/all.qh

   1 #pragma once
   2
   3 #include <common/command/_mod.qh>
   4
   5 #include <common/constants.qh>
   6 #include <common/teams.qh>
   7 #include <common/util.qh>
   8 #include <common/sounds/sound.qh>
   9
  10 #ifdef CSQC
  11 #include <client/autocvars.qh>
  12 #endif
  13
  14 /** main types/groups of notifications */
  15 ENUMCLASS(MSG)
  16         /** "Global" AND "personal" announcer messages */
  17         CASE(MSG, ANNCE)
  18         /** "Global" information messages */
  19         CASE(MSG, INFO)
  20         /** "Personal" centerprint messages */
  21         CASE(MSG, CENTER)
  22         /** Subcall MSG_INFO and/or MSG_CENTER notifications */
  23         CASE(MSG, MULTI)
  24         /** Choose which subcall wrapper to activate */
  25         CASE(MSG, CHOICE)
  26         /** Kill centerprint message @deprecated */
  27         CASE(MSG, CENTER_KILL)
  28 ENUMCLASS_END(MSG)
  29
  30 string Get_Notif_TypeName(MSG net_type)
  31 {
  32         switch (net_type)
  33         {
  34                 case MSG_ANNCE: return "MSG_ANNCE";
  35                 case MSG_INFO: return "MSG_INFO";
  36                 case MSG_CENTER: return "MSG_CENTER";
  37                 case MSG_MULTI: return "MSG_MULTI";
  38                 case MSG_CHOICE: return "MSG_CHOICE";
  39         }
  40         LOG_WARNF("Get_Notif_TypeName(%d): Improper net type!", ORDINAL(net_type));
  41         return "";
  42 }
  43
  44 ENUMCLASS(CPID)
  45         CASE(CPID, ASSAULT_ROLE)
  46         CASE(CPID, ROUND)
  47         CASE(CPID, CAMPCHECK)
  48         CASE(CPID, CTF_CAPSHIELD)
  49         CASE(CPID, CTF_LOWPRIO)
  50         CASE(CPID, CTF_PASS)
  51         CASE(CPID, STALEMATE)
  52         CASE(CPID, NADES)
  53         CASE(CPID, IDLING)
  54         CASE(CPID, ITEM)
  55         CASE(CPID, PREVENT_JOIN)
  56         CASE(CPID, KEEPAWAY)
  57         CASE(CPID, KEEPAWAY_WARN)
  58         CASE(CPID, KEYHUNT)
  59         CASE(CPID, KEYHUNT_OTHER)
  60         CASE(CPID, LMS)
  61         CASE(CPID, MISSING_TEAMS)
  62         CASE(CPID, MISSING_PLAYERS)
  63         CASE(CPID, INSTAGIB_FINDAMMO)
  64         CASE(CPID, MOTD)
  65         CASE(CPID, NIX)
  66         CASE(CPID, ONSLAUGHT)
  67         CASE(CPID, ONS_CAPSHIELD)
  68         CASE(CPID, OVERTIME)
  69         CASE(CPID, POWERUP)
  70         CASE(CPID, RACE_FINISHLAP)
  71         CASE(CPID, TEAMCHANGE)
  72         CASE(CPID, TIMEOUT)
  73         CASE(CPID, TIMEIN)
  74         CASE(CPID, VEHICLES)
  75         CASE(CPID, VEHICLES_OTHER)
  76         /** always last */
  77         CASE(CPID, LAST)
  78 ENUMCLASS_END(CPID)
  79
  80 USING(Notification, entity);
  81
  82 // used for notification system multi-team identifiers
  83 #define APP_TEAM_NUM(num, prefix) ((num == NUM_TEAM_1) ? prefix##_RED : ((num == NUM_TEAM_2) ? prefix##_BLUE : ((num == NUM_TEAM_3) ? prefix##_YELLOW : prefix##_PINK)))
  84 #define APP_NUM(num, prefix) ((num) ? APP_TEAM_NUM(num, prefix) : prefix##_NEUTRAL)
  85
  86 #define EIGHT_VARS_TO_VARARGS_VARLIST \
  87         VARITEM(1, 0, s1) \
  88         VARITEM(2, 0, XPD(s1, s2)) \
  89         VARITEM(3, 0, XPD(s1, s2, s3)) \
  90         VARITEM(4, 0, XPD(s1, s2, s3, s4)) \
  91         VARITEM(0, 1, f1) \
  92         VARITEM(1, 1, XPD(s1, f1)) \
  93         VARITEM(2, 1, XPD(s1, s2, f1)) \
  94         VARITEM(3, 1, XPD(s1, s2, s3, f1)) \
  95         VARITEM(4, 1, XPD(s1, s2, s3, s4, f1)) \
  96         VARITEM(0, 2, XPD(f1, f2)) \
  97         VARITEM(1, 2, XPD(s1, f1, f2)) \
  98         VARITEM(2, 2, XPD(s1, s2, f1, f2)) \
  99         VARITEM(3, 2, XPD(s1, s2, s3, f1, f2)) \
 100         VARITEM(4, 2, XPD(s1, s2, s3, s4, f1, f2)) \
 101         VARITEM(0, 3, XPD(f1, f2, f3)) \
 102         VARITEM(1, 3, XPD(s1, f1, f2, f3)) \
 103         VARITEM(2, 3, XPD(s1, s2, f1, f2, f3)) \
 104         VARITEM(3, 3, XPD(s1, s2, s3, f1, f2, f3)) \
 105         VARITEM(4, 3, XPD(s1, s2, s3, s4, f1, f2, f3)) \
 106         VARITEM(0, 4, XPD(f1, f2, f3, f4)) \
 107         VARITEM(1, 4, XPD(s1, f1, f2, f3, f4)) \
 108         VARITEM(2, 4, XPD(s1, s2, f1, f2, f3, f4)) \
 109         VARITEM(3, 4, XPD(s1, s2, s3, f1, f2, f3, f4)) \
 110         VARITEM(4, 4, XPD(s1, s2, s3, s4, f1, f2, f3, f4))
 111
 112 void Destroy_All_Notifications();
 113 void Create_Notification_Entity(entity notif,
 114         float var_default,
 115         float var_cvar,
 116         MSG typeId,
 117         string namestring,
 118         int teamnum);
 119 void Create_Notification_Entity_Annce(entity notif,
 120                                                                                 float var_cvar,
 121                                                                                 string namestring,
 122                                                                                 /* MSG_ANNCE */
 123                                                                                 float channel,
 124                                                                                 string snd,
 125                                                                                 float vol,
 126                                                                                 float position);
 127
 128 void Create_Notification_Entity_InfoCenter(entity notif,
 129                                                                                         float var_cvar,
 130                                                                                         string namestring,
 131                                                                                         int strnum,
 132                                                                                         int flnum,
 133                                                                                         /* MSG_INFO & MSG_CENTER */
 134                                                                                         string args,
 135                                                                                         string hudargs,
 136                                                                                         string icon,
 137                                                                                         CPID cpid,
 138                                                                                         string durcnt,
 139                                                                                         string normal,
 140                                                                                         string gentle);
 141
 142 void Create_Notification_Entity_Multi(entity notif,
 143                                                                                 float var_cvar,
 144                                                                                 string namestring,
 145                                                                                 /* MSG_MULTI */
 146                                                                                 Notification anncename,
 147                                                                                 Notification infoname,
 148                                                                                 Notification centername);
 149
 150 void Create_Notification_Entity_Choice(entity notif,
 151                                                                                 float var_cvar,
 152                                                                                 string namestring,
 153                                                                                 /* MSG_CHOICE */
 154                                                                                 float challow_def,
 155                                                                                 float challow_var,
 156                                                                                 MSG chtype,
 157                                                                                 Notification optiona,
 158                                                                                 Notification optionb);
 159
 160 void Dump_Notifications(int fh, bool alsoprint);
 161
 162 GENERIC_COMMAND(dumpnotifs, "Dump all notifications into notifications_dump.txt")
 163 {
 164         switch (request)
 165         {
 166                 case CMD_REQUEST_COMMAND:
 167                 {
 168                         #ifdef GAMEQC
 169                         string filename = argv(1);
 170                         bool alsoprint = false;
 171                         if (filename == "")
 172                         {
 173                                 filename = "notifications_dump.cfg";
 174                                 alsoprint = false;
 175                         }
 176                         else if (filename == "-")
 177                         {
 178                                 filename = "notifications_dump.cfg";
 179                                 alsoprint = true;
 180                         }
 181                         int fh = fopen(filename, FILE_WRITE);
 182                         if (fh >= 0)
 183                         {
 184                                 Dump_Notifications(fh, alsoprint);
 185                                 LOG_INFOF("Dumping notifications... File located in ^2data/data/%s^7.", filename);
 186                                 fclose(fh);
 187                         }
 188                         else
 189                         {
 190                                 LOG_INFOF("^1Error: ^7Could not open file '%s'!", filename);
 191                         }
 192                         #else
 193                         LOG_INFO(_("Notification dump command only works with cl_cmd and sv_cmd."));
 194                         #endif
 195                         return;
 196                 }
 197                 default:
 198                 case CMD_REQUEST_USAGE:
 199                 {
 200                         LOG_INFO("Usage:^3 ", GetProgramCommandPrefix(), " dumpnotifs [filename]");
 201                         LOG_INFO("  Where 'filename' is the file to write (default is notifications_dump.cfg),");
 202                         LOG_INFO("  if supplied with '-' output to console as well as default,");
 203                         LOG_INFO("  if left blank, it will only write to default.");
 204                         return;
 205                 }
 206         }
 207 }
 208
 209 #ifdef NOTIFICATIONS_DEBUG
 210 bool autocvar_notification_debug = false;
 211 void Debug_Notification(string input)
 212 {
 213         switch (autocvar_notification_debug)
 214         {
 215                 case 1: { LOG_TRACE(input); break; }
 216                 case 2: { LOG_INFO(input); break; }
 217         }
 218 }
 219 #endif
 220
 221 void Local_Notification(MSG net_type, Notification net_name, ...count);
 222 /** glue for networking, forwards to `Local_Notification` */
 223 void Local_Notification_WOVA(
 224         MSG net_type, Notification net_name,
 225         float stringcount, float floatcount,
 226         string s1, string s2, string s3, string s4,
 227         float f1, float f2, float f3, float f4);
 228
 229 #ifdef CSQC
 230 string prev_soundfile;
 231 float prev_soundtime;
 232 #endif
 233
 234 #ifdef SVQC
 235 IntrusiveList g_notifications;
 236 STATIC_INIT(g_notifications) { g_notifications = IL_NEW(); }
 237 #endif
 238
 239 #ifdef SVQC
 240 ENUMCLASS(NOTIF)
 241         /** send to one client and their spectators */
 242         CASE(NOTIF, ONE)
 243         /** send ONLY to one client */
 244         CASE(NOTIF, ONE_ONLY)
 245         /** send only to X team and their spectators */
 246         CASE(NOTIF, TEAM)
 247         /** send only to X team and their spectators, except for Y person and their spectators */
 248         CASE(NOTIF, TEAM_EXCEPT)
 249         /** send to everyone */
 250         CASE(NOTIF, ALL)
 251         /** send to everyone except X person and their spectators */
 252         CASE(NOTIF, ALL_EXCEPT)
 253 ENUMCLASS_END(NOTIF)
 254
 255 string Get_Notif_BroadcastName(NOTIF broadcast)
 256 {
 257         switch (broadcast)
 258         {
 259                 case NOTIF_ONE: return "NOTIF_ONE";
 260                 case NOTIF_ONE_ONLY: return "NOTIF_ONE_ONLY";
 261                 case NOTIF_ALL_EXCEPT: return "NOTIF_ALL_EXCEPT";
 262                 case NOTIF_ALL: return "NOTIF_ALL";
 263                 case NOTIF_TEAM: return "NOTIF_TEAM";
 264                 case NOTIF_TEAM_EXCEPT: return "NOTIF_TEAM_EXCEPT";
 265         }
 266         LOG_WARNF("Get_Notif_BroadcastName(%d): Improper broadcast!", broadcast);
 267         return "";
 268 }
 269
 270 void Kill_Notification(
 271         NOTIF broadcast, entity client,
 272         MSG net_type, CPID net_name);
 273 void Send_Notification(
 274         NOTIF broadcast, entity client,
 275         MSG net_type, Notification net_name,
 276         ...count);
 277 void Send_Notification_WOVA(
 278         NOTIF broadcast, entity client,
 279         MSG net_type, Notification net_name,
 280         float stringcount, float floatcount,
 281         string s1, string s2, string s3, string s4,
 282         float f1, float f2, float f3, float f4);
 283 void Send_Notification_WOCOVA(
 284         NOTIF broadcast, entity client,
 285         MSG net_type, Notification net_name,
 286         string s1, string s2, string s3, string s4,
 287         float f1, float f2, float f3, float f4);
 288 #endif
 289
 290 // ===========================
 291 //  Special CVAR Declarations
 292 // ===========================
 293
 294 // MAKE SURE THIS IS ALWAYS SYNCHRONIZED WITH THE DUMP
 295 // NOTIFICATIONS FUNCTION IN THE .QC FILE!
 296
 297 #define NOTIF_ADD_AUTOCVAR(name,default) float autocvar_notification_##name = default;
 298
 299 float autocvar_notification_show_location = false;
 300 string autocvar_notification_show_location_string = ""; //_(" at the %s");
 301 float autocvar_notification_show_sprees = true;
 302 float autocvar_notification_show_sprees_info = 3; // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 303 float autocvar_notification_show_sprees_info_newline = true;
 304 float autocvar_notification_show_sprees_info_specialonly = true;
 305 float autocvar_notification_errors_are_fatal = true;
 306 #ifdef SVQC
 307 float autocvar_notification_lifetime_runtime = 0.5;
 308 float autocvar_notification_lifetime_mapload = 10;
 309 #endif
 310
 311 #ifdef SVQC
 312 .float FRAG_VERBOSE;
 313 void Notification_GetCvars(entity this);
 314 float autocvar_notification_server_allows_location = 1; // 0 = no, 1 = yes
 315 #else
 316 float autocvar_notification_item_centerprinttime = 1.5;
 317
 318 // 0 = no, 1 = yes, 2 = forced on for all MSG_INFO notifs
 319 // DISABLED IN CODE, BUT ENABLED IN CONFIG FOR COMPATIBILITY WITH OLD CLIENTS
 320 float autocvar_notification_allow_chatboxprint = 0;
 321
 322 float autocvar_notification_show_sprees_center = true;
 323 float autocvar_notification_show_sprees_center_specialonly = true;
 324 #endif
 325
 326
 327 // ============================
 328 //  Notification Argument List
 329 // ============================
 330 /*
 331  These arguments get replaced with the Local_Notification_sprintf
 332  and other such functions found in all.qc to supply data
 333  from networked notifications to their usage in sprintf... It
 334  allows for more dynamic data to be inferred by the local
 335  notification parser, so that the server does not have to network
 336  anything too crazy on a per-client/per-situation basis.
 337
 338  Pay attention to the CSQC/SVQC relations, some of these are redefined
 339  in slightly different ways for different programs, this is because the
 340  server does a more conservative approach to the notifs than the client.
 341
 342  All arguments are swapped into strings, so be sure that your
 343  sprintf usage matches with proper %s placement.
 344
 345  Argument descriptions:
 346         s1-s4: string arguments to be literally swapped into sprintf
 347         s2loc: s2 string of locations of deaths or other events
 348         s3loc: s3 string of locations of deaths or other events
 349         f1-f4: float arguments expanded into strings to be swapped into sprintf
 350         f1p2dec: f1 float to string with 2 decimal places
 351         f2p2dec: f2 float to string with 2 decimal places
 352         f2primsec: f2 float primary or secondary selection for weapons
 353         f3primsec: f3 float primary or secondary selection for weapons
 354         f1secs: count_seconds of f1
 355         f1points: point or points depending on f1
 356         f1ord: count_ordinal of f1
 357         f1time: process_time of f1
 358         f1race_time: mmssss of f1
 359         f2race_time: mmssss of f2
 360         race_col: color of race time/position (i.e. good or bad)
 361         race_diff: show time difference between f2 and f3
 362         missing_teams: show which teams still need players
 363         pass_key: find the keybind for "passing" or "dropping" in CTF game mode
 364         nade_key: find the keybind for nade throwing
 365         frag_ping: show the ping of a player
 366         frag_stats: show health/armor/ping of a player
 367         frag_pos: show score status and position in the match of a player
 368         spree_cen: centerprint notif for kill spree/how many kills they have
 369         spree_inf: info notif for kill spree/how many kills they have
 370         spree_end: placed at the end of murder messages to show ending of sprees
 371         spree_lost: placed at the end of suicide messages to show losing of sprees
 372         item_wepname: return full name of a weapon from weaponid
 373         item_wepammo: ammo display for weapon from string
 374         item_centime: amount of time to display weapon message in centerprint
 375         item_buffname: return full name of a buff from buffid
 376         death_team: show the full name of the team a player is switching from
 377         minigame1_name: return human readable name of a minigame from its id(s1)
 378         minigame1_d: return descriptor name of a minigame from its id(s1)
 379 */
 380
 381 const float NOTIF_MAX_ARGS = 7;
 382 const float NOTIF_MAX_HUDARGS = 2;
 383 const float NOTIF_MAX_DURCNT = 2;
 384
 385 string arg_slot[NOTIF_MAX_ARGS];
 386
 387 const float ARG_CS_SV_HA = 1; // enabled on CSQC, SVQC, and Hudargs
 388 const float ARG_CS_SV_DC = 2; // enabled on CSQC, SVQC, and durcnt centerprint
 389 const float ARG_CS_SV = 3; // enabled on CSQC and SVQC
 390 const float ARG_CS = 4; // unique result to CSQC
 391 const float ARG_SV = 5; // unique result to SVQC
 392 const float ARG_DC = 6; // unique result to durcnt/centerprint
 393
 394 // todo possible idea.... declare how many floats/strings each arg needs, and then dynamically increment the input
 395 // this way, we don't need to have duplicates like i.e. s2loc and s3loc?
 396
 397 string BUFF_NAME(int i);
 398
 399 #define NOTIF_ARGUMENT_LIST \
 400         ARG_CASE(ARG_CS_SV_HA,  "s1",            s1) \
 401         ARG_CASE(ARG_CS_SV_HA,  "s2",            s2) \
 402         ARG_CASE(ARG_CS_SV_HA,  "s3",            s3) \
 403         ARG_CASE(ARG_CS_SV_HA,  "s4",            s4) \
 404         ARG_CASE(ARG_CS_SV,     "s2loc",         ((autocvar_notification_show_location && (s2 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s2) : "")) \
 405         ARG_CASE(ARG_CS_SV,     "s3loc",         ((autocvar_notification_show_location && (s3 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s3) : "")) \
 406         ARG_CASE(ARG_CS_SV_DC,  "f1",            ftos(f1)) \
 407         ARG_CASE(ARG_CS_SV_DC,  "f2",            ftos(f2)) \
 408         ARG_CASE(ARG_CS_SV,     "f3",            ftos(f3)) \
 409         ARG_CASE(ARG_CS_SV,     "f4",            ftos(f4)) \
 410         ARG_CASE(ARG_CS_SV,     "f1dtime",       ftos_decimals(TIME_DECODE(f1), 2)) \
 411         ARG_CASE(ARG_CS_SV,     "f2dtime",       ftos_decimals(TIME_DECODE(f2), 2)) \
 412         ARG_CASE(ARG_CS,        "f2primsec",     (f2 ? _("secondary") : _("primary"))) \
 413         ARG_CASE(ARG_CS,        "f3primsec",     (f3 ? _("secondary") : _("primary"))) \
 414         ARG_CASE(ARG_CS,        "f1secs",        count_seconds(f1)) \
 415         ARG_CASE(ARG_CS,        "f1points",      (f1 == 1 ? _("point") : _("points"))) \
 416         ARG_CASE(ARG_CS_SV,     "f1ord",         count_ordinal(f1)) \
 417         ARG_CASE(ARG_CS_SV,     "f1time",        process_time(2, f1)) \
 418         ARG_CASE(ARG_CS_SV_HA,  "f1race_time",   mmssss(f1)) \
 419         ARG_CASE(ARG_CS_SV_HA,  "f2race_time",   mmssss(f2)) \
 420         ARG_CASE(ARG_CS_SV_HA,  "f3race_time",   mmssss(f3)) \
 421         ARG_CASE(ARG_CS_SV,     "race_col",      CCR(((f1 == 1) ? "^F1" : "^F2"))) \
 422         ARG_CASE(ARG_CS_SV,     "race_diff",     ((f2 > f3) ? sprintf(CCR("^1[+%s]"), mmssss(f2 - f3)) : sprintf(CCR("^2[-%s]"), mmssss(f3 - f2)))) \
 423         ARG_CASE(ARG_CS,        "missing_teams", notif_arg_missing_teams(f1)) \
 424         ARG_CASE(ARG_CS,        "pass_key",      getcommandkey(_("drop flag"), "+use")) \
 425         ARG_CASE(ARG_CS,        "nade_key",      getcommandkey(_("throw nade"), "dropweapon")) \
 426         ARG_CASE(ARG_CS,        "frag_ping",     notif_arg_frag_ping(true, f2)) \
 427         ARG_CASE(ARG_CS,        "frag_stats",    notif_arg_frag_stats(f2, f3, f4)) \
 428         /*ARG_CASE(ARG_CS,      "frag_pos",      ((Should_Print_Score_Pos(f1)) ? sprintf("\n^BG%s", Read_Score_Pos(f1)) : ""))*/ \
 429         ARG_CASE(ARG_CS,        "spree_cen",     (autocvar_notification_show_sprees ? notif_arg_spree_cen(f1) : "")) \
 430         ARG_CASE(ARG_CS_SV,     "spree_inf",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(1, input, s2, f2) : "")) \
 431         ARG_CASE(ARG_CS_SV,     "spree_end",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(-1, "", "", f1) : "")) \
 432         ARG_CASE(ARG_CS_SV,     "spree_lost",    (autocvar_notification_show_sprees ? notif_arg_spree_inf(-2, "", "", f1) : "")) \
 433         ARG_CASE(ARG_CS_SV,     "item_wepname",  Weapons_from(f1).m_name) \
 434         ARG_CASE(ARG_CS_SV,     "item_buffname", BUFF_NAME(f1)) \
 435         ARG_CASE(ARG_CS_SV,     "f3buffname",    BUFF_NAME(f3)) \
 436         ARG_CASE(ARG_CS_SV,     "item_wepammo",  (s1 != "" ? sprintf(_(" with %s"), s1) : "")) \
 437         ARG_CASE(ARG_DC,        "item_centime",  ftos(autocvar_notification_item_centerprinttime)) \
 438         ARG_CASE(ARG_SV,        "death_team",    Team_ColoredFullName(f1)) \
 439         ARG_CASE(ARG_CS,        "death_team",    Team_ColoredFullName(f1 - 1)) \
 440         ARG_CASE(ARG_CS_SV_HA,  "minigame1_name",find(NULL,netname,s1).descriptor.message) \
 441         ARG_CASE(ARG_CS_SV_HA,  "minigame1_d",   find(NULL,netname,s1).descriptor.netname)
 442
 443 #define NOTIF_HIT_MAX(count,funcname) MACRO_BEGIN { \
 444         if(sel_num == count) { backtrace(sprintf("%s: Hit maximum arguments!\n", funcname)); break; } \
 445 } MACRO_END
 446 #define NOTIF_HIT_UNKNOWN(token,funcname) { backtrace(sprintf("%s: Hit unknown token in selected string! '%s'\n", funcname, selected)); break; }
 447
 448 #define KILL_SPREE_LIST \
 449         SPREE_ITEM(3, 03, _("TRIPLE FRAG! "), _("%s^K1 made a TRIPLE FRAG! %s^BG"), _("%s^K1 made a TRIPLE SCORE! %s^BG")) \
 450         SPREE_ITEM(5, 05, _("RAGE! "), _("%s^K1 unlocked RAGE! %s^BG"), _("%s^K1 made FIVE SCORES IN A ROW! %s^BG")) \
 451         SPREE_ITEM(10, 10, _("MASSACRE! "), _("%s^K1 started a MASSACRE! %s^BG"), _("%s^K1 made TEN SCORES IN A ROW! %s^BG")) \
 452         SPREE_ITEM(15, 15, _("MAYHEM! "), _("%s^K1 executed MAYHEM! %s^BG"), _("%s^K1 made FIFTEEN SCORES IN A ROW! %s^BG")) \
 453         SPREE_ITEM(20, 20, _("BERSERKER! "), _("%s^K1 is a BERSERKER! %s^BG"), _("%s^K1 made TWENTY SCORES IN A ROW! %s^BG")) \
 454         SPREE_ITEM(25, 25, _("CARNAGE! "), _("%s^K1 inflicts CARNAGE! %s^BG"), _("%s^K1 made TWENTY FIVE SCORES IN A ROW! %s^BG")) \
 455         SPREE_ITEM(30, 30, _("ARMAGEDDON! "), _("%s^K1 unleashes ARMAGEDDON! %s^BG"), _("%s^K1 made THIRTY SCORES IN A ROW! %s^BG"))
 456
 457 #ifdef CSQC
 458 string notif_arg_frag_ping(bool newline, float fping)
 459 {
 460         string s = newline ? "\n" : " ";
 461         if (fping < 0)
 462                 return sprintf(CCR(_("%s(^F1Bot^BG)")), s);
 463         else
 464                 return sprintf(CCR(_("%s(Ping ^F1%d^BG)")), s, fping);
 465 }
 466
 467 string notif_arg_frag_stats(float fhealth, float farmor, float fping)
 468 {
 469         string s = notif_arg_frag_ping(false, fping);
 470         if (fhealth > 1)
 471                 return sprintf(CCR(_("\n(Health ^1%d^BG / Armor ^2%d^BG)%s")), fhealth, farmor, s);
 472         else
 473                 return sprintf(CCR(_("\n(^F4Dead^BG)%s")), s);
 474 }
 475
 476 string notif_arg_missing_teams(float f1)
 477 {
 478         return strcat(
 479                 ((f1 & BIT(0)) ? strcat(Team_ColoredFullName(NUM_TEAM_1), (f1 >> 1) ? ", " : "") : ""),
 480                 ((f1 & BIT(1)) ? strcat(Team_ColoredFullName(NUM_TEAM_2), (f1 >> 2) ? ", " : "") : ""),
 481                 ((f1 & BIT(2)) ? strcat(Team_ColoredFullName(NUM_TEAM_3), (f1 >> 3) ? ", " : "") : ""),
 482                 ((f1 & BIT(3)) ?        Team_ColoredFullName(NUM_TEAM_4)                         : "")
 483         );
 484 }
 485
 486 string notif_arg_spree_cen(float spree)
 487 {
 488         // 0 = off, 1 = target (but only for first victim) and attacker
 489         if(autocvar_notification_show_sprees_center)
 490         {
 491                 if(spree > 1)
 492                 {
 493                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 494                                 case counta: { return normal_or_gentle(center, sprintf(_("%d score spree! "), spree)); }
 495
 496                         switch(spree)
 497                         {
 498                                 KILL_SPREE_LIST
 499                                 default:
 500                                 {
 501                                         if (!autocvar_notification_show_sprees_center_specialonly)
 502                                         {
 503                                                 return
 504                                                         sprintf(
 505                                                                 normal_or_gentle(
 506                                                                         _("%d frag spree! "),
 507                                                                         _("%d score spree! ")
 508                                                                 ),
 509                                                                 spree);
 510                                         }
 511                                         else { return ""; } // don't show spree information if it isn't an achievement
 512                                 }
 513                         }
 514
 515                         #undef SPREE_ITEM
 516                 }
 517                 else if(spree == -1) // first blood
 518                 {
 519                         return normal_or_gentle(_("First blood! "), _("First score! "));
 520                 }
 521                 else if(spree == -2) // first victim
 522                 {
 523                         return normal_or_gentle(_("First victim! "), _("First casualty! "));
 524                 }
 525         }
 526         return "";
 527 }
 528 #endif
 529
 530 string notif_arg_spree_inf(float type, string input, string player, float spree)
 531 {
 532         switch(type)
 533         {
 534                 case 1: // attacker kill spree
 535                 {
 536                         // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 537                         // this conditional (& 2) is true for 2 and 3
 538                         if(autocvar_notification_show_sprees_info & 2)
 539                         {
 540                                 #ifdef CSQC
 541                                 string spree_newline =
 542                                         ( autocvar_notification_show_sprees_info_newline ?
 543                                                 ((substring(input, 0, 1) == "\{3}") ? "\n\{3}" : "\n") : "" );
 544                                 #else
 545                                 string spree_newline =
 546                                         (autocvar_notification_show_sprees_info_newline ? "\n" : "");
 547                                 #endif
 548
 549                                 if(spree > 1)
 550                                 {
 551                                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 552                                                 case counta: { return sprintf(CCR(normal_or_gentle(normal, gentle)), player, spree_newline); }
 553
 554                                         switch(spree)
 555                                         {
 556                                                 KILL_SPREE_LIST
 557                                                 default:
 558                                                 {
 559                                                         if (!autocvar_notification_show_sprees_info_specialonly)
 560                                                         {
 561                                                                 return
 562                                                                         sprintf(
 563                                                                                 CCR(normal_or_gentle(
 564                                                                                         _("%s^K1 has %d frags in a row! %s^BG"),
 565                                                                                         _("%s^K1 made %d scores in a row! %s^BG")
 566                                                                                 )),
 567                                                                                 player,
 568                                                                                 spree,
 569                                                                                 spree_newline
 570                                                                         );
 571                                                         }
 572                                                         else { return ""; } // don't show spree information if it isn't an achievement
 573                                                 }
 574                                         }
 575
 576                                         #undef SPREE_ITEM
 577                                 }
 578                                 else if(spree == -1) // firstblood
 579                                 {
 580                                         return
 581                                                 sprintf(
 582                                                         CCR(normal_or_gentle(
 583                                                                 _("%s^K1 drew first blood! %s^BG"),
 584                                                                 _("%s^K1 got the first score! %s^BG")
 585                                                         )),
 586                                                         player,
 587                                                         spree_newline
 588                                                 );
 589                                 }
 590                         }
 591                         break;
 592                 }
 593
 594                 case -1: // kill spree ended
 595                 {
 596                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 597                         {
 598                                 return
 599                                         sprintf(normal_or_gentle(
 600                                                 _(", ending their %d frag spree"),
 601                                                 _(", ending their %d score spree")
 602                                                 ),
 603                                                 spree
 604                                         );
 605                         }
 606                         break;
 607                 }
 608
 609                 case -2: // kill spree lost
 610                 {
 611                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 612                         {
 613                                 return
 614                                         sprintf(normal_or_gentle(
 615                                                 _(", losing their %d frag spree"),
 616                                                 _(", losing their %d score spree")
 617                                                 ),
 618                                                 spree
 619                                         );
 620                         }
 621                         break;
 622                 }
 623         }
 624         return "";
 625 }
 626
 627
 628 // ====================================
 629 //  Initialization/Create Declarations
 630 // ====================================
 631
 632 // common notification entity values
 633 .int nent_default;
 634 .bool nent_enabled;
 635 .MSG nent_type;
 636 .string nent_name;
 637 .int nent_stringcount;
 638 .int nent_floatcount;
 639 .int nent_teamnum;
 640
 641 // MSG_ANNCE entity values
 642 .int nent_channel;
 643 .string nent_snd;
 644 .float nent_vol;
 645 .float nent_position;
 646
 647 // MSG_INFO and MSG_CENTER entity values
 648 .string nent_args; // used by both
 649 .string nent_hudargs; // used by info
 650 .string nent_icon; // used by info
 651 .CPID nent_cpid; // used by center
 652 .string nent_durcnt; // used by center
 653 .string nent_string; // used by both
 654
 655 // MSG_MULTI entity values
 656 .entity nent_msgannce;
 657 .entity nent_msginfo;
 658 .entity nent_msgcenter;
 659
 660 // MSG_CHOICE entity values
 661 .float nent_challow_def;
 662 .float nent_challow_var;
 663 .entity nent_optiona;
 664 .entity nent_optionb;
 665
 666 // networked notification entity values
 667 #ifdef SVQC
 668 .NOTIF nent_broadcast;
 669 #endif
 670 .entity nent_client;
 671 .MSG nent_net_type;
 672 .float nent_net_name;
 673 .string nent_strings[4];
 674 .float nent_floats[4];
 675
 676 #define ACVNN(name) autocvar_notification_##name
 677
 678 REGISTRY(Notifications, BITS(11))
 679 REGISTER_REGISTRY(Notifications)
 680 REGISTRY_SORT(Notifications);
 681 STATIC_INIT(Notifications) { FOREACH(Notifications, true, it.m_id = i); }
 682 REGISTRY_CHECK(Notifications)
 683
 684 const int NOTIF_CHOICE_MAX = 50;
 685 int nent_choice_count = 0;
 686 .int nent_choice_idx;
 687 .int msg_choice_choices[NOTIF_CHOICE_MAX]; // set on each player containing MSG_CHOICE choices
 688 // initialization error detection
 689 bool notif_error;
 690 bool notif_global_error;
 691
 692 STATIC_INIT_LATE(Notif_Choices) {
 693         int c = 0;
 694         FOREACH(Notifications, it.nent_type == MSG_CHOICE, { c++; });
 695         if (c > NOTIF_CHOICE_MAX) {
 696                 LOG_FATALF("Too many MSG_CHOICE notifications (%d)", c);
 697         }
 698 }
 699
 700 string Get_Notif_CvarName(Notification notif)
 701 {
 702         if(!notif.nent_teamnum)
 703                 return notif.nent_name;
 704         return substring(notif.nent_name, 0, -strlen(Static_Team_ColorName(notif.nent_teamnum)) - 2);
 705 }
 706
 707 Notification Get_Notif_Ent(MSG net_type, int net_name)
 708 {
 709         Notification it = _Notifications_from(net_name, NULL);
 710         if (it.nent_type != net_type) {
 711                 LOG_WARNF("Get_Notif_Ent(%s (%d), %s (%d)): Improper net type '%s'!",
 712                         Get_Notif_TypeName(net_type), net_type,
 713                         it.registered_id, net_name,
 714                         Get_Notif_TypeName(it.nent_type)
 715                 );
 716                 return NULL;
 717         }
 718         return it;
 719 }
 720
 721 #define MSG_ANNCE_NOTIF_TEAM(teamnum, name, cvarname, default, sound, channel, volume, position) \
 722         MSG_ANNCE_NOTIF_(teamnum, ANNCE_##name, ANNCE_##cvarname, default, sound, channel, volume, position)
 723
 724 #define MSG_ANNCE_NOTIF(name, default, sound, channel, volume, position) \
 725         NOTIF_ADD_AUTOCVAR(ANNCE_##name, default) \
 726         MSG_ANNCE_NOTIF_(0, ANNCE_##name, ANNCE_##name, default, sound, channel, volume, position)
 727
 728 #define MSG_ANNCE_NOTIF_(teamnum, name, cvarname, default, sound, channel, volume, position) \
 729         REGISTER(Notifications, name, m_id, new_pure(msg_annce_notification)) { \
 730                 Create_Notification_Entity      (this, default, ACVNN(cvarname), MSG_ANNCE, strtoupper(#name), teamnum); \
 731                 Create_Notification_Entity_Annce(this, ACVNN(cvarname), strtoupper(#name), \
 732                         channel,   /* channel  */ \
 733                         sound,     /* snd      */ \
 734                         volume,    /* vol      */ \
 735                         position); /* position */ \
 736         }
 737
 738 #define MSG_INFO_NOTIF_TEAM(teamnum, name, cvarname, default, strnum, flnum, args, hudargs, icon, normal, gentle) \
 739         MSG_INFO_NOTIF_(teamnum, INFO_##name, INFO_##cvarname, default, strnum, flnum, args, hudargs, icon, normal, gentle)
 740
 741 #define MSG_INFO_NOTIF(name, default, strnum, flnum, args, hudargs, icon, normal, gentle) \
 742         NOTIF_ADD_AUTOCVAR(INFO_##name, default) \
 743         MSG_INFO_NOTIF_(0, INFO_##name, INFO_##name, default, strnum, flnum, args, hudargs, icon, normal, gentle)
 744
 745 #define MSG_INFO_NOTIF_(teamnum, name, cvarname, default, strnum, flnum, args, hudargs, icon, normal, gentle) \
 746         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 747                 Create_Notification_Entity           (this, default, ACVNN(cvarname), MSG_INFO, strtoupper(#name), teamnum); \
 748                 Create_Notification_Entity_InfoCenter(this, ACVNN(cvarname), strtoupper(#name), strnum, flnum, \
 749                         args,     /* args    */ \
 750                         hudargs,  /* hudargs */ \
 751                         icon,     /* icon    */ \
 752                         CPID_Null,/* cpid    */ \
 753                         "",       /* durcnt  */ \
 754                         normal,   /* normal  */ \
 755                         gentle);  /* gentle  */ \
 756         }
 757
 758 .string nent_iconargs;
 759 #define MULTIICON_INFO(name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 760         MULTIICON_INFO_(INFO_##name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle)
 761 #define MULTIICON_INFO_(name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 762         NOTIF_ADD_AUTOCVAR(name, default) \
 763         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 764                 Create_Notification_Entity           (this, default, ACVNN(name), MSG_INFO, strtoupper(#name), 0); \
 765                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
 766                         args,     /* args    */ \
 767                         hudargs,  /* hudargs */ \
 768                         icon,     /* icon    */ \
 769                         CPID_Null,/* cpid    */ \
 770                         "",       /* durcnt  */ \
 771                         normal,   /* normal  */ \
 772                         gentle);  /* gentle  */ \
 773                 this.nent_iconargs = iconargs; \
 774         }
 775
 776 #define MSG_CENTER_NOTIF_TEAM(teamnum, name, cvarname, default, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 777         MSG_CENTER_NOTIF_(teamnum, CENTER_##name, CENTER_##cvarname, default, strnum, flnum, args, cpid, durcnt, normal, gentle)
 778
 779 #define MSG_CENTER_NOTIF(name, default, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 780         NOTIF_ADD_AUTOCVAR(CENTER_##name, default) \
 781         MSG_CENTER_NOTIF_(0, CENTER_##name, CENTER_##name, default, strnum, flnum, args, cpid, durcnt, normal, gentle)
 782
 783 #define MSG_CENTER_NOTIF_(teamnum, name, cvarname, default, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 784         REGISTER(Notifications, name, m_id, new_pure(msg_center_notification)) { \
 785                 Create_Notification_Entity           (this, default, ACVNN(cvarname), MSG_CENTER, strtoupper(#name), teamnum); \
 786                 Create_Notification_Entity_InfoCenter(this, ACVNN(cvarname), strtoupper(#name), strnum, flnum, \
 787                         args,    /* args    */ \
 788                         "",      /* hudargs */ \
 789                         "",      /* icon    */ \
 790                         cpid,    /* cpid    */ \
 791                         durcnt,  /* durcnt  */ \
 792                         normal,  /* normal  */ \
 793                         gentle); /* gentle  */ \
 794         }
 795
 796 #define MSG_MULTI_NOTIF(name, default, anncename, infoname, centername) \
 797         NOTIF_ADD_AUTOCVAR(name, default) \
 798         REGISTER(Notifications, name, m_id, new_pure(msg_multi_notification)) { \
 799                 Create_Notification_Entity      (this, default, ACVNN(name), MSG_MULTI, strtoupper(#name), 0); \
 800                 Create_Notification_Entity_Multi(this, ACVNN(name), strtoupper(#name), \
 801                         anncename,   /* anncename  */ \
 802                         infoname,    /* infoname   */ \
 803                         centername); /* centername */ \
 804         }
 805
 806 #define MSG_CHOICE_NOTIF_TEAM(teamnum, name, cvarname, default, challow, chtype, optiona, optionb) \
 807         MSG_CHOICE_NOTIF_(teamnum, CHOICE_##name, CHOICE_##cvarname, default, challow, chtype, optiona, optionb)
 808
 809 #define MSG_CHOICE_NOTIF(name, default, challow, chtype, optiona, optionb) \
 810         NOTIF_ADD_AUTOCVAR(CHOICE_##name, default) \
 811         NOTIF_ADD_AUTOCVAR(CHOICE_##name##_ALLOWED, challow) \
 812         MSG_CHOICE_NOTIF_(0, CHOICE_##name, CHOICE_##name, default, challow, chtype, optiona, optionb)
 813
 814 #define MSG_CHOICE_NOTIF_(teamnum, name, cvarname, default, challow, chtype, optiona, optionb) \
 815         REGISTER(Notifications, name, m_id, new_pure(msg_choice_notification)) { \
 816                 this.nent_choice_idx = nent_choice_count++; \
 817                 Create_Notification_Entity       (this, default, ACVNN(cvarname), MSG_CHOICE, strtoupper(#name), teamnum); \
 818                 Create_Notification_Entity_Choice(this, ACVNN(cvarname), strtoupper(#name), \
 819                         challow,                                 /* challow_def */ \
 820                         autocvar_notification_##cvarname##_ALLOWED,  /* challow_var */ \
 821                         chtype,                                  /* chtype      */ \
 822                         optiona,                                 /* optiona     */ \
 823                         optionb);                                /* optionb     */ \
 824         }
 825
 826 REGISTRY_BEGIN(Notifications)
 827 {
 828         notif_global_error = false;
 829 }
 830
 831 REGISTRY_END(Notifications)
 832 {
 833         if (!notif_global_error) return;
 834         // shit happened... stop the loading of the program now if this is unacceptable
 835         if (autocvar_notification_errors_are_fatal)
 836                 LOG_FATAL("Notification initialization failed! Read above and fix the errors!");
 837         else
 838                 LOG_SEVERE("Notification initialization failed! Read above and fix the errors!");
 839 }
 840
 841 #include "all.inc"