qcsrc/common/physics.qc

   1 #include "physics.qh"
   2 #include "triggers/include.qh"
   3 #include "viewloc.qh"
   4
   5 #ifdef SVQC
   6
   7 #include "../server/miscfunctions.qh"
   8 #include "triggers/trigger/viewloc.qh"
   9
  10 // client side physics
  11 bool Physics_Valid(string thecvar)
  12 {
  13         return autocvar_g_physics_clientselect && strhasword(autocvar_g_physics_clientselect_options, thecvar);
  14 }
  15
  16 float Physics_ClientOption(entity this, string option)
  17 {
  18         if(Physics_Valid(this.cvar_cl_physics))
  19         {
  20                 string s = sprintf("g_physics_%s_%s", this.cvar_cl_physics, option);
  21                 if(cvar_type(s) & CVAR_TYPEFLAG_EXISTS)
  22                         return cvar(s);
  23         }
  24         if(autocvar_g_physics_clientselect && autocvar_g_physics_clientselect_default)
  25         {
  26                 string s = sprintf("g_physics_%s_%s", autocvar_g_physics_clientselect_default, option);
  27                 if(cvar_type(s) & CVAR_TYPEFLAG_EXISTS)
  28                         return cvar(s);
  29         }
  30         return cvar(strcat("sv_", option));
  31 }
  32
  33 void Physics_UpdateStats(entity this, float maxspd_mod)
  34 {
  35         STAT(MOVEVARS_AIRACCEL_QW, this) = AdjustAirAccelQW(Physics_ClientOption(this, "airaccel_qw"), maxspd_mod);
  36         STAT(MOVEVARS_AIRSTRAFEACCEL_QW, this) = (Physics_ClientOption(this, "airstrafeaccel_qw"))
  37                 ? AdjustAirAccelQW(Physics_ClientOption(this, "airstrafeaccel_qw"), maxspd_mod)
  38                 : 0;
  39         STAT(MOVEVARS_AIRSPEEDLIMIT_NONQW, this) = Physics_ClientOption(this, "airspeedlimit_nonqw") * maxspd_mod;
  40         STAT(MOVEVARS_MAXSPEED, this) = Physics_ClientOption(this, "maxspeed") * maxspd_mod; // also slow walking
  41
  42         // old stats
  43         // fix some new settings
  44         STAT(MOVEVARS_AIRACCEL_QW_STRETCHFACTOR, this) = Physics_ClientOption(this, "airaccel_qw_stretchfactor");
  45         STAT(MOVEVARS_MAXAIRSTRAFESPEED, this) = Physics_ClientOption(this, "maxairstrafespeed");
  46         STAT(MOVEVARS_MAXAIRSPEED, this) = Physics_ClientOption(this, "maxairspeed");
  47         STAT(MOVEVARS_AIRSTRAFEACCELERATE, this) = Physics_ClientOption(this, "airstrafeaccelerate");
  48         STAT(MOVEVARS_WARSOWBUNNY_TURNACCEL, this) = Physics_ClientOption(this, "warsowbunny_turnaccel");
  49         STAT(MOVEVARS_AIRACCEL_SIDEWAYS_FRICTION, this) = Physics_ClientOption(this, "airaccel_sideways_friction");
  50         STAT(MOVEVARS_AIRCONTROL, this) = Physics_ClientOption(this, "aircontrol");
  51         STAT(MOVEVARS_AIRCONTROL_POWER, this) = Physics_ClientOption(this, "aircontrol_power");
  52         STAT(MOVEVARS_AIRCONTROL_PENALTY, this) = Physics_ClientOption(this, "aircontrol_penalty");
  53         STAT(MOVEVARS_WARSOWBUNNY_AIRFORWARDACCEL, this) = Physics_ClientOption(this, "warsowbunny_airforwardaccel");
  54         STAT(MOVEVARS_WARSOWBUNNY_TOPSPEED, this) = Physics_ClientOption(this, "warsowbunny_topspeed");
  55         STAT(MOVEVARS_WARSOWBUNNY_ACCEL, this) = Physics_ClientOption(this, "warsowbunny_accel");
  56         STAT(MOVEVARS_WARSOWBUNNY_BACKTOSIDERATIO, this) = Physics_ClientOption(this, "warsowbunny_backtosideratio");
  57         STAT(MOVEVARS_FRICTION, this) = Physics_ClientOption(this, "friction");
  58         STAT(MOVEVARS_ACCELERATE, this) = Physics_ClientOption(this, "accelerate");
  59         STAT(MOVEVARS_STOPSPEED, this) = Physics_ClientOption(this, "stopspeed");
  60         STAT(MOVEVARS_AIRACCELERATE, this) = Physics_ClientOption(this, "airaccelerate");
  61         STAT(MOVEVARS_AIRSTOPACCELERATE, this) = Physics_ClientOption(this, "airstopaccelerate");
  62         STAT(MOVEVARS_JUMPVELOCITY, this) = Physics_ClientOption(this, "jumpvelocity");
  63         STAT(MOVEVARS_TRACK_CANJUMP, this) = Physics_ClientOption(this, "track_canjump");
  64 }
  65 #endif
  66
  67 float IsMoveInDirection(vector mv, float ang) // key mix factor
  68 {
  69         if (mv_x == 0 && mv_y == 0)
  70                 return 0; // avoid division by zero
  71         ang -= RAD2DEG * atan2(mv_y, mv_x);
  72         ang = remainder(ang, 360) / 45;
  73         return ang > 1 ? 0 : ang < -1 ? 0 : 1 - fabs(ang);
  74 }
  75
  76 float GeomLerp(float a, float lerp, float b)
  77 {
  78         return a == 0 ? (lerp < 1 ? 0 : b)
  79                 : b == 0 ? (lerp > 0 ? 0 : a)
  80                 : a * pow(fabs(b / a), lerp);
  81 }
  82
  83 #define unstick_offsets(X) \
  84 /* 1 no nudge (just return the original if this test passes) */ \
  85         X(' 0.000  0.000  0.000') \
  86 /* 6 simple nudges */ \
  87         X(' 0.000  0.000  0.125') X('0.000  0.000 -0.125') \
  88         X('-0.125  0.000  0.000') X('0.125  0.000  0.000') \
  89         X(' 0.000 -0.125  0.000') X('0.000  0.125  0.000') \
  90 /* 4 diagonal flat nudges */ \
  91         X('-0.125 -0.125  0.000') X('0.125 -0.125  0.000') \
  92         X('-0.125  0.125  0.000') X('0.125  0.125  0.000') \
  93 /* 8 diagonal upward nudges */ \
  94         X('-0.125  0.000  0.125') X('0.125  0.000  0.125') \
  95         X(' 0.000 -0.125  0.125') X('0.000  0.125  0.125') \
  96         X('-0.125 -0.125  0.125') X('0.125 -0.125  0.125') \
  97         X('-0.125  0.125  0.125') X('0.125  0.125  0.125') \
  98 /* 8 diagonal downward nudges */ \
  99         X('-0.125  0.000 -0.125') X('0.125  0.000 -0.125') \
 100         X(' 0.000 -0.125 -0.125') X('0.000  0.125 -0.125') \
 101         X('-0.125 -0.125 -0.125') X('0.125 -0.125 -0.125') \
 102         X('-0.125  0.125 -0.125') X('0.125  0.125 -0.125') \
 103 /**/
 104
 105 void PM_ClientMovement_Unstick(entity this)
 106 {
 107         #define X(unstick_offset) \
 108         { \
 109                 vector neworigin = unstick_offset + this.origin; \
 110                 tracebox(neworigin, PL_CROUCH_MIN, PL_CROUCH_MAX, neworigin, MOVE_NORMAL, this); \
 111                 if (!trace_startsolid) \
 112                 { \
 113                         setorigin(this, neworigin); \
 114                         return; \
 115                 } \
 116         }
 117         unstick_offsets(X);
 118         #undef X
 119 }
 120
 121 void PM_ClientMovement_UpdateStatus(entity this, bool ground)
 122 {
 123 #ifdef CSQC
 124         // make sure player is not stuck
 125         PM_ClientMovement_Unstick(this);
 126
 127         // set crouched
 128         if (PHYS_INPUT_BUTTON_CROUCH(this))
 129         {
 130                 // wants to crouch, this always works
 131                 if (!IS_DUCKED(this)) SET_DUCKED(this);
 132         }
 133         else
 134         {
 135                 // wants to stand, if currently crouching we need to check for a low ceiling first
 136                 if (IS_DUCKED(this))
 137                 {
 138                         tracebox(this.origin, PL_MIN, PL_MAX, this.origin, MOVE_NORMAL, this);
 139                         if (!trace_startsolid) UNSET_DUCKED(this);
 140                 }
 141         }
 142
 143         // set onground
 144         vector origin1 = this.origin + '0 0 1';
 145         vector origin2 = this.origin - '0 0 1';
 146
 147         if (ground && autocvar_cl_movement != 3)
 148         {
 149                 tracebox(origin1, this.mins, this.maxs, origin2, MOVE_NORMAL, this);
 150                 if (trace_fraction < 1.0 && trace_plane_normal.z > 0.7)
 151                 {
 152                         SET_ONGROUND(this);
 153
 154                         // this code actually "predicts" an impact; so let's clip velocity first
 155                         this.velocity -= this.velocity * trace_plane_normal * trace_plane_normal;
 156                 }
 157                 else
 158                         UNSET_ONGROUND(this);
 159         }
 160
 161         // set watertype/waterlevel
 162         origin1 = this.origin;
 163         origin1.z += this.mins_z + 1;
 164         this.waterlevel = WATERLEVEL_NONE;
 165
 166         int thepoint = pointcontents(origin1);
 167
 168         this.watertype = (thepoint == CONTENT_WATER || thepoint == CONTENT_LAVA || thepoint == CONTENT_SLIME);
 169
 170         if (this.watertype)
 171         {
 172                 this.waterlevel = WATERLEVEL_WETFEET;
 173                 origin1.z = this.origin.z + (this.mins.z + this.maxs.z) * 0.5;
 174                 thepoint = pointcontents(origin1);
 175                 if (thepoint == CONTENT_WATER || thepoint == CONTENT_LAVA || thepoint == CONTENT_SLIME)
 176                 {
 177                         this.waterlevel = WATERLEVEL_SWIMMING;
 178                         origin1.z = this.origin.z + 22;
 179                         thepoint = pointcontents(origin1);
 180                         if (thepoint == CONTENT_WATER || thepoint == CONTENT_LAVA || thepoint == CONTENT_SLIME)
 181                                 this.waterlevel = WATERLEVEL_SUBMERGED;
 182                 }
 183         }
 184
 185         if (IS_ONGROUND(this) || this.velocity.z <= 0 || PHYS_TELEPORT_TIME(this) <= 0)
 186                 PHYS_TELEPORT_TIME(this) = 0;
 187 #endif
 188 }
 189
 190 void PM_ClientMovement_Move(entity this)
 191 {
 192 #ifdef CSQC
 193
 194         PM_ClientMovement_UpdateStatus(this, false);
 195         if(autocvar_cl_movement == 3)
 196                 return;
 197
 198         int bump;
 199         float t;
 200         float f;
 201         vector neworigin;
 202         vector currentorigin2;
 203         vector neworigin2;
 204         vector primalvelocity;
 205
 206         vector trace1_endpos = '0 0 0';
 207         vector trace2_endpos = '0 0 0';
 208         vector trace3_endpos = '0 0 0';
 209         float trace1_fraction = 0;
 210         float trace2_fraction = 0;
 211         float trace3_fraction = 0;
 212         vector trace1_plane_normal = '0 0 0';
 213         vector trace2_plane_normal = '0 0 0';
 214         vector trace3_plane_normal = '0 0 0';
 215
 216         primalvelocity = this.velocity;
 217         for(bump = 0, t = PHYS_INPUT_TIMELENGTH; bump < 8 && (this.velocity * this.velocity) > 0; bump++)
 218         {
 219                 neworigin = this.origin + t * this.velocity;
 220                 tracebox(this.origin, this.mins, this.maxs, neworigin, MOVE_NORMAL, this);
 221                 trace1_endpos = trace_endpos;
 222                 trace1_fraction = trace_fraction;
 223                 trace1_plane_normal = trace_plane_normal;
 224                 if(trace1_fraction < 1 && trace1_plane_normal_z == 0)
 225                 {
 226                         // may be a step or wall, try stepping up
 227                         // first move forward at a higher level
 228                         currentorigin2 = this.origin;
 229                         currentorigin2_z += PHYS_STEPHEIGHT;
 230                         neworigin2 = neworigin;
 231                         neworigin2_z += PHYS_STEPHEIGHT;
 232                         tracebox(currentorigin2, this.mins, this.maxs, neworigin2, MOVE_NORMAL, this);
 233                         trace2_endpos = trace_endpos;
 234                         trace2_fraction = trace_fraction;
 235                         trace2_plane_normal = trace_plane_normal;
 236                         if(!trace_startsolid)
 237                         {
 238                                 // then move down from there
 239                                 currentorigin2 = trace2_endpos;
 240                                 neworigin2 = trace2_endpos;
 241                                 neworigin2_z = this.origin_z;
 242                                 tracebox(currentorigin2, this.mins, this.maxs, neworigin2, MOVE_NORMAL, this);
 243                                 trace3_endpos = trace_endpos;
 244                                 trace3_fraction = trace_fraction;
 245                                 trace3_plane_normal = trace_plane_normal;
 246                                 // accept the new trace if it made some progress
 247                                 if(fabs(trace3_endpos_x - trace1_endpos_x) >= 0.03125 || fabs(trace3_endpos_y - trace1_endpos_y) >= 0.03125)
 248                                 {
 249                                         trace1_endpos = trace2_endpos;
 250                                         trace1_fraction = trace2_fraction;
 251                                         trace1_plane_normal = trace2_plane_normal;
 252                                         trace1_endpos = trace3_endpos;
 253                                 }
 254                         }
 255                 }
 256
 257                 // check if it moved at all
 258                 if(trace1_fraction >= 0.001)
 259                         setorigin(this, trace1_endpos);
 260
 261                 // check if it moved all the way
 262                 if(trace1_fraction == 1)
 263                         break;
 264
 265                 // this is only really needed for nogravityonground combined with gravityunaffectedbyticrate
 266                 // <LordHavoc> I'm pretty sure I commented it out solely because it seemed redundant
 267                 // this got commented out in a change that supposedly makes the code match QW better
 268                 // so if this is broken, maybe put it in an if(cls.protocol != PROTOCOL_QUAKEWORLD) block
 269                 if(trace1_plane_normal_z > 0.7)
 270                         SET_ONGROUND(this);
 271
 272                 t -= t * trace1_fraction;
 273
 274                 f = (this.velocity * trace1_plane_normal);
 275                 this.velocity = this.velocity + -f * trace1_plane_normal;
 276         }
 277         if(PHYS_TELEPORT_TIME(this) > 0)
 278                 this.velocity = primalvelocity;
 279 #endif
 280 }
 281
 282 void CPM_PM_Aircontrol(entity this, vector wishdir, float wishspeed)
 283 {
 284         float k = 32 * (2 * IsMoveInDirection(this.movement, 0) - 1);
 285         if (k <= 0)
 286                 return;
 287
 288         k *= bound(0, wishspeed / PHYS_MAXAIRSPEED(this), 1);
 289
 290         float zspeed = this.velocity_z;
 291         this.velocity_z = 0;
 292         float xyspeed = vlen(this.velocity);
 293         this.velocity = normalize(this.velocity);
 294
 295         float dot = this.velocity * wishdir;
 296
 297         if (dot > 0) // we can't change direction while slowing down
 298         {
 299                 k *= pow(dot, PHYS_AIRCONTROL_POWER(this)) * PHYS_INPUT_TIMELENGTH;
 300                 xyspeed = max(0, xyspeed - PHYS_AIRCONTROL_PENALTY(this) * sqrt(max(0, 1 - dot*dot)) * k/32);
 301                 k *= PHYS_AIRCONTROL(this);
 302                 this.velocity = normalize(this.velocity * xyspeed + wishdir * k);
 303         }
 304
 305         this.velocity = this.velocity * xyspeed;
 306         this.velocity_z = zspeed;
 307 }
 308
 309 float AdjustAirAccelQW(float accelqw, float factor)
 310 {
 311         return copysign(bound(0.000001, 1 - (1 - fabs(accelqw)) * factor, 1), accelqw);
 312 }
 313
 314 // example config for alternate speed clamping:
 315 //   sv_airaccel_qw 0.8
 316 //   sv_airaccel_sideways_friction 0
 317 //   prvm_globalset server speedclamp_mode 1
 318 //     (or 2)
 319 void PM_Accelerate(entity this, vector wishdir, float wishspeed, float wishspeed0, float accel, float accelqw, float stretchfactor, float sidefric, float speedlimit)
 320 {
 321         float speedclamp = stretchfactor > 0 ? stretchfactor
 322         : accelqw < 0 ? 1 // full clamping, no stretch
 323         : -1; // no clamping
 324
 325         accelqw = fabs(accelqw);
 326
 327         if (GAMEPLAYFIX_Q2AIRACCELERATE)
 328                 wishspeed0 = wishspeed; // don't need to emulate this Q1 bug
 329
 330         float vel_straight = this.velocity * wishdir;
 331         float vel_z = this.velocity_z;
 332         vector vel_xy = vec2(this.velocity);
 333         vector vel_perpend = vel_xy - vel_straight * wishdir;
 334
 335         float step = accel * PHYS_INPUT_TIMELENGTH * wishspeed0;
 336
 337         float vel_xy_current  = vlen(vel_xy);
 338         if (speedlimit)
 339                 accelqw = AdjustAirAccelQW(accelqw, (speedlimit - bound(wishspeed, vel_xy_current, speedlimit)) / max(1, speedlimit - wishspeed));
 340         float vel_xy_forward =  vel_xy_current  + bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
 341         float vel_xy_backward = vel_xy_current  - bound(0, wishspeed + vel_xy_current, step) * accelqw - step * (1 - accelqw);
 342         vel_xy_backward = max(0, vel_xy_backward); // not that it REALLY occurs that this would cause wrong behaviour afterwards
 343         vel_straight =          vel_straight    + bound(0, wishspeed - vel_straight,   step) * accelqw + step * (1 - accelqw);
 344
 345         if (sidefric < 0 && (vel_perpend*vel_perpend))
 346                 // negative: only apply so much sideways friction to stay below the speed you could get by "braking"
 347         {
 348                 float f = max(0, 1 + PHYS_INPUT_TIMELENGTH * wishspeed * sidefric);
 349                 float themin = (vel_xy_backward * vel_xy_backward - vel_straight * vel_straight) / (vel_perpend * vel_perpend);
 350                 // assume: themin > 1
 351                 // vel_xy_backward*vel_xy_backward - vel_straight*vel_straight > vel_perpend*vel_perpend
 352                 // vel_xy_backward*vel_xy_backward > vel_straight*vel_straight + vel_perpend*vel_perpend
 353                 // vel_xy_backward*vel_xy_backward > vel_xy * vel_xy
 354                 // obviously, this cannot be
 355                 if (themin <= 0)
 356                         vel_perpend *= f;
 357                 else
 358                 {
 359                         themin = sqrt(themin);
 360                         vel_perpend *= max(themin, f);
 361                 }
 362         }
 363         else
 364                 vel_perpend *= max(0, 1 - PHYS_INPUT_TIMELENGTH * wishspeed * sidefric);
 365
 366         vel_xy = vel_straight * wishdir + vel_perpend;
 367
 368         if (speedclamp >= 0)
 369         {
 370                 float vel_xy_preclamp;
 371                 vel_xy_preclamp = vlen(vel_xy);
 372                 if (vel_xy_preclamp > 0) // prevent division by zero
 373                 {
 374                         vel_xy_current += (vel_xy_forward - vel_xy_current) * speedclamp;
 375                         if (vel_xy_current < vel_xy_preclamp)
 376                                 vel_xy *= (vel_xy_current / vel_xy_preclamp);
 377                 }
 378         }
 379
 380         this.velocity = vel_xy + vel_z * '0 0 1';
 381 }
 382
 383 void PM_AirAccelerate(entity this, vector wishdir, float wishspeed)
 384 {
 385         if (wishspeed == 0)
 386                 return;
 387
 388         vector curvel = this.velocity;
 389         curvel_z = 0;
 390         float curspeed = vlen(curvel);
 391
 392         if (wishspeed > curspeed * 1.01)
 393                 wishspeed = min(wishspeed, curspeed + PHYS_WARSOWBUNNY_AIRFORWARDACCEL(this) * PHYS_MAXSPEED(this) * PHYS_INPUT_TIMELENGTH);
 394         else
 395         {
 396                 float f = max(0, (PHYS_WARSOWBUNNY_TOPSPEED(this) - curspeed) / (PHYS_WARSOWBUNNY_TOPSPEED(this) - PHYS_MAXSPEED(this)));
 397                 wishspeed = max(curspeed, PHYS_MAXSPEED(this)) + PHYS_WARSOWBUNNY_ACCEL(this) * f * PHYS_MAXSPEED(this) * PHYS_INPUT_TIMELENGTH;
 398         }
 399         vector wishvel = wishdir * wishspeed;
 400         vector acceldir = wishvel - curvel;
 401         float addspeed = vlen(acceldir);
 402         acceldir = normalize(acceldir);
 403
 404         float accelspeed = min(addspeed, PHYS_WARSOWBUNNY_TURNACCEL(this) * PHYS_MAXSPEED(this) * PHYS_INPUT_TIMELENGTH);
 405
 406         if (PHYS_WARSOWBUNNY_BACKTOSIDERATIO(this) < 1)
 407         {
 408                 vector curdir = normalize(curvel);
 409                 float dot = acceldir * curdir;
 410                 if (dot < 0)
 411                         acceldir -= (1 - PHYS_WARSOWBUNNY_BACKTOSIDERATIO(this)) * dot * curdir;
 412         }
 413
 414         this.velocity += accelspeed * acceldir;
 415 }
 416
 417
 418 /*
 419 =============
 420 PlayerJump
 421
 422 When you press the jump key
 423 returns true if handled
 424 =============
 425 */
 426 bool PlayerJump(entity this)
 427 {
 428         if (PHYS_FROZEN(this))
 429                 return true; // no jumping in freezetag when frozen
 430
 431 #ifdef SVQC
 432         if (this.player_blocked)
 433                 return true; // no jumping while blocked
 434 #endif
 435
 436         bool doublejump = false;
 437         float mjumpheight = PHYS_JUMPVELOCITY(this);
 438
 439         if (MUTATOR_CALLHOOK(PlayerJump, this, doublejump, mjumpheight))
 440                 return true;
 441
 442         doublejump = player_multijump;
 443         mjumpheight = player_jumpheight;
 444
 445         if (this.waterlevel >= WATERLEVEL_SWIMMING)
 446         {
 447                 this.velocity_z = PHYS_MAXSPEED(this) * 0.7;
 448                 return true;
 449         }
 450
 451         if (!doublejump)
 452                 if (!IS_ONGROUND(this))
 453                         return IS_JUMP_HELD(this);
 454
 455         bool track_jump = PHYS_CL_TRACK_CANJUMP(this);
 456         if(PHYS_TRACK_CANJUMP(this))
 457                 track_jump = true;
 458
 459         if (track_jump)
 460                 if (IS_JUMP_HELD(this))
 461                         return true;
 462
 463         // sv_jumpspeedcap_min/sv_jumpspeedcap_max act as baseline
 464         // velocity bounds.  Final velocity is bound between (jumpheight *
 465         // min + jumpheight) and (jumpheight * max + jumpheight);
 466
 467         if(PHYS_JUMPSPEEDCAP_MIN != "")
 468         {
 469                 float minjumpspeed = mjumpheight * stof(PHYS_JUMPSPEEDCAP_MIN);
 470
 471                 if (this.velocity_z < minjumpspeed)
 472                         mjumpheight += minjumpspeed - this.velocity_z;
 473         }
 474
 475         if(PHYS_JUMPSPEEDCAP_MAX != "")
 476         {
 477                 // don't do jump speedcaps on ramps to preserve old xonotic ramjump style
 478                 tracebox(this.origin + '0 0 0.01', this.mins, this.maxs, this.origin - '0 0 0.01', MOVE_NORMAL, this);
 479
 480                 if (!(trace_fraction < 1 && trace_plane_normal_z < 0.98 && PHYS_JUMPSPEEDCAP_DISABLE_ONRAMPS))
 481                 {
 482                         float maxjumpspeed = mjumpheight * stof(PHYS_JUMPSPEEDCAP_MAX);
 483
 484                         if (this.velocity_z > maxjumpspeed)
 485                                 mjumpheight -= this.velocity_z - maxjumpspeed;
 486                 }
 487         }
 488
 489         if (!WAS_ONGROUND(this))
 490         {
 491 #ifdef SVQC
 492                 if(autocvar_speedmeter)
 493                         LOG_TRACE(strcat("landing velocity: ", vtos(this.velocity), " (abs: ", ftos(vlen(this.velocity)), ")\n"));
 494 #endif
 495                 if(this.lastground < time - 0.3)
 496                 {
 497                         this.velocity_x *= (1 - PHYS_FRICTION_ONLAND);
 498                         this.velocity_y *= (1 - PHYS_FRICTION_ONLAND);
 499                 }
 500 #ifdef SVQC
 501                 if(this.jumppadcount > 1)
 502                         LOG_TRACE(strcat(ftos(this.jumppadcount), "x jumppad combo\n"));
 503                 this.jumppadcount = 0;
 504 #endif
 505         }
 506
 507         this.velocity_z += mjumpheight;
 508
 509         UNSET_ONGROUND(this);
 510         SET_JUMP_HELD(this);
 511
 512 #ifdef SVQC
 513
 514         this.oldvelocity_z = this.velocity_z;
 515
 516         animdecide_setaction(this, ANIMACTION_JUMP, true);
 517
 518         if (autocvar_g_jump_grunt)
 519                 WITH(entity, this, this, PlayerSound(playersound_jump, CH_PLAYER, VOICETYPE_PLAYERSOUND));
 520 #endif
 521         return true;
 522 }
 523
 524 void CheckWaterJump(entity this)
 525 {
 526 // check for a jump-out-of-water
 527         makevectors(this.v_angle);
 528         vector start = this.origin;
 529         start_z += 8;
 530         v_forward_z = 0;
 531         normalize(v_forward);
 532         vector end = start + v_forward*24;
 533         traceline (start, end, true, this);
 534         if (trace_fraction < 1)
 535         {       // solid at waist
 536                 start_z = start_z + this.maxs_z - 8;
 537                 end = start + v_forward*24;
 538                 this.movedir = trace_plane_normal * -50;
 539                 traceline(start, end, true, this);
 540                 if (trace_fraction == 1)
 541                 {       // open at eye level
 542                         this.velocity_z = 225;
 543                         this.flags |= FL_WATERJUMP;
 544                         SET_JUMP_HELD(this);
 545                         PHYS_TELEPORT_TIME(this) = time + 2;    // safety net
 546                 }
 547         }
 548 }
 549
 550
 551 #ifdef SVQC
 552         #define JETPACK_JUMP(s) s.cvar_cl_jetpack_jump
 553 #elif defined(CSQC)
 554         float autocvar_cl_jetpack_jump;
 555         #define JETPACK_JUMP(s) autocvar_cl_jetpack_jump
 556 #endif
 557 .float jetpack_stopped;
 558 void CheckPlayerJump(entity this)
 559 {
 560 #ifdef SVQC
 561         float was_flying = ITEMS_STAT(this) & IT_USING_JETPACK;
 562 #endif
 563         if (JETPACK_JUMP(this) < 2)
 564                 ITEMS_STAT(this) &= ~IT_USING_JETPACK;
 565
 566         if(PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_JETPACK(this))
 567         {
 568                 float air_jump = !PlayerJump(this) || player_multijump; // PlayerJump() has important side effects
 569                 float activate = JETPACK_JUMP(this) && air_jump && PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_JETPACK(this);
 570                 float has_fuel = !PHYS_JETPACK_FUEL || PHYS_AMMO_FUEL(this) || ITEMS_STAT(this) & IT_UNLIMITED_WEAPON_AMMO;
 571
 572                 if (!(ITEMS_STAT(this) & ITEM_Jetpack.m_itemid)) { }
 573                 else if (this.jetpack_stopped) { }
 574                 else if (!has_fuel)
 575                 {
 576 #ifdef SVQC
 577                         if (was_flying) // TODO: ran out of fuel message
 578                                 Send_Notification(NOTIF_ONE, this, MSG_INFO, INFO_JETPACK_NOFUEL);
 579                         else if (activate)
 580                                 Send_Notification(NOTIF_ONE, this, MSG_INFO, INFO_JETPACK_NOFUEL);
 581 #endif
 582                         this.jetpack_stopped = true;
 583                         ITEMS_STAT(this) &= ~IT_USING_JETPACK;
 584                 }
 585                 else if (activate && !PHYS_FROZEN(this))
 586                         ITEMS_STAT(this) |= IT_USING_JETPACK;
 587         }
 588         else
 589         {
 590                 this.jetpack_stopped = false;
 591                 ITEMS_STAT(this) &= ~IT_USING_JETPACK;
 592         }
 593         if (!PHYS_INPUT_BUTTON_JUMP(this))
 594                 UNSET_JUMP_HELD(this);
 595
 596         if (this.waterlevel == WATERLEVEL_SWIMMING)
 597                 CheckWaterJump(this);
 598 }
 599
 600 float racecar_angle(float forward, float down)
 601 {
 602         if (forward < 0)
 603         {
 604                 forward = -forward;
 605                 down = -down;
 606         }
 607
 608         float ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 609
 610         float angle_mult = forward / (800 + forward);
 611
 612         if (ret > 180)
 613                 return ret * angle_mult + 360 * (1 - angle_mult);
 614         else
 615                 return ret * angle_mult;
 616 }
 617
 618 string specialcommand = "xwxwxsxsxaxdxaxdx1x ";
 619 .float specialcommand_pos;
 620 void SpecialCommand()
 621 {
 622 #ifdef SVQC
 623         if (!CheatImpulse(99))
 624                 LOG_INFO("A hollow voice says \"Plugh\".\n");
 625 #endif
 626 }
 627
 628 float PM_check_specialcommand(entity this, float buttons)
 629 {
 630 #ifdef SVQC
 631         string c;
 632         if (!buttons)
 633                 c = "x";
 634         else if (buttons == 1)
 635                 c = "1";
 636         else if (buttons == 2)
 637                 c = " ";
 638         else if (buttons == 128)
 639                 c = "s";
 640         else if (buttons == 256)
 641                 c = "w";
 642         else if (buttons == 512)
 643                 c = "a";
 644         else if (buttons == 1024)
 645                 c = "d";
 646         else
 647                 c = "?";
 648
 649         if (c == substring(specialcommand, this.specialcommand_pos, 1))
 650         {
 651                 this.specialcommand_pos += 1;
 652                 if (this.specialcommand_pos >= strlen(specialcommand))
 653                 {
 654                         this.specialcommand_pos = 0;
 655                         SpecialCommand();
 656                         return true;
 657                 }
 658         }
 659         else if (this.specialcommand_pos && (c != substring(specialcommand, this.specialcommand_pos - 1, 1)))
 660                 this.specialcommand_pos = 0;
 661 #endif
 662         return false;
 663 }
 664
 665 void PM_check_nickspam(entity this)
 666 {
 667 #ifdef SVQC
 668         if (time >= this.nickspamtime)
 669                 return;
 670         if (this.nickspamcount >= autocvar_g_nick_flood_penalty_yellow)
 671         {
 672                 // slight annoyance for nick change scripts
 673                 this.movement = -1 * this.movement;
 674                 this.BUTTON_ATCK = this.BUTTON_JUMP = this.BUTTON_ATCK2 = this.BUTTON_ZOOM = this.BUTTON_CROUCH = this.BUTTON_HOOK = this.BUTTON_USE = 0;
 675
 676                 if (this.nickspamcount >= autocvar_g_nick_flood_penalty_red) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
 677                 {
 678                         this.v_angle_x = random() * 360;
 679                         this.v_angle_y = random() * 360;
 680                         // at least I'm not forcing retardedview by also assigning to angles_z
 681                         this.fixangle = true;
 682                 }
 683         }
 684 #endif
 685 }
 686
 687 void PM_check_punch(entity this)
 688 {
 689 #ifdef SVQC
 690         if (this.punchangle != '0 0 0')
 691         {
 692                 float f = vlen(this.punchangle) - 10 * PHYS_INPUT_TIMELENGTH;
 693                 if (f > 0)
 694                         this.punchangle = normalize(this.punchangle) * f;
 695                 else
 696                         this.punchangle = '0 0 0';
 697         }
 698
 699         if (this.punchvector != '0 0 0')
 700         {
 701                 float f = vlen(this.punchvector) - 30 * PHYS_INPUT_TIMELENGTH;
 702                 if (f > 0)
 703                         this.punchvector = normalize(this.punchvector) * f;
 704                 else
 705                         this.punchvector = '0 0 0';
 706         }
 707 #endif
 708 }
 709
 710 // predict frozen movement, as frozen players CAN move in some cases
 711 void PM_check_frozen(entity this)
 712 {
 713         if (!PHYS_FROZEN(this))
 714                 return;
 715         if (PHYS_DODGING_FROZEN
 716 #ifdef SVQC
 717         && IS_REAL_CLIENT(this)
 718 #endif
 719         )
 720         {
 721                 this.movement_x = bound(-5, this.movement.x, 5);
 722                 this.movement_y = bound(-5, this.movement.y, 5);
 723                 this.movement_z = bound(-5, this.movement.z, 5);
 724         }
 725         else
 726                 this.movement = '0 0 0';
 727
 728         vector midpoint = ((this.absmin + this.absmax) * 0.5);
 729         if (pointcontents(midpoint) == CONTENT_WATER)
 730         {
 731                 this.velocity = this.velocity * 0.5;
 732
 733                 if (pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
 734                         this.velocity_z = 200;
 735         }
 736 }
 737
 738 void PM_check_hitground(entity this)
 739 {
 740 #ifdef SVQC
 741         if (!IS_PLAYER(this)) return; // no fall sounds for observers thank you very much
 742         if (!IS_ONGROUND(this)) return;
 743         if (!this.wasFlying) return;
 744     this.wasFlying = false;
 745     if (this.waterlevel >= WATERLEVEL_SWIMMING) return;
 746     if (time < this.ladder_time) return;
 747     if (this.hook) return;
 748     this.nextstep = time + 0.3 + random() * 0.1;
 749     trace_dphitq3surfaceflags = 0;
 750     tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
 751     if ((trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)) return;
 752     entity fall = (trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS) ? GS_FALL_METAL : GS_FALL;
 753     WITH(entity, self, this, GlobalSound(fall, CH_PLAYER, VOICETYPE_PLAYERSOUND));
 754 #endif
 755 }
 756
 757 void PM_check_blocked(entity this)
 758 {
 759 #ifdef SVQC
 760         if (!this.player_blocked)
 761                 return;
 762         this.movement = '0 0 0';
 763         this.disableclientprediction = 1;
 764 #endif
 765 }
 766
 767 void PM_fly(entity this, float maxspd_mod)
 768 {
 769         // noclipping or flying
 770         UNSET_ONGROUND(this);
 771
 772         this.velocity = this.velocity * (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this));
 773         makevectors(this.v_angle);
 774         //wishvel = v_forward * this.movement.x + v_right * this.movement.y + v_up * this.movement.z;
 775         vector wishvel = v_forward * this.movement.x
 776                                         + v_right * this.movement.y
 777                                         + '0 0 1' * this.movement.z;
 778         // acceleration
 779         vector wishdir = normalize(wishvel);
 780         float wishspeed = min(vlen(wishvel), PHYS_MAXSPEED(this) * maxspd_mod);
 781         if(time >= PHYS_TELEPORT_TIME(this))
 782                 PM_Accelerate(this, wishdir, wishspeed, wishspeed, PHYS_ACCELERATE(this) * maxspd_mod, 1, 0, 0, 0);
 783         PM_ClientMovement_Move(this);
 784 }
 785
 786 void PM_swim(entity this, float maxspd_mod)
 787 {
 788         // swimming
 789         UNSET_ONGROUND(this);
 790
 791         float jump = PHYS_INPUT_BUTTON_JUMP(this);
 792         // water jump only in certain situations
 793         // this mimics quakeworld code
 794         if (jump && this.waterlevel == WATERLEVEL_SWIMMING && this.velocity_z >= -180)
 795         {
 796                 vector yawangles = '0 1 0' * this.v_angle.y;
 797                 makevectors(yawangles);
 798                 vector forward = v_forward;
 799                 vector spot = this.origin + 24 * forward;
 800                 spot_z += 8;
 801                 traceline(spot, spot, MOVE_NOMONSTERS, this);
 802                 if (trace_startsolid)
 803                 {
 804                         spot_z += 24;
 805                         traceline(spot, spot, MOVE_NOMONSTERS, this);
 806                         if (!trace_startsolid)
 807                         {
 808                                 this.velocity = forward * 50;
 809                                 this.velocity_z = 310;
 810                                 PHYS_TELEPORT_TIME(this) = 2;
 811                                 UNSET_ONGROUND(this);
 812                                 SET_JUMP_HELD(this);
 813                         }
 814                 }
 815         }
 816         makevectors(this.v_angle);
 817         //wishvel = v_forward * this.movement.x + v_right * this.movement.y + v_up * this.movement.z;
 818         vector wishvel = v_forward * this.movement.x
 819                                         + v_right * this.movement.y
 820                                         + '0 0 1' * this.movement.z;
 821         if (wishvel == '0 0 0')
 822                 wishvel = '0 0 -60'; // drift towards bottom
 823
 824         vector wishdir = normalize(wishvel);
 825         float wishspeed = min(vlen(wishvel), PHYS_MAXSPEED(this) * maxspd_mod) * 0.7;
 826
 827         if (IS_DUCKED(this))
 828         wishspeed *= 0.5;
 829
 830 //      if (pmove_waterjumptime <= 0) // TODO: use
 831     {
 832                 // water friction
 833                 float f = 1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this);
 834                 f = min(max(0, f), 1);
 835                 this.velocity *= f;
 836
 837                 f = wishspeed - this.velocity * wishdir;
 838                 if (f > 0)
 839                 {
 840                         float accelspeed = min(PHYS_ACCELERATE(this) * PHYS_INPUT_TIMELENGTH * wishspeed, f);
 841                         this.velocity += accelspeed * wishdir;
 842                 }
 843
 844                 // holding jump button swims upward slowly
 845                 if (jump)
 846                 {
 847 #if 0
 848                         if (this.watertype & CONTENT_LAVA)
 849                                 this.velocity_z =  50;
 850                         else if (this.watertype & CONTENT_SLIME)
 851                                 this.velocity_z =  80;
 852                         else
 853                         {
 854                                 if (IS_NEXUIZ_DERIVED(gamemode))
 855 #endif
 856                                         this.velocity_z = 200;
 857 #if 0
 858                                 else
 859                                         this.velocity_z = 100;
 860                         }
 861 #endif
 862                 }
 863         }
 864         // water acceleration
 865         PM_Accelerate(this, wishdir, wishspeed, wishspeed, PHYS_ACCELERATE(this) * maxspd_mod, 1, 0, 0, 0);
 866         PM_ClientMovement_Move(this);
 867 }
 868
 869 void PM_ladder(entity this, float maxspd_mod)
 870 {
 871         // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 872         UNSET_ONGROUND(this);
 873
 874         float g;
 875         g = PHYS_GRAVITY(this) * PHYS_INPUT_TIMELENGTH;
 876         if (PHYS_ENTGRAVITY(this))
 877                 g *= PHYS_ENTGRAVITY(this);
 878         if (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
 879         {
 880                 g *= 0.5;
 881                 this.velocity_z += g;
 882         }
 883
 884         this.velocity = this.velocity * (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this));
 885         makevectors(this.v_angle);
 886         //wishvel = v_forward * this.movement.x + v_right * this.movement.y + v_up * this.movement.z;
 887         vector wishvel = v_forward * this.movement_x
 888                                         + v_right * this.movement_y
 889                                         + '0 0 1' * this.movement_z;
 890         this.velocity_z += g;
 891         if (this.ladder_entity.classname == "func_water")
 892         {
 893                 float f = vlen(wishvel);
 894                 if (f > this.ladder_entity.speed)
 895                         wishvel *= (this.ladder_entity.speed / f);
 896
 897                 this.watertype = this.ladder_entity.skin;
 898                 f = this.ladder_entity.origin_z + this.ladder_entity.maxs_z;
 899                 if ((this.origin_z + this.view_ofs_z) < f)
 900                         this.waterlevel = WATERLEVEL_SUBMERGED;
 901                 else if ((this.origin_z + (this.mins_z + this.maxs_z) * 0.5) < f)
 902                         this.waterlevel = WATERLEVEL_SWIMMING;
 903                 else if ((this.origin_z + this.mins_z + 1) < f)
 904                         this.waterlevel = WATERLEVEL_WETFEET;
 905                 else
 906                 {
 907                         this.waterlevel = WATERLEVEL_NONE;
 908                         this.watertype = CONTENT_EMPTY;
 909                 }
 910         }
 911         // acceleration
 912         vector wishdir = normalize(wishvel);
 913         float wishspeed = min(vlen(wishvel), PHYS_MAXSPEED(this) * maxspd_mod);
 914         if(time >= PHYS_TELEPORT_TIME(this))
 915                 // water acceleration
 916                 PM_Accelerate(this, wishdir, wishspeed, wishspeed, PHYS_ACCELERATE(this)*maxspd_mod, 1, 0, 0, 0);
 917         PM_ClientMovement_Move(this);
 918 }
 919
 920 void PM_jetpack(entity this, float maxspd_mod)
 921 {
 922         //makevectors(this.v_angle.y * '0 1 0');
 923         makevectors(this.v_angle);
 924         vector wishvel = v_forward * this.movement_x
 925                                         + v_right * this.movement_y;
 926         // add remaining speed as Z component
 927         float maxairspd = PHYS_MAXAIRSPEED(this) * max(1, maxspd_mod);
 928         // fix speedhacks :P
 929         wishvel = normalize(wishvel) * min(1, vlen(wishvel) / maxairspd);
 930         // add the unused velocity as up component
 931         wishvel_z = 0;
 932
 933         // if (this.BUTTON_JUMP)
 934                 wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
 935
 936         // it is now normalized, so...
 937         float a_side = PHYS_JETPACK_ACCEL_SIDE;
 938         float a_up = PHYS_JETPACK_ACCEL_UP;
 939         float a_add = PHYS_JETPACK_ANTIGRAVITY * PHYS_GRAVITY(this);
 940
 941         wishvel_x *= a_side;
 942         wishvel_y *= a_side;
 943         wishvel_z *= a_up;
 944         wishvel_z += a_add;
 945
 946         float best = 0;
 947         //////////////////////////////////////////////////////////////////////////////////////
 948         // finding the maximum over all vectors of above form
 949         // with wishvel having an absolute value of 1
 950         //////////////////////////////////////////////////////////////////////////////////////
 951         // we're finding the maximum over
 952         //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
 953         // for z in the range from -1 to 1
 954         //////////////////////////////////////////////////////////////////////////////////////
 955         // maximum is EITHER attained at the single extreme point:
 956         float a_diff = a_side * a_side - a_up * a_up;
 957         float f;
 958         if (a_diff != 0)
 959         {
 960                 f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
 961                 if (f > -1 && f < 1) // can it be attained?
 962                 {
 963                         best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
 964                         //print("middle\n");
 965                 }
 966         }
 967         // OR attained at z = 1:
 968         f = (a_up + a_add) * (a_up + a_add);
 969         if (f > best)
 970         {
 971                 best = f;
 972                 //print("top\n");
 973         }
 974         // OR attained at z = -1:
 975         f = (a_up - a_add) * (a_up - a_add);
 976         if (f > best)
 977         {
 978                 best = f;
 979                 //print("bottom\n");
 980         }
 981         best = sqrt(best);
 982         //////////////////////////////////////////////////////////////////////////////////////
 983
 984         //print("best possible acceleration: ", ftos(best), "\n");
 985
 986         float fxy, fz;
 987         fxy = bound(0, 1 - (this.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / PHYS_JETPACK_MAXSPEED_SIDE, 1);
 988         if (wishvel_z - PHYS_GRAVITY(this) > 0)
 989                 fz = bound(0, 1 - this.velocity_z / PHYS_JETPACK_MAXSPEED_UP, 1);
 990         else
 991                 fz = bound(0, 1 + this.velocity_z / PHYS_JETPACK_MAXSPEED_UP, 1);
 992
 993         float fvel;
 994         fvel = vlen(wishvel);
 995         wishvel_x *= fxy;
 996         wishvel_y *= fxy;
 997         wishvel_z = (wishvel_z - PHYS_GRAVITY(this)) * fz + PHYS_GRAVITY(this);
 998
 999         fvel = min(1, vlen(wishvel) / best);
1000         if (PHYS_JETPACK_FUEL && !(ITEMS_STAT(this) & IT_UNLIMITED_WEAPON_AMMO))
1001                 f = min(1, PHYS_AMMO_FUEL(this) / (PHYS_JETPACK_FUEL * PHYS_INPUT_TIMELENGTH * fvel));
1002         else
1003                 f = 1;
1004
1005         //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
1006
1007         if (f > 0 && wishvel != '0 0 0')
1008         {
1009                 this.velocity = this.velocity + wishvel * f * PHYS_INPUT_TIMELENGTH;
1010                 UNSET_ONGROUND(this);
1011
1012 #ifdef SVQC
1013                 if (!(ITEMS_STAT(this) & IT_UNLIMITED_WEAPON_AMMO))
1014                         this.ammo_fuel -= PHYS_JETPACK_FUEL * PHYS_INPUT_TIMELENGTH * fvel * f;
1015
1016                 ITEMS_STAT(this) |= IT_USING_JETPACK;
1017
1018                 // jetpack also inhibits health regeneration, but only for 1 second
1019                 this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_fuel_regen);
1020 #endif
1021         }
1022
1023 #ifdef CSQC
1024         float g = PHYS_GRAVITY(this) * PHYS_ENTGRAVITY(this) * PHYS_INPUT_TIMELENGTH;
1025         if(autocvar_cl_movement != 3)
1026         {
1027                 if (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
1028                         this.velocity_z -= g * 0.5;
1029                 else
1030                         this.velocity_z -= g;
1031         }
1032         PM_ClientMovement_Move(this);
1033         if(autocvar_cl_movement != 3)
1034         {
1035                 if (!IS_ONGROUND(this) || !(GAMEPLAYFIX_NOGRAVITYONGROUND))
1036                         if (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
1037                                 this.velocity_z -= g * 0.5;
1038         }
1039 #endif
1040 }
1041
1042 void PM_walk(entity this, float maxspd_mod)
1043 {
1044         if (!WAS_ONGROUND(this))
1045         {
1046 #ifdef SVQC
1047                 if (autocvar_speedmeter)
1048                         LOG_TRACE(strcat("landing velocity: ", vtos(this.velocity), " (abs: ", ftos(vlen(this.velocity)), ")\n"));
1049 #endif
1050                 if (this.lastground < time - 0.3)
1051                         this.velocity *= (1 - PHYS_FRICTION_ONLAND);
1052 #ifdef SVQC
1053                 if (this.jumppadcount > 1)
1054                         LOG_TRACE(strcat(ftos(this.jumppadcount), "x jumppad combo\n"));
1055                 this.jumppadcount = 0;
1056 #endif
1057         }
1058
1059         // walking
1060         makevectors(this.v_angle.y * '0 1 0');
1061         const vector wishvel = v_forward * this.movement.x
1062                                                 + v_right * this.movement.y;
1063         // acceleration
1064         const vector wishdir = normalize(wishvel);
1065         float wishspeed = vlen(wishvel);
1066         wishspeed = min(wishspeed, PHYS_MAXSPEED(this) * maxspd_mod);
1067         if (IS_DUCKED(this)) wishspeed *= 0.5;
1068
1069         // apply edge friction
1070         const float f2 = vlen2(vec2(this.velocity));
1071         if (f2 > 0)
1072         {
1073                 trace_dphitq3surfaceflags = 0;
1074                 tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
1075                 // TODO: apply edge friction
1076                 // apply ground friction
1077                 const int realfriction = (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK)
1078                         ? PHYS_FRICTION_SLICK
1079                         : PHYS_FRICTION(this);
1080
1081                 float f = sqrt(f2);
1082                 f = 1 - PHYS_INPUT_TIMELENGTH * realfriction * ((f < PHYS_STOPSPEED(this)) ? (PHYS_STOPSPEED(this) / f) : 1);
1083                 f = max(0, f);
1084                 this.velocity *= f;
1085                 /*
1086                    Mathematical analysis time!
1087
1088                    Our goal is to invert this mess.
1089
1090                    For the two cases we get:
1091                         v = v0 * (1 - PHYS_INPUT_TIMELENGTH * (PHYS_STOPSPEED(this) / v0) * PHYS_FRICTION(this))
1092                           = v0 - PHYS_INPUT_TIMELENGTH * PHYS_STOPSPEED(this) * PHYS_FRICTION(this)
1093                         v0 = v + PHYS_INPUT_TIMELENGTH * PHYS_STOPSPEED(this) * PHYS_FRICTION(this)
1094                    and
1095                         v = v0 * (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this))
1096                         v0 = v / (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this))
1097
1098                    These cases would be chosen ONLY if:
1099                         v0 < PHYS_STOPSPEED(this)
1100                         v + PHYS_INPUT_TIMELENGTH * PHYS_STOPSPEED(this) * PHYS_FRICTION(this) < PHYS_STOPSPEED(this)
1101                         v < PHYS_STOPSPEED(this) * (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this))
1102                    and, respectively:
1103                         v0 >= PHYS_STOPSPEED(this)
1104                         v / (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this)) >= PHYS_STOPSPEED(this)
1105                         v >= PHYS_STOPSPEED(this) * (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this))
1106                  */
1107         }
1108         const float addspeed = wishspeed - this.velocity * wishdir;
1109         if (addspeed > 0)
1110         {
1111                 const float accelspeed = min(PHYS_ACCELERATE(this) * PHYS_INPUT_TIMELENGTH * wishspeed, addspeed);
1112                 this.velocity += accelspeed * wishdir;
1113         }
1114 #ifdef CSQC
1115         float g = PHYS_GRAVITY(this) * PHYS_ENTGRAVITY(this) * PHYS_INPUT_TIMELENGTH;
1116         if(autocvar_cl_movement != 3)
1117         {
1118                 if (!(GAMEPLAYFIX_NOGRAVITYONGROUND))
1119                         this.velocity_z -= g * (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE ? 0.5 : 1);
1120         }
1121         if (vdist(this.velocity, >, 0))
1122                 PM_ClientMovement_Move(this);
1123         if(autocvar_cl_movement != 3)
1124         {
1125                 if (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
1126                         if (!IS_ONGROUND(this) || !GAMEPLAYFIX_NOGRAVITYONGROUND)
1127                                 this.velocity_z -= g * 0.5;
1128         }
1129 #endif
1130 }
1131
1132 void PM_air(entity this, float buttons_prev, float maxspd_mod)
1133 {
1134         makevectors(this.v_angle.y * '0 1 0');
1135         vector wishvel = v_forward * this.movement.x
1136                                         + v_right * this.movement.y;
1137         // acceleration
1138         vector wishdir = normalize(wishvel);
1139         float wishspeed = vlen(wishvel);
1140
1141         if(PHYS_TELEPORT_TIME(this) < time)
1142         {
1143                 float maxairspd = PHYS_MAXAIRSPEED(this) * min(maxspd_mod, 1);
1144
1145                 // apply air speed limit
1146                 float airaccelqw = PHYS_AIRACCEL_QW(this);
1147                 float wishspeed0 = wishspeed;
1148                 wishspeed = min(wishspeed, maxairspd);
1149                 if (IS_DUCKED(this))
1150                         wishspeed *= 0.5;
1151                 float airaccel = PHYS_AIRACCELERATE(this) * min(maxspd_mod, 1);
1152
1153                 float accelerating = (this.velocity * wishdir > 0);
1154                 float wishspeed2 = wishspeed;
1155
1156                 // CPM: air control
1157                 if (PHYS_AIRSTOPACCELERATE(this))
1158                 {
1159                         vector curdir = normalize(vec2(this.velocity));
1160                         airaccel += (PHYS_AIRSTOPACCELERATE(this)*maxspd_mod - airaccel) * max(0, -(curdir * wishdir));
1161                 }
1162                 // note that for straight forward jumping:
1163                 // step = accel * PHYS_INPUT_TIMELENGTH * wishspeed0;
1164                 // accel  = bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
1165                 // -->
1166                 // dv/dt = accel * maxspeed (when slow)
1167                 // dv/dt = accel * maxspeed * (1 - accelqw) (when fast)
1168                 // log dv/dt = logaccel + logmaxspeed (when slow)
1169                 // log dv/dt = logaccel + logmaxspeed + log(1 - accelqw) (when fast)
1170                 float strafity = IsMoveInDirection(this.movement, -90) + IsMoveInDirection(this.movement, +90); // if one is nonzero, other is always zero
1171                 if (PHYS_MAXAIRSTRAFESPEED(this))
1172                         wishspeed = min(wishspeed, GeomLerp(PHYS_MAXAIRSPEED(this)*maxspd_mod, strafity, PHYS_MAXAIRSTRAFESPEED(this)*maxspd_mod));
1173                 if (PHYS_AIRSTRAFEACCELERATE(this))
1174                         airaccel = GeomLerp(airaccel, strafity, PHYS_AIRSTRAFEACCELERATE(this)*maxspd_mod);
1175                 if (PHYS_AIRSTRAFEACCEL_QW(this))
1176                         airaccelqw =
1177                 (((strafity > 0.5 ? PHYS_AIRSTRAFEACCEL_QW(this) : PHYS_AIRACCEL_QW(this)) >= 0) ? +1 : -1)
1178                 *
1179                 (1 - GeomLerp(1 - fabs(PHYS_AIRACCEL_QW(this)), strafity, 1 - fabs(PHYS_AIRSTRAFEACCEL_QW(this))));
1180                 // !CPM
1181
1182                 if (PHYS_WARSOWBUNNY_TURNACCEL(this) && accelerating && this.movement.y == 0 && this.movement.x != 0)
1183                         PM_AirAccelerate(this, wishdir, wishspeed2);
1184                 else
1185                         PM_Accelerate(this, wishdir, wishspeed, wishspeed0, airaccel, airaccelqw, PHYS_AIRACCEL_QW_STRETCHFACTOR(this), PHYS_AIRACCEL_SIDEWAYS_FRICTION(this) / maxairspd, PHYS_AIRSPEEDLIMIT_NONQW(this));
1186
1187                 if (PHYS_AIRCONTROL(this))
1188                         CPM_PM_Aircontrol(this, wishdir, wishspeed2);
1189         }
1190 #ifdef CSQC
1191         float g = PHYS_GRAVITY(this) * PHYS_ENTGRAVITY(this) * PHYS_INPUT_TIMELENGTH;
1192         if(autocvar_cl_movement != 3)
1193         if (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
1194                 this.velocity_z -= g * 0.5;
1195         else
1196                 this.velocity_z -= g;
1197 #endif
1198         PM_ClientMovement_Move(this);
1199 #ifdef CSQC
1200         if(autocvar_cl_movement != 3)
1201         if (!IS_ONGROUND(this) || !(GAMEPLAYFIX_NOGRAVITYONGROUND))
1202                 if (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
1203                         this.velocity_z -= g * 0.5;
1204 #endif
1205 }
1206
1207 // used for calculating airshots
1208 bool IsFlying(entity this)
1209 {
1210         if(IS_ONGROUND(this))
1211                 return false;
1212         if(this.waterlevel >= WATERLEVEL_SWIMMING)
1213                 return false;
1214         traceline(this.origin, this.origin - '0 0 48', MOVE_NORMAL, this);
1215         if(trace_fraction < 1)
1216                 return false;
1217         return true;
1218 }
1219
1220 void PM_Main(entity this)
1221 {
1222         int buttons = PHYS_INPUT_BUTTON_MASK(this);
1223 #ifdef CSQC
1224         this.items = getstati(STAT_ITEMS, 0, 24);
1225
1226         this.movement = PHYS_INPUT_MOVEVALUES(this);
1227
1228         vector oldv_angle = this.v_angle;
1229         vector oldangles = this.angles; // we need to save these, as they're abused by other code
1230         this.v_angle = PHYS_INPUT_ANGLES(this);
1231         this.angles = PHYS_WORLD_ANGLES(this);
1232
1233         this.team = myteam + 1; // is this correct?
1234         if (!(PHYS_INPUT_BUTTON_JUMP(this))) // !jump
1235                 UNSET_JUMP_HELD(this); // canjump = true
1236         PHYS_TELEPORT_TIME(this) -= PHYS_INPUT_TIMELENGTH;
1237
1238         PM_ClientMovement_UpdateStatus(this, true);
1239 #endif
1240
1241
1242 #ifdef SVQC
1243         WarpZone_PlayerPhysics_FixVAngle();
1244 #endif
1245         float maxspeed_mod = 1;
1246         maxspeed_mod *= PHYS_HIGHSPEED;
1247
1248 #ifdef SVQC
1249         Physics_UpdateStats(this, maxspeed_mod);
1250
1251         if (this.PlayerPhysplug)
1252                 if (this.PlayerPhysplug())
1253                         return;
1254 #endif
1255
1256 #ifdef SVQC
1257         anticheat_physics(this);
1258 #endif
1259
1260         if (PM_check_specialcommand(this, buttons))
1261                 return;
1262 #ifdef SVQC
1263         if (sv_maxidle > 0)
1264         {
1265                 if (buttons != this.buttons_old || this.movement != this.movement_old || this.v_angle != this.v_angle_old)
1266                         this.parm_idlesince = time;
1267         }
1268 #endif
1269         int buttons_prev = this.buttons_old;
1270         this.buttons_old = buttons;
1271         this.movement_old = this.movement;
1272         this.v_angle_old = this.v_angle;
1273
1274         PM_check_nickspam(this);
1275
1276         PM_check_punch(this);
1277 #ifdef SVQC
1278         if (IS_BOT_CLIENT(this))
1279         {
1280                 if (playerdemo_read(this))
1281                         return;
1282                 WITH(entity, self, this, bot_think());
1283         }
1284 #endif
1285
1286 #ifdef SVQC
1287         if (IS_PLAYER(this))
1288         {
1289                 const bool allowed_to_move = (time >= game_starttime);
1290                 if (!allowed_to_move)
1291                 {
1292                         this.velocity = '0 0 0';
1293                         this.movetype = MOVETYPE_NONE;
1294                         this.disableclientprediction = 2;
1295                 }
1296                 else if (this.disableclientprediction == 2)
1297                 {
1298                         if (this.movetype == MOVETYPE_NONE)
1299                                 this.movetype = MOVETYPE_WALK;
1300                         this.disableclientprediction = 0;
1301                 }
1302         }
1303 #endif
1304
1305 #ifdef SVQC
1306         if (this.movetype == MOVETYPE_NONE)
1307                 return;
1308
1309         // when we get here, disableclientprediction cannot be 2
1310         this.disableclientprediction = 0;
1311 #endif
1312
1313         viewloc_PlayerPhysics(this);
1314
1315         PM_check_frozen(this);
1316
1317         PM_check_blocked(this);
1318
1319         maxspeed_mod = 1;
1320
1321         if (this.in_swamp)
1322                 maxspeed_mod *= this.swamp_slowdown; //cvar("g_balance_swamp_moverate");
1323
1324         // conveyors: first fix velocity
1325         if (this.conveyor.state)
1326                 this.velocity -= this.conveyor.movedir;
1327
1328         MUTATOR_CALLHOOK(PlayerPhysics, this);
1329
1330 #ifdef SVQC
1331         if (!IS_PLAYER(this))
1332         {
1333                 maxspeed_mod = autocvar_sv_spectator_speed_multiplier;
1334                 if (!this.spectatorspeed)
1335                         this.spectatorspeed = maxspeed_mod;
1336                 if (this.impulse && this.impulse <= 19 || (this.impulse >= 200 && this.impulse <= 209) || (this.impulse >= 220 && this.impulse <= 229))
1337                 {
1338                         if (this.lastclassname != "player")
1339                         {
1340                                 if (this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209))
1341                                         this.spectatorspeed = bound(1, this.spectatorspeed + 0.5, 5);
1342                                 else if (this.impulse == 11)
1343                                         this.spectatorspeed = maxspeed_mod;
1344                                 else if (this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229))
1345                                         this.spectatorspeed = bound(1, this.spectatorspeed - 0.5, 5);
1346                                 else if (this.impulse >= 1 && this.impulse <= 9)
1347                                         this.spectatorspeed = 1 + 0.5 * (this.impulse - 1);
1348                         } // otherwise just clear
1349                         this.impulse = 0;
1350                 }
1351                 maxspeed_mod = this.spectatorspeed;
1352         }
1353
1354         float spd = max(PHYS_MAXSPEED(this), PHYS_MAXAIRSPEED(this)) * maxspeed_mod;
1355         if(this.speed != spd)
1356         {
1357                 this.speed = spd;
1358                 string temps = ftos(spd);
1359                 stuffcmd(this, strcat("cl_forwardspeed ", temps, "\n"));
1360                 stuffcmd(this, strcat("cl_backspeed ", temps, "\n"));
1361                 stuffcmd(this, strcat("cl_sidespeed ", temps, "\n"));
1362                 stuffcmd(this, strcat("cl_upspeed ", temps, "\n"));
1363         }
1364
1365         if(this.stat_jumpspeedcap_min != PHYS_JUMPSPEEDCAP_MIN)
1366         {
1367                 this.stat_jumpspeedcap_min = PHYS_JUMPSPEEDCAP_MIN;
1368                 stuffcmd(this, strcat("cl_jumpspeedcap_min ", PHYS_JUMPSPEEDCAP_MIN, "\n"));
1369         }
1370         if(this.stat_jumpspeedcap_max != PHYS_JUMPSPEEDCAP_MAX)
1371         {
1372                 this.stat_jumpspeedcap_min = PHYS_JUMPSPEEDCAP_MAX;
1373                 stuffcmd(this, strcat("cl_jumpspeedcap_max ", PHYS_JUMPSPEEDCAP_MAX, "\n"));
1374         }
1375 #endif
1376
1377         if(PHYS_DEAD(this))
1378         {
1379                 // handle water here
1380                 vector midpoint = ((this.absmin + this.absmax) * 0.5);
1381                 if(pointcontents(midpoint) == CONTENT_WATER)
1382                 {
1383                         this.velocity = this.velocity * 0.5;
1384
1385                         // do we want this?
1386                         //if(pointcontents(midpoint + '0 0 2') == CONTENT_WATER)
1387                                 //{ this.velocity_z = 70; }
1388                 }
1389                 goto end;
1390         }
1391
1392 #ifdef SVQC
1393         if (!this.fixangle)
1394                 this.angles = '0 1 0' * this.v_angle.y;
1395 #endif
1396
1397         PM_check_hitground(this);
1398
1399         if(IsFlying(this))
1400                 this.wasFlying = 1;
1401
1402         if (IS_PLAYER(this))
1403                 CheckPlayerJump(this);
1404
1405         if (this.flags & FL_WATERJUMP)
1406         {
1407                 this.velocity_x = this.movedir.x;
1408                 this.velocity_y = this.movedir.y;
1409                 if (time > PHYS_TELEPORT_TIME(this) || this.waterlevel == WATERLEVEL_NONE)
1410                 {
1411                         this.flags &= ~FL_WATERJUMP;
1412                         PHYS_TELEPORT_TIME(this) = 0;
1413                 }
1414         }
1415
1416         else if (MUTATOR_CALLHOOK(PM_Physics, this, maxspeed_mod))
1417                 { }
1418
1419 #ifdef SVQC
1420         else if (this.movetype == MOVETYPE_NOCLIP || this.movetype == MOVETYPE_FLY || this.movetype == MOVETYPE_FLY_WORLDONLY || MUTATOR_CALLHOOK(IsFlying, this))
1421 #elif defined(CSQC)
1422         else if (this.move_movetype == MOVETYPE_NOCLIP || this.move_movetype == MOVETYPE_FLY || this.move_movetype == MOVETYPE_FLY_WORLDONLY || MUTATOR_CALLHOOK(IsFlying, this))
1423 #endif
1424                 PM_fly(this, maxspeed_mod);
1425
1426         else if (this.waterlevel >= WATERLEVEL_SWIMMING)
1427                 PM_swim(this, maxspeed_mod);
1428
1429         else if (time < this.ladder_time)
1430                 PM_ladder(this, maxspeed_mod);
1431
1432         else if (ITEMS_STAT(this) & IT_USING_JETPACK)
1433                 PM_jetpack(this, maxspeed_mod);
1434
1435         else if (IS_ONGROUND(this))
1436                 PM_walk(this, maxspeed_mod);
1437
1438         else
1439                 PM_air(this, buttons_prev, maxspeed_mod);
1440
1441 :end
1442         if (IS_ONGROUND(this))
1443                 this.lastground = time;
1444
1445         // conveyors: then break velocity again
1446         if(this.conveyor.state)
1447                 this.velocity += this.conveyor.movedir;
1448
1449         this.lastflags = this.flags;
1450
1451         this.lastclassname = this.classname;
1452
1453 #ifdef CSQC
1454         this.v_angle = oldv_angle;
1455         this.angles = oldangles;
1456 #endif
1457 }
1458
1459 #if defined(SVQC)
1460 void SV_PlayerPhysics()
1461 #elif defined(CSQC)
1462 void CSQC_ClientMovement_PlayerMove_Frame(entity this)
1463 #endif
1464 {
1465 #ifdef SVQC
1466         SELFPARAM();
1467 #endif
1468         PM_Main(this);
1469 }