qcsrc/common/triggers/trigger/jumppads.qc

   1 // TODO: split target_push and put it in the target folder
   2 #ifdef SVQC
   3 #include "../../../server/_all.qh"
   4 #include "jumppads.qh"
   5 #include "../../movetypes/movetypes.qh"
   6
   7 void trigger_push_use()
   8 {
   9         if(teamplay)
  10         {
  11                 self.team = activator.team;
  12                 self.SendFlags |= 2;
  13         }
  14 }
  15 #endif
  16
  17 /*
  18         trigger_push_calculatevelocity
  19
  20         Arguments:
  21           org - origin of the object which is to be pushed
  22           tgt - target entity (can be either a point or a model entity; if it is
  23                 the latter, its midpoint is used)
  24           ht  - jump height, measured from the higher one of org and tgt's midpoint
  25
  26         Returns: velocity for the jump
  27         the global trigger_push_calculatevelocity_flighttime is set to the total
  28         jump time
  29  */
  30
  31 vector trigger_push_calculatevelocity(vector org, entity tgt, float ht)
  32 {
  33         float grav, sdist, zdist, vs, vz, jumpheight;
  34         vector sdir, torg;
  35
  36         torg = tgt.origin + (tgt.mins + tgt.maxs) * 0.5;
  37
  38         grav = PHYS_GRAVITY;
  39         if(PHYS_ENTGRAVITY(other))
  40                 grav *= PHYS_ENTGRAVITY(other);
  41
  42         zdist = torg.z - org.z;
  43         sdist = vlen(torg - org - zdist * '0 0 1');
  44         sdir = normalize(torg - org - zdist * '0 0 1');
  45
  46         // how high do we need to push the player?
  47         jumpheight = fabs(ht);
  48         if(zdist > 0)
  49                 jumpheight = jumpheight + zdist;
  50
  51         /*
  52                 STOP.
  53
  54                 You will not understand the following equations anyway...
  55                 But here is what I did to get them.
  56
  57                 I used the functions
  58
  59                   s(t) = t * vs
  60                   z(t) = t * vz - 1/2 grav t^2
  61
  62                 and solved for:
  63
  64                   s(ti) = sdist
  65                   z(ti) = zdist
  66                   max(z, ti) = jumpheight
  67
  68                 From these three equations, you will find the three parameters vs, vz
  69                 and ti.
  70          */
  71
  72         // push him so high...
  73         vz = sqrt(fabs(2 * grav * jumpheight)); // NOTE: sqrt(positive)!
  74
  75         // we start with downwards velocity only if it's a downjump and the jump apex should be outside the jump!
  76         if(ht < 0)
  77                 if(zdist < 0)
  78                         vz = -vz;
  79
  80         vector solution;
  81         solution = solve_quadratic(0.5 * grav, -vz, zdist); // equation "z(ti) = zdist"
  82         // ALWAYS solvable because jumpheight >= zdist
  83         if(!solution.z)
  84                 solution_y = solution.x; // just in case it is not solvable due to roundoff errors, assume two equal solutions at their center (this is mainly for the usual case with ht == 0)
  85         if(zdist == 0)
  86                 solution_x = solution.y; // solution_x is 0 in this case, so don't use it, but rather use solution_y (which will be sqrt(0.5 * jumpheight / grav), actually)
  87
  88         if(zdist < 0)
  89         {
  90                 // down-jump
  91                 if(ht < 0)
  92                 {
  93                         // almost straight line type
  94                         // jump apex is before the jump
  95                         // we must take the larger one
  96                         trigger_push_calculatevelocity_flighttime = solution.y;
  97                 }
  98                 else
  99                 {
 100                         // regular jump
 101                         // jump apex is during the jump
 102                         // we must take the larger one too
 103                         trigger_push_calculatevelocity_flighttime = solution.y;
 104                 }
 105         }
 106         else
 107         {
 108                 // up-jump
 109                 if(ht < 0)
 110                 {
 111                         // almost straight line type
 112                         // jump apex is after the jump
 113                         // we must take the smaller one
 114                         trigger_push_calculatevelocity_flighttime = solution.x;
 115                 }
 116                 else
 117                 {
 118                         // regular jump
 119                         // jump apex is during the jump
 120                         // we must take the larger one
 121                         trigger_push_calculatevelocity_flighttime = solution.y;
 122                 }
 123         }
 124         vs = sdist / trigger_push_calculatevelocity_flighttime;
 125
 126         // finally calculate the velocity
 127         return sdir * vs + '0 0 1' * vz;
 128 }
 129
 130 void trigger_push_touch()
 131 {
 132         if (self.active == ACTIVE_NOT)
 133                 return;
 134
 135 #ifdef SVQC
 136         if (!isPushable(other))
 137                 return;
 138 #endif
 139
 140         if(self.team)
 141                 if(((self.spawnflags & 4) == 0) == (DIFF_TEAM(self, other)))
 142                         return;
 143
 144         EXACTTRIGGER_TOUCH;
 145
 146         if(self.enemy)
 147         {
 148                 other.velocity = trigger_push_calculatevelocity(other.origin, self.enemy, self.height);
 149                 other.move_velocity = other.velocity;
 150         }
 151         else if(self.target)
 152         {
 153                 entity e;
 154                 RandomSelection_Init();
 155                 for(e = world; (e = find(e, targetname, self.target)); )
 156                 {
 157                         if(e.cnt)
 158                                 RandomSelection_Add(e, 0, string_null, e.cnt, 1);
 159                         else
 160                                 RandomSelection_Add(e, 0, string_null, 1, 1);
 161                 }
 162                 other.velocity = trigger_push_calculatevelocity(other.origin, RandomSelection_chosen_ent, self.height);
 163                 other.move_velocity = other.velocity;
 164         }
 165         else
 166         {
 167                 other.velocity = self.movedir;
 168                 other.move_velocity = other.velocity;
 169         }
 170
 171         UNSET_ONGROUND(other);
 172
 173         other.move_flags &= ~FL_ONGROUND;
 174
 175 #ifdef SVQC
 176         if (IS_PLAYER(other))
 177         {
 178                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
 179                 other.oldvelocity = other.velocity;
 180
 181                 if(self.pushltime < time)  // prevent "snorring" sound when a player hits the jumppad more than once
 182                 {
 183                         // flash when activated
 184                         pointparticles(particleeffectnum("jumppad_activate"), other.origin, other.velocity, 1);
 185                         sound (other, CH_TRIGGER, self.noise, VOL_BASE, ATTEN_NORM);
 186                         self.pushltime = time + 0.2;
 187                 }
 188                 if(IS_REAL_CLIENT(other) || IS_BOT_CLIENT(other))
 189                 {
 190                         bool found = false;
 191                         for(int i = 0; i < other.jumppadcount && i < NUM_JUMPPADSUSED; ++i)
 192                                 if(other.(jumppadsused[i]) == self)
 193                                         found = true;
 194                         if(!found)
 195                         {
 196                                 other.(jumppadsused[other.jumppadcount % NUM_JUMPPADSUSED]) = self;
 197                                 other.jumppadcount = other.jumppadcount + 1;
 198                         }
 199
 200                         if(IS_REAL_CLIENT(other))
 201                         {
 202                                 if(self.message)
 203                                         centerprint(other, self.message);
 204                         }
 205                         else
 206                                 other.lastteleporttime = time;
 207
 208                         if (other.deadflag == DEAD_NO)
 209                                 animdecide_setaction(other, ANIMACTION_JUMP, true);
 210                 }
 211                 else
 212                         other.jumppadcount = true;
 213
 214                 // reset tracking of who pushed you into a hazard (for kill credit)
 215                 other.pushltime = 0;
 216                 other.istypefrag = 0;
 217         }
 218
 219         if(self.enemy.target)
 220         {
 221                 entity oldself;
 222                 oldself = self;
 223                 activator = other;
 224                 self = self.enemy;
 225                 SUB_UseTargets();
 226                 self = oldself;
 227         }
 228
 229         if (other.flags & FL_PROJECTILE)
 230         {
 231                 other.angles = vectoangles (other.velocity);
 232                 switch(other.movetype)
 233                 {
 234                         case MOVETYPE_FLY:
 235                                 other.movetype = MOVETYPE_TOSS;
 236                                 other.gravity = 1;
 237                                 break;
 238                         case MOVETYPE_BOUNCEMISSILE:
 239                                 other.movetype = MOVETYPE_BOUNCE;
 240                                 other.gravity = 1;
 241                                 break;
 242                 }
 243                 UpdateCSQCProjectile(other);
 244         }
 245
 246         if (self.spawnflags & PUSH_ONCE)
 247         {
 248                 self.touch = func_null;
 249                 self.think = SUB_Remove;
 250                 self.nextthink = time;
 251         }
 252 #endif
 253 }
 254
 255 #ifdef SVQC
 256 void trigger_push_link();
 257 void trigger_push_updatelink();
 258 #endif
 259 void trigger_push_findtarget()
 260 {
 261         entity t;
 262         vector org;
 263
 264         // first calculate a typical start point for the jump
 265         org = (self.absmin + self.absmax) * 0.5;
 266         org_z = self.absmax.z - PL_MIN.z;
 267
 268         if (self.target)
 269         {
 270                 float n = 0;
 271                 for(t = world; (t = find(t, targetname, self.target)); )
 272                 {
 273                         ++n;
 274 #ifdef SVQC
 275                         entity e = spawn();
 276                         setorigin(e, org);
 277                         setsize(e, PL_MIN, PL_MAX);
 278                         e.velocity = trigger_push_calculatevelocity(org, t, self.height);
 279                         tracetoss(e, e);
 280                         if(e.movetype == MOVETYPE_NONE)
 281                                 waypoint_spawnforteleporter(self, trace_endpos, vlen(trace_endpos - org) / vlen(e.velocity));
 282                         remove(e);
 283 #endif
 284                 }
 285
 286                 if(!n)
 287                 {
 288                         // no dest!
 289 #ifdef SVQC
 290                         objerror ("Jumppad with nonexistant target");
 291 #endif
 292                         return;
 293                 }
 294                 else if(n == 1)
 295                 {
 296                         // exactly one dest - bots love that
 297                         self.enemy = find(world, targetname, self.target);
 298                 }
 299                 else
 300                 {
 301                         // have to use random selection every single time
 302                         self.enemy = world;
 303                 }
 304         }
 305 #ifdef SVQC
 306         else
 307         {
 308                 entity e = spawn();
 309                 setorigin(e, org);
 310                 setsize(e, PL_MIN, PL_MAX);
 311                 e.velocity = self.movedir;
 312                 tracetoss(e, e);
 313                 waypoint_spawnforteleporter(self, trace_endpos, vlen(trace_endpos - org) / vlen(e.velocity));
 314                 remove(e);
 315         }
 316
 317         trigger_push_link();
 318         defer(0.1, trigger_push_updatelink);
 319 #endif
 320 }
 321
 322 #ifdef SVQC
 323 float trigger_push_send(entity to, float sf)
 324 {
 325         WriteByte(MSG_ENTITY, ENT_CLIENT_TRIGGER_PUSH);
 326         WriteByte(MSG_ENTITY, sf);
 327
 328         if(sf & 1)
 329         {
 330                 WriteByte(MSG_ENTITY, self.team);
 331                 WriteInt24_t(MSG_ENTITY, self.spawnflags);
 332                 WriteByte(MSG_ENTITY, self.active);
 333                 WriteByte(MSG_ENTITY, self.height);
 334
 335                 trigger_common_write(true);
 336         }
 337
 338         if(sf & 2)
 339         {
 340                 WriteByte(MSG_ENTITY, self.team);
 341                 WriteByte(MSG_ENTITY, self.active);
 342         }
 343
 344         return true;
 345 }
 346
 347 void trigger_push_updatelink()
 348 {
 349         self.SendFlags |= 1;
 350 }
 351
 352 void trigger_push_link()
 353 {
 354         //Net_LinkEntity(self, false, 0, trigger_push_send);
 355 }
 356 #endif
 357 #ifdef SVQC
 358 /*
 359  * ENTITY PARAMETERS:
 360  *
 361  *   target:  target of jump
 362  *   height:  the absolute value is the height of the highest point of the jump
 363  *            trajectory above the higher one of the player and the target.
 364  *            the sign indicates whether the highest point is INSIDE (positive)
 365  *            or OUTSIDE (negative) of the jump trajectory. General rule: use
 366  *            positive values for targets mounted on the floor, and use negative
 367  *            values to target a point on the ceiling.
 368  *   movedir: if target is not set, this * speed * 10 is the velocity to be reached.
 369  */
 370 void spawnfunc_trigger_push()
 371 {
 372         SetMovedir ();
 373
 374         EXACTTRIGGER_INIT;
 375
 376         self.active = ACTIVE_ACTIVE;
 377         self.use = trigger_push_use;
 378         self.touch = trigger_push_touch;
 379
 380         // normal push setup
 381         if (!self.speed)
 382                 self.speed = 1000;
 383         self.movedir = self.movedir * self.speed * 10;
 384
 385         if (!self.noise)
 386                 self.noise = "misc/jumppad.wav";
 387         precache_sound (self.noise);
 388
 389         // this must be called to spawn the teleport waypoints for bots
 390         InitializeEntity(self, trigger_push_findtarget, INITPRIO_FINDTARGET);
 391 }
 392
 393
 394 float target_push_send(entity to, float sf)
 395 {
 396         WriteByte(MSG_ENTITY, ENT_CLIENT_TARGET_PUSH);
 397
 398         WriteByte(MSG_ENTITY, self.cnt);
 399         WriteString(MSG_ENTITY, self.targetname);
 400         WriteCoord(MSG_ENTITY, self.origin_x);
 401         WriteCoord(MSG_ENTITY, self.origin_y);
 402         WriteCoord(MSG_ENTITY, self.origin_z);
 403
 404         return true;
 405 }
 406
 407 void target_push_link()
 408 {
 409         Net_LinkEntity(self, false, 0, target_push_send);
 410         self.SendFlags |= 1; // update
 411 }
 412
 413 void spawnfunc_target_push() { target_push_link(); }
 414 void spawnfunc_info_notnull() { target_push_link(); }
 415 void spawnfunc_target_position() { target_push_link(); }
 416
 417 #endif
 418
 419 #ifdef CSQC
 420
 421 void ent_trigger_push()
 422 {
 423         float sf = ReadByte();
 424
 425         if(sf & 1)
 426         {
 427                 self.classname = "jumppad";
 428                 int mytm = ReadByte(); if(mytm) { self.team = mytm - 1; }
 429                 self.spawnflags = ReadInt24_t();
 430                 self.active = ReadByte();
 431                 self.height = ReadByte();
 432
 433                 trigger_common_read(true);
 434
 435                 self.entremove = trigger_remove_generic;
 436                 self.solid = SOLID_TRIGGER;
 437                 self.draw = trigger_draw_generic;
 438                 self.trigger_touch = trigger_push_touch;
 439                 self.drawmask = MASK_NORMAL;
 440                 self.move_time = time;
 441                 trigger_push_findtarget();
 442         }
 443
 444         if(sf & 2)
 445         {
 446                 self.team = ReadByte();
 447                 self.active = ReadByte();
 448         }
 449 }
 450
 451 void target_push_remove()
 452 {
 453         if(self.classname)
 454                 strunzone(self.classname);
 455         self.classname = string_null;
 456
 457         if(self.targetname)
 458                 strunzone(self.targetname);
 459         self.targetname = string_null;
 460 }
 461
 462 void ent_target_push()
 463 {
 464         self.classname = "push_target";
 465         self.cnt = ReadByte();
 466         self.targetname = strzone(ReadString());
 467         self.origin_x = ReadCoord();
 468         self.origin_y = ReadCoord();
 469         self.origin_z = ReadCoord();
 470         setorigin(self, self.origin);
 471
 472         self.drawmask = MASK_NORMAL;
 473         self.entremove = target_push_remove;
 474 }
 475 #endif