qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "triggers/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include <common/mutators/mutator/buffs/buffs.qh>
  26
  27     #include "../lib/warpzone/util_server.qh"
  28 #elif defined(CSQC)
  29         #include "physics/movetypes/movetypes.qh"
  30         #include <common/weapons/_all.qh>
  31         #include "../lib/csqcmodel/cl_model.qh"
  32         #include "../lib/csqcmodel/common.qh"
  33 #endif
  34
  35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  36
  37 #ifdef CSQC
  38 bool autocvar_cl_ghost_items_vehicle = true;
  39 .vector item_glowmod;
  40 void Item_SetAlpha(entity this)
  41 {
  42         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  43
  44         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  45         {
  46                 this.alpha = 1;
  47                 this.colormod = '1 1 1';
  48                 this.glowmod = this.item_glowmod;
  49         }
  50         else
  51         {
  52                 if (autocvar_cl_ghost_items_color)
  53                 {
  54                         this.alpha = autocvar_cl_ghost_items;
  55                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  56                 }
  57                 else
  58                         this.alpha = -1;
  59         }
  60
  61         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
  62         {
  63                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  64                 this.alpha = autocvar_cl_weapon_stay_alpha;
  65         }
  66
  67         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
  68 }
  69
  70 void ItemDraw(entity this)
  71 {
  72     if(this.gravity)
  73     {
  74         Movetype_Physics_MatchServer(this, false);
  75         if(IS_ONGROUND(this))
  76         { // For some reason avelocity gets set to '0 0 0' here ...
  77             this.oldorigin = this.origin;
  78             this.gravity = 0;
  79
  80             if(autocvar_cl_animate_items)
  81             { // ... so reset it if animations are requested.
  82                 if(this.ItemStatus & ITS_ANIMATE1)
  83                     this.avelocity = '0 180 0';
  84
  85                 if(this.ItemStatus & ITS_ANIMATE2)
  86                     this.avelocity = '0 -90 0';
  87             }
  88
  89             // delay is for blocking item's position for a while;
  90             // it's a workaround for dropped weapons that receive the position
  91             // another time right after they spawn overriding animation position
  92             this.onground_time = time + 0.5;
  93         }
  94     }
  95     else if (autocvar_cl_animate_items)
  96     {
  97         if(this.ItemStatus & ITS_ANIMATE1)
  98         {
  99             this.angles += this.avelocity * frametime;
 100             float fade_in = bound(0, time - this.onground_time, 1);
 101             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
 102         }
 103
 104         if(this.ItemStatus & ITS_ANIMATE2)
 105         {
 106             this.angles += this.avelocity * frametime;
 107             float fade_in = bound(0, time - this.onground_time, 1);
 108             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 109         }
 110     }
 111
 112     Item_SetAlpha(this);
 113 }
 114
 115 void ItemDrawSimple(entity this)
 116 {
 117     if(this.gravity)
 118     {
 119         Movetype_Physics_MatchServer(this, false);
 120
 121         if(IS_ONGROUND(this))
 122             this.gravity = 0;
 123     }
 124
 125     Item_SetAlpha(this);
 126 }
 127
 128 void Item_PreDraw(entity this)
 129 {
 130         if(warpzone_warpzones_exist)
 131         {
 132                 setpredraw(this, func_null); // no need to keep running this
 133                 return;
 134         }
 135         float alph;
 136         vector org = getpropertyvec(VF_ORIGIN);
 137         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 138                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
 139         if(this.fade_start)
 140         {
 141                 if(vdist(org - this.origin, >, this.fade_end))
 142                         alph = 0; // save on some processing
 143                 else if(vdist(org - this.origin, <, this.fade_start))
 144                         alph = 1; // more processing saved
 145                 else
 146                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 147         }
 148         else
 149                 alph = 1;
 150         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 151         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 152                 this.alpha = alph;
 153         if(alph <= 0)
 154                 this.drawmask = 0;
 155         //else
 156                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
 157 }
 158
 159 void ItemRemove(entity this)
 160 {
 161         if(this.mdl)
 162                 strunzone(this.mdl);
 163 }
 164
 165 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 166 {
 167     int sf = ReadByte();
 168
 169     if(sf & ISF_LOCATION)
 170     {
 171         this.origin_x = ReadCoord();
 172         this.origin_y = ReadCoord();
 173         this.origin_z = ReadCoord();
 174         setorigin(this, this.origin);
 175         this.oldorigin = this.origin;
 176     }
 177
 178     if(sf & ISF_ANGLES)
 179     {
 180         this.angles_x = ReadAngle();
 181         this.angles_y = ReadAngle();
 182         this.angles_z = ReadAngle();
 183     }
 184
 185     if(sf & ISF_SIZE)
 186     {
 187         float use_bigsize = ReadByte();
 188         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 189     }
 190
 191     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
 192     {
 193         this.ItemStatus = ReadByte();
 194
 195         Item_SetAlpha(this);
 196
 197         if(autocvar_cl_fullbright_items)
 198             if(this.ItemStatus & ITS_ALLOWFB)
 199                 this.effects |= EF_FULLBRIGHT;
 200
 201         if(this.ItemStatus & ITS_GLOW)
 202         {
 203             if(this.ItemStatus & ITS_AVAILABLE)
 204                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 205             else
 206                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 207         }
 208     }
 209
 210     if(sf & ISF_MODEL)
 211     {
 212         this.drawmask  = MASK_NORMAL;
 213                 set_movetype(this, MOVETYPE_TOSS);
 214                 if (isnew) IL_PUSH(g_drawables, this);
 215         this.draw       = ItemDraw;
 216         this.solid = SOLID_TRIGGER;
 217         //this.flags |= FL_ITEM;
 218
 219         bool use_bigsize = ReadByte();
 220
 221         this.fade_end = ReadShort();
 222         this.fade_start = ReadShort();
 223         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
 224                 setpredraw(this, Item_PreDraw);
 225
 226         if(this.mdl)
 227             strunzone(this.mdl);
 228
 229         this.mdl = "";
 230         string _fn = ReadString();
 231
 232         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 233         {
 234             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 235             this.draw = ItemDrawSimple;
 236
 237             if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3")))
 238                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3"));
 239             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm")))
 240                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm"));
 241             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm")))
 242                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm"));
 243             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl")))
 244                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl"));
 245             else
 246             {
 247                 this.draw = ItemDraw;
 248                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
 249             }
 250         }
 251
 252         if(this.draw != ItemDrawSimple)
 253             this.mdl = strzone(_fn);
 254
 255
 256         if(this.mdl == "")
 257             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
 258
 259         precache_model(this.mdl);
 260         _setmodel(this, this.mdl);
 261
 262         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 263     }
 264
 265     if(sf & ISF_COLORMAP)
 266     {
 267         this.colormap = ReadShort();
 268         this.item_glowmod_x = ReadByte() / 255.0;
 269         this.item_glowmod_y = ReadByte() / 255.0;
 270         this.item_glowmod_z = ReadByte() / 255.0;
 271     }
 272
 273     if(sf & ISF_DROP)
 274     {
 275         this.gravity = 1;
 276         this.pushable = true;
 277         //this.angles = '0 0 0';
 278         set_movetype(this, MOVETYPE_TOSS);
 279         this.velocity_x = ReadCoord();
 280         this.velocity_y = ReadCoord();
 281         this.velocity_z = ReadCoord();
 282         setorigin(this, this.oldorigin);
 283
 284         if(!this.move_time)
 285         {
 286             this.move_time = time;
 287             this.spawntime = time;
 288         }
 289         else
 290             this.move_time = max(this.move_time, time);
 291     }
 292
 293     if(autocvar_cl_animate_items)
 294     {
 295         if(this.ItemStatus & ITS_ANIMATE1)
 296             this.avelocity = '0 180 0';
 297
 298         if(this.ItemStatus & ITS_ANIMATE2)
 299             this.avelocity = '0 -90 0';
 300     }
 301
 302     this.entremove = ItemRemove;
 303
 304     return true;
 305 }
 306
 307 #endif
 308
 309 #ifdef SVQC
 310 bool ItemSend(entity this, entity to, int sf)
 311 {
 312         if(this.gravity)
 313                 sf |= ISF_DROP;
 314         else
 315                 sf &= ~ISF_DROP;
 316
 317         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 318         WriteByte(MSG_ENTITY, sf);
 319
 320         //WriteByte(MSG_ENTITY, this.cnt);
 321         if(sf & ISF_LOCATION)
 322         {
 323                 WriteCoord(MSG_ENTITY, this.origin.x);
 324                 WriteCoord(MSG_ENTITY, this.origin.y);
 325                 WriteCoord(MSG_ENTITY, this.origin.z);
 326         }
 327
 328         if(sf & ISF_ANGLES)
 329         {
 330                 WriteAngle(MSG_ENTITY, this.angles_x);
 331                 WriteAngle(MSG_ENTITY, this.angles_y);
 332                 WriteAngle(MSG_ENTITY, this.angles_z);
 333         }
 334
 335         if(sf & ISF_SIZE)
 336         {
 337                 Pickup p = this.itemdef;
 338                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 339         }
 340
 341         if(sf & ISF_STATUS)
 342                 WriteByte(MSG_ENTITY, this.ItemStatus);
 343
 344         if(sf & ISF_MODEL)
 345         {
 346                 Pickup p = this.itemdef;
 347                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 348                 WriteShort(MSG_ENTITY, this.fade_end);
 349                 WriteShort(MSG_ENTITY, this.fade_start);
 350
 351                 if(this.mdl == "")
 352                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 353
 354                 WriteString(MSG_ENTITY, this.mdl);
 355         }
 356
 357
 358         if(sf & ISF_COLORMAP)
 359         {
 360                 WriteShort(MSG_ENTITY, this.colormap);
 361                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 362         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 363         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 364         }
 365
 366         if(sf & ISF_DROP)
 367         {
 368                 WriteCoord(MSG_ENTITY, this.velocity.x);
 369                 WriteCoord(MSG_ENTITY, this.velocity.y);
 370                 WriteCoord(MSG_ENTITY, this.velocity.z);
 371         }
 372
 373         return true;
 374 }
 375
 376 void ItemUpdate(entity this)
 377 {
 378         this.oldorigin = this.origin;
 379         this.SendFlags |= ISF_LOCATION;
 380 }
 381
 382 void UpdateItemAfterTeleport(entity this)
 383 {
 384         if(getSendEntity(this) == ItemSend)
 385                 ItemUpdate(this);
 386 }
 387
 388 bool have_pickup_item(entity this)
 389 {
 390         if(this.itemdef.instanceOfPowerup)
 391         {
 392                 if(autocvar_g_powerups > 0)
 393                         return true;
 394                 if(autocvar_g_powerups == 0)
 395                         return false;
 396         }
 397         else
 398         {
 399                 if(autocvar_g_pickup_items > 0)
 400                         return true;
 401                 if(autocvar_g_pickup_items == 0)
 402                         return false;
 403                 if(g_weaponarena)
 404                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 405                                 return false;
 406         }
 407         return true;
 408 }
 409
 410 /*
 411 float Item_Customize()
 412 {
 413         if(this.spawnshieldtime)
 414                 return true;
 415         if(this.weapons & ~other.weapons)
 416         {
 417                 this.colormod = '0 0 0';
 418                 this.glowmod = this.colormod;
 419                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 420                 return true;
 421         }
 422         else
 423         {
 424                 if(g_ghost_items)
 425                 {
 426                         this.colormod = stov(autocvar_g_ghost_items_color);
 427                         this.glowmod = this.colormod;
 428                         this.alpha = g_ghost_items;
 429                         return true;
 430                 }
 431                 else
 432                         return false;
 433         }
 434 }
 435 */
 436
 437 void Item_Show (entity e, float mode)
 438 {
 439         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 440         e.ItemStatus &= ~ITS_STAYWEP;
 441         entity def = e.itemdef;
 442         if (mode > 0)
 443         {
 444                 // make the item look normal, and be touchable
 445                 e.model = e.mdl;
 446                 e.solid = SOLID_TRIGGER;
 447                 e.spawnshieldtime = 1;
 448                 e.ItemStatus |= ITS_AVAILABLE;
 449         }
 450         else if (mode < 0)
 451         {
 452                 // hide the item completely
 453                 e.model = string_null;
 454                 e.solid = SOLID_NOT;
 455                 e.spawnshieldtime = 1;
 456                 e.ItemStatus &= ~ITS_AVAILABLE;
 457         }
 458         else
 459         {
 460                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 461                         || e.team // weapon stay isn't supported for teamed weapons
 462                         ;
 463                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 464                 {
 465                         // make the item translucent and not touchable
 466                         e.model = e.mdl;
 467                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
 468                         e.effects |= EF_STARDUST;
 469                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 470                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 471                 }
 472                 else
 473                 {
 474                         //setmodel(e, "null");
 475                         e.solid = SOLID_NOT;
 476                         e.colormod = '0 0 0';
 477                         //e.glowmod = e.colormod;
 478                         e.spawnshieldtime = 1;
 479                         e.ItemStatus &= ~ITS_AVAILABLE;
 480                 }
 481         }
 482
 483         if (def.m_glow)
 484                 e.ItemStatus |= ITS_GLOW;
 485
 486         if (autocvar_g_nodepthtestitems)
 487                 e.effects |= EF_NODEPTHTEST;
 488
 489
 490         if (autocvar_g_fullbrightitems)
 491                 e.ItemStatus |= ITS_ALLOWFB;
 492
 493         if (autocvar_sv_simple_items)
 494                 e.ItemStatus |= ITS_ALLOWSI;
 495
 496         // relink entity (because solid may have changed)
 497         setorigin(e, e.origin);
 498         e.SendFlags |= ISF_STATUS;
 499 }
 500
 501 void Item_Think(entity this)
 502 {
 503         this.nextthink = time;
 504         if(this.origin != this.oldorigin)
 505                 ItemUpdate(this);
 506 }
 507
 508 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 509 bool Item_ItemsTime_Allow(GameItem it);
 510 float Item_ItemsTime_UpdateTime(entity e, float t);
 511 void Item_ItemsTime_SetTime(entity e, float t);
 512 void Item_ItemsTime_SetTimesForAllPlayers();
 513
 514 void Item_Respawn (entity this)
 515 {
 516         Item_Show(this, 1);
 517         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 518         setorigin(this, this.origin);
 519
 520     if (Item_ItemsTime_Allow(this.itemdef) || (this.weapons & WEPSET_SUPERWEAPONS))
 521         {
 522                 float t = Item_ItemsTime_UpdateTime(this, 0);
 523                 Item_ItemsTime_SetTime(this, t);
 524                 Item_ItemsTime_SetTimesForAllPlayers();
 525         }
 526
 527         setthink(this, Item_Think);
 528         this.nextthink = time;
 529
 530         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 531         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 532 }
 533
 534 void Item_RespawnCountdown (entity this)
 535 {
 536         if(this.count >= ITEM_RESPAWN_TICKS)
 537         {
 538                 if(this.waypointsprite_attached)
 539                         WaypointSprite_Kill(this.waypointsprite_attached);
 540                 Item_Respawn(this);
 541         }
 542         else
 543         {
 544                 this.nextthink = time + 1;
 545                 this.count += 1;
 546                 if(this.count == 1)
 547                 {
 548                         do {
 549                                 {
 550                                         entity wi = Weapons_from(this.weapon);
 551                                         if (wi != WEP_Null) {
 552                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 553                                                 wp.wp_extra = wi.m_id;
 554                                                 break;
 555                                         }
 556                                 }
 557                                 {
 558                                         entity ii = this.itemdef;
 559                                         if (ii != NULL) {
 560                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 561                                                 wp.wp_extra = ii.m_id;
 562                                                 break;
 563                                         }
 564                                 }
 565                         } while (0);
 566                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
 567             if(this.waypointsprite_attached)
 568             {
 569                 GameItem def = this.itemdef;
 570                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
 571                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 572                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 573             }
 574                 }
 575
 576                 if(this.waypointsprite_attached)
 577                 {
 578                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 579                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 580                                 {
 581                                         msg_entity = it;
 582                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 583                                 }
 584                         });
 585
 586                         WaypointSprite_Ping(this.waypointsprite_attached);
 587                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.count);
 588                 }
 589         }
 590 }
 591
 592 void Item_RespawnThink(entity this)
 593 {
 594         this.nextthink = time;
 595         if(this.origin != this.oldorigin)
 596                 ItemUpdate(this);
 597
 598         if(time >= this.wait)
 599                 Item_Respawn(this);
 600 }
 601
 602 void Item_ScheduleRespawnIn(entity e, float t)
 603 {
 604         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 605         if ((Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
 606         {
 607                 setthink(e, Item_RespawnCountdown);
 608                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 609                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 610                 e.count = 0;
 611                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 612                 {
 613                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 614                         Item_ItemsTime_SetTime(e, t);
 615                         Item_ItemsTime_SetTimesForAllPlayers();
 616                 }
 617         }
 618         else
 619         {
 620                 setthink(e, Item_RespawnThink);
 621                 e.nextthink = time;
 622                 e.scheduledrespawntime = time + t;
 623                 e.wait = time + t;
 624
 625                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 626                 {
 627                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 628                         Item_ItemsTime_SetTime(e, t);
 629                         Item_ItemsTime_SetTimesForAllPlayers();
 630                 }
 631         }
 632 }
 633
 634 void Item_ScheduleRespawn(entity e)
 635 {
 636         if(e.respawntime > 0)
 637         {
 638                 Item_Show(e, 0);
 639                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 640         }
 641         else // if respawntime is -1, this item does not respawn
 642                 Item_Show(e, -1);
 643 }
 644
 645 void Item_ScheduleInitialRespawn(entity e)
 646 {
 647         Item_Show(e, 0);
 648         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
 649 }
 650
 651 void GivePlayerHealth(entity player, float amount)
 652 {
 653         if (amount == 0)
 654         {
 655                 return;
 656         }
 657         // Ugly hack. We do not check if health goes beyond hard limit since
 658         // currently it is done in player_regen. We need to bring back this check
 659         // when other code is ported to this function.
 660         player.health = bound(player.health, player.health + amount,
 661                 autocvar_g_balance_health_limit);
 662         // Correct code:
 663         //player.health = bound(player.health, player.health + amount,
 664         //      min(autocvar_g_balance_health_limit, ITEM_COUNT_HARD_LIMIT));
 665         player.pauserothealth_finished = max(player.pauserothealth_finished, time +
 666                 autocvar_g_balance_pause_health_rot);
 667 }
 668
 669 void GivePlayerArmor(entity player, float amount)
 670 {
 671         if (amount == 0)
 672         {
 673                 return;
 674         }
 675         // Ugly hack. We do not check if armor goes beyond hard limit since
 676         // currently it is done in player_regen. We need to bring back this check
 677         // when other code is ported to this function.
 678         player.armorvalue = bound(player.armorvalue, player.armorvalue + amount,
 679                 autocvar_g_balance_armor_limit);
 680         // Correct code:
 681         //player.armorvalue = bound(player.armorvalue, player.armorvalue + amount,
 682         //      min(autocvar_g_balance_armor_limit, ITEM_COUNT_HARD_LIMIT));
 683         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time +
 684                 autocvar_g_balance_pause_armor_rot);
 685 }
 686
 687 void GivePlayerAmmo(entity player, .float ammotype, float amount)
 688 {
 689         if (amount == 0)
 690         {
 691                 return;
 692         }
 693         float maxvalue = ITEM_COUNT_HARD_LIMIT;
 694         switch (ammotype)
 695         {
 696                 case ammo_shells:
 697                 {
 698                         maxvalue = g_pickup_shells_max;
 699                         break;
 700                 }
 701                 case ammo_cells:
 702                 {
 703                         maxvalue = g_pickup_cells_max;
 704                         break;
 705                 }
 706                 case ammo_rockets:
 707                 {
 708                         maxvalue = g_pickup_rockets_max;
 709                         break;
 710                 }
 711                 case ammo_plasma:
 712                 {
 713                         maxvalue = g_pickup_plasma_max;
 714                         break;
 715                 }
 716                 case ammo_nails:
 717                 {
 718                         maxvalue = g_pickup_nails_max;
 719                         break;
 720                 }
 721         }
 722         player.(ammotype) = min(player.(ammotype) + amount,
 723                 min(maxvalue, ITEM_COUNT_HARD_LIMIT));
 724 }
 725
 726 void GivePlayerFuel(entity player, float amount)
 727 {
 728         if (amount == 0)
 729         {
 730                 return;
 731         }
 732         player.ammo_fuel = bound(player.ammo_fuel, player.ammo_fuel + amount,
 733                  min(g_pickup_fuel_max, ITEM_COUNT_HARD_LIMIT));
 734         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time +
 735                 autocvar_g_balance_pause_fuel_rot);
 736 }
 737
 738 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 739 {
 740         if (!item.(ammotype))
 741                 return false;
 742
 743         if (item.spawnshieldtime)
 744         {
 745                 if ((player.(ammotype) < ammomax) || item.pickup_anyway > 0)
 746                 {
 747                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 748                         goto YEAH;
 749                 }
 750         }
 751         else if(g_weapon_stay == 2)
 752         {
 753                 float mi = min(item.(ammotype), ammomax);
 754                 if (player.(ammotype) < mi)
 755                 {
 756                         player.(ammotype) = mi;
 757                         goto YEAH;
 758                 }
 759         }
 760
 761         return false;
 762
 763 LABEL(YEAH)
 764         switch(mode)
 765         {
 766                 case ITEM_MODE_FUEL:
 767                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 768                         break;
 769                 case ITEM_MODE_HEALTH:
 770                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 771                         break;
 772                 case ITEM_MODE_ARMOR:
 773                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 774                         break;
 775                 default:
 776                         break;
 777         }
 778         return true;
 779 }
 780
 781 float Item_GiveTo(entity item, entity player)
 782 {
 783         float pickedup;
 784
 785         // if nothing happens to player, just return without taking the item
 786         pickedup = false;
 787         int _switchweapon = 0;
 788         // in case the player has autoswitch enabled do the following:
 789         // if the player is using their best weapon before items are given, they
 790         // probably want to switch to an even better weapon after items are given
 791
 792         if(CS(player).autoswitch)
 793         {
 794                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 795                 {
 796                         .entity weaponentity = weaponentities[slot];
 797                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 798                         {
 799                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 800                                         _switchweapon |= BIT(slot);
 801
 802                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 803                                         _switchweapon |= BIT(slot);
 804                         }
 805                 }
 806         }
 807
 808         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 809         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 810         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 811         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 812         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 813         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 814         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 815         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 816
 817         if (item.itemdef.instanceOfWeaponPickup)
 818         {
 819                 WepSet w;
 820                 w = item.weapons;
 821                 w &= ~player.weapons;
 822
 823                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 824                 {
 825                         pickedup = true;
 826                         FOREACH(Weapons, it != WEP_Null, {
 827                                 if(w & (it.m_wepset))
 828                                 {
 829                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 830                                         {
 831                                                 .entity weaponentity = weaponentities[slot];
 832                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 833                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 834                                         }
 835                                         W_GiveWeapon(player, it.m_id);
 836                                 }
 837                         });
 838                 }
 839         }
 840
 841         if (item.itemdef.instanceOfPowerup)
 842         {
 843                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 844                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 845                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 846                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 847         }
 848
 849         int its;
 850         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 851         {
 852                 pickedup = true;
 853                 player.items |= its;
 854                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 855         }
 856
 857         if (item.strength_finished)
 858         {
 859                 pickedup = true;
 860                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 861         }
 862         if (item.invincible_finished)
 863         {
 864                 pickedup = true;
 865                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 866         }
 867         if (item.superweapons_finished)
 868         {
 869                 pickedup = true;
 870                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 871         }
 872
 873 LABEL(skip)
 874
 875         // always eat teamed entities
 876         if(item.team)
 877                 pickedup = true;
 878
 879         if (!pickedup)
 880                 return 0;
 881
 882         // crude hack to enforce switching weapons
 883         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 884         {
 885                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 886                 {
 887                         .entity weaponentity = weaponentities[slot];
 888                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 889                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 890                 }
 891                 return 1;
 892         }
 893
 894         if(_switchweapon)
 895         {
 896                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 897                 {
 898                         .entity weaponentity = weaponentities[slot];
 899                         if(_switchweapon & BIT(slot))
 900                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 901                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 902                 }
 903         }
 904
 905         return 1;
 906 }
 907
 908 void Item_Touch(entity this, entity toucher)
 909 {
 910
 911         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 912         if (this.classname == "droppedweapon")
 913         {
 914                 if (ITEM_TOUCH_NEEDKILL())
 915                 {
 916                         delete(this);
 917                         return;
 918                 }
 919         }
 920
 921         if(!(toucher.flags & FL_PICKUPITEMS)
 922         || STAT(FROZEN, toucher)
 923         || IS_DEAD(toucher)
 924         || (this.solid != SOLID_TRIGGER)
 925         || (this.owner == toucher)
 926         || (time < this.item_spawnshieldtime)
 927         ) { return; }
 928
 929         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 930         {
 931                 case MUT_ITEMTOUCH_RETURN: { return; }
 932                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 933         }
 934
 935         toucher = M_ARGV(1, entity);
 936
 937         if (this.classname == "droppedweapon")
 938         {
 939                 this.strength_finished = max(0, this.strength_finished - time);
 940                 this.invincible_finished = max(0, this.invincible_finished - time);
 941                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 942         }
 943         entity it = this.itemdef;
 944         bool gave = ITEM_HANDLE(Pickup, it, this, toucher);
 945         if (!gave)
 946         {
 947                 if (this.classname == "droppedweapon")
 948                 {
 949                         // undo what we did above
 950                         this.strength_finished += time;
 951                         this.invincible_finished += time;
 952                         this.superweapons_finished += time;
 953                 }
 954                 return;
 955         }
 956
 957 LABEL(pickup)
 958
 959         toucher.last_pickup = time;
 960
 961         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 962         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 963
 964         if (this.classname == "droppedweapon")
 965                 delete(this);
 966         else if (this.spawnshieldtime)
 967         {
 968                 entity e;
 969                 if(this.team)
 970                 {
 971                         RandomSelection_Init();
 972                         IL_EACH(g_items, it.team == this.team,
 973                         {
 974                                 if(it.itemdef) // is a registered item
 975                                 {
 976                                         Item_Show(it, -1);
 977                                         RandomSelection_AddEnt(it, it.cnt, 0);
 978                                 }
 979                         });
 980                         e = RandomSelection_chosen_ent;
 981                         Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
 982                 }
 983                 else
 984                         e = this;
 985                 Item_ScheduleRespawn(e);
 986         }
 987 }
 988
 989 void Item_Reset(entity this)
 990 {
 991         Item_Show(this, !this.state);
 992         setorigin(this, this.origin);
 993
 994         if (this.classname != "droppedweapon")
 995         {
 996                 setthink(this, Item_Think);
 997                 this.nextthink = time;
 998
 999                 if (this.waypointsprite_attached)
1000                         WaypointSprite_Kill(this.waypointsprite_attached);
1001
1002                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
1003                         Item_ScheduleInitialRespawn(this);
1004         }
1005 }
1006
1007 void Item_FindTeam(entity this)
1008 {
1009         entity e;
1010
1011         if(this.effects & EF_NODRAW)
1012         {
1013                 // marker for item team search
1014                 LOG_TRACE("Initializing item team ", ftos(this.team));
1015                 RandomSelection_Init();
1016                 IL_EACH(g_items, it.team == this.team,
1017                 {
1018                         if(it.itemdef) // is a registered item
1019                                 RandomSelection_AddEnt(it, it.cnt, 0);
1020                 });
1021
1022                 e = RandomSelection_chosen_ent;
1023                 e.state = 0;
1024                 Item_Show(e, 1);
1025
1026                 IL_EACH(g_items, it.team == this.team,
1027                 {
1028                         if(it.itemdef) // is a registered item
1029                         {
1030                                 if(it != e)
1031                                 {
1032                                         // make it non-spawned
1033                                         Item_Show(it, -1);
1034                                         it.state = 1; // state 1 = initially hidden item, apparently
1035                                 }
1036                                 it.effects &= ~EF_NODRAW;
1037                         }
1038                 });
1039
1040                 Item_Reset(this);
1041         }
1042 }
1043
1044 // Savage: used for item garbage-collection
1045 void RemoveItem(entity this)
1046 {
1047         if(wasfreed(this) || !this) { return; }
1048         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1049         delete(this);
1050 }
1051
1052 // pickup evaluation functions
1053 // these functions decide how desirable an item is to the bots
1054
1055 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1056
1057 float weapon_pickupevalfunc(entity player, entity item)
1058 {
1059         // See if I have it already
1060         if(player.weapons & item.weapons)
1061         {
1062                 // If I can pick it up
1063                 if(!item.spawnshieldtime)
1064                         return 0;
1065                 return ammo_pickupevalfunc(player, item);
1066         }
1067
1068         // reduce weapon value if bot already got a good arsenal
1069         float c = 1;
1070         int weapons_value = 0;
1071         FOREACH(Weapons, it != WEP_Null && (player.weapons & it.m_wepset), {
1072                 weapons_value += it.bot_pickupbasevalue;
1073         });
1074         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1075
1076         return item.bot_pickupbasevalue * c;
1077 }
1078
1079 float ammo_pickupevalfunc(entity player, entity item)
1080 {
1081         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1082         entity wpn = NULL;
1083         float c = 0;
1084         float rating = 0;
1085
1086         // Detect needed ammo
1087         if(item.itemdef.instanceOfWeaponPickup)
1088         {
1089                 entity ammo = NULL;
1090                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
1091                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
1092                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
1093                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
1094                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
1095                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1096
1097                 if(!ammo)
1098                         return 0;
1099                 wpn = item;
1100                 rating = ammo.m_botvalue;
1101         }
1102         else
1103         {
1104                 FOREACH(Weapons, it != WEP_Null, {
1105                         if(!(player.weapons & (it.m_wepset)))
1106                                 continue;
1107
1108                         switch(it.ammo_field)
1109                         {
1110                                 case ammo_shells:  need_shells  = true; break;
1111                                 case ammo_nails:   need_nails   = true; break;
1112                                 case ammo_rockets: need_rockets = true; break;
1113                                 case ammo_cells:   need_cells   = true; break;
1114                                 case ammo_plasma:  need_plasma  = true; break;
1115                                 case ammo_fuel:    need_fuel    = true; break;
1116                         }
1117                 });
1118                 rating = item.bot_pickupbasevalue;
1119         }
1120
1121         float noammorating = 0.5;
1122
1123         if ((need_shells) && (item.ammo_shells) && (player.ammo_shells < g_pickup_shells_max))
1124                 c = item.ammo_shells / max(noammorating, player.ammo_shells);
1125
1126         if ((need_nails) && (item.ammo_nails) && (player.ammo_nails < g_pickup_nails_max))
1127                 c = item.ammo_nails / max(noammorating, player.ammo_nails);
1128
1129         if ((need_rockets) && (item.ammo_rockets) && (player.ammo_rockets < g_pickup_rockets_max))
1130                 c = item.ammo_rockets / max(noammorating, player.ammo_rockets);
1131
1132         if ((need_cells) && (item.ammo_cells) && (player.ammo_cells < g_pickup_cells_max))
1133                 c = item.ammo_cells / max(noammorating, player.ammo_cells);
1134
1135         if ((need_plasma) && (item.ammo_plasma) && (player.ammo_plasma < g_pickup_plasma_max))
1136                 c = item.ammo_plasma / max(noammorating, player.ammo_plasma);
1137
1138         if ((need_fuel) && (item.ammo_fuel) && (player.ammo_fuel < g_pickup_fuel_max))
1139                 c = item.ammo_fuel / max(noammorating, player.ammo_fuel);
1140
1141         rating *= min(c, 2);
1142         if(wpn)
1143                 rating += wpn.bot_pickupbasevalue * 0.1;
1144         return rating;
1145 }
1146
1147 .int item_group;
1148 .int item_group_count;
1149 float healtharmor_pickupevalfunc(entity player, entity item)
1150 {
1151         float c = 0;
1152         float rating = item.bot_pickupbasevalue;
1153
1154         float itemarmor = item.armorvalue;
1155         float itemhealth = item.health;
1156
1157         if(item.item_group)
1158         {
1159                 itemarmor *= min(4, item.item_group_count);
1160                 itemhealth *= min(4, item.item_group_count);
1161         }
1162
1163         if (itemarmor && (player.armorvalue < item.max_armorvalue))
1164                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1165
1166         if (itemhealth && (player.health < item.max_health))
1167                 c = itemhealth / max(1, player.health);
1168
1169         rating *= min(2, c);
1170         return rating;
1171 }
1172
1173 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1174 {
1175         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1176                 RemoveItem(this);
1177 }
1178
1179 void item_use(entity this, entity actor, entity trigger)
1180 {
1181         // use the touch function to handle collection
1182         gettouch(this)(this, actor);
1183 }
1184
1185 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1186 {
1187         string itemname = def.m_name;
1188         Model itemmodel = def.m_model;
1189     Sound pickupsound = def.m_sound;
1190         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1191         float pickupbasevalue = def.m_botvalue;
1192         int itemflags = def.m_itemflags;
1193
1194         startitem_failed = false;
1195
1196         this.item_model_ent = itemmodel;
1197     this.item_pickupsound_ent = pickupsound;
1198
1199     if(def.m_iteminit)
1200         def.m_iteminit(this);
1201
1202         if(!this.respawntime) // both need to be set
1203         {
1204                 this.respawntime = defaultrespawntime;
1205                 this.respawntimejitter = defaultrespawntimejitter;
1206         }
1207
1208         if(!this.pickup_anyway && def.m_pickupanyway)
1209                 this.pickup_anyway = def.m_pickupanyway();
1210
1211         int itemid = def.m_itemid;
1212         this.items = itemid;
1213         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1214         this.weapon = weaponid;
1215
1216         if(!this.fade_end)
1217         {
1218                 this.fade_start = autocvar_g_items_mindist;
1219                 this.fade_end = autocvar_g_items_maxdist;
1220         }
1221
1222         if(weaponid)
1223                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1224
1225         this.flags = FL_ITEM | itemflags;
1226         IL_PUSH(g_items, this);
1227
1228         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1229         {
1230                 startitem_failed = true;
1231                 delete(this);
1232                 return;
1233         }
1234
1235         // is it a dropped weapon?
1236         if (this.classname == "droppedweapon")
1237         {
1238                 this.reset = SUB_Remove;
1239                 // it's a dropped weapon
1240                 set_movetype(this, MOVETYPE_TOSS);
1241
1242                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1243                 setthink(this, RemoveItem);
1244                 this.nextthink = time + 20;
1245
1246                 this.takedamage = DAMAGE_YES;
1247                 this.event_damage = Item_Damage;
1248
1249                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1250                 {
1251                         // if item is worthless after a timer, have it expire then
1252                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1253                 }
1254
1255                 // don't drop if in a NODROP zone (such as lava)
1256                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1257                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1258                 {
1259                         startitem_failed = true;
1260                         delete(this);
1261                         return;
1262                 }
1263         }
1264         else
1265         {
1266                 if(!have_pickup_item(this))
1267                 {
1268                         startitem_failed = true;
1269                         delete(this);
1270                         return;
1271                 }
1272
1273                 if(this.angles != '0 0 0')
1274                         this.SendFlags |= ISF_ANGLES;
1275
1276                 this.reset = Item_Reset;
1277                 // it's a level item
1278                 if(this.spawnflags & 1)
1279                         this.noalign = 1;
1280                 if (this.noalign > 0)
1281                         set_movetype(this, MOVETYPE_NONE);
1282                 else
1283                         set_movetype(this, MOVETYPE_TOSS);
1284                 // do item filtering according to game mode and other things
1285                 if (this.noalign <= 0)
1286                 {
1287                         // first nudge it off the floor a little bit to avoid math errors
1288                         setorigin(this, this.origin + '0 0 1');
1289                         // set item size before we spawn a spawnfunc_waypoint
1290                         setsize(this, def.m_mins, def.m_maxs);
1291                         this.SendFlags |= ISF_SIZE;
1292                         // note droptofloor returns false if stuck/or would fall too far
1293                         if (!this.noalign)
1294                                 droptofloor(this);
1295                         waypoint_spawnforitem(this);
1296                 }
1297
1298                 /*
1299                  * can't do it that way, as it would break maps
1300                  * TODO make a target_give like entity another way, that perhaps has
1301                  * the weapon name in a key
1302                 if(this.targetname)
1303                 {
1304                         // target_give not yet supported; maybe later
1305                         print("removed targeted ", this.classname, "\n");
1306                         startitem_failed = true;
1307                         delete(this);
1308                         return;
1309                 }
1310                 */
1311
1312                 if(this.targetname != "" && (this.spawnflags & 16))
1313                         this.use = item_use;
1314
1315                 if(autocvar_spawn_debug >= 2)
1316                 {
1317             // why not flags & fl_item?
1318                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1319                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1320                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1321                 error("Mapper sucks.");
1322             });
1323                         this.is_item = true;
1324                 }
1325
1326                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1327
1328                 precache_model(this.model);
1329                 precache_sound(this.item_pickupsound);
1330
1331                 if (   def.instanceOfPowerup
1332                         || def.instanceOfWeaponPickup
1333                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1334                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1335                         || (itemid & (IT_KEY1 | IT_KEY2))
1336                 ) this.target = "###item###"; // for finding the nearest item using find()
1337
1338                 Item_ItemsTime_SetTime(this, 0);
1339         }
1340
1341         this.bot_pickup = true;
1342         this.bot_pickupevalfunc = pickupevalfunc;
1343         this.bot_pickupbasevalue = pickupbasevalue;
1344         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1345         this.netname = itemname;
1346         settouch(this, Item_Touch);
1347         setmodel(this, MDL_Null); // precision set below
1348         //this.effects |= EF_LOWPRECISION;
1349
1350         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1351
1352         this.SendFlags |= ISF_SIZE;
1353
1354         if (!(this.spawnflags & 1024)) {
1355                 if(def.instanceOfPowerup)
1356                         this.ItemStatus |= ITS_ANIMATE1;
1357
1358                 if(this.armorvalue || this.health)
1359                         this.ItemStatus |= ITS_ANIMATE2;
1360         }
1361
1362         if(def.instanceOfWeaponPickup)
1363         {
1364                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1365                         this.colormap = 1024; // color shirt=0 pants=0 grey
1366                 else
1367                         this.gravity = 1;
1368                 if (!(this.spawnflags & 1024))
1369                         this.ItemStatus |= ITS_ANIMATE1;
1370                 this.SendFlags |= ISF_COLORMAP;
1371         }
1372
1373         this.state = 0;
1374         if(this.team) // broken, no idea why.
1375         {
1376                 if(!this.cnt)
1377                         this.cnt = 1; // item probability weight
1378
1379                 this.effects |= EF_NODRAW; // marker for item team search
1380                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1381         }
1382         else
1383                 Item_Reset(this);
1384
1385         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1386
1387         // call this hook after everything else has been done
1388         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1389         {
1390                 startitem_failed = true;
1391                 delete(this);
1392                 return;
1393         }
1394
1395         setItemGroup(this);
1396 }
1397
1398 void StartItem(entity this, GameItem def)
1399 {
1400     _StartItem(
1401         this,
1402         this.itemdef = def,
1403         def.m_respawntime(), // defaultrespawntime
1404         def.m_respawntimejitter() // defaultrespawntimejitter
1405         );
1406 }
1407
1408 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1409 int group_count = 1;
1410
1411 void setItemGroup(entity this)
1412 {
1413         if(!IS_SMALL(this.itemdef))
1414                 return;
1415
1416         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1417         {
1418                 if(!this.item_group)
1419                 {
1420                         if(!it.item_group)
1421                         {
1422                                 it.item_group = group_count;
1423                                 group_count++;
1424                         }
1425                         this.item_group = it.item_group;
1426                 }
1427                 else // spawning item is already part of a item_group X
1428                 {
1429                         if(!it.item_group)
1430                                 it.item_group = this.item_group;
1431                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1432                         {
1433                                 int grY = it.item_group;
1434                                 // move all items of item_group Y to item_group X
1435                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1436                                 {
1437                                         if(it.item_group == grY)
1438                                                 it.item_group = this.item_group;
1439                                 });
1440                         }
1441                 }
1442         });
1443 }
1444
1445 void setItemGroupCount()
1446 {
1447         for (int k = 1; k <= group_count; k++)
1448         {
1449                 int count = 0;
1450                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1451                 if (count)
1452                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1453         }
1454 }
1455
1456 spawnfunc(item_rockets)
1457 {
1458     StartItem(this, ITEM_Rockets);
1459 }
1460
1461 spawnfunc(item_bullets)
1462 {
1463         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1464            (this.classname != "droppedweapon"))
1465         {
1466                 weaponswapping = true;
1467                 spawnfunc_item_shells(this);
1468                 weaponswapping = false;
1469                 return;
1470         }
1471
1472     StartItem(this, ITEM_Bullets);
1473 }
1474
1475 spawnfunc(item_cells)
1476 {
1477         StartItem(this, ITEM_Cells);
1478 }
1479
1480 spawnfunc(item_plasma)
1481 {
1482         StartItem(this, ITEM_Plasma);
1483 }
1484
1485 spawnfunc(item_shells)
1486 {
1487         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1488            (this.classname != "droppedweapon"))
1489         {
1490                 weaponswapping = true;
1491                 spawnfunc_item_bullets(this);
1492                 weaponswapping = false;
1493                 return;
1494         }
1495
1496         StartItem(this, ITEM_Shells);
1497 }
1498
1499 spawnfunc(item_armor_small)
1500 {
1501         StartItem(this, ITEM_ArmorSmall);
1502 }
1503
1504 spawnfunc(item_armor_medium)
1505 {
1506         StartItem(this, ITEM_ArmorMedium);
1507 }
1508
1509 spawnfunc(item_armor_big)
1510 {
1511         StartItem(this, ITEM_ArmorBig);
1512 }
1513
1514 spawnfunc(item_armor_mega)
1515 {
1516         StartItem(this, ITEM_ArmorMega);
1517 }
1518
1519 spawnfunc(item_health_small)
1520 {
1521         StartItem(this, ITEM_HealthSmall);
1522 }
1523
1524 spawnfunc(item_health_medium)
1525 {
1526     StartItem(this, ITEM_HealthMedium);
1527 }
1528
1529 spawnfunc(item_health_big)
1530 {
1531         StartItem(this, ITEM_HealthBig);
1532 }
1533
1534 spawnfunc(item_health_mega)
1535 {
1536     StartItem(this, ITEM_HealthMega);
1537 }
1538
1539 // support old misnamed entities
1540 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1541 spawnfunc(item_armor25) { spawnfunc_item_armor_mega(this); }
1542 spawnfunc(item_armor_large) { spawnfunc_item_armor_mega(this); }
1543 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1544 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1545 spawnfunc(item_health_large) { spawnfunc_item_health_big(this); }
1546 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1547
1548 spawnfunc(item_strength)
1549 {
1550         StartItem(this, ITEM_Strength);
1551 }
1552
1553 spawnfunc(item_invincible)
1554 {
1555         StartItem(this, ITEM_Shield);
1556 }
1557
1558 // compatibility:
1559 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1560
1561 void target_items_use(entity this, entity actor, entity trigger)
1562 {
1563         if(actor.classname == "droppedweapon")
1564         {
1565                 EXACTTRIGGER_TOUCH(this, trigger);
1566                 delete(actor);
1567                 return;
1568         }
1569
1570         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1571                 return;
1572
1573         if(trigger.solid == SOLID_TRIGGER)
1574         {
1575                 EXACTTRIGGER_TOUCH(this, trigger);
1576         }
1577
1578         IL_EACH(g_items, it.enemy == actor && it.classname == "droppedweapon",
1579         {
1580                 delete(it);
1581         });
1582
1583         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1584                 centerprint(actor, this.message);
1585 }
1586
1587 spawnfunc(target_items)
1588 {
1589         int n;
1590         string s;
1591
1592         this.use = target_items_use;
1593         if(!this.strength_finished)
1594                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1595         if(!this.invincible_finished)
1596                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1597         if(!this.superweapons_finished)
1598                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1599
1600         n = tokenize_console(this.netname);
1601         if(argv(0) == "give")
1602         {
1603                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1604         }
1605         else
1606         {
1607                 for(int j = 0; j < n; ++j)
1608                 {
1609                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1610                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1611                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1612                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1613                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1614                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1615                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1616                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1617                         else
1618                         {
1619                                 FOREACH(Buffs, it != BUFF_Null,
1620                                 {
1621                                         s = Buff_UndeprecateName(argv(j));
1622                                         if(s == it.m_name)
1623                                         {
1624                                                 this.buffs |= (it.m_itemid);
1625                                                 break;
1626                                         }
1627                                 });
1628                                 FOREACH(Weapons, it != WEP_Null, {
1629                                         s = W_UndeprecateName(argv(j));
1630                                         if(s == it.netname)
1631                                         {
1632                                                 this.weapons |= (it.m_wepset);
1633                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1634                                                         it.wr_init(it);
1635                                                 break;
1636                                         }
1637                                 });
1638                         }
1639                 }
1640
1641                 string itemprefix, valueprefix;
1642                 if(this.spawnflags == 0)
1643                 {
1644                         itemprefix = "";
1645                         valueprefix = "";
1646                 }
1647                 else if(this.spawnflags == 1)
1648                 {
1649                         itemprefix = "max ";
1650                         valueprefix = "max ";
1651                 }
1652                 else if(this.spawnflags == 2)
1653                 {
1654                         itemprefix = "min ";
1655                         valueprefix = "min ";
1656                 }
1657                 else if(this.spawnflags == 4)
1658                 {
1659                         itemprefix = "minus ";
1660                         valueprefix = "max ";
1661                 }
1662                 else
1663                 {
1664                         error("invalid spawnflags");
1665                         itemprefix = valueprefix = string_null;
1666                 }
1667
1668                 this.netname = "";
1669                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1670                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1671                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1672                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1673                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1674                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1675                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1676                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1677                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1678                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1679                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1680                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1681                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1682                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1683                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1684                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.buffs & (it.m_itemid)), it.m_name));
1685                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1686         }
1687         this.netname = strzone(this.netname);
1688         //print(this.netname, "\n");
1689
1690         n = tokenize_console(this.netname);
1691         for(int j = 0; j < n; ++j)
1692         {
1693                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1694             it.wr_init(it);
1695             break;
1696                 });
1697         }
1698 }
1699
1700 spawnfunc(item_fuel)
1701 {
1702         StartItem(this, ITEM_JetpackFuel);
1703 }
1704
1705 spawnfunc(item_fuel_regen)
1706 {
1707         if(start_items & ITEM_JetpackRegen.m_itemid)
1708         {
1709                 spawnfunc_item_fuel(this);
1710                 return;
1711         }
1712         StartItem(this, ITEM_JetpackRegen);
1713 }
1714
1715 spawnfunc(item_jetpack)
1716 {
1717         if(start_items & ITEM_Jetpack.m_itemid)
1718         {
1719                 spawnfunc_item_fuel(this);
1720                 return;
1721         }
1722         StartItem(this, ITEM_Jetpack);
1723 }
1724
1725 float GiveWeapon(entity e, float wpn, float op, float val)
1726 {
1727         WepSet v0, v1;
1728         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1729         v0 = (e.weapons & s);
1730         switch(op)
1731         {
1732                 case OP_SET:
1733                         if(val > 0)
1734                                 e.weapons |= s;
1735                         else
1736                                 e.weapons &= ~s;
1737                         break;
1738                 case OP_MIN:
1739                 case OP_PLUS:
1740                         if(val > 0)
1741                                 e.weapons |= s;
1742                         break;
1743                 case OP_MAX:
1744                         if(val <= 0)
1745                                 e.weapons &= ~s;
1746                         break;
1747                 case OP_MINUS:
1748                         if(val > 0)
1749                                 e.weapons &= ~s;
1750                         break;
1751         }
1752         v1 = (e.weapons & s);
1753         return (v0 != v1);
1754 }
1755
1756 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1757 {
1758         bool had_buff = (e.buffs & thebuff.m_itemid);
1759         switch(op)
1760         {
1761                 case OP_SET:
1762                         if(val > 0)
1763                                 e.buffs |= thebuff.m_itemid;
1764                         else
1765                                 e.buffs &= ~thebuff.m_itemid;
1766                         break;
1767                 case OP_MIN:
1768                 case OP_PLUS:
1769                         if(val > 0)
1770                                 e.buffs |= thebuff.m_itemid;
1771                         break;
1772                 case OP_MAX:
1773                         if(val <= 0)
1774                                 e.buffs &= ~thebuff.m_itemid;
1775                         break;
1776                 case OP_MINUS:
1777                         if(val > 0)
1778                                 e.buffs &= ~thebuff.m_itemid;
1779                         break;
1780         }
1781         bool have_buff = (e.buffs & thebuff.m_itemid);
1782         return (had_buff != have_buff);
1783 }
1784
1785 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1786 {
1787         if(v1 == v0)
1788                 return;
1789         if(v1 <= v0 - t)
1790         {
1791                 if(snd_decr != NULL)
1792                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1793         }
1794         else if(v0 >= v0 + t)
1795         {
1796                 if(snd_incr != NULL)
1797                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1798         }
1799 }
1800
1801 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1802 {
1803         if(v0 < v1)
1804                 e.(rotfield) = max(e.(rotfield), time + rottime);
1805         else if(v0 > v1)
1806                 e.(regenfield) = max(e.(regenfield), time + regentime);
1807 }
1808 float GiveItems(entity e, float beginarg, float endarg)
1809 {
1810         float got, i, val, op;
1811         string cmd;
1812
1813         val = 999;
1814         op = OP_SET;
1815
1816         got = 0;
1817
1818         int _switchweapon = 0;
1819
1820         if(CS(e).autoswitch)
1821         {
1822                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1823                 {
1824                         .entity weaponentity = weaponentities[slot];
1825                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1826                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1827                                 _switchweapon |= BIT(slot);
1828                 }
1829         }
1830
1831         e.strength_finished = max(0, e.strength_finished - time);
1832         e.invincible_finished = max(0, e.invincible_finished - time);
1833         e.superweapons_finished = max(0, e.superweapons_finished - time);
1834
1835         PREGIVE(e, items);
1836         PREGIVE_WEAPONS(e);
1837         PREGIVE(e, strength_finished);
1838         PREGIVE(e, invincible_finished);
1839         PREGIVE(e, superweapons_finished);
1840         PREGIVE(e, ammo_nails);
1841         PREGIVE(e, ammo_cells);
1842         PREGIVE(e, ammo_plasma);
1843         PREGIVE(e, ammo_shells);
1844         PREGIVE(e, ammo_rockets);
1845         PREGIVE(e, ammo_fuel);
1846         PREGIVE(e, armorvalue);
1847         PREGIVE(e, health);
1848
1849         for(i = beginarg; i < endarg; ++i)
1850         {
1851                 cmd = argv(i);
1852
1853                 if(cmd == "0" || stof(cmd))
1854                 {
1855                         val = stof(cmd);
1856                         continue;
1857                 }
1858                 switch(cmd)
1859                 {
1860                         case "no":
1861                                 op = OP_MAX;
1862                                 val = 0;
1863                                 continue;
1864                         case "max":
1865                                 op = OP_MAX;
1866                                 continue;
1867                         case "min":
1868                                 op = OP_MIN;
1869                                 continue;
1870                         case "plus":
1871                                 op = OP_PLUS;
1872                                 continue;
1873                         case "minus":
1874                                 op = OP_MINUS;
1875                                 continue;
1876                         case "ALL":
1877                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1878                                 got += GiveValue(e, strength_finished, op, val);
1879                                 got += GiveValue(e, invincible_finished, op, val);
1880                                 got += GiveValue(e, superweapons_finished, op, val);
1881                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1882                         case "all":
1883                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1884                                 got += GiveValue(e, health, op, val);
1885                                 got += GiveValue(e, armorvalue, op, val);
1886                         case "allweapons":
1887                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1888                         //case "allbuffs": // all buffs makes a player god, do not want!
1889                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1890                         case "allammo":
1891                                 got += GiveValue(e, ammo_cells, op, val);
1892                                 got += GiveValue(e, ammo_plasma, op, val);
1893                                 got += GiveValue(e, ammo_shells, op, val);
1894                                 got += GiveValue(e, ammo_nails, op, val);
1895                                 got += GiveValue(e, ammo_rockets, op, val);
1896                                 got += GiveValue(e, ammo_fuel, op, val);
1897                                 break;
1898                         case "unlimited_ammo":
1899                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1900                                 break;
1901                         case "unlimited_weapon_ammo":
1902                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1903                                 break;
1904                         case "unlimited_superweapons":
1905                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1906                                 break;
1907                         case "jetpack":
1908                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1909                                 break;
1910                         case "fuel_regen":
1911                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1912                                 break;
1913                         case "strength":
1914                                 got += GiveValue(e, strength_finished, op, val);
1915                                 break;
1916                         case "invincible":
1917                                 got += GiveValue(e, invincible_finished, op, val);
1918                                 break;
1919                         case "superweapons":
1920                                 got += GiveValue(e, superweapons_finished, op, val);
1921                                 break;
1922                         case "cells":
1923                                 got += GiveValue(e, ammo_cells, op, val);
1924                                 break;
1925                         case "plasma":
1926                                 got += GiveValue(e, ammo_plasma, op, val);
1927                                 break;
1928                         case "shells":
1929                                 got += GiveValue(e, ammo_shells, op, val);
1930                                 break;
1931                         case "nails":
1932                         case "bullets":
1933                                 got += GiveValue(e, ammo_nails, op, val);
1934                                 break;
1935                         case "rockets":
1936                                 got += GiveValue(e, ammo_rockets, op, val);
1937                                 break;
1938                         case "health":
1939                                 got += GiveValue(e, health, op, val);
1940                                 break;
1941                         case "armor":
1942                                 got += GiveValue(e, armorvalue, op, val);
1943                                 break;
1944                         case "fuel":
1945                                 got += GiveValue(e, ammo_fuel, op, val);
1946                                 break;
1947                         default:
1948                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1949                                 {
1950                                         got += GiveBuff(e, it, op, val);
1951                                         break;
1952                                 });
1953                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1954                     got += GiveWeapon(e, it.m_id, op, val);
1955                     break;
1956                                 });
1957                                 break;
1958                 }
1959                 val = 999;
1960                 op = OP_SET;
1961         }
1962
1963         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1964         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1965         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1966         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1967         FOREACH(Weapons, it != WEP_Null, {
1968                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1969                 if(!(save_weapons & (it.m_wepset)))
1970                         if(e.weapons & (it.m_wepset))
1971                                 it.wr_init(it);
1972         });
1973         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1974         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1975         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1976         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1977         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1978         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1979         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1980         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1981         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1982         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1983         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1984
1985         if(e.superweapons_finished <= 0)
1986                 if(e.weapons & WEPSET_SUPERWEAPONS)
1987                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1988
1989         if(e.strength_finished <= 0)
1990                 e.strength_finished = 0;
1991         else
1992                 e.strength_finished += time;
1993         if(e.invincible_finished <= 0)
1994                 e.invincible_finished = 0;
1995         else
1996                 e.invincible_finished += time;
1997         if(e.superweapons_finished <= 0)
1998                 e.superweapons_finished = 0;
1999         else
2000                 e.superweapons_finished += time;
2001
2002         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2003         {
2004                 .entity weaponentity = weaponentities[slot];
2005                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
2006                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
2007                         _switchweapon |= BIT(slot);
2008         }
2009
2010         if(_switchweapon)
2011         {
2012                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2013                 {
2014                         .entity weaponentity = weaponentities[slot];
2015                         if(_switchweapon & BIT(slot))
2016                         {
2017                                 Weapon wep = w_getbestweapon(e, weaponentity);
2018                                 if(wep != e.(weaponentity).m_switchweapon)
2019                                         W_SwitchWeapon_Force(e, wep, weaponentity);
2020                         }
2021                 }
2022         }
2023
2024         return got;
2025 }
2026 #endif