qcsrc/common/turrets/turret/walker.qc

   1 #ifndef TUR_WALKER_H
   2 #define TUR_WALKER_H
   3
   4 CLASS(WalkerTurret, Turret)
   5 /* spawnflags */ ATTRIB(WalkerTurret, spawnflags, int, TUR_FLAG_PLAYER | TUR_FLAG_MOVE);
   6 /* mins       */ ATTRIB(WalkerTurret, mins, vector, '-70 -70 0');
   7 /* maxs       */ ATTRIB(WalkerTurret, maxs, vector, '70 70 95');
   8 /* modelname  */ ATTRIB(WalkerTurret, mdl, string, "walker_body.md3");
   9 /* model      */ ATTRIB(WalkerTurret, model, string, strzone(strcat("models/turrets/", this.mdl)));
  10 /* head_model */ ATTRIB(WalkerTurret, head_model, string, strzone(strcat("models/turrets/", "walker_head_minigun.md3")));
  11 /* netname    */ ATTRIB(WalkerTurret, netname, string, "walker");
  12 /* fullname   */ ATTRIB(WalkerTurret, turret_name, string, _("Walker Turret"));
  13 ENDCLASS(WalkerTurret)
  14
  15 REGISTER_TURRET(WALKER, NEW(WalkerTurret));
  16
  17 #endif
  18
  19 #ifdef IMPLEMENTATION
  20 #ifdef SVQC
  21 float autocvar_g_turrets_unit_walker_melee_damage;
  22 float autocvar_g_turrets_unit_walker_melee_force;
  23 float autocvar_g_turrets_unit_walker_melee_range;
  24 float autocvar_g_turrets_unit_walker_rocket_damage;
  25 float autocvar_g_turrets_unit_walker_rocket_radius;
  26 float autocvar_g_turrets_unit_walker_rocket_force;
  27 float autocvar_g_turrets_unit_walker_rocket_speed;
  28 float autocvar_g_turrets_unit_walker_rocket_range;
  29 float autocvar_g_turrets_unit_walker_rocket_range_min;
  30 float autocvar_g_turrets_unit_walker_rocket_refire;
  31 float autocvar_g_turrets_unit_walker_rocket_turnrate;
  32 float autocvar_g_turrets_unit_walker_speed_stop;
  33 float autocvar_g_turrets_unit_walker_speed_walk;
  34 float autocvar_g_turrets_unit_walker_speed_run;
  35 float autocvar_g_turrets_unit_walker_speed_jump;
  36 float autocvar_g_turrets_unit_walker_speed_swim;
  37 float autocvar_g_turrets_unit_walker_speed_roam;
  38 float autocvar_g_turrets_unit_walker_turn;
  39 float autocvar_g_turrets_unit_walker_turn_walk;
  40 float autocvar_g_turrets_unit_walker_turn_strafe;
  41 float autocvar_g_turrets_unit_walker_turn_swim;
  42 float autocvar_g_turrets_unit_walker_turn_run;
  43
  44 #define ANIM_NO         0
  45 #define ANIM_TURN       1
  46 #define ANIM_WALK       2
  47 #define ANIM_RUN        3
  48 #define ANIM_STRAFE_L   4
  49 #define ANIM_STRAFE_R   5
  50 #define ANIM_JUMP       6
  51 #define ANIM_LAND       7
  52 #define ANIM_PAIN       8
  53 #define ANIM_MELEE      9
  54 #define ANIM_SWIM       10
  55 #define ANIM_ROAM       11
  56
  57 .float animflag;
  58 .float idletime;
  59
  60 #define WALKER_PATH(s,e) pathlib_astar(s,e)
  61
  62 float walker_firecheck()
  63 {SELFPARAM();
  64     if (self.animflag == ANIM_MELEE)
  65         return 0;
  66
  67     return turret_firecheck();
  68 }
  69
  70 void walker_melee_do_dmg()
  71 {SELFPARAM();
  72     vector where;
  73     entity e;
  74
  75     makevectors(self.angles);
  76     where = self.origin + v_forward * 128;
  77
  78     e = findradius(where,32);
  79     while (e)
  80     {
  81         if (turret_validate_target(self, e, self.target_validate_flags))
  82             if (e != self && e.owner != self)
  83                 Damage(e, self, self, (autocvar_g_turrets_unit_walker_melee_damage), DEATH_TURRET_WALK_MELEE, '0 0 0', v_forward * (autocvar_g_turrets_unit_walker_melee_force));
  84
  85         e = e.chain;
  86     }
  87 }
  88
  89 void walker_setnoanim()
  90 {SELFPARAM();
  91     turrets_setframe(ANIM_NO, false);
  92     self.animflag = self.frame;
  93 }
  94 void walker_rocket_explode()
  95 {SELFPARAM();
  96     RadiusDamage (self, self.owner, (autocvar_g_turrets_unit_walker_rocket_damage), 0, (autocvar_g_turrets_unit_walker_rocket_radius), self, world, (autocvar_g_turrets_unit_walker_rocket_force), DEATH_TURRET_WALK_ROCKET, world);
  97     remove (self);
  98 }
  99
 100 void walker_rocket_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector vforce)
 101 {SELFPARAM();
 102     self.health = self.health - damage;
 103     self.velocity = self.velocity + vforce;
 104
 105     if (self.health <= 0)
 106         W_PrepareExplosionByDamage(self.owner, walker_rocket_explode);
 107 }
 108
 109 #define WALKER_ROCKET_MOVE movelib_move_simple(newdir, (autocvar_g_turrets_unit_walker_rocket_speed), (autocvar_g_turrets_unit_walker_rocket_turnrate)); UpdateCSQCProjectile(self)
 110 void walker_rocket_loop();
 111 void walker_rocket_think()
 112 {SELFPARAM();
 113     vector newdir;
 114     float edist;
 115     float itime;
 116     float m_speed;
 117
 118     self.nextthink = time;
 119
 120     edist = vlen(self.enemy.origin - self.origin);
 121
 122     // Simulate crude guidance
 123     if (self.cnt < time)
 124     {
 125         if (edist < 1000)
 126             self.tur_shotorg = randomvec() * min(edist, 64);
 127         else
 128             self.tur_shotorg = randomvec() * min(edist, 256);
 129
 130         self.cnt = time + 0.5;
 131     }
 132
 133     if (edist < 128)
 134         self.tur_shotorg = '0 0 0';
 135
 136     if (self.max_health < time)
 137     {
 138         self.think        = walker_rocket_explode;
 139         self.nextthink  = time;
 140         return;
 141     }
 142
 143     if (self.shot_dmg != 1337 && random() < 0.01)
 144     {
 145         walker_rocket_loop();
 146         return;
 147     }
 148
 149     m_speed = vlen(self.velocity);
 150
 151     // Enemy dead? just keep on the current heading then.
 152     if (self.enemy == world || self.enemy.deadflag != DEAD_NO)
 153         self.enemy = world;
 154
 155     if (self.enemy)
 156     {
 157         itime = max(edist / m_speed, 1);
 158         newdir = steerlib_pull(self.enemy.origin + self.tur_shotorg);
 159     }
 160     else
 161         newdir  = normalize(self.velocity);
 162
 163     WALKER_ROCKET_MOVE;
 164 }
 165
 166 void walker_rocket_loop3()
 167 {SELFPARAM();
 168     vector newdir;
 169     self.nextthink = time;
 170
 171     if (self.max_health < time)
 172     {
 173         self.think = walker_rocket_explode;
 174         return;
 175     }
 176
 177     if (vlen(self.origin - self.tur_shotorg) < 100 )
 178     {
 179         self.think = walker_rocket_think;
 180         return;
 181     }
 182
 183     newdir = steerlib_pull(self.tur_shotorg);
 184     WALKER_ROCKET_MOVE;
 185
 186     self.angles = vectoangles(self.velocity);
 187 }
 188
 189 void walker_rocket_loop2()
 190 {SELFPARAM();
 191     vector newdir;
 192
 193     self.nextthink = time;
 194
 195     if (self.max_health < time)
 196     {
 197         self.think = walker_rocket_explode;
 198         return;
 199     }
 200
 201     if (vlen(self.origin - self.tur_shotorg) < 100 )
 202     {
 203         self.tur_shotorg = self.origin - '0 0 200';
 204         self.think = walker_rocket_loop3;
 205         return;
 206     }
 207
 208     newdir = steerlib_pull(self.tur_shotorg);
 209     WALKER_ROCKET_MOVE;
 210 }
 211
 212 void walker_rocket_loop()
 213 {SELFPARAM();
 214     self.nextthink = time;
 215     self.tur_shotorg = self.origin + '0 0 300';
 216     self.think = walker_rocket_loop2;
 217     self.shot_dmg = 1337;
 218 }
 219
 220 void walker_fire_rocket(vector org)
 221 {SELFPARAM();
 222     entity rocket;
 223
 224     fixedmakevectors(self.angles);
 225
 226     te_explosion (org);
 227
 228     rocket = spawn ();
 229     setorigin(rocket, org);
 230
 231     sound (self, CH_WEAPON_A, SND_HAGAR_FIRE, VOL_BASE, ATTEN_NORM);
 232     setsize (rocket, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 233
 234     rocket.classname              = "walker_rocket";
 235     rocket.owner                          = self;
 236     rocket.bot_dodge              = true;
 237     rocket.bot_dodgerating      = 50;
 238     rocket.takedamage            = DAMAGE_YES;
 239     rocket.damageforcescale   = 2;
 240     rocket.health                        = 25;
 241     rocket.tur_shotorg          = randomvec() * 512;
 242     rocket.cnt                          = time + 1;
 243     rocket.enemy                          = self.enemy;
 244
 245     if (random() < 0.01)
 246         rocket.think              = walker_rocket_loop;
 247     else
 248         rocket.think              = walker_rocket_think;
 249
 250     rocket.event_damage    = walker_rocket_damage;
 251
 252     rocket.nextthink              = time;
 253     rocket.movetype                = MOVETYPE_FLY;
 254     rocket.velocity                = normalize((v_forward + v_up * 0.5) + (randomvec() * 0.2)) * (autocvar_g_turrets_unit_walker_rocket_speed);
 255     rocket.angles                        = vectoangles(rocket.velocity);
 256     rocket.touch                          = walker_rocket_explode;
 257     rocket.flags                          = FL_PROJECTILE;
 258     rocket.solid                          = SOLID_BBOX;
 259     rocket.max_health            = time + 9;
 260     rocket.missile_flags = MIF_SPLASH | MIF_PROXY | MIF_GUIDED_HEAT;
 261
 262     CSQCProjectile(rocket, false, PROJECTILE_ROCKET, false); // no culling, has fly sound
 263 }
 264
 265 .vector enemy_last_loc;
 266 .float enemy_last_time;
 267 void walker_move_to(vector _target, float _dist)
 268 {SELFPARAM();
 269     switch (self.waterlevel)
 270     {
 271         case WATERLEVEL_NONE:
 272             if (_dist > 500)
 273                 self.animflag = ANIM_RUN;
 274             else
 275                 self.animflag = ANIM_WALK;
 276         case WATERLEVEL_WETFEET:
 277         case WATERLEVEL_SWIMMING:
 278             if (self.animflag != ANIM_SWIM)
 279                 self.animflag = ANIM_WALK;
 280             else
 281                 self.animflag = ANIM_SWIM;
 282             break;
 283         case WATERLEVEL_SUBMERGED:
 284             self.animflag = ANIM_SWIM;
 285     }
 286
 287     self.moveto = _target;
 288     self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 289
 290     if(self.enemy)
 291     {
 292         self.enemy_last_loc = _target;
 293         self.enemy_last_time = time;
 294     }
 295 }
 296
 297 //#define WALKER_FANCYPATHING
 298
 299 void walker_move_path()
 300 {SELFPARAM();
 301 #ifdef WALKER_FANCYPATHING
 302     // Are we close enougth to a path node to switch to the next?
 303     if (vlen(self.origin  - self.pathcurrent.origin) < 64)
 304         if (self.pathcurrent.path_next == world)
 305         {
 306             // Path endpoint reached
 307             pathlib_deletepath(self.pathcurrent.owner);
 308             self.pathcurrent = world;
 309
 310             if (self.pathgoal)
 311             {
 312                 if (self.pathgoal.use)
 313                     self.pathgoal.use();
 314
 315                 if (self.pathgoal.enemy)
 316                 {
 317                     self.pathcurrent = WALKER_PATH(self.pathgoal.origin,self.pathgoal.enemy.origin);
 318                     self.pathgoal = self.pathgoal.enemy;
 319                 }
 320             }
 321             else
 322                 self.pathgoal = world;
 323         }
 324         else
 325             self.pathcurrent = self.pathcurrent.path_next;
 326
 327     self.moveto = self.pathcurrent.origin;
 328     self.steerto = steerlib_attract2(self.moveto,0.5,500,0.95);
 329     walker_move_to(self.moveto, 0);
 330
 331 #else
 332     if (vlen(self.origin - self.pathcurrent.origin) < 64)
 333         self.pathcurrent = self.pathcurrent.enemy;
 334
 335     if(!self.pathcurrent)
 336         return;
 337
 338     self.moveto = self.pathcurrent.origin;
 339     self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 340     walker_move_to(self.moveto, 0);
 341 #endif
 342 }
 343
 344 void spawnfunc_turret_walker() { SELFPARAM(); if(!turret_initialize(TUR_WALKER.m_id)) remove(self); }
 345
 346         METHOD(WalkerTurret, tr_attack, bool(WalkerTurret thistur))
 347         {
 348             sound (self, CH_WEAPON_A, SND_UZI_FIRE, VOL_BASE, ATTEN_NORM);
 349             fireBullet (self.tur_shotorg, self.tur_shotdir_updated, self.shot_spread, 0, self.shot_dmg, self.shot_force, DEATH_TURRET_WALK_GUN, 0);
 350             Send_Effect(EFFECT_BLASTER_MUZZLEFLASH, self.tur_shotorg, self.tur_shotdir_updated * 1000, 1);
 351
 352             return true;
 353         }
 354         METHOD(WalkerTurret, tr_think, bool(WalkerTurret thistur))
 355         {
 356             fixedmakevectors(self.angles);
 357
 358             if (self.spawnflags & TSF_NO_PATHBREAK && self.pathcurrent)
 359                 walker_move_path();
 360             else if (self.enemy == world)
 361             {
 362                 if(self.pathcurrent)
 363                     walker_move_path();
 364                 else
 365                 {
 366                     if(self.enemy_last_time != 0)
 367                     {
 368                         if(vlen(self.origin - self.enemy_last_loc) < 128 || time - self.enemy_last_time > 10)
 369                             self.enemy_last_time = 0;
 370                         else
 371                             walker_move_to(self.enemy_last_loc, 0);
 372                     }
 373                     else
 374                     {
 375                         if(self.animflag != ANIM_NO)
 376                         {
 377                             traceline(self.origin + '0 0 64', self.origin + '0 0 64' + v_forward * 128, MOVE_NORMAL, self);
 378
 379                             if(trace_fraction != 1.0)
 380                                 self.tur_head.idletime = -1337;
 381                             else
 382                             {
 383                                 traceline(trace_endpos, trace_endpos - '0 0 256', MOVE_NORMAL, self);
 384                                 if(trace_fraction == 1.0)
 385                                     self.tur_head.idletime = -1337;
 386                             }
 387
 388                             if(self.tur_head.idletime == -1337)
 389                             {
 390                                 self.moveto = self.origin + randomvec() * 256;
 391                                 self.tur_head.idletime = 0;
 392                             }
 393
 394                             self.moveto = self.moveto * 0.9 + ((self.origin + v_forward * 500) + randomvec() * 400) * 0.1;
 395                             self.moveto_z = self.origin_z + 64;
 396                             walker_move_to(self.moveto, 0);
 397                         }
 398
 399                         if(self.idletime < time)
 400                         {
 401                             if(random() < 0.5 || !(self.spawnflags & TSL_ROAM))
 402                             {
 403                                 self.idletime = time + 1 + random() * 5;
 404                                 self.moveto = self.origin;
 405                                 self.animflag = ANIM_NO;
 406                             }
 407                             else
 408                             {
 409                                 self.animflag = ANIM_WALK;
 410                                 self.idletime = time + 4 + random() * 2;
 411                                 self.moveto = self.origin + randomvec() * 256;
 412                                 self.tur_head.moveto = self.moveto;
 413                                 self.tur_head.idletime = 0;
 414                             }
 415                         }
 416                     }
 417                 }
 418             }
 419             else
 420             {
 421                 if (self.tur_dist_enemy < (autocvar_g_turrets_unit_walker_melee_range) && self.animflag != ANIM_MELEE)
 422                 {
 423                     vector wish_angle;
 424
 425                     wish_angle = angleofs(self, self.enemy);
 426                     if (self.animflag != ANIM_SWIM)
 427                     if (fabs(wish_angle_y) < 15)
 428                     {
 429                         self.moveto   = self.enemy.origin;
 430                         self.steerto  = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 431                         self.animflag = ANIM_MELEE;
 432                     }
 433                 }
 434                 else if (self.tur_head.attack_finished_single < time)
 435                 {
 436                     if(self.tur_head.shot_volly)
 437                     {
 438                         self.animflag = ANIM_NO;
 439
 440                         self.tur_head.shot_volly = self.tur_head.shot_volly -1;
 441                         if(self.tur_head.shot_volly == 0)
 442                             self.tur_head.attack_finished_single = time + (autocvar_g_turrets_unit_walker_rocket_refire);
 443                         else
 444                             self.tur_head.attack_finished_single = time + 0.2;
 445
 446                         if(self.tur_head.shot_volly > 1)
 447                             walker_fire_rocket(gettaginfo(self, gettagindex(self, "tag_rocket01")));
 448                         else
 449                             walker_fire_rocket(gettaginfo(self, gettagindex(self, "tag_rocket02")));
 450                     }
 451                     else
 452                     {
 453                         if (self.tur_dist_enemy > (autocvar_g_turrets_unit_walker_rocket_range_min))
 454                         if (self.tur_dist_enemy < (autocvar_g_turrets_unit_walker_rocket_range))
 455                             self.tur_head.shot_volly = 4;
 456                     }
 457                 }
 458                 else
 459                 {
 460                     if (self.animflag != ANIM_MELEE)
 461                         walker_move_to(self.enemy.origin, self.tur_dist_enemy);
 462                 }
 463             }
 464
 465             {
 466                 vector real_angle;
 467                 float turny = 0, turnx = 0;
 468                 float vz;
 469
 470                 real_angle = vectoangles(self.steerto) - self.angles;
 471                 vz = self.velocity_z;
 472
 473                 switch (self.animflag)
 474                 {
 475                     case ANIM_NO:
 476                         movelib_beak_simple((autocvar_g_turrets_unit_walker_speed_stop));
 477                         break;
 478
 479                     case ANIM_TURN:
 480                         turny = (autocvar_g_turrets_unit_walker_turn);
 481                         movelib_beak_simple((autocvar_g_turrets_unit_walker_speed_stop));
 482                         break;
 483
 484                     case ANIM_WALK:
 485                         turny = (autocvar_g_turrets_unit_walker_turn_walk);
 486                         movelib_move_simple(v_forward, (autocvar_g_turrets_unit_walker_speed_walk), 0.6);
 487                         break;
 488
 489                     case ANIM_RUN:
 490                         turny = (autocvar_g_turrets_unit_walker_turn_run);
 491                         movelib_move_simple(v_forward, (autocvar_g_turrets_unit_walker_speed_run), 0.6);
 492                         break;
 493
 494                     case ANIM_STRAFE_L:
 495                         turny = (autocvar_g_turrets_unit_walker_turn_strafe);
 496                         movelib_move_simple(v_right * -1, (autocvar_g_turrets_unit_walker_speed_walk), 0.8);
 497                         break;
 498
 499                     case ANIM_STRAFE_R:
 500                         turny = (autocvar_g_turrets_unit_walker_turn_strafe);
 501                         movelib_move_simple(v_right, (autocvar_g_turrets_unit_walker_speed_walk), 0.8);
 502                         break;
 503
 504                     case ANIM_JUMP:
 505                         self.velocity += '0 0 1' * (autocvar_g_turrets_unit_walker_speed_jump);
 506                         break;
 507
 508                     case ANIM_LAND:
 509                         break;
 510
 511                     case ANIM_PAIN:
 512                         if(self.frame != ANIM_PAIN)
 513                             defer(0.25, walker_setnoanim);
 514
 515                         break;
 516
 517                     case ANIM_MELEE:
 518                         if(self.frame != ANIM_MELEE)
 519                         {
 520                             defer(0.41, walker_setnoanim);
 521                             defer(0.21, walker_melee_do_dmg);
 522                         }
 523
 524                         movelib_beak_simple((autocvar_g_turrets_unit_walker_speed_stop));
 525                         break;
 526
 527                     case ANIM_SWIM:
 528                         turny = (autocvar_g_turrets_unit_walker_turn_swim);
 529                         turnx = (autocvar_g_turrets_unit_walker_turn_swim);
 530
 531                         self.angles_x += bound(-10, shortangle_f(real_angle_x, self.angles_x), 10);
 532                         movelib_move_simple(v_forward, (autocvar_g_turrets_unit_walker_speed_swim), 0.3);
 533                         vz = self.velocity_z + sin(time * 4) * 8;
 534                         break;
 535
 536                     case ANIM_ROAM:
 537                         turny = (autocvar_g_turrets_unit_walker_turn_walk);
 538                         movelib_move_simple(v_forward ,(autocvar_g_turrets_unit_walker_speed_roam), 0.5);
 539                         break;
 540                 }
 541
 542                 if(turny)
 543                 {
 544                     turny = bound( turny * -1, shortangle_f(real_angle_y, self.angles_y), turny );
 545                     self.angles_y += turny;
 546                 }
 547
 548                 if(turnx)
 549                 {
 550                     turnx = bound( turnx * -1, shortangle_f(real_angle_x, self.angles_x), turnx );
 551                     self.angles_x += turnx;
 552                 }
 553
 554                 self.velocity_z = vz;
 555             }
 556
 557
 558             if(self.origin != self.oldorigin)
 559                 self.SendFlags |= TNSF_MOVE;
 560
 561             self.oldorigin = self.origin;
 562             turrets_setframe(self.animflag, false);
 563
 564             return true;
 565         }
 566         METHOD(WalkerTurret, tr_death, bool(WalkerTurret thistur))
 567         {
 568 #ifdef WALKER_FANCYPATHING
 569             if (self.pathcurrent)
 570                 pathlib_deletepath(self.pathcurrent.owner);
 571 #endif
 572             self.pathcurrent = world;
 573
 574             return true;
 575         }
 576         METHOD(WalkerTurret, tr_setup, bool(WalkerTurret thistur))
 577         {
 578             self.ticrate = 0.05;
 579
 580             entity e;
 581
 582             // Respawn is called & first spawn to, to set team. need to make sure we do not move the initial spawn.
 583             if(self.movetype == MOVETYPE_WALK)
 584             {
 585                 if(self.pos1)
 586                     setorigin(self, self.pos1);
 587                 if(self.pos2)
 588                     self.angles = self.pos2;
 589             }
 590
 591             self.ammo_flags = TFL_AMMO_BULLETS | TFL_AMMO_RECHARGE | TFL_AMMO_RECIEVE;
 592             self.aim_flags = TFL_AIM_LEAD;
 593             self.turret_flags |= TUR_FLAG_HITSCAN;
 594
 595             self.target_select_flags = TFL_TARGETSELECT_PLAYERS | TFL_TARGETSELECT_RANGELIMITS | TFL_TARGETSELECT_TEAMCHECK | TFL_TARGETSELECT_LOS;
 596             self.target_validate_flags = TFL_TARGETSELECT_PLAYERS | TFL_TARGETSELECT_RANGELIMITS | TFL_TARGETSELECT_TEAMCHECK | TFL_TARGETSELECT_LOS;
 597             self.iscreature = true;
 598             self.teleportable = TELEPORT_NORMAL;
 599             self.damagedbycontents = true;
 600             self.solid = SOLID_SLIDEBOX;
 601             self.takedamage = DAMAGE_AIM;
 602             if(self.movetype != MOVETYPE_WALK)
 603             {
 604                 setorigin(self, self.origin);
 605                 tracebox(self.origin + '0 0 128', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_NORMAL, self);
 606                 setorigin(self, trace_endpos + '0 0 4');
 607                 self.pos1 = self.origin;
 608                 self.pos2 = self.angles;
 609             }
 610             self.movetype = MOVETYPE_WALK;
 611             self.idle_aim = '0 0 0';
 612             self.turret_firecheckfunc = walker_firecheck;
 613
 614             if (self.target != "")
 615             {
 616                 e = find(world, targetname, self.target);
 617                 if (!e)
 618                 {
 619                     LOG_TRACE("Initital waypoint for walker does NOT exsist, fix your map!\n");
 620                     self.target = "";
 621                 }
 622
 623                 if (e.classname != "turret_checkpoint")
 624                     LOG_TRACE("Warning: not a turrret path\n");
 625                 else
 626                 {
 627 #ifdef WALKER_FANCYPATHING
 628                     self.pathcurrent = WALKER_PATH(self.origin, e.origin);
 629                     self.pathgoal = e;
 630 #else
 631                     self.pathcurrent = e;
 632 #endif
 633                 }
 634             }
 635
 636             return true;
 637         }
 638         METHOD(WalkerTurret, tr_precache, bool(WalkerTurret thistur))
 639         {
 640             return true;
 641         }
 642
 643 #endif // SVQC
 644 #ifdef CSQC
 645
 646 #include "../../../client/movelib.qh"
 647
 648 void walker_draw()
 649 {SELFPARAM();
 650     float dt;
 651
 652     dt = time - self.move_time;
 653     self.move_time = time;
 654     if(dt <= 0)
 655         return;
 656
 657     fixedmakevectors(self.angles);
 658     movelib_groundalign4point(300, 100, 0.25, 45);
 659     setorigin(self, self.origin + self.velocity * dt);
 660     self.tur_head.angles += dt * self.tur_head.move_avelocity;
 661     self.angles_y = self.move_angles_y;
 662
 663     if (self.health < 127)
 664     if(random() < 0.15)
 665         te_spark(self.origin + '0 0 40', randomvec() * 256 + '0 0 256', 16);
 666 }
 667
 668         METHOD(WalkerTurret, tr_setup, bool(WalkerTurret thistur))
 669         {
 670             self.gravity                = 1;
 671             self.movetype               = MOVETYPE_BOUNCE;
 672             self.move_movetype  = MOVETYPE_BOUNCE;
 673             self.move_origin    = self.origin;
 674             self.move_time              = time;
 675             self.draw                   = walker_draw;
 676
 677             return true;
 678         }
 679         METHOD(WalkerTurret, tr_precache, bool(WalkerTurret thistur))
 680         {
 681             return true;
 682         }
 683
 684 #endif // CSQC
 685 #endif // REGISTER_TURRET