]> de.git.xonotic.org Git - xonotic/xonotic-data.pk3dir.git/blob - qcsrc/common/triggers/func/ladder.qc
Merge branch 'master' into terencehill/bot_waypoints
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / triggers / func / ladder.qc
1 #include "ladder.qh"
2 REGISTER_NET_LINKED(ENT_CLIENT_LADDER)
3
4 void func_ladder_touch(entity this, entity toucher)
5 {
6 #ifdef SVQC
7         if (!toucher.iscreature)
8                 return;
9         if(IS_VEHICLE(toucher))
10                 return;
11 #elif defined(CSQC)
12         if(!toucher.isplayermodel)
13                 return;
14 #endif
15
16         EXACTTRIGGER_TOUCH(this, toucher);
17
18         toucher.ladder_time = time + 0.1;
19         toucher.ladder_entity = this;
20 }
21
22 #ifdef SVQC
23 bool func_ladder_send(entity this, entity to, int sf)
24 {
25         WriteHeader(MSG_ENTITY, ENT_CLIENT_LADDER);
26
27         WriteString(MSG_ENTITY, this.classname);
28         WriteByte(MSG_ENTITY, this.skin);
29         WriteCoord(MSG_ENTITY, this.speed);
30
31         trigger_common_write(this, false);
32
33         return true;
34 }
35
36 void func_ladder_link(entity this)
37 {
38         trigger_link(this, func_ladder_send);
39         //this.model = "null";
40 }
41
42 void func_ladder_init(entity this)
43 {
44         settouch(this, func_ladder_touch);
45         trigger_init(this);
46         func_ladder_link(this);
47
48         if(min(this.absmax.x - this.absmin.x, this.absmax.y - this.absmin.y) > 100)
49                 return;
50
51         vector top_min = (this.absmin + this.absmax) / 2;
52         top_min.z = this.absmax.z;
53         vector top_max = top_min;
54         top_max.z += PL_MAX_CONST.z - PL_MIN_CONST.z;
55         tracebox(top_max + jumpstepheightvec, PL_MIN_CONST, PL_MAX_CONST, top_min, MOVE_NOMONSTERS, NULL);
56         if(trace_startsolid)
57         {
58                 tracebox(top_max + stepheightvec, PL_MIN_CONST, PL_MAX_CONST, top_min, MOVE_NOMONSTERS, NULL);
59                 if(trace_startsolid)
60                 {
61                         tracebox(top_max, PL_MIN_CONST, PL_MAX_CONST, top_min, MOVE_NOMONSTERS, NULL);
62                         if(trace_startsolid)
63                                 return;
64                 }
65         }
66         if(trace_endpos.z < this.absmax.z)
67                 return;
68
69         this.bot_pickup = true; // allow bots to make use of this ladder
70         float cost = waypoint_getlinearcost(trace_endpos.z - this.absmin.z);
71         top_min = trace_endpos;
72         waypoint_spawnforteleporter_boxes(this, WAYPOINTFLAG_LADDER, this.absmin, this.absmax, top_min, top_min, cost);
73 }
74
75 spawnfunc(func_ladder)
76 {
77         IL_PUSH(g_ladders, this); // TODO: also func_water? bots currently loop through func_ladder only
78
79         func_ladder_init(this);
80 }
81
82 spawnfunc(func_water)
83 {
84         func_ladder_init(this);
85 }
86
87 #elif defined(CSQC)
88 .float speed;
89
90 void func_ladder_remove(entity this)
91 {
92         if(this.classname) { strunzone(this.classname); }
93         this.classname = string_null;
94 }
95
96 NET_HANDLE(ENT_CLIENT_LADDER, bool isnew)
97 {
98         this.classname = strzone(ReadString());
99         this.skin = ReadByte();
100         this.speed = ReadCoord();
101
102         trigger_common_read(this, false);
103
104         this.solid = SOLID_TRIGGER;
105         settouch(this, func_ladder_touch);
106         this.drawmask = MASK_NORMAL;
107         this.move_time = time;
108         this.entremove = func_ladder_remove;
109
110         return true;
111 }
112 #endif