qcsrc/common/triggers/func/ladder.qc

   1 #include "ladder.qh"
   2 REGISTER_NET_LINKED(ENT_CLIENT_LADDER)
   3
   4 void func_ladder_touch(entity this, entity toucher)
   5 {
   6 #ifdef SVQC
   7         if (!toucher.iscreature)
   8                 return;
   9         if(IS_VEHICLE(toucher))
  10                 return;
  11 #elif defined(CSQC)
  12         if(!toucher.isplayermodel)
  13                 return;
  14 #endif
  15
  16         EXACTTRIGGER_TOUCH(this, toucher);
  17
  18         toucher.ladder_time = time + 0.1;
  19         toucher.ladder_entity = this;
  20 }
  21
  22 #ifdef SVQC
  23 bool func_ladder_send(entity this, entity to, int sf)
  24 {
  25         WriteHeader(MSG_ENTITY, ENT_CLIENT_LADDER);
  26
  27         WriteString(MSG_ENTITY, this.classname);
  28         WriteByte(MSG_ENTITY, this.skin);
  29         WriteCoord(MSG_ENTITY, this.speed);
  30
  31         trigger_common_write(this, false);
  32
  33         return true;
  34 }
  35
  36 void func_ladder_link(entity this)
  37 {
  38         trigger_link(this, func_ladder_send);
  39         //this.model = "null";
  40 }
  41
  42 void func_ladder_init(entity this)
  43 {
  44         settouch(this, func_ladder_touch);
  45
  46         trigger_init(this);
  47         func_ladder_link(this);
  48         vector top = (this.absmin + this.absmax) / 2;
  49         top.z = this.absmax.z + 1 - PL_MIN_CONST.z;
  50         float height = this.absmax.z - this.absmin.z;
  51         waypoint_spawnforteleporter_boxes(this, WAYPOINTFLAG_LADDER, this.absmin, this.absmax, top, top, height);
  52 }
  53
  54 spawnfunc(func_ladder)
  55 {
  56         IL_PUSH(g_ladders, this); // TODO: also func_water? bots currently loop through func_ladder only
  57
  58         func_ladder_init(this);
  59 }
  60
  61 spawnfunc(func_water)
  62 {
  63         func_ladder_init(this);
  64 }
  65
  66 #elif defined(CSQC)
  67 .float speed;
  68
  69 void func_ladder_remove(entity this)
  70 {
  71         if(this.classname) { strunzone(this.classname); }
  72         this.classname = string_null;
  73 }
  74
  75 NET_HANDLE(ENT_CLIENT_LADDER, bool isnew)
  76 {
  77         this.classname = strzone(ReadString());
  78         this.skin = ReadByte();
  79         this.speed = ReadCoord();
  80
  81         trigger_common_read(this, false);
  82
  83         this.solid = SOLID_TRIGGER;
  84         settouch(this, func_ladder_touch);
  85         this.drawmask = MASK_NORMAL;
  86         this.move_time = time;
  87         this.entremove = func_ladder_remove;
  88
  89         return true;
  90 }
  91 #endif