qcsrc/common/triggers/func/breakable.qc

   1 #include "breakable.qh"
   2 #ifdef SVQC
   3
   4 #include <server/g_subs.qh>
   5 #include <server/g_damage.qh>
   6 #include <server/bot/api.qh>
   7 #include <common/csqcmodel_settings.qh>
   8 #include <lib/csqcmodel/sv_model.qh>
   9 #include <server/weapons/common.qh>
  10
  11 .entity sprite;
  12
  13 .float dmg;
  14 .float dmg_edge;
  15 .float dmg_radius;
  16 .float dmg_force;
  17 .float debrismovetype;
  18 .float debrissolid;
  19 .vector debrisvelocity;
  20 .vector debrisvelocityjitter;
  21 .vector debrisavelocityjitter;
  22 .float debristime;
  23 .float debristimejitter;
  24 .float debrisfadetime;
  25 .float debrisdamageforcescale;
  26 .float debrisskin;
  27
  28 .string mdl_dead; // or "" to hide when broken
  29 .string debris; // space separated list of debris models
  30 // other fields:
  31 //   mdl = particle effect name
  32 //   count = particle effect multiplier
  33 //   targetname = target to trigger to unbreak the model
  34 //   target = targets to trigger when broken
  35 //   health = amount of damage it can take
  36 //   spawnflags:
  37 //     1 = start disabled (needs to be triggered to activate)
  38 //     2 = indicate damage
  39 //     4 = don't take direct damage (needs to be triggered to 'explode', then triggered again to restore)
  40 // notes:
  41 //   for mdl_dead to work, origin must be set (using a common/origin brush).
  42 //   Otherwise mdl_dead will be displayed at the map origin, and nobody would
  43 //   want that!
  44
  45 void func_breakable_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force);
  46
  47 //
  48 // func_breakable
  49 // - basically func_assault_destructible for general gameplay use
  50 //
  51 void LaunchDebris (entity this, string debrisname, vector force)
  52 {
  53         entity dbr = spawn();
  54         vector org = this.absmin
  55                    + '1 0 0' * random() * (this.absmax.x - this.absmin.x)
  56                    + '0 1 0' * random() * (this.absmax.y - this.absmin.y)
  57                    + '0 0 1' * random() * (this.absmax.z - this.absmin.z);
  58         setorigin(dbr, org);
  59         _setmodel (dbr, debrisname );
  60         dbr.skin = this.debrisskin;
  61         dbr.colormap = this.colormap; // inherit team colors
  62         dbr.owner = this; // do not be affected by our own explosion
  63         set_movetype(dbr, this.debrismovetype);
  64         dbr.solid = this.debrissolid;
  65         if(dbr.solid != SOLID_BSP) // SOLID_BSP has exact collision, MAYBE this works? TODO check this out
  66                 setsize(dbr, '0 0 0', '0 0 0'); // needed for performance, until engine can deal better with it
  67         dbr.velocity_x = this.debrisvelocity.x + this.debrisvelocityjitter.x * crandom();
  68         dbr.velocity_y = this.debrisvelocity.y + this.debrisvelocityjitter.y * crandom();
  69         dbr.velocity_z = this.debrisvelocity.z + this.debrisvelocityjitter.z * crandom();
  70         this.velocity = this.velocity + force * this.debrisdamageforcescale;
  71         dbr.avelocity_x = random()*this.debrisavelocityjitter.x;
  72         dbr.avelocity_y = random()*this.debrisavelocityjitter.y;
  73         dbr.avelocity_z = random()*this.debrisavelocityjitter.z;
  74         dbr.damageforcescale = this.debrisdamageforcescale;
  75         if(dbr.damageforcescale)
  76                 dbr.takedamage = DAMAGE_YES;
  77         SUB_SetFade(dbr, time + this.debristime + crandom() * this.debristimejitter, this.debrisfadetime);
  78 }
  79
  80 void func_breakable_colormod(entity this)
  81 {
  82         float h;
  83         if (!(this.spawnflags & 2))
  84                 return;
  85         h = this.health / this.max_health;
  86         if(h < 0.25)
  87                 this.colormod = '1 0 0';
  88         else if(h <= 0.75)
  89                 this.colormod = '1 0 0' + '0 1 0' * (2 * h - 0.5);
  90         else
  91                 this.colormod = '1 1 1';
  92
  93         CSQCMODEL_AUTOUPDATE(this);
  94 }
  95
  96 void func_breakable_look_destroyed(entity this)
  97 {
  98         float floorZ;
  99
 100         if(this.solid == SOLID_BSP) // in case a misc_follow moved me, save the current origin first
 101                 this.dropped_origin = this.origin;
 102
 103         if(this.mdl_dead == "")
 104                 this.effects |= EF_NODRAW;
 105         else {
 106                 if (this.origin == '0 0 0')     {       // probably no origin brush, so don't spawn in the middle of the map..
 107                         floorZ = this.absmin.z;
 108                         setorigin(this, ((this.absmax + this.absmin) * 0.5));
 109                         this.origin_z = floorZ;
 110                 }
 111                 _setmodel(this, this.mdl_dead);
 112                 this.effects &= ~EF_NODRAW;
 113         }
 114
 115         CSQCMODEL_AUTOUPDATE(this);
 116
 117         this.solid = SOLID_NOT;
 118 }
 119
 120 void func_breakable_look_restore(entity this)
 121 {
 122         _setmodel(this, this.mdl);
 123         this.effects &= ~EF_NODRAW;
 124
 125         if(this.mdl_dead != "") // only do this if we use mdl_dead, to behave better with misc_follow
 126                 setorigin(this, this.dropped_origin);
 127
 128         CSQCMODEL_AUTOUPDATE(this);
 129
 130         this.solid = SOLID_BSP;
 131 }
 132
 133 void func_breakable_behave_destroyed(entity this)
 134 {
 135         this.health = this.max_health;
 136         this.takedamage = DAMAGE_NO;
 137         if(this.bot_attack)
 138                 IL_REMOVE(g_bot_targets, this);
 139         this.bot_attack = false;
 140         this.event_damage = func_null;
 141         this.state = 1;
 142         if(this.spawnflags & 4)
 143                 this.use = func_null;
 144         func_breakable_colormod(this);
 145         if (this.noise1)
 146                 stopsound (this, CH_TRIGGER_SINGLE);
 147 }
 148
 149 void func_breakable_behave_restore(entity this)
 150 {
 151         this.health = this.max_health;
 152         if(this.sprite)
 153         {
 154                 WaypointSprite_UpdateMaxHealth(this.sprite, this.max_health);
 155                 WaypointSprite_UpdateHealth(this.sprite, this.health);
 156         }
 157         if(!(this.spawnflags & 4))
 158         {
 159                 this.takedamage = DAMAGE_AIM;
 160                 if(!this.bot_attack)
 161                         IL_PUSH(g_bot_targets, this);
 162                 this.bot_attack = true;
 163                 this.event_damage = func_breakable_damage;
 164         }
 165         this.state = 0;
 166         this.nextthink = 0; // cancel auto respawn
 167         func_breakable_colormod(this);
 168         if (this.noise1)
 169                 _sound (this, CH_TRIGGER_SINGLE, this.noise1, VOL_BASE, ATTEN_NORM);
 170 }
 171
 172 void func_breakable_init_for_player(entity this, entity player)
 173 {
 174         if (this.noise1 && this.state == 0 && clienttype(player) == CLIENTTYPE_REAL)
 175         {
 176                 msg_entity = player;
 177                 soundto (MSG_ONE, this, CH_TRIGGER_SINGLE, this.noise1, VOL_BASE, ATTEN_NORM);
 178         }
 179 }
 180
 181 void func_breakable_destroyed(entity this)
 182 {
 183         func_breakable_look_destroyed(this);
 184         func_breakable_behave_destroyed(this);
 185
 186         CSQCMODEL_AUTOUPDATE(this);
 187 }
 188
 189 void func_breakable_restore(entity this, entity actor, entity trigger)
 190 {
 191         func_breakable_look_restore(this);
 192         func_breakable_behave_restore(this);
 193
 194         CSQCMODEL_AUTOUPDATE(this);
 195 }
 196
 197 void func_breakable_restore_self(entity this)
 198 {
 199         func_breakable_restore(this, NULL, NULL);
 200 }
 201
 202 vector debrisforce; // global, set before calling this
 203 void func_breakable_destroy(entity this, entity actor, entity trigger)
 204 {
 205         float n, i;
 206         string oldmsg;
 207
 208         entity act = this.owner;
 209         this.owner = NULL; // set by W_PrepareExplosionByDamage
 210
 211         // now throw around the debris
 212         n = tokenize_console(this.debris);
 213         for(i = 0; i < n; ++i)
 214                 LaunchDebris(this, argv(i), debrisforce);
 215
 216         func_breakable_destroyed(this);
 217
 218         if(this.noise)
 219                 _sound (this, CH_TRIGGER, this.noise, VOL_BASE, ATTEN_NORM);
 220
 221         if(this.dmg)
 222                 RadiusDamage(this, act, this.dmg, this.dmg_edge, this.dmg_radius, this, NULL, this.dmg_force, DEATH_HURTTRIGGER.m_id, NULL);
 223
 224         if(this.cnt) // TODO
 225                 __pointparticles(this.cnt, this.absmin * 0.5 + this.absmax * 0.5, '0 0 0', this.count);
 226
 227         if(this.respawntime)
 228         {
 229                 setthink(this, func_breakable_restore_self);
 230                 this.nextthink = time + this.respawntime + crandom() * this.respawntimejitter;
 231         }
 232
 233         oldmsg = this.message;
 234         this.message = "";
 235         SUB_UseTargets(this, act, trigger);
 236         this.message = oldmsg;
 237 }
 238
 239 void func_breakable_destroy_self(entity this)
 240 {
 241         func_breakable_destroy(this, NULL, NULL);
 242 }
 243
 244 void func_breakable_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 245 {
 246         if(this.state == 1)
 247                 return;
 248         if(this.spawnflags & DOOR_NOSPLASH)
 249                 if(!(DEATH_ISSPECIAL(deathtype)) && (deathtype & HITTYPE_SPLASH))
 250                         return;
 251         if(this.team)
 252                 if(attacker.team == this.team)
 253                         return;
 254         this.pain_finished = time;
 255         this.health = this.health - damage;
 256         if(this.sprite)
 257         {
 258                 WaypointSprite_Ping(this.sprite);
 259                 WaypointSprite_UpdateHealth(this.sprite, this.health);
 260         }
 261         func_breakable_colormod(this);
 262
 263         if(this.health <= 0)
 264         {
 265                 debrisforce = force;
 266
 267                 this.takedamage = DAMAGE_NO;
 268                 this.event_damage = func_null;
 269
 270                 if(IS_CLIENT(attacker) && this.classname == "func_assault_destructible")
 271                 {
 272                         this.owner = attacker;
 273                         this.realowner = attacker;
 274                 }
 275
 276                 // do not explode NOW but in the NEXT FRAME!
 277                 // because recursive calls to RadiusDamage are not allowed
 278                 this.nextthink = time;
 279                 setthink(this, func_breakable_destroy_self);
 280         }
 281 }
 282
 283 void func_breakable_reset(entity this)
 284 {
 285         this.team = this.team_saved;
 286         func_breakable_look_restore(this);
 287         if(this.spawnflags & 1)
 288                 func_breakable_behave_destroyed(this);
 289         else
 290                 func_breakable_behave_restore(this);
 291
 292         CSQCMODEL_AUTOUPDATE(this);
 293 }
 294
 295 // destructible walls that can be used to trigger target_objective_decrease
 296 spawnfunc(func_breakable)
 297 {
 298         float n, i;
 299         if(!this.health)
 300                 this.health = 100;
 301         this.max_health = this.health;
 302
 303         // yes, I know, MOVETYPE_NONE is not available here, not that one would want it here anyway
 304         if(!this.debrismovetype) this.debrismovetype = MOVETYPE_BOUNCE;
 305         if(!this.debrissolid) this.debrissolid = SOLID_NOT;
 306         if(this.debrisvelocity == '0 0 0') this.debrisvelocity = '0 0 140';
 307         if(this.debrisvelocityjitter == '0 0 0') this.debrisvelocityjitter = '70 70 70';
 308         if(this.debrisavelocityjitter == '0 0 0') this.debrisavelocityjitter = '600 600 600';
 309         if(!this.debristime) this.debristime = 3.5;
 310         if(!this.debristimejitter) this.debristime = 2.5;
 311
 312         if(this.mdl != "")
 313                 this.cnt = _particleeffectnum(this.mdl);
 314         if(this.count == 0)
 315                 this.count = 1;
 316
 317         if(this.message == "")
 318                 this.message = "got too close to an explosion";
 319         if(this.message2 == "")
 320                 this.message2 = "was pushed into an explosion by";
 321         if(!this.dmg_radius)
 322                 this.dmg_radius = 150;
 323         if(!this.dmg_force)
 324                 this.dmg_force = 200;
 325
 326         this.mdl = this.model;
 327         SetBrushEntityModel(this);
 328
 329         if(this.spawnflags & 4)
 330                 this.use = func_breakable_destroy;
 331         else
 332                 this.use = func_breakable_restore;
 333
 334         if(this.spawnflags & 4)
 335         {
 336                 this.takedamage = DAMAGE_NO;
 337                 this.event_damage = func_null;
 338                 this.bot_attack = false;
 339         }
 340
 341         // precache all the models
 342         if (this.mdl_dead)
 343                 precache_model(this.mdl_dead);
 344         n = tokenize_console(this.debris);
 345         for(i = 0; i < n; ++i)
 346                 precache_model(argv(i));
 347         if(this.noise)
 348                 precache_sound(this.noise);
 349         if(this.noise1)
 350                 precache_sound(this.noise1);
 351
 352         this.team_saved = this.team;
 353         this.dropped_origin = this.origin;
 354
 355         this.reset = func_breakable_reset;
 356         this.reset(this);
 357
 358         IL_PUSH(g_initforplayer, this);
 359         this.init_for_player = func_breakable_init_for_player;
 360
 361         CSQCMODEL_AUTOINIT(this);
 362 }
 363
 364 // for use in maps with a "model" key set
 365 spawnfunc(misc_breakablemodel) {
 366         spawnfunc_func_breakable(this);
 367 }
 368 #endif