qcsrc/common/turrets/unit/phaser.qc

   1 #ifdef REGISTER_TURRET
   2 REGISTER_TURRET(
   3 /* TUR_##id   */ PHASER,
   4 /* function   */ t_phaser,
   5 /* spawnflags */ TUR_FLAG_SNIPER | TUR_FLAG_HITSCAN | TUR_FLAG_PLAYER,
   6 /* mins,maxs  */ '-32 -32 0', '32 32 64',
   7 /* model          */ "base.md3",
   8 /* head_model */ "phaser.md3",
   9 /* netname        */ "phaser",
  10 /* fullname   */ _("Phaser Cannon")
  11 );
  12
  13 #define PHASER_SETTINGS(turret)
  14
  15
  16 #ifdef SVQC
  17 PHASER_SETTINGS(phaser)
  18 #endif // SVQC
  19 #else
  20 #ifdef SVQC
  21
  22 .float fireflag;
  23
  24 float turret_phaser_firecheck()
  25 {
  26         if (self.fireflag != 0) return 0;
  27         return turret_firecheck();
  28 }
  29
  30 void beam_think()
  31 {
  32         if ((time > self.cnt) || (self.owner.deadflag != DEAD_NO))
  33         {
  34                 self.owner.attack_finished_single = time + self.owner.shot_refire;
  35                 self.owner.fireflag = 2;
  36                 self.owner.tur_head.frame = 10;
  37                 sound (self, CH_SHOTS_SINGLE, "misc/null.wav", VOL_BASE, ATTEN_NORM);
  38                 remove(self);
  39                 return;
  40         }
  41
  42         turret_do_updates(self.owner);
  43
  44         if (time - self.shot_spread > 0)
  45         {
  46                 self.shot_spread = time + 2;
  47                 sound (self, CH_SHOTS_SINGLE, "turrets/phaser.wav", VOL_BASE, ATTEN_NORM);
  48         }
  49
  50
  51         self.nextthink = time + self.ticrate;
  52
  53         self.owner.attack_finished_single = time + frametime;
  54         entity oldself;
  55         oldself = self;
  56         self = self.owner;
  57         FireImoBeam (   self.tur_shotorg,
  58                                         self.tur_shotorg + self.tur_shotdir_updated * self.target_range,
  59                                         '-1 -1 -1' * self.shot_radius,
  60                                         '1 1 1' * self.shot_radius,
  61                                         self.shot_force,
  62                                         oldself.shot_dmg,
  63                                         0.75,
  64                                         DEATH_TURRET_PHASER);
  65         self = oldself;
  66         self.scale = vlen(self.owner.tur_shotorg - trace_endpos) / 256;
  67
  68 }
  69
  70 void spawnfunc_turret_phaser() { if not(turret_initialize(TUR_PHASER)) remove(self); }
  71
  72 float t_phaser(float req)
  73 {
  74         switch(req)
  75         {
  76                 case TR_ATTACK:
  77                 {
  78                         entity beam;
  79
  80                         beam = spawn();
  81                         beam.ticrate = 0.1; //autocvar_sys_ticrate;
  82                         setmodel(beam,"models/turrets/phaser_beam.md3");
  83                         beam.effects = EF_LOWPRECISION;
  84                         beam.solid = SOLID_NOT;
  85                         beam.think = beam_think;
  86                         beam.cnt = time + self.shot_speed;
  87                         beam.shot_spread = time + 2;
  88                         beam.nextthink = time;
  89                         beam.owner = self;
  90                         beam.shot_dmg = self.shot_dmg / (self.shot_speed / beam.ticrate);
  91                         beam.scale = self.target_range / 256;
  92                         beam.movetype = MOVETYPE_NONE;
  93                         beam.enemy = self.enemy;
  94                         beam.bot_dodge = TRUE;
  95                         beam.bot_dodgerating = beam.shot_dmg;
  96                         sound (beam, CH_SHOTS_SINGLE, "turrets/phaser.wav", VOL_BASE, ATTEN_NORM);
  97                         self.fireflag = 1;
  98
  99                         beam.attack_finished_single = self.attack_finished_single;
 100                         self.attack_finished_single = time; // + autocvar_sys_ticrate;
 101
 102                         setattachment(beam,self.tur_head,"tag_fire");
 103
 104                         soundat (self, trace_endpos, CH_SHOTS, "weapons/neximpact.wav", VOL_BASE, ATTEN_NORM);
 105
 106                         if (self.tur_head.frame == 0)
 107                                 self.tur_head.frame = 1;
 108
 109                         return TRUE;
 110                 }
 111                 case TR_THINK:
 112                 {
 113                         if (self.tur_head.frame != 0)
 114                         {
 115                                 if (self.fireflag == 1)
 116                                 {
 117                                         if (self.tur_head.frame == 10)
 118                                                 self.tur_head.frame = 1;
 119                                         else
 120                                                 self.tur_head.frame = self.tur_head.frame +1;
 121                                 }
 122                                 else if (self.fireflag == 2 )
 123                                 {
 124                                         self.tur_head.frame = self.tur_head.frame +1;
 125                                         if (self.tur_head.frame == 15)
 126                                         {
 127                                                 self.tur_head.frame = 0;
 128                                                 self.fireflag = 0;
 129                                         }
 130                                 }
 131                         }
 132
 133                         return TRUE;
 134                 }
 135                 case TR_DEATH:
 136                 {
 137                         return TRUE;
 138                 }
 139                 case TR_SETUP:
 140                 {
 141                         self.ammo_flags = TFL_AMMO_ENERGY | TFL_AMMO_RECHARGE | TFL_AMMO_RECIEVE;
 142                         self.aim_flags = TFL_AIM_LEAD;
 143
 144                         self.turret_firecheckfunc = turret_phaser_firecheck;
 145
 146                         return TRUE;
 147                 }
 148                 case TR_PRECACHE:
 149                 {
 150                         precache_model ("models/turrets/base.md3");
 151                         precache_model ("models/turrets/phaser.md3");
 152                         precache_model ("models/turrets/phaser_beam.md3");
 153                         precache_sound ("turrets/phaser.wav");
 154                         return TRUE;
 155                 }
 156                 case TR_CONFIG:
 157                 {
 158                         TUR_CONFIG_SETTINGS(PHASER_SETTINGS(phaser))
 159                         return TRUE;
 160                 }
 161         }
 162
 163         return TRUE;
 164 }
 165
 166 #endif // SVQC
 167 #ifdef CSQC
 168 float t_phaser(float req)
 169 {
 170         switch(req)
 171         {
 172                 case TR_SETUP:
 173                 {
 174                         return TRUE;
 175                 }
 176                 case TR_PRECACHE:
 177                 {
 178                         precache_model ("models/turrets/base.md3");
 179                         precache_model ("models/turrets/phaser.md3");
 180                         return TRUE;
 181                 }
 182         }
 183
 184         return TRUE;
 185 }
 186
 187 #endif // CSQC
 188 #endif // REGISTER_TURRET