qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "triggers/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include "../lib/warpzone/util_server.qh"
  26 #elif defined(CSQC)
  27         #include "physics/movetypes/movetypes.qh"
  28         #include <common/weapons/_all.qh>
  29         #include "../lib/csqcmodel/cl_model.qh"
  30         #include "../lib/csqcmodel/common.qh"
  31 #endif
  32
  33 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  34
  35 #ifdef CSQC
  36 bool autocvar_cl_ghost_items_vehicle = true;
  37 .vector item_glowmod;
  38 void Item_SetAlpha(entity this)
  39 {
  40         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  41
  42         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  43         {
  44                 this.alpha = 1;
  45                 this.colormod = '1 1 1';
  46                 this.glowmod = this.item_glowmod;
  47         }
  48         else
  49         {
  50                 if (autocvar_cl_ghost_items_color)
  51                 {
  52                         this.alpha = autocvar_cl_ghost_items;
  53                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  54                 }
  55                 else
  56                         this.alpha = -1;
  57         }
  58
  59         if(!veh_hud)
  60         if(this.ItemStatus & ITS_STAYWEP)
  61         {
  62                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  63                 this.alpha = autocvar_cl_weapon_stay_alpha;
  64         }
  65 }
  66
  67 void ItemDraw(entity this)
  68 {
  69     if(this.gravity)
  70     {
  71         Movetype_Physics_MatchServer(this, false);
  72         if(IS_ONGROUND(this))
  73         { // For some reason avelocity gets set to '0 0 0' here ...
  74             this.oldorigin = this.origin;
  75             this.gravity = 0;
  76
  77             if(autocvar_cl_animate_items)
  78             { // ... so reset it if animations are requested.
  79                 if(this.ItemStatus & ITS_ANIMATE1)
  80                     this.avelocity = '0 180 0';
  81
  82                 if(this.ItemStatus & ITS_ANIMATE2)
  83                     this.avelocity = '0 -90 0';
  84             }
  85         }
  86     }
  87     else if (autocvar_cl_animate_items)
  88     {
  89         if(this.ItemStatus & ITS_ANIMATE1)
  90         {
  91             this.angles += this.avelocity * frametime;
  92             setorigin(this, '0 0 10' + this.oldorigin + '0 0 8' * sin(time * 2));
  93         }
  94
  95         if(this.ItemStatus & ITS_ANIMATE2)
  96         {
  97             this.angles += this.avelocity * frametime;
  98             setorigin(this, '0 0 8' + this.oldorigin + '0 0 4' * sin(time * 3));
  99         }
 100     }
 101
 102     Item_SetAlpha(this);
 103 }
 104
 105 void ItemDrawSimple(entity this)
 106 {
 107     if(this.gravity)
 108     {
 109         Movetype_Physics_MatchServer(this, false);
 110
 111         if(IS_ONGROUND(this))
 112             this.gravity = 0;
 113     }
 114
 115     Item_SetAlpha(this);
 116 }
 117
 118 void Item_PreDraw(entity this)
 119 {
 120         if(warpzone_warpzones_exist)
 121         {
 122                 // just incase warpzones were initialized last, reset these
 123                 //this.alpha = 1; // alpha is already set by the draw function
 124                 this.drawmask = MASK_NORMAL;
 125                 return;
 126         }
 127         float alph;
 128         vector org = getpropertyvec(VF_ORIGIN);
 129         if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 130                 alph = 0;
 131         else if(this.fade_start)
 132                 alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 133         else
 134                 alph = 1;
 135         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 136         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 137                 this.alpha = alph;
 138         if(alph <= 0)
 139                 this.drawmask = 0;
 140         else
 141                 this.drawmask = MASK_NORMAL;
 142 }
 143
 144 void ItemRemove(entity this)
 145 {
 146         if(this.mdl)
 147                 strunzone(this.mdl);
 148 }
 149
 150 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 151 {
 152     int sf = ReadByte();
 153
 154     if(sf & ISF_LOCATION)
 155     {
 156         this.origin_x = ReadCoord();
 157         this.origin_y = ReadCoord();
 158         this.origin_z = ReadCoord();
 159         setorigin(this, this.origin);
 160         this.oldorigin = this.origin;
 161     }
 162
 163     if(sf & ISF_ANGLES)
 164     {
 165         this.angles_x = ReadAngle();
 166         this.angles_y = ReadAngle();
 167         this.angles_z = ReadAngle();
 168     }
 169
 170     if(sf & ISF_SIZE)
 171     {
 172         float use_bigsize = ReadByte();
 173         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 174     }
 175
 176     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
 177     {
 178         this.ItemStatus = ReadByte();
 179
 180         Item_SetAlpha(this);
 181
 182         if(autocvar_cl_fullbright_items)
 183             if(this.ItemStatus & ITS_ALLOWFB)
 184                 this.effects |= EF_FULLBRIGHT;
 185
 186         if(this.ItemStatus & ITS_GLOW)
 187         {
 188             if(this.ItemStatus & ITS_AVAILABLE)
 189                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 190             else
 191                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 192         }
 193     }
 194
 195     if(sf & ISF_MODEL)
 196     {
 197         this.drawmask  = MASK_NORMAL;
 198                 set_movetype(this, MOVETYPE_TOSS);
 199                 if (isnew) IL_PUSH(g_drawables, this);
 200         this.draw       = ItemDraw;
 201         this.solid = SOLID_TRIGGER;
 202         //this.flags |= FL_ITEM;
 203
 204         bool use_bigsize = ReadByte();
 205
 206         this.fade_end = ReadShort();
 207         this.fade_start = ReadShort();
 208         if(this.fade_start && !autocvar_cl_items_nofade)
 209                 setpredraw(this, Item_PreDraw);
 210
 211         if(this.mdl)
 212             strunzone(this.mdl);
 213
 214         this.mdl = "";
 215         string _fn = ReadString();
 216
 217         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 218         {
 219             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 220             this.draw = ItemDrawSimple;
 221
 222             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
 223                 this.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
 224             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
 225                 this.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
 226             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
 227                 this.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
 228             else if(fexists(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix)))
 229                 this.mdl = strzone(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix));
 230             else
 231             {
 232                 this.draw = ItemDraw;
 233                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
 234             }
 235         }
 236
 237         if(this.draw != ItemDrawSimple)
 238             this.mdl = strzone(_fn);
 239
 240
 241         if(this.mdl == "")
 242             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
 243
 244         precache_model(this.mdl);
 245         _setmodel(this, this.mdl);
 246
 247         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 248     }
 249
 250     if(sf & ISF_COLORMAP)
 251     {
 252         this.colormap = ReadShort();
 253         this.item_glowmod_x = ReadByte() / 255.0;
 254         this.item_glowmod_y = ReadByte() / 255.0;
 255         this.item_glowmod_z = ReadByte() / 255.0;
 256     }
 257
 258     if(sf & ISF_DROP)
 259     {
 260         this.gravity = 1;
 261         this.pushable = true;
 262         //this.angles = '0 0 0';
 263         set_movetype(this, MOVETYPE_TOSS);
 264         this.velocity_x = ReadCoord();
 265         this.velocity_y = ReadCoord();
 266         this.velocity_z = ReadCoord();
 267         setorigin(this, this.oldorigin);
 268
 269         if(!this.move_time)
 270         {
 271             this.move_time = time;
 272             this.spawntime = time;
 273         }
 274         else
 275             this.move_time = max(this.move_time, time);
 276     }
 277
 278     if(autocvar_cl_animate_items)
 279     {
 280         if(this.ItemStatus & ITS_ANIMATE1)
 281             this.avelocity = '0 180 0';
 282
 283         if(this.ItemStatus & ITS_ANIMATE2)
 284             this.avelocity = '0 -90 0';
 285     }
 286
 287     this.entremove = ItemRemove;
 288
 289     return true;
 290 }
 291
 292 #endif
 293
 294 #ifdef SVQC
 295 bool ItemSend(entity this, entity to, int sf)
 296 {
 297         if(this.gravity)
 298                 sf |= ISF_DROP;
 299         else
 300                 sf &= ~ISF_DROP;
 301
 302         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 303         WriteByte(MSG_ENTITY, sf);
 304
 305         //WriteByte(MSG_ENTITY, this.cnt);
 306         if(sf & ISF_LOCATION)
 307         {
 308                 WriteCoord(MSG_ENTITY, this.origin.x);
 309                 WriteCoord(MSG_ENTITY, this.origin.y);
 310                 WriteCoord(MSG_ENTITY, this.origin.z);
 311         }
 312
 313         if(sf & ISF_ANGLES)
 314         {
 315                 WriteAngle(MSG_ENTITY, this.angles_x);
 316                 WriteAngle(MSG_ENTITY, this.angles_y);
 317                 WriteAngle(MSG_ENTITY, this.angles_z);
 318         }
 319
 320         if(sf & ISF_SIZE)
 321         {
 322                 Pickup p = this.itemdef;
 323                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 324         }
 325
 326         if(sf & ISF_STATUS)
 327                 WriteByte(MSG_ENTITY, this.ItemStatus);
 328
 329         if(sf & ISF_MODEL)
 330         {
 331                 Pickup p = this.itemdef;
 332                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 333                 WriteShort(MSG_ENTITY, this.fade_end);
 334                 WriteShort(MSG_ENTITY, this.fade_start);
 335
 336                 if(this.mdl == "")
 337                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 338
 339                 WriteString(MSG_ENTITY, this.mdl);
 340         }
 341
 342
 343         if(sf & ISF_COLORMAP)
 344         {
 345                 WriteShort(MSG_ENTITY, this.colormap);
 346                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 347         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 348         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 349         }
 350
 351         if(sf & ISF_DROP)
 352         {
 353                 WriteCoord(MSG_ENTITY, this.velocity.x);
 354                 WriteCoord(MSG_ENTITY, this.velocity.y);
 355                 WriteCoord(MSG_ENTITY, this.velocity.z);
 356         }
 357
 358         return true;
 359 }
 360
 361 void ItemUpdate(entity this)
 362 {
 363         this.oldorigin = this.origin;
 364         this.SendFlags |= ISF_LOCATION;
 365 }
 366
 367 void UpdateItemAfterTeleport(entity this)
 368 {
 369         if(getSendEntity(this) == ItemSend)
 370                 ItemUpdate(this);
 371 }
 372
 373 bool have_pickup_item(entity this)
 374 {
 375         if(this.itemdef.instanceOfPowerup)
 376         {
 377                 if(autocvar_g_powerups > 0)
 378                         return true;
 379                 if(autocvar_g_powerups == 0)
 380                         return false;
 381         }
 382         else
 383         {
 384                 if(autocvar_g_pickup_items > 0)
 385                         return true;
 386                 if(autocvar_g_pickup_items == 0)
 387                         return false;
 388                 if(g_weaponarena)
 389                         if(this.weapons || (this.items & IT_AMMO)) // no item or ammo pickups in weaponarena
 390                                 return false;
 391         }
 392         return true;
 393 }
 394
 395 /*
 396 float Item_Customize()
 397 {
 398         if(this.spawnshieldtime)
 399                 return true;
 400         if(this.weapons & ~other.weapons)
 401         {
 402                 this.colormod = '0 0 0';
 403                 this.glowmod = this.colormod;
 404                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 405                 return true;
 406         }
 407         else
 408         {
 409                 if(g_ghost_items)
 410                 {
 411                         this.colormod = stov(autocvar_g_ghost_items_color);
 412                         this.glowmod = this.colormod;
 413                         this.alpha = g_ghost_items;
 414                         return true;
 415                 }
 416                 else
 417                         return false;
 418         }
 419 }
 420 */
 421
 422 void Item_Show (entity e, float mode)
 423 {
 424         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 425         e.ItemStatus &= ~ITS_STAYWEP;
 426         entity def = e.itemdef;
 427         if (mode > 0)
 428         {
 429                 // make the item look normal, and be touchable
 430                 e.model = e.mdl;
 431                 e.solid = SOLID_TRIGGER;
 432                 e.spawnshieldtime = 1;
 433                 e.ItemStatus |= ITS_AVAILABLE;
 434         }
 435         else if (mode < 0)
 436         {
 437                 // hide the item completely
 438                 e.model = string_null;
 439                 e.solid = SOLID_NOT;
 440                 e.spawnshieldtime = 1;
 441                 e.ItemStatus &= ~ITS_AVAILABLE;
 442         }
 443         else {
 444         bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 445                 || e.team // weapon stay isn't supported for teamed weapons
 446                 ;
 447         if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 448         {
 449                 // make the item translucent and not touchable
 450                 e.model = e.mdl;
 451                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 452                 e.effects |= EF_STARDUST;
 453                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 454                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 455         }
 456         else
 457         {
 458                 //setmodel(e, "null");
 459                 e.solid = SOLID_NOT;
 460                 e.colormod = '0 0 0';
 461                 //e.glowmod = e.colormod;
 462                 e.spawnshieldtime = 1;
 463                 e.ItemStatus &= ~ITS_AVAILABLE;
 464         }}
 465
 466         if (def.m_glow)
 467                 e.ItemStatus |= ITS_GLOW;
 468
 469         if (autocvar_g_nodepthtestitems)
 470                 e.effects |= EF_NODEPTHTEST;
 471
 472
 473         if (autocvar_g_fullbrightitems)
 474                 e.ItemStatus |= ITS_ALLOWFB;
 475
 476         if (autocvar_sv_simple_items)
 477                 e.ItemStatus |= ITS_ALLOWSI;
 478
 479         // relink entity (because solid may have changed)
 480         setorigin(e, e.origin);
 481         e.SendFlags |= ISF_STATUS;
 482 }
 483
 484 void Item_Think(entity this)
 485 {
 486         this.nextthink = time;
 487         if(this.origin != this.oldorigin)
 488                 ItemUpdate(this);
 489 }
 490
 491 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 492 bool Item_ItemsTime_Allow(GameItem it);
 493 float Item_ItemsTime_UpdateTime(entity e, float t);
 494 void Item_ItemsTime_SetTime(entity e, float t);
 495 void Item_ItemsTime_SetTimesForAllPlayers();
 496
 497 void Item_Respawn (entity this)
 498 {
 499         Item_Show(this, 1);
 500         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 501         setorigin(this, this.origin);
 502
 503     if (Item_ItemsTime_Allow(this.itemdef) || this.weapons & WEPSET_SUPERWEAPONS)
 504         {
 505                 float t = Item_ItemsTime_UpdateTime(this, 0);
 506                 Item_ItemsTime_SetTime(this, t);
 507                 Item_ItemsTime_SetTimesForAllPlayers();
 508         }
 509
 510         setthink(this, Item_Think);
 511         this.nextthink = time;
 512
 513         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 514         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 515 }
 516
 517 void Item_RespawnCountdown (entity this)
 518 {
 519         if(this.count >= ITEM_RESPAWN_TICKS)
 520         {
 521                 if(this.waypointsprite_attached)
 522                         WaypointSprite_Kill(this.waypointsprite_attached);
 523                 Item_Respawn(this);
 524         }
 525         else
 526         {
 527                 this.nextthink = time + 1;
 528                 this.count += 1;
 529                 if(this.count == 1)
 530                 {
 531                         MUTATOR_CALLHOOK(Item_RespawnCountdown, string_null, '0 0 0');
 532                         do {
 533                                 {
 534                                         entity wi = Weapons_from(this.weapon);
 535                                         if (wi != WEP_Null) {
 536                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 537                                                 wp.wp_extra = wi.m_id;
 538                                                 break;
 539                                         }
 540                                 }
 541                                 {
 542                                         entity ii = this.itemdef;
 543                                         if (ii != NULL) {
 544                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 545                                                 wp.wp_extra = ii.m_id;
 546                                                 break;
 547                                         }
 548                                 }
 549                         } while (0);
 550             if(this.waypointsprite_attached)
 551             {
 552                 GameItem def = this.itemdef;
 553                 if (Item_ItemsTime_SpectatorOnly(def))
 554                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 555                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 556             }
 557                 }
 558
 559                 if(this.waypointsprite_attached)
 560                 {
 561                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 562                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 563                                 {
 564                                         msg_entity = it;
 565                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 566                                 }
 567                         });
 568
 569                         WaypointSprite_Ping(this.waypointsprite_attached);
 570                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.count);
 571                 }
 572         }
 573 }
 574
 575 void Item_RespawnThink(entity this)
 576 {
 577         this.nextthink = time;
 578         if(this.origin != this.oldorigin)
 579                 ItemUpdate(this);
 580
 581         if(time >= this.wait)
 582                 Item_Respawn(this);
 583 }
 584
 585 void Item_ScheduleRespawnIn(entity e, float t)
 586 {
 587         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 588         if ((Item_ItemsTime_Allow(e.itemdef) || e.weapons & WEPSET_SUPERWEAPONS) && (t - ITEM_RESPAWN_TICKS) > 0)
 589         {
 590                 setthink(e, Item_RespawnCountdown);
 591                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 592                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 593                 e.count = 0;
 594                 t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 595                 Item_ItemsTime_SetTime(e, t);
 596                 Item_ItemsTime_SetTimesForAllPlayers();
 597         }
 598         else
 599         {
 600                 setthink(e, Item_RespawnThink);
 601                 e.nextthink = time;
 602                 e.scheduledrespawntime = time + t;
 603                 e.wait = time + t;
 604         }
 605 }
 606
 607 void Item_ScheduleRespawn(entity e)
 608 {
 609         if(e.respawntime > 0)
 610         {
 611                 Item_Show(e, 0);
 612                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 613         }
 614         else // if respawntime is -1, this item does not respawn
 615                 Item_Show(e, -1);
 616 }
 617
 618 void Item_ScheduleInitialRespawn(entity e)
 619 {
 620         Item_Show(e, 0);
 621         Item_ScheduleRespawnIn(e, game_starttime - time + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
 622 }
 623
 624 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 625 {
 626         if (!item.(ammotype))
 627                 return false;
 628
 629         if (item.spawnshieldtime)
 630         {
 631                 if ((player.(ammotype) < ammomax) || item.pickup_anyway > 0)
 632                 {
 633                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 634                         goto YEAH;
 635                 }
 636         }
 637         else if(g_weapon_stay == 2)
 638         {
 639                 float mi = min(item.(ammotype), ammomax);
 640                 if (player.(ammotype) < mi)
 641                 {
 642                         player.(ammotype) = mi;
 643                         goto YEAH;
 644                 }
 645         }
 646
 647         return false;
 648
 649 LABEL(YEAH)
 650         switch(mode)
 651         {
 652                 case ITEM_MODE_FUEL:
 653                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 654                         break;
 655                 case ITEM_MODE_HEALTH:
 656                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 657                         break;
 658                 case ITEM_MODE_ARMOR:
 659                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 660                         break;
 661                 default:
 662                         break;
 663         }
 664         return true;
 665 }
 666
 667 float Item_GiveTo(entity item, entity player)
 668 {
 669         float _switchweapon;
 670         float pickedup;
 671
 672         // if nothing happens to player, just return without taking the item
 673         pickedup = false;
 674         _switchweapon = false;
 675         // in case the player has autoswitch enabled do the following:
 676         // if the player is using their best weapon before items are given, they
 677         // probably want to switch to an even better weapon after items are given
 678         if (player.autoswitch)
 679         if (PS(player).m_switchweapon == w_getbestweapon(player))
 680                 _switchweapon = true;
 681
 682         if (!(player.weapons & WepSet_FromWeapon(PS(player).m_switchweapon)))
 683                 _switchweapon = true;
 684
 685         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 686         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 687         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 688         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 689         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 690         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 691         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 692         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 693
 694         if (item.itemdef.instanceOfWeaponPickup)
 695         {
 696                 WepSet w;
 697                 w = item.weapons;
 698                 w &= ~player.weapons;
 699
 700                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 701                 {
 702                         pickedup = true;
 703                         FOREACH(Weapons, it != WEP_Null, {
 704                                 if(w & (it.m_wepset))
 705                                 {
 706                                         W_DropEvent(wr_pickup, player, it.m_id, item);
 707                                         W_GiveWeapon(player, it.m_id);
 708                                 }
 709                         });
 710                 }
 711         }
 712
 713         if (item.itemdef.instanceOfPowerup)
 714         {
 715                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 716                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 717                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 718                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 719         }
 720
 721         int its;
 722         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 723         {
 724                 pickedup = true;
 725                 player.items |= its;
 726                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 727         }
 728
 729         if (item.strength_finished)
 730         {
 731                 pickedup = true;
 732                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 733         }
 734         if (item.invincible_finished)
 735         {
 736                 pickedup = true;
 737                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 738         }
 739         if (item.superweapons_finished)
 740         {
 741                 pickedup = true;
 742                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 743         }
 744
 745 LABEL(skip)
 746
 747         // always eat teamed entities
 748         if(item.team)
 749                 pickedup = true;
 750
 751         if (!pickedup)
 752                 return 0;
 753
 754         // crude hack to enforce switching weapons
 755         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 756         {
 757                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon));
 758                 return 1;
 759         }
 760
 761         if (_switchweapon)
 762                 if (PS(player).m_switchweapon != w_getbestweapon(player))
 763                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 764
 765         return 1;
 766 }
 767
 768 void Item_Touch(entity this, entity toucher)
 769 {
 770
 771         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 772         if (this.classname == "droppedweapon")
 773         {
 774                 if (ITEM_TOUCH_NEEDKILL())
 775                 {
 776                         delete(this);
 777                         return;
 778                 }
 779         }
 780
 781         if(!(toucher.flags & FL_PICKUPITEMS)
 782         || STAT(FROZEN, toucher)
 783         || IS_DEAD(toucher)
 784         || (this.solid != SOLID_TRIGGER)
 785         || (this.owner == toucher)
 786         || (time < this.item_spawnshieldtime)
 787         ) { return; }
 788
 789         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 790         {
 791                 case MUT_ITEMTOUCH_RETURN: { return; }
 792                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 793         }
 794
 795         toucher = M_ARGV(1, entity);
 796
 797         if (this.classname == "droppedweapon")
 798         {
 799                 this.strength_finished = max(0, this.strength_finished - time);
 800                 this.invincible_finished = max(0, this.invincible_finished - time);
 801                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 802         }
 803         entity it = this.itemdef;
 804         bool gave = ITEM_HANDLE(Pickup, it, this, toucher);
 805         if (!gave)
 806         {
 807                 if (this.classname == "droppedweapon")
 808                 {
 809                         // undo what we did above
 810                         this.strength_finished += time;
 811                         this.invincible_finished += time;
 812                         this.superweapons_finished += time;
 813                 }
 814                 return;
 815         }
 816
 817 LABEL(pickup)
 818
 819         toucher.last_pickup = time;
 820
 821         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 822         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 823
 824         if (this.classname == "droppedweapon")
 825                 delete (this);
 826         else if (this.spawnshieldtime)
 827         {
 828                 entity e;
 829                 if(this.team)
 830                 {
 831                         RandomSelection_Init();
 832                         IL_EACH(g_items, it.team == this.team,
 833                         {
 834                                 if(it.classname != "item_flag_team" && it.classname != "item_kh_key")
 835                                 {
 836                                         Item_Show(it, -1);
 837                                         RandomSelection_AddEnt(it, it.cnt, 0);
 838                                 }
 839                         });
 840                         e = RandomSelection_chosen_ent;
 841
 842                 }
 843                 else
 844                         e = this;
 845                 Item_ScheduleRespawn(e);
 846         }
 847 }
 848
 849 void Item_Reset(entity this)
 850 {
 851         Item_Show(this, !this.state);
 852         setorigin(this, this.origin);
 853
 854         if (this.classname != "droppedweapon")
 855         {
 856                 setthink(this, Item_Think);
 857                 this.nextthink = time;
 858
 859                 if (this.waypointsprite_attached)
 860                         WaypointSprite_Kill(this.waypointsprite_attached);
 861
 862                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 863                         Item_ScheduleInitialRespawn(this);
 864         }
 865 }
 866
 867 void Item_FindTeam(entity this)
 868 {
 869         entity e;
 870
 871         if(this.effects & EF_NODRAW)
 872         {
 873                 // marker for item team search
 874                 LOG_TRACE("Initializing item team ", ftos(this.team));
 875                 RandomSelection_Init();
 876                 IL_EACH(g_items, it.team == this.team,
 877                 {
 878                         if(it.classname != "item_flag_team" && it.classname != "item_kh_key")
 879                                 RandomSelection_AddEnt(it, it.cnt, 0);
 880                 });
 881
 882                 e = RandomSelection_chosen_ent;
 883                 e.state = 0;
 884                 Item_Show(e, 1);
 885
 886                 IL_EACH(g_items, it.team == this.team,
 887                 {
 888                         if(it.classname != "item_flag_team" && it.classname != "item_kh_key")
 889                         {
 890                                 if(it != e)
 891                                 {
 892                                         // make it non-spawned
 893                                         Item_Show(it, -1);
 894                                         it.state = 1; // state 1 = initially hidden item, apparently
 895                                 }
 896                                 it.effects &= ~EF_NODRAW;
 897                         }
 898                 });
 899
 900                 Item_Reset(this);
 901         }
 902 }
 903
 904 // Savage: used for item garbage-collection
 905 void RemoveItem(entity this)
 906 {
 907         if(wasfreed(this) || !this) { return; }
 908         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 909         delete(this);
 910 }
 911
 912 // pickup evaluation functions
 913 // these functions decide how desirable an item is to the bots
 914
 915 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 916
 917 float weapon_pickupevalfunc(entity player, entity item)
 918 {
 919         float c;
 920
 921         // See if I have it already
 922         if(item.weapons & ~player.weapons)
 923         {
 924                 // If I can pick it up
 925                 if(!item.spawnshieldtime)
 926                         c = 0;
 927                 else if(player.ammo_cells || player.ammo_shells || player.ammo_plasma || player.ammo_nails || player.ammo_rockets)
 928                 {
 929                         // Skilled bots will grab more
 930                         c = bound(0, skill / 10, 1) * 0.5;
 931                 }
 932                 else
 933                         c = 0;
 934         }
 935         else
 936                 c = 1;
 937
 938         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 939         if( bot_custom_weapon && c )
 940         {
 941                 // Find the highest position on any range
 942                 int position = -1;
 943                 for (int j = 0; j < WEP_LAST ; ++j){
 944                         if(
 945                                         bot_weapons_far[j] == item.weapon ||
 946                                         bot_weapons_mid[j] == item.weapon ||
 947                                         bot_weapons_close[j] == item.weapon
 948                           )
 949                         {
 950                                 position = j;
 951                                 break;
 952                         }
 953                 }
 954
 955                 // Rate it
 956                 if (position >= 0 )
 957                 {
 958                         position = WEP_LAST - position;
 959                         // item.bot_pickupbasevalue is overwritten here
 960                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 961                 }
 962         }
 963
 964         return item.bot_pickupbasevalue * c;
 965 }
 966
 967 float commodity_pickupevalfunc(entity player, entity item)
 968 {
 969         float c;
 970         float need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
 971         c = 0;
 972
 973         // Detect needed ammo
 974         FOREACH(Weapons, it != WEP_Null, {
 975                 if(!(player.weapons & (it.m_wepset)))
 976                         continue;
 977
 978                 if(it.items & ITEM_Shells.m_itemid)
 979                         need_shells = true;
 980                 else if(it.items & ITEM_Bullets.m_itemid)
 981                         need_nails = true;
 982                 else if(it.items & ITEM_Rockets.m_itemid)
 983                         need_rockets = true;
 984                 else if(it.items & ITEM_Cells.m_itemid)
 985                         need_cells = true;
 986                 else if(it.items & ITEM_Plasma.m_itemid)
 987                         need_plasma = true;
 988                 else if(it.items & ITEM_JetpackFuel.m_itemid)
 989                         need_fuel = true;
 990         });
 991
 992         // TODO: figure out if the player even has the weapon this ammo is for?
 993         // may not affect strategy much though...
 994         // find out how much more ammo/armor/health the player can hold
 995         if (need_shells)
 996         if (item.ammo_shells)
 997         if (player.ammo_shells < g_pickup_shells_max)
 998                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 999         if (need_nails)
1000         if (item.ammo_nails)
1001         if (player.ammo_nails < g_pickup_nails_max)
1002                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
1003         if (need_rockets)
1004         if (item.ammo_rockets)
1005         if (player.ammo_rockets < g_pickup_rockets_max)
1006                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
1007         if (need_cells)
1008         if (item.ammo_cells)
1009         if (player.ammo_cells < g_pickup_cells_max)
1010                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
1011         if (need_plasma)
1012         if (item.ammo_plasma)
1013         if (player.ammo_plasma < g_pickup_plasma_max)
1014                 c = c + max(0, 1 - player.ammo_plasma / g_pickup_plasma_max);
1015         if (need_fuel)
1016         if (item.ammo_fuel)
1017         if (player.ammo_fuel < g_pickup_fuel_max)
1018                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
1019         if (item.armorvalue)
1020         if (player.armorvalue < item.max_armorvalue)
1021                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
1022         if (item.health)
1023         if (player.health < item.max_health)
1024                 c = c + max(0, 1 - player.health / item.max_health);
1025
1026         return item.bot_pickupbasevalue * c;
1027 }
1028
1029 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1030 {
1031         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1032                 RemoveItem(this);
1033 }
1034
1035 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1036 {
1037         string itemname = def.m_name;
1038         Model itemmodel = def.m_model;
1039     Sound pickupsound = def.m_sound;
1040         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1041         float pickupbasevalue = def.m_botvalue;
1042         int itemflags = def.m_itemflags;
1043
1044         startitem_failed = false;
1045
1046         this.item_model_ent = itemmodel;
1047     this.item_pickupsound_ent = pickupsound;
1048
1049         if(!this.respawntime) // both need to be set
1050         {
1051                 this.respawntime = defaultrespawntime;
1052                 this.respawntimejitter = defaultrespawntimejitter;
1053         }
1054
1055         int itemid = def.m_itemid;
1056         this.items = itemid;
1057         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1058         this.weapon = weaponid;
1059
1060         if(!this.fade_end)
1061         {
1062                 this.fade_start = autocvar_g_items_mindist;
1063                 this.fade_end = autocvar_g_items_maxdist;
1064         }
1065
1066         if(weaponid)
1067                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1068
1069         this.flags = FL_ITEM | itemflags;
1070         IL_PUSH(g_items, this);
1071
1072         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1073         {
1074                 startitem_failed = true;
1075                 delete(this);
1076                 return;
1077         }
1078
1079         // is it a dropped weapon?
1080         if (this.classname == "droppedweapon")
1081         {
1082                 this.reset = SUB_Remove;
1083                 // it's a dropped weapon
1084                 set_movetype(this, MOVETYPE_TOSS);
1085
1086                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1087                 setthink(this, RemoveItem);
1088                 this.nextthink = time + 20;
1089
1090                 this.takedamage = DAMAGE_YES;
1091                 this.event_damage = Item_Damage;
1092
1093                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1094                 {
1095                         // if item is worthless after a timer, have it expire then
1096                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1097                 }
1098
1099                 // don't drop if in a NODROP zone (such as lava)
1100                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1101                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1102                 {
1103                         startitem_failed = true;
1104                         delete(this);
1105                         return;
1106                 }
1107         }
1108         else
1109         {
1110                 if(!have_pickup_item(this))
1111                 {
1112                         startitem_failed = true;
1113                         delete (this);
1114                         return;
1115                 }
1116
1117                 if(this.angles != '0 0 0')
1118                         this.SendFlags |= ISF_ANGLES;
1119
1120                 this.reset = Item_Reset;
1121                 // it's a level item
1122                 if(this.spawnflags & 1)
1123                         this.noalign = 1;
1124                 if (this.noalign > 0)
1125                         set_movetype(this, MOVETYPE_NONE);
1126                 else
1127                         set_movetype(this, MOVETYPE_TOSS);
1128                 // do item filtering according to game mode and other things
1129                 if (this.noalign <= 0)
1130                 {
1131                         // first nudge it off the floor a little bit to avoid math errors
1132                         setorigin(this, this.origin + '0 0 1');
1133                         // set item size before we spawn a spawnfunc_waypoint
1134                         setsize(this, def.m_mins, def.m_maxs);
1135                         this.SendFlags |= ISF_SIZE;
1136                         // note droptofloor returns false if stuck/or would fall too far
1137                         if (!this.noalign)
1138                                 droptofloor(this);
1139                         waypoint_spawnforitem(this);
1140                 }
1141
1142                 /*
1143                  * can't do it that way, as it would break maps
1144                  * TODO make a target_give like entity another way, that perhaps has
1145                  * the weapon name in a key
1146                 if(this.targetname)
1147                 {
1148                         // target_give not yet supported; maybe later
1149                         print("removed targeted ", this.classname, "\n");
1150                         startitem_failed = true;
1151                         remove (this);
1152                         return;
1153                 }
1154                 */
1155
1156                 if(autocvar_spawn_debug >= 2)
1157                 {
1158             // why not flags & fl_item?
1159                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1160                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1161                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1162                 error("Mapper sucks.");
1163             });
1164                         this.is_item = true;
1165                 }
1166
1167                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1168
1169                 precache_model(this.model);
1170                 precache_sound(this.item_pickupsound);
1171
1172                 if (   def.instanceOfPowerup
1173                         || def.instanceOfWeaponPickup
1174                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1175                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1176                         || (itemid & (IT_KEY1 | IT_KEY2))
1177                 ) this.target = "###item###"; // for finding the nearest item using find()
1178
1179                 Item_ItemsTime_SetTime(this, 0);
1180         }
1181
1182         this.bot_pickup = true;
1183         this.bot_pickupevalfunc = pickupevalfunc;
1184         this.bot_pickupbasevalue = pickupbasevalue;
1185         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1186         this.netname = itemname;
1187         settouch(this, Item_Touch);
1188         setmodel(this, MDL_Null); // precision set below
1189         //this.effects |= EF_LOWPRECISION;
1190
1191         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1192
1193         this.SendFlags |= ISF_SIZE;
1194
1195         if (!(this.spawnflags & 1024)) {
1196                 if(def.instanceOfPowerup)
1197                         this.ItemStatus |= ITS_ANIMATE1;
1198
1199                 if(this.armorvalue || this.health)
1200                         this.ItemStatus |= ITS_ANIMATE2;
1201         }
1202
1203         if(def.instanceOfWeaponPickup)
1204         {
1205                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1206                         this.colormap = 1024; // color shirt=0 pants=0 grey
1207                 else
1208                         this.gravity = 1;
1209                 if (!(this.spawnflags & 1024))
1210                         this.ItemStatus |= ITS_ANIMATE1;
1211                 this.SendFlags |= ISF_COLORMAP;
1212         }
1213
1214         this.state = 0;
1215         if(this.team) // broken, no idea why.
1216         {
1217                 if(!this.cnt)
1218                         this.cnt = 1; // item probability weight
1219
1220                 this.effects |= EF_NODRAW; // marker for item team search
1221                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1222         }
1223         else
1224                 Item_Reset(this);
1225
1226         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1227
1228         // call this hook after everything else has been done
1229         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1230         {
1231                 startitem_failed = true;
1232                 delete(this);
1233                 return;
1234         }
1235 }
1236
1237 void StartItem(entity this, GameItem def)
1238 {
1239     _StartItem(
1240         this,
1241         this.itemdef = def,
1242         def.m_respawntime(), // defaultrespawntime
1243         def.m_respawntimejitter() // defaultrespawntimejitter
1244         );
1245 }
1246
1247 spawnfunc(item_rockets)
1248 {
1249         if(!this.ammo_rockets)
1250                 this.ammo_rockets = g_pickup_rockets;
1251         if(!this.pickup_anyway)
1252                 this.pickup_anyway = g_pickup_ammo_anyway;
1253     StartItem(this, ITEM_Rockets);
1254 }
1255
1256 spawnfunc(item_bullets)
1257 {
1258         if(!weaponswapping)
1259         if(autocvar_sv_q3acompat_machineshotgunswap)
1260         if(this.classname != "droppedweapon")
1261         {
1262                 weaponswapping = true;
1263                 spawnfunc_item_shells(this);
1264                 weaponswapping = false;
1265                 return;
1266         }
1267
1268         if(!this.ammo_nails)
1269                 this.ammo_nails = g_pickup_nails;
1270         if(!this.pickup_anyway)
1271                 this.pickup_anyway = g_pickup_ammo_anyway;
1272     StartItem(this, ITEM_Bullets);
1273 }
1274
1275 spawnfunc(item_cells)
1276 {
1277         if(!this.ammo_cells)
1278                 this.ammo_cells = g_pickup_cells;
1279         if(!this.pickup_anyway)
1280                 this.pickup_anyway = g_pickup_ammo_anyway;
1281         StartItem(this, ITEM_Cells);
1282 }
1283
1284 spawnfunc(item_plasma)
1285 {
1286         if(!this.ammo_plasma)
1287                 this.ammo_plasma = g_pickup_plasma;
1288         if(!this.pickup_anyway)
1289                 this.pickup_anyway = g_pickup_ammo_anyway;
1290         StartItem(this, ITEM_Plasma);
1291 }
1292
1293 spawnfunc(item_shells)
1294 {
1295         if(!weaponswapping)
1296         if(autocvar_sv_q3acompat_machineshotgunswap)
1297         if(this.classname != "droppedweapon")
1298         {
1299                 weaponswapping = true;
1300                 spawnfunc_item_bullets(this);
1301                 weaponswapping = false;
1302                 return;
1303         }
1304
1305         if(!this.ammo_shells)
1306                 this.ammo_shells = g_pickup_shells;
1307         if(!this.pickup_anyway)
1308                 this.pickup_anyway = g_pickup_ammo_anyway;
1309         StartItem(this, ITEM_Shells);
1310 }
1311
1312 spawnfunc(item_armor_small)
1313 {
1314         if(!this.armorvalue)
1315                 this.armorvalue = g_pickup_armorsmall;
1316         if(!this.max_armorvalue)
1317                 this.max_armorvalue = g_pickup_armorsmall_max;
1318         if(!this.pickup_anyway)
1319                 this.pickup_anyway = g_pickup_armorsmall_anyway;
1320         StartItem(this, ITEM_ArmorSmall);
1321 }
1322
1323 spawnfunc(item_armor_medium)
1324 {
1325         if(!this.armorvalue)
1326                 this.armorvalue = g_pickup_armormedium;
1327         if(!this.max_armorvalue)
1328                 this.max_armorvalue = g_pickup_armormedium_max;
1329         if(!this.pickup_anyway)
1330                 this.pickup_anyway = g_pickup_armormedium_anyway;
1331         StartItem(this, ITEM_ArmorMedium);
1332 }
1333
1334 spawnfunc(item_armor_big)
1335 {
1336         if(!this.armorvalue)
1337                 this.armorvalue = g_pickup_armorbig;
1338         if(!this.max_armorvalue)
1339                 this.max_armorvalue = g_pickup_armorbig_max;
1340         if(!this.pickup_anyway)
1341                 this.pickup_anyway = g_pickup_armorbig_anyway;
1342         StartItem(this, ITEM_ArmorLarge);
1343 }
1344
1345 spawnfunc(item_armor_large)
1346 {
1347         if(!this.armorvalue)
1348                 this.armorvalue = g_pickup_armorlarge;
1349         if(!this.max_armorvalue)
1350                 this.max_armorvalue = g_pickup_armorlarge_max;
1351         if(!this.pickup_anyway)
1352                 this.pickup_anyway = g_pickup_armorlarge_anyway;
1353         StartItem(this, ITEM_ArmorMega);
1354 }
1355
1356 spawnfunc(item_health_small)
1357 {
1358         if(!this.max_health)
1359                 this.max_health = g_pickup_healthsmall_max;
1360         if(!this.health)
1361                 this.health = g_pickup_healthsmall;
1362         if(!this.pickup_anyway)
1363                 this.pickup_anyway = g_pickup_healthsmall_anyway;
1364         StartItem(this, ITEM_HealthSmall);
1365 }
1366
1367 spawnfunc(item_health_medium)
1368 {
1369         if(!this.max_health)
1370                 this.max_health = g_pickup_healthmedium_max;
1371         if(!this.health)
1372                 this.health = g_pickup_healthmedium;
1373         if(!this.pickup_anyway)
1374                 this.pickup_anyway = g_pickup_healthmedium_anyway;
1375     StartItem(this, ITEM_HealthMedium);
1376 }
1377
1378 spawnfunc(item_health_large)
1379 {
1380         if(!this.max_health)
1381                 this.max_health = g_pickup_healthlarge_max;
1382         if(!this.health)
1383                 this.health = g_pickup_healthlarge;
1384         if(!this.pickup_anyway)
1385                 this.pickup_anyway = g_pickup_healthlarge_anyway;
1386         StartItem(this, ITEM_HealthLarge);
1387 }
1388
1389 spawnfunc(item_health_mega)
1390 {
1391     if(!this.max_health)
1392         this.max_health = g_pickup_healthmega_max;
1393     if(!this.health)
1394         this.health = g_pickup_healthmega;
1395     if(!this.pickup_anyway)
1396         this.pickup_anyway = g_pickup_healthmega_anyway;
1397     StartItem(this, ITEM_HealthMega);
1398 }
1399
1400 // support old misnamed entities
1401 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1402 spawnfunc(item_armor25) { spawnfunc_item_armor_large(this); }
1403 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1404 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1405 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1406
1407 spawnfunc(item_strength)
1408 {
1409                 if(!this.strength_finished)
1410                         this.strength_finished = autocvar_g_balance_powerup_strength_time;
1411                 StartItem(this, ITEM_Strength);
1412 }
1413
1414 spawnfunc(item_invincible)
1415 {
1416                 if(!this.invincible_finished)
1417                         this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1418                 StartItem(this, ITEM_Shield);
1419 }
1420
1421 // compatibility:
1422 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1423
1424 void target_items_use(entity this, entity actor, entity trigger)
1425 {
1426         if(actor.classname == "droppedweapon")
1427         {
1428                 EXACTTRIGGER_TOUCH(this, trigger);
1429                 delete(actor);
1430                 return;
1431         }
1432
1433         if (!IS_PLAYER(actor))
1434                 return;
1435         if(IS_DEAD(actor))
1436                 return;
1437         if(trigger.solid == SOLID_TRIGGER)
1438         {
1439                 EXACTTRIGGER_TOUCH(this, trigger);
1440         }
1441
1442         IL_EACH(g_items, it.enemy == actor && it.classname == "droppedweapon",
1443         {
1444                 delete(it);
1445         });
1446
1447         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1448                 centerprint(actor, this.message);
1449 }
1450
1451 spawnfunc(target_items)
1452 {
1453         int n, j;
1454         string s;
1455
1456         this.use = target_items_use;
1457         if(!this.strength_finished)
1458                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1459         if(!this.invincible_finished)
1460                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1461         if(!this.superweapons_finished)
1462                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1463
1464         n = tokenize_console(this.netname);
1465         if(argv(0) == "give")
1466         {
1467                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1468         }
1469         else
1470         {
1471                 for(j = 0; j < n; ++j)
1472                 {
1473                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1474                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1475                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1476                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1477                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1478                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1479                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1480                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1481                         else
1482                         {
1483                                 FOREACH(Weapons, it != WEP_Null, {
1484                                         s = W_UndeprecateName(argv(j));
1485                                         if(s == it.netname)
1486                                         {
1487                                                 this.weapons |= (it.m_wepset);
1488                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1489                                                         it.wr_init(it);
1490                                                 break;
1491                                         }
1492                                 });
1493                         }
1494                 }
1495
1496                 string itemprefix, valueprefix;
1497                 if(this.spawnflags == 0)
1498                 {
1499                         itemprefix = "";
1500                         valueprefix = "";
1501                 }
1502                 else if(this.spawnflags == 1)
1503                 {
1504                         itemprefix = "max ";
1505                         valueprefix = "max ";
1506                 }
1507                 else if(this.spawnflags == 2)
1508                 {
1509                         itemprefix = "min ";
1510                         valueprefix = "min ";
1511                 }
1512                 else if(this.spawnflags == 4)
1513                 {
1514                         itemprefix = "minus ";
1515                         valueprefix = "max ";
1516                 }
1517                 else
1518                 {
1519                         error("invalid spawnflags");
1520                         itemprefix = valueprefix = string_null;
1521                 }
1522
1523                 this.netname = "";
1524                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1525                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1526                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1527                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1528                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1529                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1530                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1531                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1532                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1533                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1534                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1535                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1536                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1537                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1538                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1539                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1540         }
1541         this.netname = strzone(this.netname);
1542         //print(this.netname, "\n");
1543
1544         n = tokenize_console(this.netname);
1545         for(j = 0; j < n; ++j)
1546         {
1547                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1548             it.wr_init(it);
1549             break;
1550                 });
1551         }
1552 }
1553
1554 spawnfunc(item_fuel)
1555 {
1556         if(!this.ammo_fuel)
1557                 this.ammo_fuel = g_pickup_fuel;
1558         if(!this.pickup_anyway)
1559                 this.pickup_anyway = g_pickup_ammo_anyway;
1560         StartItem(this, ITEM_JetpackFuel);
1561 }
1562
1563 spawnfunc(item_fuel_regen)
1564 {
1565         if(start_items & ITEM_JetpackRegen.m_itemid)
1566         {
1567                 spawnfunc_item_fuel(this);
1568                 return;
1569         }
1570         StartItem(this, ITEM_JetpackRegen);
1571 }
1572
1573 spawnfunc(item_jetpack)
1574 {
1575         if(!this.ammo_fuel)
1576                 this.ammo_fuel = g_pickup_fuel_jetpack;
1577         if(start_items & ITEM_Jetpack.m_itemid)
1578         {
1579                 spawnfunc_item_fuel(this);
1580                 return;
1581         }
1582         StartItem(this, ITEM_Jetpack);
1583 }
1584
1585 float GiveWeapon(entity e, float wpn, float op, float val)
1586 {
1587         WepSet v0, v1;
1588         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1589         v0 = (e.weapons & s);
1590         switch(op)
1591         {
1592                 case OP_SET:
1593                         if(val > 0)
1594                                 e.weapons |= s;
1595                         else
1596                                 e.weapons &= ~s;
1597                         break;
1598                 case OP_MIN:
1599                 case OP_PLUS:
1600                         if(val > 0)
1601                                 e.weapons |= s;
1602                         break;
1603                 case OP_MAX:
1604                         if(val <= 0)
1605                                 e.weapons &= ~s;
1606                         break;
1607                 case OP_MINUS:
1608                         if(val > 0)
1609                                 e.weapons &= ~s;
1610                         break;
1611         }
1612         v1 = (e.weapons & s);
1613         return (v0 != v1);
1614 }
1615
1616 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1617 {
1618         if(v1 == v0)
1619                 return;
1620         if(v1 <= v0 - t)
1621         {
1622                 if(snd_decr != NULL)
1623                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1624         }
1625         else if(v0 >= v0 + t)
1626         {
1627                 if(snd_incr != NULL)
1628                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1629         }
1630 }
1631
1632 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1633 {
1634         if(v0 < v1)
1635                 e.(rotfield) = max(e.(rotfield), time + rottime);
1636         else if(v0 > v1)
1637                 e.(regenfield) = max(e.(regenfield), time + regentime);
1638 }
1639 float GiveItems(entity e, float beginarg, float endarg)
1640 {
1641         float got, i, val, op;
1642         float _switchweapon;
1643         string cmd;
1644
1645         val = 999;
1646         op = OP_SET;
1647
1648         got = 0;
1649
1650         _switchweapon = false;
1651         if (e.autoswitch)
1652                 if (PS(e).m_switchweapon == w_getbestweapon(e))
1653                         _switchweapon = true;
1654
1655         e.strength_finished = max(0, e.strength_finished - time);
1656         e.invincible_finished = max(0, e.invincible_finished - time);
1657         e.superweapons_finished = max(0, e.superweapons_finished - time);
1658
1659         PREGIVE(e, items);
1660         PREGIVE_WEAPONS(e);
1661         PREGIVE(e, strength_finished);
1662         PREGIVE(e, invincible_finished);
1663         PREGIVE(e, superweapons_finished);
1664         PREGIVE(e, ammo_nails);
1665         PREGIVE(e, ammo_cells);
1666         PREGIVE(e, ammo_plasma);
1667         PREGIVE(e, ammo_shells);
1668         PREGIVE(e, ammo_rockets);
1669         PREGIVE(e, ammo_fuel);
1670         PREGIVE(e, armorvalue);
1671         PREGIVE(e, health);
1672
1673         for(i = beginarg; i < endarg; ++i)
1674         {
1675                 cmd = argv(i);
1676
1677                 if(cmd == "0" || stof(cmd))
1678                 {
1679                         val = stof(cmd);
1680                         continue;
1681                 }
1682                 switch(cmd)
1683                 {
1684                         case "no":
1685                                 op = OP_MAX;
1686                                 val = 0;
1687                                 continue;
1688                         case "max":
1689                                 op = OP_MAX;
1690                                 continue;
1691                         case "min":
1692                                 op = OP_MIN;
1693                                 continue;
1694                         case "plus":
1695                                 op = OP_PLUS;
1696                                 continue;
1697                         case "minus":
1698                                 op = OP_MINUS;
1699                                 continue;
1700                         case "ALL":
1701                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1702                                 got += GiveValue(e, strength_finished, op, val);
1703                                 got += GiveValue(e, invincible_finished, op, val);
1704                                 got += GiveValue(e, superweapons_finished, op, val);
1705                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1706                         case "all":
1707                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1708                                 got += GiveValue(e, health, op, val);
1709                                 got += GiveValue(e, armorvalue, op, val);
1710                         case "allweapons":
1711                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1712                         case "allammo":
1713                                 got += GiveValue(e, ammo_cells, op, val);
1714                                 got += GiveValue(e, ammo_plasma, op, val);
1715                                 got += GiveValue(e, ammo_shells, op, val);
1716                                 got += GiveValue(e, ammo_nails, op, val);
1717                                 got += GiveValue(e, ammo_rockets, op, val);
1718                                 got += GiveValue(e, ammo_fuel, op, val);
1719                                 break;
1720                         case "unlimited_ammo":
1721                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1722                                 break;
1723                         case "unlimited_weapon_ammo":
1724                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1725                                 break;
1726                         case "unlimited_superweapons":
1727                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1728                                 break;
1729                         case "jetpack":
1730                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1731                                 break;
1732                         case "fuel_regen":
1733                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1734                                 break;
1735                         case "strength":
1736                                 got += GiveValue(e, strength_finished, op, val);
1737                                 break;
1738                         case "invincible":
1739                                 got += GiveValue(e, invincible_finished, op, val);
1740                                 break;
1741                         case "superweapons":
1742                                 got += GiveValue(e, superweapons_finished, op, val);
1743                                 break;
1744                         case "cells":
1745                                 got += GiveValue(e, ammo_cells, op, val);
1746                                 break;
1747                         case "plasma":
1748                                 got += GiveValue(e, ammo_plasma, op, val);
1749                                 break;
1750                         case "shells":
1751                                 got += GiveValue(e, ammo_shells, op, val);
1752                                 break;
1753                         case "nails":
1754                         case "bullets":
1755                                 got += GiveValue(e, ammo_nails, op, val);
1756                                 break;
1757                         case "rockets":
1758                                 got += GiveValue(e, ammo_rockets, op, val);
1759                                 break;
1760                         case "health":
1761                                 got += GiveValue(e, health, op, val);
1762                                 break;
1763                         case "armor":
1764                                 got += GiveValue(e, armorvalue, op, val);
1765                                 break;
1766                         case "fuel":
1767                                 got += GiveValue(e, ammo_fuel, op, val);
1768                                 break;
1769                         default:
1770                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1771                     got += GiveWeapon(e, it.m_id, op, val);
1772                     break;
1773                                 });
1774                                 break;
1775                 }
1776                 val = 999;
1777                 op = OP_SET;
1778         }
1779
1780         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1781         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1782         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1783         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1784         FOREACH(Weapons, it != WEP_Null, {
1785                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1786                 if(!(save_weapons & (it.m_wepset)))
1787                         if(e.weapons & (it.m_wepset))
1788                                 it.wr_init(it);
1789         });
1790         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1791         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1792         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1793         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1794         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1795         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1796         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1797         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1798         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1799         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1800
1801         if(e.superweapons_finished <= 0)
1802                 if(e.weapons & WEPSET_SUPERWEAPONS)
1803                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1804
1805         if(e.strength_finished <= 0)
1806                 e.strength_finished = 0;
1807         else
1808                 e.strength_finished += time;
1809         if(e.invincible_finished <= 0)
1810                 e.invincible_finished = 0;
1811         else
1812                 e.invincible_finished += time;
1813         if(e.superweapons_finished <= 0)
1814                 e.superweapons_finished = 0;
1815         else
1816                 e.superweapons_finished += time;
1817
1818         if (!(e.weapons & WepSet_FromWeapon(PS(e).m_switchweapon)))
1819                 _switchweapon = true;
1820         if(_switchweapon)
1821                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1822
1823         return got;
1824 }
1825 #endif