qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "triggers/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include <common/mutators/mutator/buffs/buffs.qh>
  26
  27     #include "../lib/warpzone/util_server.qh"
  28 #elif defined(CSQC)
  29         #include "physics/movetypes/movetypes.qh"
  30         #include <common/weapons/_all.qh>
  31         #include "../lib/csqcmodel/cl_model.qh"
  32         #include "../lib/csqcmodel/common.qh"
  33 #endif
  34
  35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  36
  37 #ifdef CSQC
  38 bool autocvar_cl_ghost_items_vehicle = true;
  39 .vector item_glowmod;
  40 void Item_SetAlpha(entity this)
  41 {
  42         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  43
  44         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  45         {
  46                 this.alpha = 1;
  47                 this.colormod = '1 1 1';
  48                 this.glowmod = this.item_glowmod;
  49         }
  50         else
  51         {
  52                 if (autocvar_cl_ghost_items_color)
  53                 {
  54                         this.alpha = autocvar_cl_ghost_items;
  55                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  56                 }
  57                 else
  58                         this.alpha = -1;
  59         }
  60
  61         if(!veh_hud)
  62         if(this.ItemStatus & ITS_STAYWEP)
  63         {
  64                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  65                 this.alpha = autocvar_cl_weapon_stay_alpha;
  66         }
  67 }
  68
  69 void ItemDraw(entity this)
  70 {
  71     if(this.gravity)
  72     {
  73         Movetype_Physics_MatchServer(this, false);
  74         if(IS_ONGROUND(this))
  75         { // For some reason avelocity gets set to '0 0 0' here ...
  76             this.oldorigin = this.origin;
  77             this.gravity = 0;
  78
  79             if(autocvar_cl_animate_items)
  80             { // ... so reset it if animations are requested.
  81                 if(this.ItemStatus & ITS_ANIMATE1)
  82                     this.avelocity = '0 180 0';
  83
  84                 if(this.ItemStatus & ITS_ANIMATE2)
  85                     this.avelocity = '0 -90 0';
  86             }
  87
  88             // delay is for blocking item's position for a while;
  89             // it's a workaround for dropped weapons that receive the position
  90             // another time right after they spawn overriding animation position
  91             this.onground_time = time + 0.5;
  92         }
  93     }
  94     else if (autocvar_cl_animate_items)
  95     {
  96         if(this.ItemStatus & ITS_ANIMATE1)
  97         {
  98             this.angles += this.avelocity * frametime;
  99             float fade_in = bound(0, time - this.onground_time, 1);
 100             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
 101         }
 102
 103         if(this.ItemStatus & ITS_ANIMATE2)
 104         {
 105             this.angles += this.avelocity * frametime;
 106             float fade_in = bound(0, time - this.onground_time, 1);
 107             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 108         }
 109     }
 110
 111     Item_SetAlpha(this);
 112 }
 113
 114 void ItemDrawSimple(entity this)
 115 {
 116     if(this.gravity)
 117     {
 118         Movetype_Physics_MatchServer(this, false);
 119
 120         if(IS_ONGROUND(this))
 121             this.gravity = 0;
 122     }
 123
 124     Item_SetAlpha(this);
 125 }
 126
 127 void Item_PreDraw(entity this)
 128 {
 129         if(warpzone_warpzones_exist)
 130         {
 131                 // just incase warpzones were initialized last, reset these
 132                 //this.alpha = 1; // alpha is already set by the draw function
 133                 this.drawmask = MASK_NORMAL;
 134                 return;
 135         }
 136         float alph;
 137         vector org = getpropertyvec(VF_ORIGIN);
 138         if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 139                 alph = 0;
 140         else if(this.fade_start)
 141                 alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 142         else
 143                 alph = 1;
 144         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 145         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 146                 this.alpha = alph;
 147         if(alph <= 0)
 148                 this.drawmask = 0;
 149         else
 150                 this.drawmask = MASK_NORMAL;
 151 }
 152
 153 void ItemRemove(entity this)
 154 {
 155         if(this.mdl)
 156                 strunzone(this.mdl);
 157 }
 158
 159 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 160 {
 161     int sf = ReadByte();
 162
 163     if(sf & ISF_LOCATION)
 164     {
 165         this.origin_x = ReadCoord();
 166         this.origin_y = ReadCoord();
 167         this.origin_z = ReadCoord();
 168         setorigin(this, this.origin);
 169         this.oldorigin = this.origin;
 170     }
 171
 172     if(sf & ISF_ANGLES)
 173     {
 174         this.angles_x = ReadAngle();
 175         this.angles_y = ReadAngle();
 176         this.angles_z = ReadAngle();
 177     }
 178
 179     if(sf & ISF_SIZE)
 180     {
 181         float use_bigsize = ReadByte();
 182         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 183     }
 184
 185     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
 186     {
 187         this.ItemStatus = ReadByte();
 188
 189         Item_SetAlpha(this);
 190
 191         if(autocvar_cl_fullbright_items)
 192             if(this.ItemStatus & ITS_ALLOWFB)
 193                 this.effects |= EF_FULLBRIGHT;
 194
 195         if(this.ItemStatus & ITS_GLOW)
 196         {
 197             if(this.ItemStatus & ITS_AVAILABLE)
 198                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 199             else
 200                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 201         }
 202     }
 203
 204     if(sf & ISF_MODEL)
 205     {
 206         this.drawmask  = MASK_NORMAL;
 207                 set_movetype(this, MOVETYPE_TOSS);
 208                 if (isnew) IL_PUSH(g_drawables, this);
 209         this.draw       = ItemDraw;
 210         this.solid = SOLID_TRIGGER;
 211         //this.flags |= FL_ITEM;
 212
 213         bool use_bigsize = ReadByte();
 214
 215         this.fade_end = ReadShort();
 216         this.fade_start = ReadShort();
 217         if(this.fade_start && !autocvar_cl_items_nofade)
 218                 setpredraw(this, Item_PreDraw);
 219
 220         if(this.mdl)
 221             strunzone(this.mdl);
 222
 223         this.mdl = "";
 224         string _fn = ReadString();
 225
 226         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 227         {
 228             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 229             this.draw = ItemDrawSimple;
 230
 231             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
 232                 this.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
 233             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
 234                 this.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
 235             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
 236                 this.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
 237             else if(fexists(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix)))
 238                 this.mdl = strzone(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix));
 239             else
 240             {
 241                 this.draw = ItemDraw;
 242                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
 243             }
 244         }
 245
 246         if(this.draw != ItemDrawSimple)
 247             this.mdl = strzone(_fn);
 248
 249
 250         if(this.mdl == "")
 251             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
 252
 253         precache_model(this.mdl);
 254         _setmodel(this, this.mdl);
 255
 256         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 257     }
 258
 259     if(sf & ISF_COLORMAP)
 260     {
 261         this.colormap = ReadShort();
 262         this.item_glowmod_x = ReadByte() / 255.0;
 263         this.item_glowmod_y = ReadByte() / 255.0;
 264         this.item_glowmod_z = ReadByte() / 255.0;
 265     }
 266
 267     if(sf & ISF_DROP)
 268     {
 269         this.gravity = 1;
 270         this.pushable = true;
 271         //this.angles = '0 0 0';
 272         set_movetype(this, MOVETYPE_TOSS);
 273         this.velocity_x = ReadCoord();
 274         this.velocity_y = ReadCoord();
 275         this.velocity_z = ReadCoord();
 276         setorigin(this, this.oldorigin);
 277
 278         if(!this.move_time)
 279         {
 280             this.move_time = time;
 281             this.spawntime = time;
 282         }
 283         else
 284             this.move_time = max(this.move_time, time);
 285     }
 286
 287     if(autocvar_cl_animate_items)
 288     {
 289         if(this.ItemStatus & ITS_ANIMATE1)
 290             this.avelocity = '0 180 0';
 291
 292         if(this.ItemStatus & ITS_ANIMATE2)
 293             this.avelocity = '0 -90 0';
 294     }
 295
 296     this.entremove = ItemRemove;
 297
 298     return true;
 299 }
 300
 301 #endif
 302
 303 #ifdef SVQC
 304 bool ItemSend(entity this, entity to, int sf)
 305 {
 306         if(this.gravity)
 307                 sf |= ISF_DROP;
 308         else
 309                 sf &= ~ISF_DROP;
 310
 311         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 312         WriteByte(MSG_ENTITY, sf);
 313
 314         //WriteByte(MSG_ENTITY, this.cnt);
 315         if(sf & ISF_LOCATION)
 316         {
 317                 WriteCoord(MSG_ENTITY, this.origin.x);
 318                 WriteCoord(MSG_ENTITY, this.origin.y);
 319                 WriteCoord(MSG_ENTITY, this.origin.z);
 320         }
 321
 322         if(sf & ISF_ANGLES)
 323         {
 324                 WriteAngle(MSG_ENTITY, this.angles_x);
 325                 WriteAngle(MSG_ENTITY, this.angles_y);
 326                 WriteAngle(MSG_ENTITY, this.angles_z);
 327         }
 328
 329         if(sf & ISF_SIZE)
 330         {
 331                 Pickup p = this.itemdef;
 332                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 333         }
 334
 335         if(sf & ISF_STATUS)
 336                 WriteByte(MSG_ENTITY, this.ItemStatus);
 337
 338         if(sf & ISF_MODEL)
 339         {
 340                 Pickup p = this.itemdef;
 341                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 342                 WriteShort(MSG_ENTITY, this.fade_end);
 343                 WriteShort(MSG_ENTITY, this.fade_start);
 344
 345                 if(this.mdl == "")
 346                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 347
 348                 WriteString(MSG_ENTITY, this.mdl);
 349         }
 350
 351
 352         if(sf & ISF_COLORMAP)
 353         {
 354                 WriteShort(MSG_ENTITY, this.colormap);
 355                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 356         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 357         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 358         }
 359
 360         if(sf & ISF_DROP)
 361         {
 362                 WriteCoord(MSG_ENTITY, this.velocity.x);
 363                 WriteCoord(MSG_ENTITY, this.velocity.y);
 364                 WriteCoord(MSG_ENTITY, this.velocity.z);
 365         }
 366
 367         return true;
 368 }
 369
 370 void ItemUpdate(entity this)
 371 {
 372         this.oldorigin = this.origin;
 373         this.SendFlags |= ISF_LOCATION;
 374 }
 375
 376 void UpdateItemAfterTeleport(entity this)
 377 {
 378         if(getSendEntity(this) == ItemSend)
 379                 ItemUpdate(this);
 380 }
 381
 382 bool have_pickup_item(entity this)
 383 {
 384         if(this.itemdef.instanceOfPowerup)
 385         {
 386                 if(autocvar_g_powerups > 0)
 387                         return true;
 388                 if(autocvar_g_powerups == 0)
 389                         return false;
 390         }
 391         else
 392         {
 393                 if(autocvar_g_pickup_items > 0)
 394                         return true;
 395                 if(autocvar_g_pickup_items == 0)
 396                         return false;
 397                 if(g_weaponarena)
 398                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 399                                 return false;
 400         }
 401         return true;
 402 }
 403
 404 /*
 405 float Item_Customize()
 406 {
 407         if(this.spawnshieldtime)
 408                 return true;
 409         if(this.weapons & ~other.weapons)
 410         {
 411                 this.colormod = '0 0 0';
 412                 this.glowmod = this.colormod;
 413                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 414                 return true;
 415         }
 416         else
 417         {
 418                 if(g_ghost_items)
 419                 {
 420                         this.colormod = stov(autocvar_g_ghost_items_color);
 421                         this.glowmod = this.colormod;
 422                         this.alpha = g_ghost_items;
 423                         return true;
 424                 }
 425                 else
 426                         return false;
 427         }
 428 }
 429 */
 430
 431 void Item_Show (entity e, float mode)
 432 {
 433         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 434         e.ItemStatus &= ~ITS_STAYWEP;
 435         entity def = e.itemdef;
 436         if (mode > 0)
 437         {
 438                 // make the item look normal, and be touchable
 439                 e.model = e.mdl;
 440                 e.solid = SOLID_TRIGGER;
 441                 e.spawnshieldtime = 1;
 442                 e.ItemStatus |= ITS_AVAILABLE;
 443         }
 444         else if (mode < 0)
 445         {
 446                 // hide the item completely
 447                 e.model = string_null;
 448                 e.solid = SOLID_NOT;
 449                 e.spawnshieldtime = 1;
 450                 e.ItemStatus &= ~ITS_AVAILABLE;
 451         }
 452         else {
 453         bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 454                 || e.team // weapon stay isn't supported for teamed weapons
 455                 ;
 456         if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 457         {
 458                 // make the item translucent and not touchable
 459                 e.model = e.mdl;
 460                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 461                 e.effects |= EF_STARDUST;
 462                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 463                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 464         }
 465         else
 466         {
 467                 //setmodel(e, "null");
 468                 e.solid = SOLID_NOT;
 469                 e.colormod = '0 0 0';
 470                 //e.glowmod = e.colormod;
 471                 e.spawnshieldtime = 1;
 472                 e.ItemStatus &= ~ITS_AVAILABLE;
 473         }}
 474
 475         if (def.m_glow)
 476                 e.ItemStatus |= ITS_GLOW;
 477
 478         if (autocvar_g_nodepthtestitems)
 479                 e.effects |= EF_NODEPTHTEST;
 480
 481
 482         if (autocvar_g_fullbrightitems)
 483                 e.ItemStatus |= ITS_ALLOWFB;
 484
 485         if (autocvar_sv_simple_items)
 486                 e.ItemStatus |= ITS_ALLOWSI;
 487
 488         // relink entity (because solid may have changed)
 489         setorigin(e, e.origin);
 490         e.SendFlags |= ISF_STATUS;
 491 }
 492
 493 void Item_Think(entity this)
 494 {
 495         this.nextthink = time;
 496         if(this.origin != this.oldorigin)
 497                 ItemUpdate(this);
 498 }
 499
 500 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 501 bool Item_ItemsTime_Allow(GameItem it);
 502 float Item_ItemsTime_UpdateTime(entity e, float t);
 503 void Item_ItemsTime_SetTime(entity e, float t);
 504 void Item_ItemsTime_SetTimesForAllPlayers();
 505
 506 void Item_Respawn (entity this)
 507 {
 508         Item_Show(this, 1);
 509         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 510         setorigin(this, this.origin);
 511
 512     if (Item_ItemsTime_Allow(this.itemdef) || (this.weapons & WEPSET_SUPERWEAPONS))
 513         {
 514                 float t = Item_ItemsTime_UpdateTime(this, 0);
 515                 Item_ItemsTime_SetTime(this, t);
 516                 Item_ItemsTime_SetTimesForAllPlayers();
 517         }
 518
 519         setthink(this, Item_Think);
 520         this.nextthink = time;
 521
 522         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 523         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 524 }
 525
 526 void Item_RespawnCountdown (entity this)
 527 {
 528         if(this.count >= ITEM_RESPAWN_TICKS)
 529         {
 530                 if(this.waypointsprite_attached)
 531                         WaypointSprite_Kill(this.waypointsprite_attached);
 532                 Item_Respawn(this);
 533         }
 534         else
 535         {
 536                 this.nextthink = time + 1;
 537                 this.count += 1;
 538                 if(this.count == 1)
 539                 {
 540                         do {
 541                                 {
 542                                         entity wi = Weapons_from(this.weapon);
 543                                         if (wi != WEP_Null) {
 544                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 545                                                 wp.wp_extra = wi.m_id;
 546                                                 break;
 547                                         }
 548                                 }
 549                                 {
 550                                         entity ii = this.itemdef;
 551                                         if (ii != NULL) {
 552                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 553                                                 wp.wp_extra = ii.m_id;
 554                                                 break;
 555                                         }
 556                                 }
 557                         } while (0);
 558                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
 559             if(this.waypointsprite_attached)
 560             {
 561                 GameItem def = this.itemdef;
 562                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
 563                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 564                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 565             }
 566                 }
 567
 568                 if(this.waypointsprite_attached)
 569                 {
 570                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 571                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 572                                 {
 573                                         msg_entity = it;
 574                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 575                                 }
 576                         });
 577
 578                         WaypointSprite_Ping(this.waypointsprite_attached);
 579                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.count);
 580                 }
 581         }
 582 }
 583
 584 void Item_RespawnThink(entity this)
 585 {
 586         this.nextthink = time;
 587         if(this.origin != this.oldorigin)
 588                 ItemUpdate(this);
 589
 590         if(time >= this.wait)
 591                 Item_Respawn(this);
 592 }
 593
 594 void Item_ScheduleRespawnIn(entity e, float t)
 595 {
 596         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 597         if ((Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
 598         {
 599                 setthink(e, Item_RespawnCountdown);
 600                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 601                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 602                 e.count = 0;
 603                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 604                 {
 605                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 606                         Item_ItemsTime_SetTime(e, t);
 607                         Item_ItemsTime_SetTimesForAllPlayers();
 608                 }
 609         }
 610         else
 611         {
 612                 setthink(e, Item_RespawnThink);
 613                 e.nextthink = time;
 614                 e.scheduledrespawntime = time + t;
 615                 e.wait = time + t;
 616
 617                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 618                 {
 619                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 620                         Item_ItemsTime_SetTime(e, t);
 621                         Item_ItemsTime_SetTimesForAllPlayers();
 622                 }
 623         }
 624 }
 625
 626 void Item_ScheduleRespawn(entity e)
 627 {
 628         if(e.respawntime > 0)
 629         {
 630                 Item_Show(e, 0);
 631                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 632         }
 633         else // if respawntime is -1, this item does not respawn
 634                 Item_Show(e, -1);
 635 }
 636
 637 void Item_ScheduleInitialRespawn(entity e)
 638 {
 639         Item_Show(e, 0);
 640         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
 641 }
 642
 643 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 644 {
 645         if (!item.(ammotype))
 646                 return false;
 647
 648         if (item.spawnshieldtime)
 649         {
 650                 if ((player.(ammotype) < ammomax) || item.pickup_anyway > 0)
 651                 {
 652                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 653                         goto YEAH;
 654                 }
 655         }
 656         else if(g_weapon_stay == 2)
 657         {
 658                 float mi = min(item.(ammotype), ammomax);
 659                 if (player.(ammotype) < mi)
 660                 {
 661                         player.(ammotype) = mi;
 662                         goto YEAH;
 663                 }
 664         }
 665
 666         return false;
 667
 668 LABEL(YEAH)
 669         switch(mode)
 670         {
 671                 case ITEM_MODE_FUEL:
 672                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 673                         break;
 674                 case ITEM_MODE_HEALTH:
 675                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 676                         break;
 677                 case ITEM_MODE_ARMOR:
 678                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 679                         break;
 680                 default:
 681                         break;
 682         }
 683         return true;
 684 }
 685
 686 float Item_GiveTo(entity item, entity player)
 687 {
 688         float pickedup;
 689
 690         // if nothing happens to player, just return without taking the item
 691         pickedup = false;
 692         int _switchweapon = 0;
 693         // in case the player has autoswitch enabled do the following:
 694         // if the player is using their best weapon before items are given, they
 695         // probably want to switch to an even better weapon after items are given
 696
 697         if(player.autoswitch)
 698         {
 699                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 700                 {
 701                         .entity weaponentity = weaponentities[slot];
 702                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 703                         {
 704                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 705                                         _switchweapon |= BIT(slot);
 706
 707                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 708                                         _switchweapon |= BIT(slot);
 709                         }
 710                 }
 711         }
 712
 713         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 714         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 715         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 716         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 717         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 718         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 719         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 720         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 721
 722         if (item.itemdef.instanceOfWeaponPickup)
 723         {
 724                 WepSet w;
 725                 w = item.weapons;
 726                 w &= ~player.weapons;
 727
 728                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 729                 {
 730                         pickedup = true;
 731                         FOREACH(Weapons, it != WEP_Null, {
 732                                 if(w & (it.m_wepset))
 733                                 {
 734                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 735                                         {
 736                                                 .entity weaponentity = weaponentities[slot];
 737                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 738                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 739                                         }
 740                                         W_GiveWeapon(player, it.m_id);
 741                                 }
 742                         });
 743                 }
 744         }
 745
 746         if (item.itemdef.instanceOfPowerup)
 747         {
 748                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 749                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 750                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 751                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 752         }
 753
 754         int its;
 755         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 756         {
 757                 pickedup = true;
 758                 player.items |= its;
 759                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 760         }
 761
 762         if (item.strength_finished)
 763         {
 764                 pickedup = true;
 765                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 766         }
 767         if (item.invincible_finished)
 768         {
 769                 pickedup = true;
 770                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 771         }
 772         if (item.superweapons_finished)
 773         {
 774                 pickedup = true;
 775                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 776         }
 777
 778 LABEL(skip)
 779
 780         // always eat teamed entities
 781         if(item.team)
 782                 pickedup = true;
 783
 784         if (!pickedup)
 785                 return 0;
 786
 787         // crude hack to enforce switching weapons
 788         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 789         {
 790                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 791                 {
 792                         .entity weaponentity = weaponentities[slot];
 793                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 794                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 795                 }
 796                 return 1;
 797         }
 798
 799         if(_switchweapon)
 800         {
 801                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 802                 {
 803                         .entity weaponentity = weaponentities[slot];
 804                         if(_switchweapon & BIT(slot))
 805                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 806                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 807                 }
 808         }
 809
 810         return 1;
 811 }
 812
 813 void Item_Touch(entity this, entity toucher)
 814 {
 815
 816         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 817         if (this.classname == "droppedweapon")
 818         {
 819                 if (ITEM_TOUCH_NEEDKILL())
 820                 {
 821                         delete(this);
 822                         return;
 823                 }
 824         }
 825
 826         if(!(toucher.flags & FL_PICKUPITEMS)
 827         || STAT(FROZEN, toucher)
 828         || IS_DEAD(toucher)
 829         || (this.solid != SOLID_TRIGGER)
 830         || (this.owner == toucher)
 831         || (time < this.item_spawnshieldtime)
 832         ) { return; }
 833
 834         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 835         {
 836                 case MUT_ITEMTOUCH_RETURN: { return; }
 837                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 838         }
 839
 840         toucher = M_ARGV(1, entity);
 841
 842         if (this.classname == "droppedweapon")
 843         {
 844                 this.strength_finished = max(0, this.strength_finished - time);
 845                 this.invincible_finished = max(0, this.invincible_finished - time);
 846                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 847         }
 848         entity it = this.itemdef;
 849         bool gave = ITEM_HANDLE(Pickup, it, this, toucher);
 850         if (!gave)
 851         {
 852                 if (this.classname == "droppedweapon")
 853                 {
 854                         // undo what we did above
 855                         this.strength_finished += time;
 856                         this.invincible_finished += time;
 857                         this.superweapons_finished += time;
 858                 }
 859                 return;
 860         }
 861
 862 LABEL(pickup)
 863
 864         toucher.last_pickup = time;
 865
 866         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 867         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 868
 869         if (this.classname == "droppedweapon")
 870                 delete (this);
 871         else if (this.spawnshieldtime)
 872         {
 873                 entity e;
 874                 if(this.team)
 875                 {
 876                         RandomSelection_Init();
 877                         IL_EACH(g_items, it.team == this.team,
 878                         {
 879                                 if(it.itemdef) // is a registered item
 880                                 {
 881                                         Item_Show(it, -1);
 882                                         RandomSelection_AddEnt(it, it.cnt, 0);
 883                                 }
 884                         });
 885                         e = RandomSelection_chosen_ent;
 886                         Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
 887                 }
 888                 else
 889                         e = this;
 890                 Item_ScheduleRespawn(e);
 891         }
 892 }
 893
 894 void Item_Reset(entity this)
 895 {
 896         Item_Show(this, !this.state);
 897         setorigin(this, this.origin);
 898
 899         if (this.classname != "droppedweapon")
 900         {
 901                 setthink(this, Item_Think);
 902                 this.nextthink = time;
 903
 904                 if (this.waypointsprite_attached)
 905                         WaypointSprite_Kill(this.waypointsprite_attached);
 906
 907                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 908                         Item_ScheduleInitialRespawn(this);
 909         }
 910 }
 911
 912 void Item_FindTeam(entity this)
 913 {
 914         entity e;
 915
 916         if(this.effects & EF_NODRAW)
 917         {
 918                 // marker for item team search
 919                 LOG_TRACE("Initializing item team ", ftos(this.team));
 920                 RandomSelection_Init();
 921                 IL_EACH(g_items, it.team == this.team,
 922                 {
 923                         if(it.itemdef) // is a registered item
 924                                 RandomSelection_AddEnt(it, it.cnt, 0);
 925                 });
 926
 927                 e = RandomSelection_chosen_ent;
 928                 e.state = 0;
 929                 Item_Show(e, 1);
 930
 931                 IL_EACH(g_items, it.team == this.team,
 932                 {
 933                         if(it.itemdef) // is a registered item
 934                         {
 935                                 if(it != e)
 936                                 {
 937                                         // make it non-spawned
 938                                         Item_Show(it, -1);
 939                                         it.state = 1; // state 1 = initially hidden item, apparently
 940                                 }
 941                                 it.effects &= ~EF_NODRAW;
 942                         }
 943                 });
 944
 945                 Item_Reset(this);
 946         }
 947 }
 948
 949 // Savage: used for item garbage-collection
 950 void RemoveItem(entity this)
 951 {
 952         if(wasfreed(this) || !this) { return; }
 953         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 954         delete(this);
 955 }
 956
 957 // pickup evaluation functions
 958 // these functions decide how desirable an item is to the bots
 959
 960 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 961
 962 float weapon_pickupevalfunc(entity player, entity item)
 963 {
 964         // See if I have it already
 965         if(player.weapons & item.weapons)
 966         {
 967                 // If I can pick it up
 968                 if(!item.spawnshieldtime)
 969                         return 0;
 970                 return ammo_pickupevalfunc(player, item);
 971         }
 972
 973         // reduce weapon value if bot already got a good arsenal
 974         float c = 1;
 975         int weapons_value = 0;
 976         FOREACH(Weapons, it != WEP_Null && (player.weapons & it.m_wepset), {
 977                 weapons_value += it.bot_pickupbasevalue;
 978         });
 979         c -= bound(0, weapons_value / 20000, 1) * 0.5;
 980
 981         return item.bot_pickupbasevalue * c;
 982 }
 983
 984 float ammo_pickupevalfunc(entity player, entity item)
 985 {
 986         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
 987         entity wpn = NULL;
 988         float c = 0;
 989         float rating = 0;
 990
 991         // Detect needed ammo
 992         if(item.itemdef.instanceOfWeaponPickup)
 993         {
 994                 entity ammo = NULL;
 995                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
 996                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
 997                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
 998                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
 999                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
1000                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1001
1002                 if(!ammo)
1003                         return 0;
1004                 wpn = item;
1005                 rating = ammo.m_botvalue;
1006         }
1007         else
1008         {
1009                 FOREACH(Weapons, it != WEP_Null, {
1010                         if(!(player.weapons & (it.m_wepset)))
1011                                 continue;
1012
1013                         switch(it.ammo_field)
1014                         {
1015                                 case ammo_shells:  need_shells  = true; break;
1016                                 case ammo_shells:  need_shells  = true; break;
1017                                 case ammo_nails:   need_nails   = true; break;
1018                                 case ammo_rockets: need_rockets = true; break;
1019                                 case ammo_cells:   need_cells   = true; break;
1020                                 case ammo_plasma:  need_plasma  = true; break;
1021                                 case ammo_fuel:    need_fuel    = true; break;
1022                         }
1023                 });
1024                 rating = item.bot_pickupbasevalue;
1025         }
1026
1027         if (need_shells)
1028         if (item.ammo_shells)
1029         if (player.ammo_shells < g_pickup_shells_max)
1030                 c = item.ammo_shells / player.ammo_shells;
1031         if (need_nails)
1032         if (item.ammo_nails)
1033         if (player.ammo_nails < g_pickup_nails_max)
1034                 c = item.ammo_nails / player.ammo_nails;
1035         if (need_rockets)
1036         if (item.ammo_rockets)
1037         if (player.ammo_rockets < g_pickup_rockets_max)
1038                 c = item.ammo_rockets / player.ammo_rockets;
1039         if (need_cells)
1040         if (item.ammo_cells)
1041         if (player.ammo_cells < g_pickup_cells_max)
1042                 c = item.ammo_cells / player.ammo_cells;
1043         if (need_plasma)
1044         if (item.ammo_plasma)
1045         if (player.ammo_plasma < g_pickup_plasma_max)
1046                 c = item.ammo_plasma / player.ammo_plasma;
1047         if (need_fuel)
1048         if (item.ammo_fuel)
1049         if (player.ammo_fuel < g_pickup_fuel_max)
1050                 c = item.ammo_fuel / player.ammo_fuel;
1051
1052         rating *= min(2, c);
1053         if(wpn)
1054                 rating += wpn.bot_pickupbasevalue * 0.1;
1055         return rating;
1056 }
1057
1058 .int item_group;
1059 .int item_group_count;
1060 float healtharmor_pickupevalfunc(entity player, entity item)
1061 {
1062         float c = 0;
1063         float rating = item.bot_pickupbasevalue;
1064
1065         float itemarmor = item.armorvalue;
1066         float itemhealth = item.health;
1067         if(item.item_group)
1068         {
1069                 itemarmor *= min(4, item.item_group_count);
1070                 itemhealth *= min(4, item.item_group_count);
1071         }
1072         if (itemarmor)
1073         if (player.armorvalue < item.max_armorvalue)
1074                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1075         if (itemhealth)
1076         if (player.health < item.max_health)
1077                 c = itemhealth / max(1, player.health);
1078
1079         rating *= min(2, c);
1080         return rating;
1081 }
1082
1083 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1084 {
1085         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1086                 RemoveItem(this);
1087 }
1088
1089 void item_use(entity this, entity actor, entity trigger)
1090 {
1091         // use the touch function to handle collection
1092         gettouch(this)(this, actor);
1093 }
1094
1095 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1096 {
1097         string itemname = def.m_name;
1098         Model itemmodel = def.m_model;
1099     Sound pickupsound = def.m_sound;
1100         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1101         float pickupbasevalue = def.m_botvalue;
1102         int itemflags = def.m_itemflags;
1103
1104         startitem_failed = false;
1105
1106         this.item_model_ent = itemmodel;
1107     this.item_pickupsound_ent = pickupsound;
1108
1109     if(def.m_iteminit)
1110         def.m_iteminit(this);
1111
1112         if(!this.respawntime) // both need to be set
1113         {
1114                 this.respawntime = defaultrespawntime;
1115                 this.respawntimejitter = defaultrespawntimejitter;
1116         }
1117
1118         if(!this.pickup_anyway && def.m_pickupanyway)
1119                 this.pickup_anyway = def.m_pickupanyway();
1120
1121         int itemid = def.m_itemid;
1122         this.items = itemid;
1123         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1124         this.weapon = weaponid;
1125
1126         if(!this.fade_end)
1127         {
1128                 this.fade_start = autocvar_g_items_mindist;
1129                 this.fade_end = autocvar_g_items_maxdist;
1130         }
1131
1132         if(weaponid)
1133                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1134
1135         this.flags = FL_ITEM | itemflags;
1136         IL_PUSH(g_items, this);
1137
1138         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1139         {
1140                 startitem_failed = true;
1141                 delete(this);
1142                 return;
1143         }
1144
1145         // is it a dropped weapon?
1146         if (this.classname == "droppedweapon")
1147         {
1148                 this.reset = SUB_Remove;
1149                 // it's a dropped weapon
1150                 set_movetype(this, MOVETYPE_TOSS);
1151
1152                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1153                 setthink(this, RemoveItem);
1154                 this.nextthink = time + 20;
1155
1156                 this.takedamage = DAMAGE_YES;
1157                 this.event_damage = Item_Damage;
1158
1159                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1160                 {
1161                         // if item is worthless after a timer, have it expire then
1162                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1163                 }
1164
1165                 // don't drop if in a NODROP zone (such as lava)
1166                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1167                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1168                 {
1169                         startitem_failed = true;
1170                         delete(this);
1171                         return;
1172                 }
1173         }
1174         else
1175         {
1176                 if(!have_pickup_item(this))
1177                 {
1178                         startitem_failed = true;
1179                         delete (this);
1180                         return;
1181                 }
1182
1183                 if(this.angles != '0 0 0')
1184                         this.SendFlags |= ISF_ANGLES;
1185
1186                 this.reset = Item_Reset;
1187                 // it's a level item
1188                 if(this.spawnflags & 1)
1189                         this.noalign = 1;
1190                 if (this.noalign > 0)
1191                         set_movetype(this, MOVETYPE_NONE);
1192                 else
1193                         set_movetype(this, MOVETYPE_TOSS);
1194                 // do item filtering according to game mode and other things
1195                 if (this.noalign <= 0)
1196                 {
1197                         // first nudge it off the floor a little bit to avoid math errors
1198                         setorigin(this, this.origin + '0 0 1');
1199                         // set item size before we spawn a spawnfunc_waypoint
1200                         setsize(this, def.m_mins, def.m_maxs);
1201                         this.SendFlags |= ISF_SIZE;
1202                         // note droptofloor returns false if stuck/or would fall too far
1203                         if (!this.noalign)
1204                                 droptofloor(this);
1205                         waypoint_spawnforitem(this);
1206                 }
1207
1208                 /*
1209                  * can't do it that way, as it would break maps
1210                  * TODO make a target_give like entity another way, that perhaps has
1211                  * the weapon name in a key
1212                 if(this.targetname)
1213                 {
1214                         // target_give not yet supported; maybe later
1215                         print("removed targeted ", this.classname, "\n");
1216                         startitem_failed = true;
1217                         remove (this);
1218                         return;
1219                 }
1220                 */
1221
1222                 if(this.targetname != "" && (this.spawnflags & 16))
1223                         this.use = item_use;
1224
1225                 if(autocvar_spawn_debug >= 2)
1226                 {
1227             // why not flags & fl_item?
1228                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1229                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1230                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1231                 error("Mapper sucks.");
1232             });
1233                         this.is_item = true;
1234                 }
1235
1236                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1237
1238                 precache_model(this.model);
1239                 precache_sound(this.item_pickupsound);
1240
1241                 if (   def.instanceOfPowerup
1242                         || def.instanceOfWeaponPickup
1243                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1244                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1245                         || (itemid & (IT_KEY1 | IT_KEY2))
1246                 ) this.target = "###item###"; // for finding the nearest item using find()
1247
1248                 Item_ItemsTime_SetTime(this, 0);
1249         }
1250
1251         this.bot_pickup = true;
1252         this.bot_pickupevalfunc = pickupevalfunc;
1253         this.bot_pickupbasevalue = pickupbasevalue;
1254         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1255         this.netname = itemname;
1256         settouch(this, Item_Touch);
1257         setmodel(this, MDL_Null); // precision set below
1258         //this.effects |= EF_LOWPRECISION;
1259
1260         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1261
1262         this.SendFlags |= ISF_SIZE;
1263
1264         if (!(this.spawnflags & 1024)) {
1265                 if(def.instanceOfPowerup)
1266                         this.ItemStatus |= ITS_ANIMATE1;
1267
1268                 if(this.armorvalue || this.health)
1269                         this.ItemStatus |= ITS_ANIMATE2;
1270         }
1271
1272         if(def.instanceOfWeaponPickup)
1273         {
1274                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1275                         this.colormap = 1024; // color shirt=0 pants=0 grey
1276                 else
1277                         this.gravity = 1;
1278                 if (!(this.spawnflags & 1024))
1279                         this.ItemStatus |= ITS_ANIMATE1;
1280                 this.SendFlags |= ISF_COLORMAP;
1281         }
1282
1283         this.state = 0;
1284         if(this.team) // broken, no idea why.
1285         {
1286                 if(!this.cnt)
1287                         this.cnt = 1; // item probability weight
1288
1289                 this.effects |= EF_NODRAW; // marker for item team search
1290                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1291         }
1292         else
1293                 Item_Reset(this);
1294
1295         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1296
1297         // call this hook after everything else has been done
1298         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1299         {
1300                 startitem_failed = true;
1301                 delete(this);
1302                 return;
1303         }
1304
1305         setItemGroup(this);
1306 }
1307
1308 void StartItem(entity this, GameItem def)
1309 {
1310     _StartItem(
1311         this,
1312         this.itemdef = def,
1313         def.m_respawntime(), // defaultrespawntime
1314         def.m_respawntimejitter() // defaultrespawntimejitter
1315         );
1316 }
1317
1318 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1319 int group_count = 1;
1320
1321 void setItemGroup(entity this)
1322 {
1323         if(!IS_SMALL(this.itemdef))
1324                 return;
1325
1326         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1327         {
1328                 if(!this.item_group)
1329                 {
1330                         if(!it.item_group)
1331                         {
1332                                 it.item_group = group_count;
1333                                 group_count++;
1334                         }
1335                         this.item_group = it.item_group;
1336                 }
1337                 else // spawning item is already part of a item_group X
1338                 {
1339                         if(!it.item_group)
1340                                 it.item_group = this.item_group;
1341                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1342                         {
1343                                 int grY = it.item_group;
1344                                 // move all items of item_group Y to item_group X
1345                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1346                                 {
1347                                         if(it.item_group == grY)
1348                                                 it.item_group = this.item_group;
1349                                 });
1350                         }
1351                 }
1352         });
1353 }
1354
1355 void setItemGroupCount()
1356 {
1357         for (int k = 1; k <= group_count; k++)
1358         {
1359                 int count = 0;
1360                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1361                 if (count)
1362                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1363         }
1364 }
1365
1366 spawnfunc(item_rockets)
1367 {
1368     StartItem(this, ITEM_Rockets);
1369 }
1370
1371 spawnfunc(item_bullets)
1372 {
1373         if(!weaponswapping)
1374         if(autocvar_sv_q3acompat_machineshotgunswap)
1375         if(this.classname != "droppedweapon")
1376         {
1377                 weaponswapping = true;
1378                 spawnfunc_item_shells(this);
1379                 weaponswapping = false;
1380                 return;
1381         }
1382
1383     StartItem(this, ITEM_Bullets);
1384 }
1385
1386 spawnfunc(item_cells)
1387 {
1388         StartItem(this, ITEM_Cells);
1389 }
1390
1391 spawnfunc(item_plasma)
1392 {
1393         StartItem(this, ITEM_Plasma);
1394 }
1395
1396 spawnfunc(item_shells)
1397 {
1398         if(!weaponswapping)
1399         if(autocvar_sv_q3acompat_machineshotgunswap)
1400         if(this.classname != "droppedweapon")
1401         {
1402                 weaponswapping = true;
1403                 spawnfunc_item_bullets(this);
1404                 weaponswapping = false;
1405                 return;
1406         }
1407
1408         StartItem(this, ITEM_Shells);
1409 }
1410
1411 spawnfunc(item_armor_small)
1412 {
1413         StartItem(this, ITEM_ArmorSmall);
1414 }
1415
1416 spawnfunc(item_armor_medium)
1417 {
1418         StartItem(this, ITEM_ArmorMedium);
1419 }
1420
1421 spawnfunc(item_armor_big)
1422 {
1423         StartItem(this, ITEM_ArmorBig);
1424 }
1425
1426 spawnfunc(item_armor_mega)
1427 {
1428         StartItem(this, ITEM_ArmorMega);
1429 }
1430
1431 spawnfunc(item_health_small)
1432 {
1433         StartItem(this, ITEM_HealthSmall);
1434 }
1435
1436 spawnfunc(item_health_medium)
1437 {
1438     StartItem(this, ITEM_HealthMedium);
1439 }
1440
1441 spawnfunc(item_health_big)
1442 {
1443         StartItem(this, ITEM_HealthBig);
1444 }
1445
1446 spawnfunc(item_health_mega)
1447 {
1448     StartItem(this, ITEM_HealthMega);
1449 }
1450
1451 // support old misnamed entities
1452 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1453 spawnfunc(item_armor25) { spawnfunc_item_armor_mega(this); }
1454 spawnfunc(item_armor_large) { spawnfunc_item_armor_mega(this); }
1455 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1456 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1457 spawnfunc(item_health_large) { spawnfunc_item_health_big(this); }
1458 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1459
1460 spawnfunc(item_strength)
1461 {
1462         StartItem(this, ITEM_Strength);
1463 }
1464
1465 spawnfunc(item_invincible)
1466 {
1467         StartItem(this, ITEM_Shield);
1468 }
1469
1470 // compatibility:
1471 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1472
1473 void target_items_use(entity this, entity actor, entity trigger)
1474 {
1475         if(actor.classname == "droppedweapon")
1476         {
1477                 EXACTTRIGGER_TOUCH(this, trigger);
1478                 delete(actor);
1479                 return;
1480         }
1481
1482         if (!IS_PLAYER(actor))
1483                 return;
1484         if(IS_DEAD(actor))
1485                 return;
1486         if(trigger.solid == SOLID_TRIGGER)
1487         {
1488                 EXACTTRIGGER_TOUCH(this, trigger);
1489         }
1490
1491         IL_EACH(g_items, it.enemy == actor && it.classname == "droppedweapon",
1492         {
1493                 delete(it);
1494         });
1495
1496         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1497                 centerprint(actor, this.message);
1498 }
1499
1500 spawnfunc(target_items)
1501 {
1502         int n, j;
1503         string s;
1504
1505         this.use = target_items_use;
1506         if(!this.strength_finished)
1507                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1508         if(!this.invincible_finished)
1509                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1510         if(!this.superweapons_finished)
1511                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1512
1513         n = tokenize_console(this.netname);
1514         if(argv(0) == "give")
1515         {
1516                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1517         }
1518         else
1519         {
1520                 for(j = 0; j < n; ++j)
1521                 {
1522                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1523                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1524                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1525                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1526                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1527                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1528                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1529                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1530                         else
1531                         {
1532                                 FOREACH(Buffs, it != BUFF_Null,
1533                                 {
1534                                         s = Buff_UndeprecateName(argv(j));
1535                                         if(s == it.m_name)
1536                                         {
1537                                                 this.buffs |= (it.m_itemid);
1538                                                 break;
1539                                         }
1540                                 });
1541                                 FOREACH(Weapons, it != WEP_Null, {
1542                                         s = W_UndeprecateName(argv(j));
1543                                         if(s == it.netname)
1544                                         {
1545                                                 this.weapons |= (it.m_wepset);
1546                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1547                                                         it.wr_init(it);
1548                                                 break;
1549                                         }
1550                                 });
1551                         }
1552                 }
1553
1554                 string itemprefix, valueprefix;
1555                 if(this.spawnflags == 0)
1556                 {
1557                         itemprefix = "";
1558                         valueprefix = "";
1559                 }
1560                 else if(this.spawnflags == 1)
1561                 {
1562                         itemprefix = "max ";
1563                         valueprefix = "max ";
1564                 }
1565                 else if(this.spawnflags == 2)
1566                 {
1567                         itemprefix = "min ";
1568                         valueprefix = "min ";
1569                 }
1570                 else if(this.spawnflags == 4)
1571                 {
1572                         itemprefix = "minus ";
1573                         valueprefix = "max ";
1574                 }
1575                 else
1576                 {
1577                         error("invalid spawnflags");
1578                         itemprefix = valueprefix = string_null;
1579                 }
1580
1581                 this.netname = "";
1582                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1583                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1584                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1585                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1586                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1587                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1588                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1589                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1590                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1591                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1592                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1593                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1594                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1595                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1596                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1597                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.buffs & (it.m_itemid)), it.m_name));
1598                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1599         }
1600         this.netname = strzone(this.netname);
1601         //print(this.netname, "\n");
1602
1603         n = tokenize_console(this.netname);
1604         for(j = 0; j < n; ++j)
1605         {
1606                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1607             it.wr_init(it);
1608             break;
1609                 });
1610         }
1611 }
1612
1613 spawnfunc(item_fuel)
1614 {
1615         StartItem(this, ITEM_JetpackFuel);
1616 }
1617
1618 spawnfunc(item_fuel_regen)
1619 {
1620         if(start_items & ITEM_JetpackRegen.m_itemid)
1621         {
1622                 spawnfunc_item_fuel(this);
1623                 return;
1624         }
1625         StartItem(this, ITEM_JetpackRegen);
1626 }
1627
1628 spawnfunc(item_jetpack)
1629 {
1630         if(start_items & ITEM_Jetpack.m_itemid)
1631         {
1632                 spawnfunc_item_fuel(this);
1633                 return;
1634         }
1635         StartItem(this, ITEM_Jetpack);
1636 }
1637
1638 float GiveWeapon(entity e, float wpn, float op, float val)
1639 {
1640         WepSet v0, v1;
1641         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1642         v0 = (e.weapons & s);
1643         switch(op)
1644         {
1645                 case OP_SET:
1646                         if(val > 0)
1647                                 e.weapons |= s;
1648                         else
1649                                 e.weapons &= ~s;
1650                         break;
1651                 case OP_MIN:
1652                 case OP_PLUS:
1653                         if(val > 0)
1654                                 e.weapons |= s;
1655                         break;
1656                 case OP_MAX:
1657                         if(val <= 0)
1658                                 e.weapons &= ~s;
1659                         break;
1660                 case OP_MINUS:
1661                         if(val > 0)
1662                                 e.weapons &= ~s;
1663                         break;
1664         }
1665         v1 = (e.weapons & s);
1666         return (v0 != v1);
1667 }
1668
1669 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1670 {
1671         bool had_buff = (e.buffs & thebuff.m_itemid);
1672         switch(op)
1673         {
1674                 case OP_SET:
1675                         if(val > 0)
1676                                 e.buffs |= thebuff.m_itemid;
1677                         else
1678                                 e.buffs &= ~thebuff.m_itemid;
1679                         break;
1680                 case OP_MIN:
1681                 case OP_PLUS:
1682                         if(val > 0)
1683                                 e.buffs |= thebuff.m_itemid;
1684                         break;
1685                 case OP_MAX:
1686                         if(val <= 0)
1687                                 e.buffs &= ~thebuff.m_itemid;
1688                         break;
1689                 case OP_MINUS:
1690                         if(val > 0)
1691                                 e.buffs &= ~thebuff.m_itemid;
1692                         break;
1693         }
1694         bool have_buff = (e.buffs & thebuff.m_itemid);
1695         return (had_buff != have_buff);
1696 }
1697
1698 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1699 {
1700         if(v1 == v0)
1701                 return;
1702         if(v1 <= v0 - t)
1703         {
1704                 if(snd_decr != NULL)
1705                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1706         }
1707         else if(v0 >= v0 + t)
1708         {
1709                 if(snd_incr != NULL)
1710                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1711         }
1712 }
1713
1714 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1715 {
1716         if(v0 < v1)
1717                 e.(rotfield) = max(e.(rotfield), time + rottime);
1718         else if(v0 > v1)
1719                 e.(regenfield) = max(e.(regenfield), time + regentime);
1720 }
1721 float GiveItems(entity e, float beginarg, float endarg)
1722 {
1723         float got, i, val, op;
1724         string cmd;
1725
1726         val = 999;
1727         op = OP_SET;
1728
1729         got = 0;
1730
1731         int _switchweapon = 0;
1732
1733         if(e.autoswitch)
1734         {
1735                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1736                 {
1737                         .entity weaponentity = weaponentities[slot];
1738                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1739                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1740                                 _switchweapon |= BIT(slot);
1741                 }
1742         }
1743
1744         e.strength_finished = max(0, e.strength_finished - time);
1745         e.invincible_finished = max(0, e.invincible_finished - time);
1746         e.superweapons_finished = max(0, e.superweapons_finished - time);
1747
1748         PREGIVE(e, items);
1749         PREGIVE_WEAPONS(e);
1750         PREGIVE(e, strength_finished);
1751         PREGIVE(e, invincible_finished);
1752         PREGIVE(e, superweapons_finished);
1753         PREGIVE(e, ammo_nails);
1754         PREGIVE(e, ammo_cells);
1755         PREGIVE(e, ammo_plasma);
1756         PREGIVE(e, ammo_shells);
1757         PREGIVE(e, ammo_rockets);
1758         PREGIVE(e, ammo_fuel);
1759         PREGIVE(e, armorvalue);
1760         PREGIVE(e, health);
1761
1762         for(i = beginarg; i < endarg; ++i)
1763         {
1764                 cmd = argv(i);
1765
1766                 if(cmd == "0" || stof(cmd))
1767                 {
1768                         val = stof(cmd);
1769                         continue;
1770                 }
1771                 switch(cmd)
1772                 {
1773                         case "no":
1774                                 op = OP_MAX;
1775                                 val = 0;
1776                                 continue;
1777                         case "max":
1778                                 op = OP_MAX;
1779                                 continue;
1780                         case "min":
1781                                 op = OP_MIN;
1782                                 continue;
1783                         case "plus":
1784                                 op = OP_PLUS;
1785                                 continue;
1786                         case "minus":
1787                                 op = OP_MINUS;
1788                                 continue;
1789                         case "ALL":
1790                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1791                                 got += GiveValue(e, strength_finished, op, val);
1792                                 got += GiveValue(e, invincible_finished, op, val);
1793                                 got += GiveValue(e, superweapons_finished, op, val);
1794                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1795                         case "all":
1796                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1797                                 got += GiveValue(e, health, op, val);
1798                                 got += GiveValue(e, armorvalue, op, val);
1799                         case "allweapons":
1800                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1801                         //case "allbuffs": // all buffs makes a player god, do not want!
1802                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1803                         case "allammo":
1804                                 got += GiveValue(e, ammo_cells, op, val);
1805                                 got += GiveValue(e, ammo_plasma, op, val);
1806                                 got += GiveValue(e, ammo_shells, op, val);
1807                                 got += GiveValue(e, ammo_nails, op, val);
1808                                 got += GiveValue(e, ammo_rockets, op, val);
1809                                 got += GiveValue(e, ammo_fuel, op, val);
1810                                 break;
1811                         case "unlimited_ammo":
1812                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1813                                 break;
1814                         case "unlimited_weapon_ammo":
1815                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1816                                 break;
1817                         case "unlimited_superweapons":
1818                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1819                                 break;
1820                         case "jetpack":
1821                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1822                                 break;
1823                         case "fuel_regen":
1824                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1825                                 break;
1826                         case "strength":
1827                                 got += GiveValue(e, strength_finished, op, val);
1828                                 break;
1829                         case "invincible":
1830                                 got += GiveValue(e, invincible_finished, op, val);
1831                                 break;
1832                         case "superweapons":
1833                                 got += GiveValue(e, superweapons_finished, op, val);
1834                                 break;
1835                         case "cells":
1836                                 got += GiveValue(e, ammo_cells, op, val);
1837                                 break;
1838                         case "plasma":
1839                                 got += GiveValue(e, ammo_plasma, op, val);
1840                                 break;
1841                         case "shells":
1842                                 got += GiveValue(e, ammo_shells, op, val);
1843                                 break;
1844                         case "nails":
1845                         case "bullets":
1846                                 got += GiveValue(e, ammo_nails, op, val);
1847                                 break;
1848                         case "rockets":
1849                                 got += GiveValue(e, ammo_rockets, op, val);
1850                                 break;
1851                         case "health":
1852                                 got += GiveValue(e, health, op, val);
1853                                 break;
1854                         case "armor":
1855                                 got += GiveValue(e, armorvalue, op, val);
1856                                 break;
1857                         case "fuel":
1858                                 got += GiveValue(e, ammo_fuel, op, val);
1859                                 break;
1860                         default:
1861                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1862                                 {
1863                                         got += GiveBuff(e, it, op, val);
1864                                         break;
1865                                 });
1866                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1867                     got += GiveWeapon(e, it.m_id, op, val);
1868                     break;
1869                                 });
1870                                 break;
1871                 }
1872                 val = 999;
1873                 op = OP_SET;
1874         }
1875
1876         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1877         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1878         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1879         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1880         FOREACH(Weapons, it != WEP_Null, {
1881                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1882                 if(!(save_weapons & (it.m_wepset)))
1883                         if(e.weapons & (it.m_wepset))
1884                                 it.wr_init(it);
1885         });
1886         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1887         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1888         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1889         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1890         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1891         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1892         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1893         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1894         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1895         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1896         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1897
1898         if(e.superweapons_finished <= 0)
1899                 if(e.weapons & WEPSET_SUPERWEAPONS)
1900                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1901
1902         if(e.strength_finished <= 0)
1903                 e.strength_finished = 0;
1904         else
1905                 e.strength_finished += time;
1906         if(e.invincible_finished <= 0)
1907                 e.invincible_finished = 0;
1908         else
1909                 e.invincible_finished += time;
1910         if(e.superweapons_finished <= 0)
1911                 e.superweapons_finished = 0;
1912         else
1913                 e.superweapons_finished += time;
1914
1915         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1916         {
1917                 .entity weaponentity = weaponentities[slot];
1918                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1919                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1920                         _switchweapon |= BIT(slot);
1921         }
1922
1923         if(_switchweapon)
1924         {
1925                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1926                 {
1927                         .entity weaponentity = weaponentities[slot];
1928                         if(_switchweapon & BIT(slot))
1929                         {
1930                                 Weapon wep = w_getbestweapon(e, weaponentity);
1931                                 if(wep != e.(weaponentity).m_switchweapon)
1932                                         W_SwitchWeapon_Force(e, wep, weaponentity);
1933                         }
1934                 }
1935         }
1936
1937         return got;
1938 }
1939 #endif