qcsrc/common/turrets/turret/hk.qc

   1 #ifndef TUR_HK_H
   2 #define TUR_HK_H
   3
   4 CLASS(HunterKiller, Turret)
   5 /* spawnflags */ ATTRIB(HunterKiller, spawnflags, int, TUR_FLAG_SPLASH | TUR_FLAG_MEDPROJ | TUR_FLAG_PLAYER | TUR_FLAG_RECIEVETARGETS);
   6 /* mins       */ ATTRIB(HunterKiller, mins, vector, '-32 -32 0');
   7 /* maxs       */ ATTRIB(HunterKiller, maxs, vector, '32 32 64');
   8 /* modelname  */ ATTRIB(HunterKiller, mdl, string, "base.md3");
   9 /* model      */ ATTRIB(HunterKiller, model, string, strzone(strcat("models/turrets/", this.mdl)));
  10 /* head_model */ ATTRIB(HunterKiller, head_model, string, strzone(strcat("models/turrets/", "hk.md3")));
  11 /* netname    */ ATTRIB(HunterKiller, netname, string, "hk");
  12 /* fullname   */ ATTRIB(HunterKiller, turret_name, string, _("Hunter-Killer Turret"));
  13 ENDCLASS(HunterKiller)
  14
  15 REGISTER_TURRET(HK, NEW(HunterKiller));
  16
  17 #endif
  18
  19 #ifdef IMPLEMENTATION
  20 #ifdef SVQC
  21 float autocvar_g_turrets_unit_hk_shot_speed;
  22 float autocvar_g_turrets_unit_hk_shot_speed_accel;
  23 float autocvar_g_turrets_unit_hk_shot_speed_accel2;
  24 float autocvar_g_turrets_unit_hk_shot_speed_decel;
  25 float autocvar_g_turrets_unit_hk_shot_speed_max;
  26 float autocvar_g_turrets_unit_hk_shot_speed_turnrate;
  27
  28 //#define TURRET_DEBUG_HK
  29
  30 #ifdef TURRET_DEBUG_HK
  31 .float atime;
  32 #endif
  33
  34 float hk_is_valid_target(entity e_target)
  35 {SELFPARAM();
  36     if (e_target == world)
  37         return 0;
  38
  39     // If only this was used more..
  40     if (e_target.flags & FL_NOTARGET)
  41         return 0;
  42
  43     // Cant touch this
  44     if ((e_target.takedamage == DAMAGE_NO) || (e_target.health < 0))
  45         return 0;
  46
  47     // player
  48     if (IS_CLIENT(e_target))
  49     {
  50         if (self.owner.target_select_playerbias < 0)
  51             return 0;
  52
  53         if (e_target.deadflag != DEAD_NO)
  54             return 0;
  55     }
  56
  57     // Missile
  58     if ((e_target.flags & FL_PROJECTILE) && (self.owner.target_select_missilebias < 0))
  59         return 0;
  60
  61     // Team check
  62     if ((e_target.team == self.owner.team) || (self.owner.team == e_target.owner.team))
  63         return 0;
  64
  65     return 1;
  66 }
  67
  68 void turret_hk_missile_think()
  69 {SELFPARAM();
  70     vector vu, vd, vf, vl, vr, ve;  // Vector (direction)
  71     float  fu, fd, ff, fl, fr, fe;  // Fraction to solid
  72     vector olddir,wishdir,newdir;   // Final direction
  73     float lt_for;   // Length of Trace FORwrad
  74     float lt_seek;  // Length of Trace SEEK (left, right, up down)
  75     float pt_seek;  // Pitch of Trace SEEK (How mutch to angele left, right up, down trace towards v_forward)
  76     vector pre_pos;
  77     float myspeed;
  78     entity e;
  79     float ad,edist;
  80
  81     self.nextthink = time + self.ticrate;
  82
  83     //if (self.cnt < time)
  84     //  turret_hk_missile_explode();
  85
  86     if (self.enemy.deadflag != DEAD_NO)
  87         self.enemy = world;
  88
  89     // Pick the closest valid target.
  90     if (!self.enemy)
  91     {
  92         e = findradius(self.origin, 5000);
  93         while (e)
  94         {
  95             if (hk_is_valid_target(e))
  96             {
  97                 if (!self.enemy)
  98                     self.enemy = e;
  99                 else
 100                     if (vlen(self.origin - e.origin) < vlen(self.origin - self.enemy.origin))
 101                         self.enemy = e;
 102             }
 103             e = e.chain;
 104         }
 105     }
 106
 107     self.angles = vectoangles(self.velocity);
 108     self.angles_x = self.angles_x * -1;
 109     makevectors(self.angles);
 110     self.angles_x = self.angles_x * -1;
 111
 112     if (self.enemy)
 113     {
 114         edist = vlen(self.origin - self.enemy.origin);
 115         // Close enougth to do decent damage?
 116         if ( edist <= (self.owner.shot_radius * 0.25) )
 117         {
 118             turret_projectile_explode();
 119             return;
 120         }
 121
 122         // Get data on enemy position
 123         pre_pos = self.enemy.origin +
 124                   self.enemy.velocity *
 125                   min((vlen(self.enemy.origin - self.origin) / vlen(self.velocity)),0.5);
 126
 127         traceline(self.origin, pre_pos,true,self.enemy);
 128         ve = normalize(pre_pos - self.origin);
 129         fe = trace_fraction;
 130
 131     }
 132     else
 133     {
 134     edist = 0;
 135     ve = '0 0 0';
 136         fe = 0;
 137     }
 138
 139     if ((fe != 1) || (self.enemy == world) || (edist > 1000))
 140     {
 141         myspeed = vlen(self.velocity);
 142
 143         lt_for  = myspeed * 3;
 144         lt_seek = myspeed * 2.95;
 145
 146         // Trace forward
 147         traceline(self.origin, self.origin + v_forward * lt_for,false,self);
 148         vf = trace_endpos;
 149         ff = trace_fraction;
 150
 151         // Find angular offset
 152         ad = vlen(vectoangles(normalize(self.enemy.origin - self.origin)) - self.angles);
 153
 154         // To close to something, Slow down!
 155         if ( ((ff < 0.7) || (ad > 4)) && (myspeed > (autocvar_g_turrets_unit_hk_shot_speed)) )
 156             myspeed = max(myspeed * (autocvar_g_turrets_unit_hk_shot_speed_decel), (autocvar_g_turrets_unit_hk_shot_speed));
 157
 158         // Failry clear, accelerate.
 159         if ( (ff > 0.7) && (myspeed < (autocvar_g_turrets_unit_hk_shot_speed_max)) )
 160             myspeed = min(myspeed * (autocvar_g_turrets_unit_hk_shot_speed_accel), (autocvar_g_turrets_unit_hk_shot_speed_max));
 161
 162         // Setup trace pitch
 163         pt_seek = 1 - ff;
 164         pt_seek = bound(0.15,pt_seek,0.8);
 165         if (ff < 0.5) pt_seek = 1;
 166
 167         // Trace left
 168         traceline(self.origin, self.origin + (-1 * (v_right * pt_seek) + (v_forward * ff)) * lt_seek,false,self);
 169         vl = trace_endpos;
 170         fl = trace_fraction;
 171
 172         // Trace right
 173         traceline(self.origin,  self.origin + ((v_right * pt_seek) + (v_forward * ff)) * lt_seek ,false,self);
 174         vr = trace_endpos;
 175         fr = trace_fraction;
 176
 177         // Trace up
 178         traceline(self.origin,  self.origin + ((v_up * pt_seek) + (v_forward * ff)) * lt_seek ,false,self);
 179         vu = trace_endpos;
 180         fu = trace_fraction;
 181
 182         // Trace down
 183         traceline(self.origin,  self.origin + (-1 * (v_up * pt_seek) + (v_forward * ff)) * lt_seek ,false,self);
 184         vd = trace_endpos;
 185         fd = trace_fraction;
 186
 187         vl = normalize(vl - self.origin);
 188         vr = normalize(vr - self.origin);
 189         vu = normalize(vu - self.origin);
 190         vd = normalize(vd - self.origin);
 191
 192         // Panic tresh passed, find a single direction and turn as hard as we can
 193         if (pt_seek == 1)
 194         {
 195             wishdir = v_right;
 196             if (fl > fr) wishdir = -1 * v_right;
 197             if (fu > fl) wishdir = v_up;
 198             if (fd > fu) wishdir = -1 * v_up;
 199         }
 200         else
 201         {
 202             // Normalize our trace vectors to make a smooth path
 203             wishdir = normalize( (vl * fl) + (vr * fr) +  (vu * fu) +  (vd * fd) );
 204         }
 205
 206         if (self.enemy)
 207         {
 208             if (fe < 0.1) fe = 0.1; // Make sure we always try to move sligtly towards our target
 209             wishdir = (wishdir * (1 - fe)) + (ve * fe);
 210         }
 211     }
 212     else
 213     {
 214         // Got a clear path to target, speed up fast (if not at full speed) and go straight for it.
 215         myspeed = vlen(self.velocity);
 216         if (myspeed < (autocvar_g_turrets_unit_hk_shot_speed_max))
 217             myspeed = min(myspeed * (autocvar_g_turrets_unit_hk_shot_speed_accel2),(autocvar_g_turrets_unit_hk_shot_speed_max));
 218
 219         wishdir = ve;
 220     }
 221
 222     if ((myspeed > (autocvar_g_turrets_unit_hk_shot_speed)) && (self.cnt > time))
 223         myspeed = min(myspeed * (autocvar_g_turrets_unit_hk_shot_speed_accel2),(autocvar_g_turrets_unit_hk_shot_speed_max));
 224
 225     // Ranoutagazfish?
 226     if (self.cnt < time)
 227     {
 228         self.cnt = time + 0.25;
 229         self.nextthink = 0;
 230         self.movetype            = MOVETYPE_BOUNCE;
 231         return;
 232     }
 233
 234     // Calculate new heading
 235     olddir = normalize(self.velocity);
 236     newdir = normalize(olddir + wishdir * (autocvar_g_turrets_unit_hk_shot_speed_turnrate));
 237
 238     // Set heading & speed
 239     self.velocity = newdir * myspeed;
 240
 241     // Align model with new heading
 242     self.angles = vectoangles(self.velocity);
 243
 244
 245 #ifdef TURRET_DEBUG_HK
 246     //if(self.atime < time) {
 247     if ((fe <= 0.99)||(edist > 1000))
 248     {
 249         te_lightning2(world,self.origin, self.origin + vr * lt_seek);
 250         te_lightning2(world,self.origin, self.origin + vl * lt_seek);
 251         te_lightning2(world,self.origin, self.origin + vu * lt_seek);
 252         te_lightning2(world,self.origin, self.origin + vd * lt_seek);
 253         te_lightning2(world,self.origin, vf);
 254     }
 255     else
 256     {
 257         te_lightning2(world,self.origin, self.enemy.origin);
 258     }
 259     bprint("Speed: ", ftos(rint(myspeed)), "\n");
 260     bprint("Trace to solid: ", ftos(rint(ff * 100)), "%\n");
 261     bprint("Trace to target:", ftos(rint(fe * 100)), "%\n");
 262     self.atime = time + 0.2;
 263     //}
 264 #endif
 265
 266     UpdateCSQCProjectile(self);
 267 }
 268
 269 float turret_hk_addtarget(entity e_target,entity e_sender)
 270 {SELFPARAM();
 271     if (e_target)
 272     {
 273         if (turret_validate_target(self,e_target,self.target_validate_flags) > 0)
 274         {
 275             self.enemy = e_target;
 276             return 1;
 277         }
 278     }
 279
 280     return 0;
 281 }
 282
 283 void spawnfunc_turret_hk() { SELFPARAM(); if(!turret_initialize(TUR_HK.m_id)) remove(self); }
 284
 285         METHOD(HunterKiller, tr_attack, void(HunterKiller thistur))
 286         {
 287             entity missile;
 288
 289             missile = turret_projectile(SND(ROCKET_FIRE), 6, 10, DEATH_TURRET_HK, PROJECTILE_ROCKET, FALSE, FALSE);
 290             te_explosion (missile.origin);
 291
 292             missile.think                       = turret_hk_missile_think;
 293             missile.nextthink           = time + 0.25;
 294             missile.movetype             = MOVETYPE_BOUNCEMISSILE;
 295             missile.velocity             = self.tur_shotdir_updated * (self.shot_speed * 0.75);
 296             missile.angles                 = vectoangles(missile.velocity);
 297             missile.cnt                   = time + 30;
 298             missile.ticrate               = max(autocvar_sys_ticrate, 0.05);
 299             missile.missile_flags = MIF_SPLASH | MIF_PROXY | MIF_GUIDED_AI;
 300
 301             if (self.tur_head.frame == 0)
 302                 self.tur_head.frame = self.tur_head.frame + 1;
 303         }
 304         METHOD(HunterKiller, tr_think, bool(HunterKiller thistur))
 305         {
 306             if (self.tur_head.frame != 0)
 307                 self.tur_head.frame = self.tur_head.frame + 1;
 308
 309             if (self.tur_head.frame > 5)
 310                 self.tur_head.frame = 0;
 311
 312             return true;
 313         }
 314         METHOD(HunterKiller, tr_death, bool(HunterKiller thistur))
 315         {
 316             return true;
 317         }
 318         METHOD(HunterKiller, tr_setup, bool(HunterKiller thistur))
 319         {
 320             self.ammo_flags = TFL_AMMO_ROCKETS | TFL_AMMO_RECHARGE;
 321             self.aim_flags = TFL_AIM_SIMPLE;
 322             self.target_select_flags = TFL_TARGETSELECT_LOS | TFL_TARGETSELECT_PLAYERS | TFL_TARGETSELECT_TRIGGERTARGET | TFL_TARGETSELECT_RANGELIMITS | TFL_TARGETSELECT_TEAMCHECK;
 323             self.firecheck_flags = TFL_FIRECHECK_DEAD | TFL_FIRECHECK_TEAMCHECK  | TFL_FIRECHECK_REFIRE | TFL_FIRECHECK_AFF;
 324             self.shoot_flags = TFL_SHOOT_CLEARTARGET;
 325             self.target_validate_flags = TFL_TARGETSELECT_PLAYERS | TFL_TARGETSELECT_TEAMCHECK;
 326
 327             self.turret_addtarget = turret_hk_addtarget;
 328
 329             return true;
 330         }
 331         METHOD(HunterKiller, tr_precache, bool(HunterKiller thistur))
 332         {
 333             return true;
 334         }
 335
 336 #endif // SVQC
 337 #ifdef CSQC
 338         METHOD(HunterKiller, tr_setup, bool(HunterKiller thistur))
 339         {
 340             return true;
 341         }
 342         METHOD(HunterKiller, tr_precache, bool(HunterKiller thistur))
 343         {
 344             return true;
 345         }
 346
 347 #endif // CSQC
 348 #endif // REGISTER_TURRET