qcsrc/common/physics/player.qc

   1 #include "player.qh"
   2 #include "../triggers/include.qh"
   3 #include "../viewloc.qh"
   4
   5 #ifdef SVQC
   6
   7 #include <server/miscfunctions.qh>
   8 #include "../triggers/trigger/viewloc.qh"
   9
  10 // client side physics
  11 bool Physics_Valid(string thecvar)
  12 {
  13         return autocvar_g_physics_clientselect && thecvar != "" && thecvar && thecvar != "default" && strhasword(autocvar_g_physics_clientselect_options, thecvar);
  14 }
  15
  16 float Physics_ClientOption(entity this, string option, float defaultval)
  17 {
  18         if(IS_REAL_CLIENT(this) && Physics_Valid(CS(this).cvar_cl_physics))
  19         {
  20                 string s = strcat("g_physics_", CS(this).cvar_cl_physics, "_", option);
  21                 if(cvar_type(s) & CVAR_TYPEFLAG_EXISTS)
  22                         return cvar(s);
  23         }
  24         if(autocvar_g_physics_clientselect && autocvar_g_physics_clientselect_default)
  25         {
  26                 string s = strcat("g_physics_", autocvar_g_physics_clientselect_default, "_", option);
  27                 if(cvar_type(s) & CVAR_TYPEFLAG_EXISTS)
  28                         return cvar(s);
  29         }
  30         return defaultval;
  31 }
  32
  33 void Physics_UpdateStats(entity this)
  34 {
  35         // update this first, as it's used on all stats (wouldn't want to update them all manually from a mutator hook now, would we?)
  36         STAT(MOVEVARS_HIGHSPEED, this) = autocvar_g_movement_highspeed;
  37
  38         MUTATOR_CALLHOOK(PlayerPhysics_UpdateStats, this);
  39         float maxspd_mod = PHYS_HIGHSPEED(this);
  40
  41         STAT(MOVEVARS_AIRACCEL_QW, this) = AdjustAirAccelQW(Physics_ClientOption(this, "airaccel_qw", autocvar_sv_airaccel_qw), maxspd_mod);
  42         STAT(MOVEVARS_AIRSTRAFEACCEL_QW, this) = (Physics_ClientOption(this, "airstrafeaccel_qw", autocvar_sv_airstrafeaccel_qw))
  43                 ? AdjustAirAccelQW(Physics_ClientOption(this, "airstrafeaccel_qw", autocvar_sv_airstrafeaccel_qw), maxspd_mod)
  44                 : 0;
  45         STAT(MOVEVARS_AIRSPEEDLIMIT_NONQW, this) = Physics_ClientOption(this, "airspeedlimit_nonqw", autocvar_sv_airspeedlimit_nonqw) * maxspd_mod;
  46         STAT(MOVEVARS_MAXSPEED, this) = Physics_ClientOption(this, "maxspeed", autocvar_sv_maxspeed) * maxspd_mod; // also slow walking
  47
  48         STAT(PL_MIN, this) = autocvar_sv_player_mins;
  49         STAT(PL_MAX, this) = autocvar_sv_player_maxs;
  50         STAT(PL_VIEW_OFS, this) = autocvar_sv_player_viewoffset;
  51         STAT(PL_CROUCH_MIN, this) = autocvar_sv_player_crouch_mins;
  52         STAT(PL_CROUCH_MAX, this) = autocvar_sv_player_crouch_maxs;
  53         STAT(PL_CROUCH_VIEW_OFS, this) = autocvar_sv_player_crouch_viewoffset;
  54
  55         // old stats
  56         // fix some new settings
  57         STAT(MOVEVARS_AIRACCEL_QW_STRETCHFACTOR, this) = Physics_ClientOption(this, "airaccel_qw_stretchfactor", autocvar_sv_airaccel_qw_stretchfactor);
  58         STAT(MOVEVARS_MAXAIRSTRAFESPEED, this) = Physics_ClientOption(this, "maxairstrafespeed", autocvar_sv_maxairstrafespeed);
  59         STAT(MOVEVARS_MAXAIRSPEED, this) = Physics_ClientOption(this, "maxairspeed", autocvar_sv_maxairspeed);
  60         STAT(MOVEVARS_AIRSTRAFEACCELERATE, this) = Physics_ClientOption(this, "airstrafeaccelerate", autocvar_sv_airstrafeaccelerate);
  61         STAT(MOVEVARS_WARSOWBUNNY_TURNACCEL, this) = Physics_ClientOption(this, "warsowbunny_turnaccel", autocvar_sv_warsowbunny_turnaccel);
  62         STAT(MOVEVARS_AIRACCEL_SIDEWAYS_FRICTION, this) = Physics_ClientOption(this, "airaccel_sideways_friction", autocvar_sv_airaccel_sideways_friction);
  63         STAT(MOVEVARS_AIRCONTROL, this) = Physics_ClientOption(this, "aircontrol", autocvar_sv_aircontrol);
  64         STAT(MOVEVARS_AIRCONTROL_POWER, this) = Physics_ClientOption(this, "aircontrol_power", autocvar_sv_aircontrol_power);
  65         STAT(MOVEVARS_AIRCONTROL_BACKWARDS, this) = Physics_ClientOption(this, "aircontrol_backwards", autocvar_sv_aircontrol_backwards);
  66         STAT(MOVEVARS_AIRCONTROL_SIDEWARDS, this) = Physics_ClientOption(this, "aircontrol_sidewards", autocvar_sv_aircontrol_sidewards);
  67         STAT(MOVEVARS_AIRCONTROL_PENALTY, this) = Physics_ClientOption(this, "aircontrol_penalty", autocvar_sv_aircontrol_penalty);
  68         STAT(MOVEVARS_WARSOWBUNNY_AIRFORWARDACCEL, this) = Physics_ClientOption(this, "warsowbunny_airforwardaccel", autocvar_sv_warsowbunny_airforwardaccel);
  69         STAT(MOVEVARS_WARSOWBUNNY_TOPSPEED, this) = Physics_ClientOption(this, "warsowbunny_topspeed", autocvar_sv_warsowbunny_topspeed);
  70         STAT(MOVEVARS_WARSOWBUNNY_ACCEL, this) = Physics_ClientOption(this, "warsowbunny_accel", autocvar_sv_warsowbunny_accel);
  71         STAT(MOVEVARS_WARSOWBUNNY_BACKTOSIDERATIO, this) = Physics_ClientOption(this, "warsowbunny_backtosideratio", autocvar_sv_warsowbunny_backtosideratio);
  72         STAT(MOVEVARS_FRICTION, this) = Physics_ClientOption(this, "friction", autocvar_sv_friction);
  73         STAT(MOVEVARS_ACCELERATE, this) = Physics_ClientOption(this, "accelerate", autocvar_sv_accelerate);
  74         STAT(MOVEVARS_STOPSPEED, this) = Physics_ClientOption(this, "stopspeed", autocvar_sv_stopspeed);
  75         STAT(MOVEVARS_AIRACCELERATE, this) = Physics_ClientOption(this, "airaccelerate", autocvar_sv_airaccelerate);
  76         STAT(MOVEVARS_AIRSTOPACCELERATE, this) = Physics_ClientOption(this, "airstopaccelerate", autocvar_sv_airstopaccelerate);
  77         STAT(MOVEVARS_JUMPVELOCITY, this) = Physics_ClientOption(this, "jumpvelocity", autocvar_sv_jumpvelocity);
  78         STAT(MOVEVARS_TRACK_CANJUMP, this) = Physics_ClientOption(this, "track_canjump", autocvar_sv_track_canjump);
  79 }
  80 #endif
  81
  82 float IsMoveInDirection(vector mv, float ang) // key mix factor
  83 {
  84         if (mv_x == 0 && mv_y == 0)
  85                 return 0; // avoid division by zero
  86         ang -= RAD2DEG * atan2(mv_y, mv_x);
  87         ang = remainder(ang, 360) / 45;
  88         return ang > 1 ? 0 : ang < -1 ? 0 : 1 - fabs(ang);
  89 }
  90
  91 float GeomLerp(float a, float _lerp, float b)
  92 {
  93         return a == 0 ? (_lerp < 1 ? 0 : b)
  94                 : b == 0 ? (_lerp > 0 ? 0 : a)
  95                 : a * (fabs(b / a) ** _lerp);
  96 }
  97
  98 void PM_ClientMovement_UpdateStatus(entity this)
  99 {
 100 #ifdef CSQC
 101         if(!IS_PLAYER(this))
 102                 return;
 103
 104         // set crouched
 105         bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
 106         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 107         {
 108                 entity wep = viewmodels[slot];
 109                 if(wep.hook && !wasfreed(wep.hook))
 110                 {
 111                         do_crouch = false;
 112                         break; // don't bother checking the others
 113                 }
 114         }
 115         if(this.waterlevel >= WATERLEVEL_SWIMMING)
 116                 do_crouch = false;
 117         if(hud != HUD_NORMAL)
 118                 do_crouch = false;
 119         if(STAT(FROZEN, this))
 120                 do_crouch = false;
 121
 122         if (do_crouch)
 123         {
 124                 // wants to crouch, this always works
 125                 if (!IS_DUCKED(this)) SET_DUCKED(this);
 126         }
 127         else
 128         {
 129                 // wants to stand, if currently crouching we need to check for a low ceiling first
 130                 if (IS_DUCKED(this))
 131                 {
 132                         tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, MOVE_NORMAL, this);
 133                         if (!trace_startsolid) UNSET_DUCKED(this);
 134                 }
 135         }
 136
 137         if (IS_ONGROUND(this) || this.velocity.z <= 0 || PHYS_WATERJUMP_TIME(this) <= 0)
 138                 PHYS_WATERJUMP_TIME(this) = 0;
 139 #endif
 140 }
 141
 142 void CPM_PM_Aircontrol(entity this, float dt, vector wishdir, float wishspeed)
 143 {
 144         float movity = IsMoveInDirection(PHYS_CS(this).movement, 0);
 145         if(PHYS_AIRCONTROL_BACKWARDS(this))
 146                 movity += IsMoveInDirection(PHYS_CS(this).movement, 180);
 147         if(PHYS_AIRCONTROL_SIDEWARDS(this))
 148         {
 149                 movity += IsMoveInDirection(PHYS_CS(this).movement, 90);
 150                 movity += IsMoveInDirection(PHYS_CS(this).movement, -90);
 151         }
 152
 153         float k = 32 * (2 * movity - 1);
 154         if (k <= 0)
 155                 return;
 156
 157         k *= bound(0, wishspeed / PHYS_MAXAIRSPEED(this), 1);
 158
 159         float zspeed = this.velocity_z;
 160         this.velocity_z = 0;
 161         float xyspeed = vlen(this.velocity);
 162         this.velocity = normalize(this.velocity);
 163
 164         float dot = this.velocity * wishdir;
 165
 166         if (dot > 0) // we can't change direction while slowing down
 167         {
 168                 k *= (dot ** PHYS_AIRCONTROL_POWER(this)) * dt;
 169                 xyspeed = max(0, xyspeed - PHYS_AIRCONTROL_PENALTY(this) * sqrt(max(0, 1 - dot*dot)) * k/32);
 170                 k *= PHYS_AIRCONTROL(this);
 171                 this.velocity = normalize(this.velocity * xyspeed + wishdir * k);
 172         }
 173
 174         this.velocity = this.velocity * xyspeed;
 175         this.velocity_z = zspeed;
 176 }
 177
 178 float AdjustAirAccelQW(float accelqw, float factor)
 179 {
 180         return copysign(bound(0.000001, 1 - (1 - fabs(accelqw)) * factor, 1), accelqw);
 181 }
 182
 183 // example config for alternate speed clamping:
 184 //   sv_airaccel_qw 0.8
 185 //   sv_airaccel_sideways_friction 0
 186 //   prvm_globalset server speedclamp_mode 1
 187 //     (or 2)
 188 void PM_Accelerate(entity this, float dt, vector wishdir, float wishspeed, float wishspeed0, float accel, float accelqw, float stretchfactor, float sidefric, float speedlimit)
 189 {
 190         float speedclamp = stretchfactor > 0 ? stretchfactor
 191         : accelqw < 0 ? 1 // full clamping, no stretch
 192         : -1; // no clamping
 193
 194         accelqw = fabs(accelqw);
 195
 196         if (GAMEPLAYFIX_Q2AIRACCELERATE)
 197                 wishspeed0 = wishspeed; // don't need to emulate this Q1 bug
 198
 199         float vel_straight = this.velocity * wishdir;
 200         float vel_z = this.velocity_z;
 201         vector vel_xy = vec2(this.velocity);
 202         vector vel_perpend = vel_xy - vel_straight * wishdir;
 203
 204         float step = accel * dt * wishspeed0;
 205
 206         float vel_xy_current  = vlen(vel_xy);
 207         if (speedlimit)
 208                 accelqw = AdjustAirAccelQW(accelqw, (speedlimit - bound(wishspeed, vel_xy_current, speedlimit)) / max(1, speedlimit - wishspeed));
 209         float vel_xy_forward =  vel_xy_current  + bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
 210         float vel_xy_backward = vel_xy_current  - bound(0, wishspeed + vel_xy_current, step) * accelqw - step * (1 - accelqw);
 211         vel_xy_backward = max(0, vel_xy_backward); // not that it REALLY occurs that this would cause wrong behaviour afterwards
 212         vel_straight =          vel_straight    + bound(0, wishspeed - vel_straight,   step) * accelqw + step * (1 - accelqw);
 213
 214         if (sidefric < 0 && (vel_perpend*vel_perpend))
 215                 // negative: only apply so much sideways friction to stay below the speed you could get by "braking"
 216         {
 217                 float f = max(0, 1 + dt * wishspeed * sidefric);
 218                 float themin = (vel_xy_backward * vel_xy_backward - vel_straight * vel_straight) / (vel_perpend * vel_perpend);
 219                 // assume: themin > 1
 220                 // vel_xy_backward*vel_xy_backward - vel_straight*vel_straight > vel_perpend*vel_perpend
 221                 // vel_xy_backward*vel_xy_backward > vel_straight*vel_straight + vel_perpend*vel_perpend
 222                 // vel_xy_backward*vel_xy_backward > vel_xy * vel_xy
 223                 // obviously, this cannot be
 224                 if (themin <= 0)
 225                         vel_perpend *= f;
 226                 else
 227                 {
 228                         themin = sqrt(themin);
 229                         vel_perpend *= max(themin, f);
 230                 }
 231         }
 232         else
 233                 vel_perpend *= max(0, 1 - dt * wishspeed * sidefric);
 234
 235         vel_xy = vel_straight * wishdir + vel_perpend;
 236
 237         if (speedclamp >= 0)
 238         {
 239                 float vel_xy_preclamp;
 240                 vel_xy_preclamp = vlen(vel_xy);
 241                 if (vel_xy_preclamp > 0) // prevent division by zero
 242                 {
 243                         vel_xy_current += (vel_xy_forward - vel_xy_current) * speedclamp;
 244                         if (vel_xy_current < vel_xy_preclamp)
 245                                 vel_xy *= (vel_xy_current / vel_xy_preclamp);
 246                 }
 247         }
 248
 249         this.velocity = vel_xy + vel_z * '0 0 1';
 250 }
 251
 252 void PM_AirAccelerate(entity this, float dt, vector wishdir, float wishspeed)
 253 {
 254         if (wishspeed == 0)
 255                 return;
 256
 257         vector curvel = this.velocity;
 258         curvel_z = 0;
 259         float curspeed = vlen(curvel);
 260
 261         if (wishspeed > curspeed * 1.01)
 262                 wishspeed = min(wishspeed, curspeed + PHYS_WARSOWBUNNY_AIRFORWARDACCEL(this) * PHYS_MAXSPEED(this) * dt);
 263         else
 264         {
 265                 float f = max(0, (PHYS_WARSOWBUNNY_TOPSPEED(this) - curspeed) / (PHYS_WARSOWBUNNY_TOPSPEED(this) - PHYS_MAXSPEED(this)));
 266                 wishspeed = max(curspeed, PHYS_MAXSPEED(this)) + PHYS_WARSOWBUNNY_ACCEL(this) * f * PHYS_MAXSPEED(this) * dt;
 267         }
 268         vector wishvel = wishdir * wishspeed;
 269         vector acceldir = wishvel - curvel;
 270         float addspeed = vlen(acceldir);
 271         acceldir = normalize(acceldir);
 272
 273         float accelspeed = min(addspeed, PHYS_WARSOWBUNNY_TURNACCEL(this) * PHYS_MAXSPEED(this) * dt);
 274
 275         if (PHYS_WARSOWBUNNY_BACKTOSIDERATIO(this) < 1)
 276         {
 277                 vector curdir = normalize(curvel);
 278                 float dot = acceldir * curdir;
 279                 if (dot < 0)
 280                         acceldir -= (1 - PHYS_WARSOWBUNNY_BACKTOSIDERATIO(this)) * dot * curdir;
 281         }
 282
 283         this.velocity += accelspeed * acceldir;
 284 }
 285
 286
 287 /*
 288 =============
 289 PlayerJump
 290
 291 When you press the jump key
 292 returns true if handled
 293 =============
 294 */
 295 bool PlayerJump(entity this)
 296 {
 297         if (PHYS_FROZEN(this))
 298                 return true; // no jumping in freezetag when frozen
 299
 300 #ifdef SVQC
 301         if (this.player_blocked)
 302                 return true; // no jumping while blocked
 303 #endif
 304
 305         bool doublejump = false;
 306         float mjumpheight = PHYS_JUMPVELOCITY(this);
 307         bool track_jump = PHYS_CL_TRACK_CANJUMP(this);
 308
 309         if (MUTATOR_CALLHOOK(PlayerJump, this, mjumpheight, doublejump))
 310                 return true;
 311
 312         mjumpheight = M_ARGV(1, float);
 313         doublejump = M_ARGV(2, bool);
 314
 315         if (this.waterlevel >= WATERLEVEL_SWIMMING)
 316         {
 317                 if(this.viewloc)
 318                 {
 319                         doublejump = true;
 320                         mjumpheight *= 0.7;
 321                         track_jump = true;
 322                 }
 323                 else
 324                 {
 325                         this.velocity_z = PHYS_MAXSPEED(this) * 0.7;
 326                         return true;
 327                 }
 328         }
 329
 330         if (!doublejump)
 331                 if (!IS_ONGROUND(this) && !IS_ONSLICK(this))
 332                         return IS_JUMP_HELD(this);
 333
 334         if(PHYS_TRACK_CANJUMP(this))
 335                 track_jump = true;
 336
 337         if (track_jump)
 338                 if (IS_JUMP_HELD(this))
 339                         return true;
 340
 341         // sv_jumpspeedcap_min/sv_jumpspeedcap_max act as baseline
 342         // velocity bounds.  Final velocity is bound between (jumpheight *
 343         // min + jumpheight) and (jumpheight * max + jumpheight);
 344
 345         if(PHYS_JUMPSPEEDCAP_MIN != "")
 346         {
 347                 float minjumpspeed = mjumpheight * stof(PHYS_JUMPSPEEDCAP_MIN);
 348
 349                 if (this.velocity_z < minjumpspeed)
 350                         mjumpheight += minjumpspeed - this.velocity_z;
 351         }
 352
 353         if(PHYS_JUMPSPEEDCAP_MAX != "")
 354         {
 355                 // don't do jump speedcaps on ramps to preserve old xonotic ramjump style
 356                 tracebox(this.origin + '0 0 0.01', this.mins, this.maxs, this.origin - '0 0 0.01', MOVE_NORMAL, this);
 357
 358                 if (!(trace_fraction < 1 && trace_plane_normal_z < 0.98 && PHYS_JUMPSPEEDCAP_DISABLE_ONRAMPS(this)))
 359                 {
 360                         float maxjumpspeed = mjumpheight * stof(PHYS_JUMPSPEEDCAP_MAX);
 361
 362                         if (this.velocity_z > maxjumpspeed)
 363                                 mjumpheight -= this.velocity_z - maxjumpspeed;
 364                 }
 365         }
 366
 367         if (!WAS_ONGROUND(this) && !WAS_ONSLICK(this))
 368         {
 369 #ifdef SVQC
 370                 if(autocvar_speedmeter)
 371                         LOG_TRACE("landing velocity: ", vtos(this.velocity), " (abs: ", ftos(vlen(this.velocity)), ")");
 372 #endif
 373                 if(this.lastground < time - 0.3)
 374                 {
 375                         float f = (1 - PHYS_FRICTION_ONLAND(this));
 376                         this.velocity_x *= f;
 377                         this.velocity_y *= f;
 378                 }
 379 #ifdef SVQC
 380                 if(this.jumppadcount > 1)
 381                         LOG_TRACE(ftos(this.jumppadcount), "x jumppad combo");
 382                 this.jumppadcount = 0;
 383 #endif
 384         }
 385
 386         this.velocity_z += mjumpheight;
 387
 388         UNSET_ONGROUND(this);
 389         UNSET_ONSLICK(this);
 390         SET_JUMP_HELD(this);
 391
 392 #ifdef SVQC
 393
 394         this.oldvelocity_z = this.velocity_z;
 395
 396         animdecide_setaction(this, ANIMACTION_JUMP, true);
 397
 398         if (autocvar_g_jump_grunt)
 399                 PlayerSound(this, playersound_jump, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
 400 #endif
 401         return true;
 402 }
 403
 404 void CheckWaterJump(entity this)
 405 {
 406 // check for a jump-out-of-water
 407         makevectors(this.v_angle);
 408         vector start = this.origin;
 409         start_z += 8;
 410         v_forward_z = 0;
 411         normalize(v_forward);
 412         vector end = start + v_forward*24;
 413         traceline (start, end, true, this);
 414         if (trace_fraction < 1)
 415         {       // solid at waist
 416                 start_z = start_z + this.maxs_z - 8;
 417                 end = start + v_forward*24;
 418                 this.movedir = trace_plane_normal * -50;
 419                 traceline(start, end, true, this);
 420                 if (trace_fraction == 1)
 421                 {       // open at eye level
 422                         this.velocity_z = 225;
 423                         this.flags |= FL_WATERJUMP;
 424                         SET_JUMP_HELD(this);
 425                 #ifdef SVQC
 426                         PHYS_TELEPORT_TIME(this) = time + 2;    // safety net
 427                 #elif defined(CSQC)
 428                         PHYS_WATERJUMP_TIME(this) = 2;
 429                 #endif
 430                 }
 431         }
 432 }
 433
 434
 435 #ifdef SVQC
 436         #define JETPACK_JUMP(s) CS(s).cvar_cl_jetpack_jump
 437 #elif defined(CSQC)
 438         float autocvar_cl_jetpack_jump;
 439         #define JETPACK_JUMP(s) autocvar_cl_jetpack_jump
 440 #endif
 441 .float jetpack_stopped;
 442 void CheckPlayerJump(entity this)
 443 {
 444 #ifdef SVQC
 445         bool was_flying = boolean(ITEMS_STAT(this) & IT_USING_JETPACK);
 446 #endif
 447         if (JETPACK_JUMP(this) < 2)
 448                 ITEMS_STAT(this) &= ~IT_USING_JETPACK;
 449
 450         if(PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_JETPACK(this))
 451         {
 452                 bool playerjump = PlayerJump(this); // required
 453
 454                 bool air_jump = !playerjump || M_ARGV(2, bool);
 455                 bool activate = JETPACK_JUMP(this) && air_jump && PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_JETPACK(this);
 456                 bool has_fuel = !PHYS_JETPACK_FUEL(this) || PHYS_AMMO_FUEL(this) || (ITEMS_STAT(this) & IT_UNLIMITED_WEAPON_AMMO);
 457
 458                 if (!(ITEMS_STAT(this) & ITEM_Jetpack.m_itemid)) { }
 459                 else if (this.jetpack_stopped) { }
 460                 else if (!has_fuel)
 461                 {
 462 #ifdef SVQC
 463                         if (was_flying) // TODO: ran out of fuel message
 464                                 Send_Notification(NOTIF_ONE, this, MSG_INFO, INFO_JETPACK_NOFUEL);
 465                         else if (activate)
 466                                 Send_Notification(NOTIF_ONE, this, MSG_INFO, INFO_JETPACK_NOFUEL);
 467 #endif
 468                         this.jetpack_stopped = true;
 469                         ITEMS_STAT(this) &= ~IT_USING_JETPACK;
 470                 }
 471                 else if (activate && !PHYS_FROZEN(this))
 472                         ITEMS_STAT(this) |= IT_USING_JETPACK;
 473         }
 474         else
 475         {
 476                 this.jetpack_stopped = false;
 477                 ITEMS_STAT(this) &= ~IT_USING_JETPACK;
 478         }
 479         if (!PHYS_INPUT_BUTTON_JUMP(this))
 480                 UNSET_JUMP_HELD(this);
 481
 482         if (this.waterlevel == WATERLEVEL_SWIMMING)
 483                 CheckWaterJump(this);
 484 }
 485
 486 #ifdef SVQC
 487 string specialcommand = "xwxwxsxsxaxdxaxdx1x ";
 488 .float specialcommand_pos;
 489 void SpecialCommand(entity this)
 490 {
 491         if (!CheatImpulse(this, CHIMPULSE_GIVE_ALL.impulse))
 492                 LOG_INFO("A hollow voice says \"Plugh\".\n");
 493 }
 494 #endif
 495
 496 bool PM_check_specialcommand(entity this, int buttons)
 497 {
 498 #ifdef SVQC
 499         string c;
 500         if (!buttons)
 501                 c = "x";
 502         else if (buttons == 1)
 503                 c = "1";
 504         else if (buttons == 2)
 505                 c = " ";
 506         else if (buttons == 128)
 507                 c = "s";
 508         else if (buttons == 256)
 509                 c = "w";
 510         else if (buttons == 512)
 511                 c = "a";
 512         else if (buttons == 1024)
 513                 c = "d";
 514         else
 515                 c = "?";
 516
 517         if (c == substring(specialcommand, this.specialcommand_pos, 1))
 518         {
 519                 this.specialcommand_pos += 1;
 520                 if (this.specialcommand_pos >= strlen(specialcommand))
 521                 {
 522                         this.specialcommand_pos = 0;
 523                         SpecialCommand(this);
 524                         return true;
 525                 }
 526         }
 527         else if (this.specialcommand_pos && (c != substring(specialcommand, this.specialcommand_pos - 1, 1)))
 528                 this.specialcommand_pos = 0;
 529 #endif
 530         return false;
 531 }
 532
 533 void PM_check_nickspam(entity this)
 534 {
 535 #ifdef SVQC
 536         if (time >= this.nickspamtime)
 537                 return;
 538         if (this.nickspamcount >= autocvar_g_nick_flood_penalty_yellow)
 539         {
 540                 // slight annoyance for nick change scripts
 541                 PHYS_CS(this).movement = -1 * PHYS_CS(this).movement;
 542                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_ZOOM(this) = PHYS_INPUT_BUTTON_CROUCH(this) = PHYS_INPUT_BUTTON_HOOK(this) = PHYS_INPUT_BUTTON_USE(this) = false;
 543
 544                 if (this.nickspamcount >= autocvar_g_nick_flood_penalty_red) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
 545                 {
 546                         this.v_angle_x = random() * 360;
 547                         this.v_angle_y = random() * 360;
 548                         // at least I'm not forcing retardedview by also assigning to angles_z
 549                         this.fixangle = true;
 550                 }
 551         }
 552 #endif
 553 }
 554
 555 void PM_check_punch(entity this, float dt)
 556 {
 557 #ifdef SVQC
 558         if (this.punchangle != '0 0 0')
 559         {
 560                 float f = vlen(this.punchangle) - 10 * dt;
 561                 if (f > 0)
 562                         this.punchangle = normalize(this.punchangle) * f;
 563                 else
 564                         this.punchangle = '0 0 0';
 565         }
 566
 567         if (this.punchvector != '0 0 0')
 568         {
 569                 float f = vlen(this.punchvector) - 30 * dt;
 570                 if (f > 0)
 571                         this.punchvector = normalize(this.punchvector) * f;
 572                 else
 573                         this.punchvector = '0 0 0';
 574         }
 575 #endif
 576 }
 577
 578 // predict frozen movement, as frozen players CAN move in some cases
 579 void PM_check_frozen(entity this)
 580 {
 581         if (!PHYS_FROZEN(this))
 582                 return;
 583         if (PHYS_DODGING_FROZEN(this)
 584 #ifdef SVQC
 585         && IS_REAL_CLIENT(this)
 586 #endif
 587         )
 588         {
 589                 PHYS_CS(this).movement_x = bound(-5, PHYS_CS(this).movement.x, 5);
 590                 PHYS_CS(this).movement_y = bound(-5, PHYS_CS(this).movement.y, 5);
 591                 PHYS_CS(this).movement_z = bound(-5, PHYS_CS(this).movement.z, 5);
 592         }
 593         else
 594                 PHYS_CS(this).movement = '0 0 0';
 595
 596         vector midpoint = ((this.absmin + this.absmax) * 0.5);
 597         if (pointcontents(midpoint) == CONTENT_WATER)
 598         {
 599                 this.velocity = this.velocity * 0.5;
 600
 601                 if (pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
 602                         this.velocity_z = 200;
 603         }
 604 }
 605
 606 void PM_check_hitground(entity this)
 607 {
 608 #ifdef SVQC
 609         if (!this.wasFlying) return;
 610     this.wasFlying = false;
 611     if (this.waterlevel >= WATERLEVEL_SWIMMING) return;
 612     if (time < this.ladder_time) return;
 613     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 614     {
 615         .entity weaponentity = weaponentities[slot];
 616         if(this.(weaponentity).hook)
 617                 return;
 618     }
 619     this.nextstep = time + 0.3 + random() * 0.1;
 620     trace_dphitq3surfaceflags = 0;
 621     tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
 622     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS) return;
 623     entity gs = (trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 624         ? GS_FALL_METAL
 625         : GS_FALL;
 626     float vol = ((IS_DUCKED(this)) ? VOL_MUFFLED : VOL_BASE);
 627     GlobalSound(this, gs, CH_PLAYER, vol, VOICETYPE_PLAYERSOUND);
 628 #endif
 629 }
 630
 631 void PM_Footsteps(entity this)
 632 {
 633 #ifdef SVQC
 634         if (!g_footsteps) return;
 635         if (IS_DUCKED(this)) return;
 636         if (time >= this.lastground + 0.2) return;
 637         if (vdist(this.velocity, <=, autocvar_sv_maxspeed * 0.6)) return;
 638         if ((time > this.nextstep) || (time < (this.nextstep - 10.0)))
 639         {
 640                 this.nextstep = time + 0.3 + random() * 0.1;
 641                 trace_dphitq3surfaceflags = 0;
 642                 tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
 643                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS) return;
 644                 entity gs = (trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 645                         ? GS_STEP_METAL
 646                         : GS_STEP;
 647                 GlobalSound(this, gs, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
 648         }
 649 #endif
 650 }
 651
 652 void PM_check_slick(entity this)
 653 {
 654         if(!IS_ONGROUND(this))
 655                 return;
 656
 657         if(!PHYS_SLICK_APPLYGRAVITY(this))
 658                 return;
 659
 660         tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
 661         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK)
 662         {
 663                 UNSET_ONGROUND(this);
 664                 SET_ONSLICK(this);
 665         }
 666         else
 667                 UNSET_ONSLICK(this);
 668 }
 669
 670 void PM_check_blocked(entity this)
 671 {
 672 #ifdef SVQC
 673         if (!this.player_blocked)
 674                 return;
 675         PHYS_CS(this).movement = '0 0 0';
 676         this.disableclientprediction = 1;
 677 #endif
 678 }
 679
 680 void PM_jetpack(entity this, float maxspd_mod, float dt)
 681 {
 682         //makevectors(this.v_angle.y * '0 1 0');
 683         makevectors(this.v_angle);
 684         vector wishvel = v_forward * PHYS_CS(this).movement_x
 685                                         + v_right * PHYS_CS(this).movement_y;
 686         // add remaining speed as Z component
 687         float maxairspd = PHYS_MAXAIRSPEED(this) * max(1, maxspd_mod);
 688         // fix speedhacks :P
 689         wishvel = normalize(wishvel) * min(1, vlen(wishvel) / maxairspd);
 690         // add the unused velocity as up component
 691         wishvel_z = 0;
 692
 693         // if (PHYS_INPUT_BUTTON_JUMP(this))
 694                 wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
 695
 696         // it is now normalized, so...
 697         float a_side = PHYS_JETPACK_ACCEL_SIDE(this);
 698         float a_up = PHYS_JETPACK_ACCEL_UP(this);
 699         float a_add = PHYS_JETPACK_ANTIGRAVITY(this) * PHYS_GRAVITY(this);
 700
 701         if(PHYS_JETPACK_REVERSE_THRUST(this) && PHYS_INPUT_BUTTON_CROUCH(this)) { a_up = PHYS_JETPACK_REVERSE_THRUST(this); }
 702
 703         wishvel_x *= a_side;
 704         wishvel_y *= a_side;
 705         wishvel_z *= a_up;
 706         wishvel_z += a_add;
 707
 708         if(PHYS_JETPACK_REVERSE_THRUST(this) && PHYS_INPUT_BUTTON_CROUCH(this)) { wishvel_z *= -1; }
 709
 710         float best = 0;
 711         //////////////////////////////////////////////////////////////////////////////////////
 712         // finding the maximum over all vectors of above form
 713         // with wishvel having an absolute value of 1
 714         //////////////////////////////////////////////////////////////////////////////////////
 715         // we're finding the maximum over
 716         //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
 717         // for z in the range from -1 to 1
 718         //////////////////////////////////////////////////////////////////////////////////////
 719         // maximum is EITHER attained at the single extreme point:
 720         float a_diff = a_side * a_side - a_up * a_up;
 721         float f;
 722         if (a_diff != 0)
 723         {
 724                 f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
 725                 if (f > -1 && f < 1) // can it be attained?
 726                 {
 727                         best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
 728                         //print("middle\n");
 729                 }
 730         }
 731         // OR attained at z = 1:
 732         f = (a_up + a_add) * (a_up + a_add);
 733         if (f > best)
 734         {
 735                 best = f;
 736                 //print("top\n");
 737         }
 738         // OR attained at z = -1:
 739         f = (a_up - a_add) * (a_up - a_add);
 740         if (f > best)
 741         {
 742                 best = f;
 743                 //print("bottom\n");
 744         }
 745         best = sqrt(best);
 746         //////////////////////////////////////////////////////////////////////////////////////
 747
 748         //print("best possible acceleration: ", ftos(best), "\n");
 749
 750         float fxy, fz;
 751         fxy = bound(0, 1 - (this.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / PHYS_JETPACK_MAXSPEED_SIDE(this), 1);
 752         if (wishvel_z - PHYS_GRAVITY(this) > 0)
 753                 fz = bound(0, 1 - this.velocity_z / PHYS_JETPACK_MAXSPEED_UP(this), 1);
 754         else
 755                 fz = bound(0, 1 + this.velocity_z / PHYS_JETPACK_MAXSPEED_UP(this), 1);
 756
 757         float fvel;
 758         fvel = vlen(wishvel);
 759         wishvel_x *= fxy;
 760         wishvel_y *= fxy;
 761         wishvel_z = (wishvel_z - PHYS_GRAVITY(this)) * fz + PHYS_GRAVITY(this);
 762
 763         fvel = min(1, vlen(wishvel) / best);
 764         if (PHYS_JETPACK_FUEL(this) && !(ITEMS_STAT(this) & IT_UNLIMITED_WEAPON_AMMO))
 765                 f = min(1, PHYS_AMMO_FUEL(this) / (PHYS_JETPACK_FUEL(this) * dt * fvel));
 766         else
 767                 f = 1;
 768
 769         //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
 770
 771         if (f > 0 && wishvel != '0 0 0')
 772         {
 773                 this.velocity = this.velocity + wishvel * f * dt;
 774                 UNSET_ONGROUND(this);
 775
 776 #ifdef SVQC
 777                 if (!(ITEMS_STAT(this) & IT_UNLIMITED_WEAPON_AMMO))
 778                         this.ammo_fuel -= PHYS_JETPACK_FUEL(this) * dt * fvel * f;
 779
 780                 ITEMS_STAT(this) |= IT_USING_JETPACK;
 781
 782                 // jetpack also inhibits health regeneration, but only for 1 second
 783                 this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_fuel_regen);
 784 #endif
 785         }
 786 }
 787
 788 // used for calculating airshots
 789 bool IsFlying(entity this)
 790 {
 791         if(IS_ONGROUND(this))
 792                 return false;
 793         if(this.waterlevel >= WATERLEVEL_SWIMMING)
 794                 return false;
 795         traceline(this.origin, this.origin - '0 0 48', MOVE_NORMAL, this);
 796         if(trace_fraction < 1)
 797                 return false;
 798         return true;
 799 }
 800
 801
 802 void sys_phys_update(entity this, float dt);
 803 #if defined(SVQC)
 804 void SV_PlayerPhysics(entity this)
 805 #elif defined(CSQC)
 806 void CSQC_ClientMovement_PlayerMove_Frame(entity this)
 807 #endif
 808 {
 809 #ifdef SVQC
 810         // needs to be called before physics are run!
 811         PM_UpdateButtons(this, CS(this));
 812 #endif
 813
 814         sys_phys_update(this, PHYS_INPUT_TIMELENGTH);
 815
 816 #ifdef SVQC
 817         CS(this).pm_frametime = frametime;
 818 #elif defined(CSQC)
 819         if((ITEMS_STAT(this) & IT_USING_JETPACK) && !IS_DEAD(this) && !intermission)
 820                 this.csqcmodel_modelflags |= MF_ROCKET;
 821         else
 822                 this.csqcmodel_modelflags &= ~MF_ROCKET;
 823 #endif
 824 }