qcsrc/common/triggers/trigger/jumppads.qc

   1 // TODO: split target_push and put it in the target folder
   2 #ifdef SVQC
   3 #include "../../../server/_all.qh"
   4 #include "jumppads.qh"
   5 #include "../../movetypes/movetypes.qh"
   6
   7 void trigger_push_use()
   8 {SELFPARAM();
   9         if(teamplay)
  10         {
  11                 self.team = activator.team;
  12                 self.SendFlags |= 2;
  13         }
  14 }
  15 #endif
  16
  17 /*
  18         trigger_push_calculatevelocity
  19
  20         Arguments:
  21           org - origin of the object which is to be pushed
  22           tgt - target entity (can be either a point or a model entity; if it is
  23                 the latter, its midpoint is used)
  24           ht  - jump height, measured from the higher one of org and tgt's midpoint
  25
  26         Returns: velocity for the jump
  27         the global trigger_push_calculatevelocity_flighttime is set to the total
  28         jump time
  29  */
  30
  31 vector trigger_push_calculatevelocity(vector org, entity tgt, float ht)
  32 {
  33         float grav, sdist, zdist, vs, vz, jumpheight;
  34         vector sdir, torg;
  35
  36         torg = tgt.origin + (tgt.mins + tgt.maxs) * 0.5;
  37
  38         grav = PHYS_GRAVITY;
  39         if(PHYS_ENTGRAVITY(other))
  40                 grav *= PHYS_ENTGRAVITY(other);
  41
  42         zdist = torg.z - org.z;
  43         sdist = vlen(torg - org - zdist * '0 0 1');
  44         sdir = normalize(torg - org - zdist * '0 0 1');
  45
  46         // how high do we need to push the player?
  47         jumpheight = fabs(ht);
  48         if(zdist > 0)
  49                 jumpheight = jumpheight + zdist;
  50
  51         /*
  52                 STOP.
  53
  54                 You will not understand the following equations anyway...
  55                 But here is what I did to get them.
  56
  57                 I used the functions
  58
  59                   s(t) = t * vs
  60                   z(t) = t * vz - 1/2 grav t^2
  61
  62                 and solved for:
  63
  64                   s(ti) = sdist
  65                   z(ti) = zdist
  66                   max(z, ti) = jumpheight
  67
  68                 From these three equations, you will find the three parameters vs, vz
  69                 and ti.
  70          */
  71
  72         // push him so high...
  73         vz = sqrt(fabs(2 * grav * jumpheight)); // NOTE: sqrt(positive)!
  74
  75         // we start with downwards velocity only if it's a downjump and the jump apex should be outside the jump!
  76         if(ht < 0)
  77                 if(zdist < 0)
  78                         vz = -vz;
  79
  80         vector solution;
  81         solution = solve_quadratic(0.5 * grav, -vz, zdist); // equation "z(ti) = zdist"
  82         // ALWAYS solvable because jumpheight >= zdist
  83         if(!solution.z)
  84                 solution_y = solution.x; // just in case it is not solvable due to roundoff errors, assume two equal solutions at their center (this is mainly for the usual case with ht == 0)
  85         if(zdist == 0)
  86                 solution_x = solution.y; // solution_x is 0 in this case, so don't use it, but rather use solution_y (which will be sqrt(0.5 * jumpheight / grav), actually)
  87
  88         if(zdist < 0)
  89         {
  90                 // down-jump
  91                 if(ht < 0)
  92                 {
  93                         // almost straight line type
  94                         // jump apex is before the jump
  95                         // we must take the larger one
  96                         trigger_push_calculatevelocity_flighttime = solution.y;
  97                 }
  98                 else
  99                 {
 100                         // regular jump
 101                         // jump apex is during the jump
 102                         // we must take the larger one too
 103                         trigger_push_calculatevelocity_flighttime = solution.y;
 104                 }
 105         }
 106         else
 107         {
 108                 // up-jump
 109                 if(ht < 0)
 110                 {
 111                         // almost straight line type
 112                         // jump apex is after the jump
 113                         // we must take the smaller one
 114                         trigger_push_calculatevelocity_flighttime = solution.x;
 115                 }
 116                 else
 117                 {
 118                         // regular jump
 119                         // jump apex is during the jump
 120                         // we must take the larger one
 121                         trigger_push_calculatevelocity_flighttime = solution.y;
 122                 }
 123         }
 124         vs = sdist / trigger_push_calculatevelocity_flighttime;
 125
 126         // finally calculate the velocity
 127         return sdir * vs + '0 0 1' * vz;
 128 }
 129
 130 void trigger_push_touch()
 131 {SELFPARAM();
 132         if (self.active == ACTIVE_NOT)
 133                 return;
 134
 135 #ifdef SVQC
 136         if (!isPushable(other))
 137                 return;
 138 #endif
 139
 140         if(self.team)
 141                 if(((self.spawnflags & 4) == 0) == (DIFF_TEAM(self, other)))
 142                         return;
 143
 144         EXACTTRIGGER_TOUCH;
 145
 146         if(self.enemy)
 147         {
 148                 other.velocity = trigger_push_calculatevelocity(other.origin, self.enemy, self.height);
 149                 other.move_velocity = other.velocity;
 150         }
 151         else if(self.target)
 152         {
 153                 entity e;
 154                 RandomSelection_Init();
 155                 for(e = world; (e = find(e, targetname, self.target)); )
 156                 {
 157                         if(e.cnt)
 158                                 RandomSelection_Add(e, 0, string_null, e.cnt, 1);
 159                         else
 160                                 RandomSelection_Add(e, 0, string_null, 1, 1);
 161                 }
 162                 other.velocity = trigger_push_calculatevelocity(other.origin, RandomSelection_chosen_ent, self.height);
 163                 other.move_velocity = other.velocity;
 164         }
 165         else
 166         {
 167                 other.velocity = self.movedir;
 168                 other.move_velocity = other.velocity;
 169         }
 170
 171         UNSET_ONGROUND(other);
 172
 173         other.move_flags &= ~FL_ONGROUND;
 174
 175 #ifdef SVQC
 176         if (IS_PLAYER(other))
 177         {
 178                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
 179                 other.oldvelocity = other.velocity;
 180
 181                 if(self.pushltime < time)  // prevent "snorring" sound when a player hits the jumppad more than once
 182                 {
 183                         // flash when activated
 184                         Send_Effect(EFFECT_JUMPPAD, other.origin, other.velocity, 1);
 185                         _sound (other, CH_TRIGGER, self.noise, VOL_BASE, ATTEN_NORM);
 186                         self.pushltime = time + 0.2;
 187                 }
 188                 if(IS_REAL_CLIENT(other) || IS_BOT_CLIENT(other))
 189                 {
 190                         bool found = false;
 191                         for(int i = 0; i < other.jumppadcount && i < NUM_JUMPPADSUSED; ++i)
 192                                 if(other.(jumppadsused[i]) == self)
 193                                         found = true;
 194                         if(!found)
 195                         {
 196                                 other.(jumppadsused[other.jumppadcount % NUM_JUMPPADSUSED]) = self;
 197                                 other.jumppadcount = other.jumppadcount + 1;
 198                         }
 199
 200                         if(IS_REAL_CLIENT(other))
 201                         {
 202                                 if(self.message)
 203                                         centerprint(other, self.message);
 204                         }
 205                         else
 206                                 other.lastteleporttime = time;
 207
 208                         if (other.deadflag == DEAD_NO)
 209                                 animdecide_setaction(other, ANIMACTION_JUMP, true);
 210                 }
 211                 else
 212                         other.jumppadcount = true;
 213
 214                 // reset tracking of who pushed you into a hazard (for kill credit)
 215                 other.pushltime = 0;
 216                 other.istypefrag = 0;
 217         }
 218
 219         if(self.enemy.target)
 220         {
 221                 activator = other;
 222                 WITH(entity, self, self.enemy, SUB_UseTargets());
 223         }
 224
 225         if (other.flags & FL_PROJECTILE)
 226         {
 227                 other.angles = vectoangles (other.velocity);
 228                 switch(other.movetype)
 229                 {
 230                         case MOVETYPE_FLY:
 231                                 other.movetype = MOVETYPE_TOSS;
 232                                 other.gravity = 1;
 233                                 break;
 234                         case MOVETYPE_BOUNCEMISSILE:
 235                                 other.movetype = MOVETYPE_BOUNCE;
 236                                 other.gravity = 1;
 237                                 break;
 238                 }
 239                 UpdateCSQCProjectile(other);
 240         }
 241
 242         if (self.spawnflags & PUSH_ONCE)
 243         {
 244                 self.touch = func_null;
 245                 self.think = SUB_Remove;
 246                 self.nextthink = time;
 247         }
 248 #endif
 249 }
 250
 251 #ifdef SVQC
 252 void trigger_push_link();
 253 void trigger_push_updatelink();
 254 #endif
 255 void trigger_push_findtarget()
 256 {SELFPARAM();
 257         entity t;
 258         vector org;
 259
 260         // first calculate a typical start point for the jump
 261         org = (self.absmin + self.absmax) * 0.5;
 262         org_z = self.absmax.z - PL_MIN.z;
 263
 264         if (self.target)
 265         {
 266                 float n = 0;
 267                 for(t = world; (t = find(t, targetname, self.target)); )
 268                 {
 269                         ++n;
 270 #ifdef SVQC
 271                         entity e = spawn();
 272                         setorigin(e, org);
 273                         setsize(e, PL_MIN, PL_MAX);
 274                         e.velocity = trigger_push_calculatevelocity(org, t, self.height);
 275                         tracetoss(e, e);
 276                         if(e.movetype == MOVETYPE_NONE)
 277                                 waypoint_spawnforteleporter(self, trace_endpos, vlen(trace_endpos - org) / vlen(e.velocity));
 278                         remove(e);
 279 #endif
 280                 }
 281
 282                 if(!n)
 283                 {
 284                         // no dest!
 285 #ifdef SVQC
 286                         objerror ("Jumppad with nonexistant target");
 287 #endif
 288                         return;
 289                 }
 290                 else if(n == 1)
 291                 {
 292                         // exactly one dest - bots love that
 293                         self.enemy = find(world, targetname, self.target);
 294                 }
 295                 else
 296                 {
 297                         // have to use random selection every single time
 298                         self.enemy = world;
 299                 }
 300         }
 301 #ifdef SVQC
 302         else
 303         {
 304                 entity e = spawn();
 305                 setorigin(e, org);
 306                 setsize(e, PL_MIN, PL_MAX);
 307                 e.velocity = self.movedir;
 308                 tracetoss(e, e);
 309                 waypoint_spawnforteleporter(self, trace_endpos, vlen(trace_endpos - org) / vlen(e.velocity));
 310                 remove(e);
 311         }
 312
 313         trigger_push_link();
 314         defer(0.1, trigger_push_updatelink);
 315 #endif
 316 }
 317
 318 #ifdef SVQC
 319 float trigger_push_send(entity to, float sf)
 320 {SELFPARAM();
 321         WriteByte(MSG_ENTITY, ENT_CLIENT_TRIGGER_PUSH);
 322         WriteByte(MSG_ENTITY, sf);
 323
 324         if(sf & 1)
 325         {
 326                 WriteByte(MSG_ENTITY, self.team);
 327                 WriteInt24_t(MSG_ENTITY, self.spawnflags);
 328                 WriteByte(MSG_ENTITY, self.active);
 329                 WriteByte(MSG_ENTITY, self.height);
 330
 331                 trigger_common_write(true);
 332         }
 333
 334         if(sf & 2)
 335         {
 336                 WriteByte(MSG_ENTITY, self.team);
 337                 WriteByte(MSG_ENTITY, self.active);
 338         }
 339
 340         return true;
 341 }
 342
 343 void trigger_push_updatelink()
 344 {SELFPARAM();
 345         self.SendFlags |= 1;
 346 }
 347
 348 void trigger_push_link()
 349 {
 350         //Net_LinkEntity(self, false, 0, trigger_push_send);
 351 }
 352 #endif
 353 #ifdef SVQC
 354 /*
 355  * ENTITY PARAMETERS:
 356  *
 357  *   target:  target of jump
 358  *   height:  the absolute value is the height of the highest point of the jump
 359  *            trajectory above the higher one of the player and the target.
 360  *            the sign indicates whether the highest point is INSIDE (positive)
 361  *            or OUTSIDE (negative) of the jump trajectory. General rule: use
 362  *            positive values for targets mounted on the floor, and use negative
 363  *            values to target a point on the ceiling.
 364  *   movedir: if target is not set, this * speed * 10 is the velocity to be reached.
 365  */
 366 void spawnfunc_trigger_push()
 367 {SELFPARAM();
 368         SetMovedir ();
 369
 370         EXACTTRIGGER_INIT;
 371
 372         self.active = ACTIVE_ACTIVE;
 373         self.use = trigger_push_use;
 374         self.touch = trigger_push_touch;
 375
 376         // normal push setup
 377         if (!self.speed)
 378                 self.speed = 1000;
 379         self.movedir = self.movedir * self.speed * 10;
 380
 381         if (!self.noise)
 382                 self.noise = "misc/jumppad.wav";
 383         precache_sound (self.noise);
 384
 385         // this must be called to spawn the teleport waypoints for bots
 386         InitializeEntity(self, trigger_push_findtarget, INITPRIO_FINDTARGET);
 387 }
 388
 389
 390 float target_push_send(entity to, float sf)
 391 {SELFPARAM();
 392         WriteByte(MSG_ENTITY, ENT_CLIENT_TARGET_PUSH);
 393
 394         WriteByte(MSG_ENTITY, self.cnt);
 395         WriteString(MSG_ENTITY, self.targetname);
 396         WriteCoord(MSG_ENTITY, self.origin_x);
 397         WriteCoord(MSG_ENTITY, self.origin_y);
 398         WriteCoord(MSG_ENTITY, self.origin_z);
 399
 400         return true;
 401 }
 402
 403 void target_push_link()
 404 {SELFPARAM();
 405         Net_LinkEntity(self, false, 0, target_push_send);
 406         self.SendFlags |= 1; // update
 407 }
 408
 409 void spawnfunc_target_push() { target_push_link(); }
 410 void spawnfunc_info_notnull() { target_push_link(); }
 411 void spawnfunc_target_position() { target_push_link(); }
 412
 413 #endif
 414
 415 #ifdef CSQC
 416
 417 void ent_trigger_push()
 418 {SELFPARAM();
 419         float sf = ReadByte();
 420
 421         if(sf & 1)
 422         {
 423                 self.classname = "jumppad";
 424                 int mytm = ReadByte(); if(mytm) { self.team = mytm - 1; }
 425                 self.spawnflags = ReadInt24_t();
 426                 self.active = ReadByte();
 427                 self.height = ReadByte();
 428
 429                 trigger_common_read(true);
 430
 431                 self.entremove = trigger_remove_generic;
 432                 self.solid = SOLID_TRIGGER;
 433                 self.draw = trigger_draw_generic;
 434                 self.trigger_touch = trigger_push_touch;
 435                 self.drawmask = MASK_NORMAL;
 436                 self.move_time = time;
 437                 trigger_push_findtarget();
 438         }
 439
 440         if(sf & 2)
 441         {
 442                 self.team = ReadByte();
 443                 self.active = ReadByte();
 444         }
 445 }
 446
 447 void target_push_remove()
 448 {SELFPARAM();
 449         if(self.classname)
 450                 strunzone(self.classname);
 451         self.classname = string_null;
 452
 453         if(self.targetname)
 454                 strunzone(self.targetname);
 455         self.targetname = string_null;
 456 }
 457
 458 void ent_target_push()
 459 {SELFPARAM();
 460         self.classname = "push_target";
 461         self.cnt = ReadByte();
 462         self.targetname = strzone(ReadString());
 463         self.origin_x = ReadCoord();
 464         self.origin_y = ReadCoord();
 465         self.origin_z = ReadCoord();
 466         setorigin(self, self.origin);
 467
 468         self.drawmask = MASK_NORMAL;
 469         self.entremove = target_push_remove;
 470 }
 471 #endif