qcsrc/common/util.qc

   1 string wordwrap_buffer;
   2
   3 void wordwrap_buffer_put(string s)
   4 {
   5         wordwrap_buffer = strcat(wordwrap_buffer, s);
   6 }
   7
   8 string wordwrap(string s, float l)
   9 {
  10         string r;
  11         wordwrap_buffer = "";
  12         wordwrap_cb(s, l, wordwrap_buffer_put);
  13         r = wordwrap_buffer;
  14         wordwrap_buffer = "";
  15         return r;
  16 }
  17
  18 #ifndef MENUQC
  19 #ifndef CSQC
  20 void wordwrap_buffer_sprint(string s)
  21 {
  22         wordwrap_buffer = strcat(wordwrap_buffer, s);
  23         if(s == "\n")
  24         {
  25                 sprint(self, wordwrap_buffer);
  26                 wordwrap_buffer = "";
  27         }
  28 }
  29
  30 void wordwrap_sprint(string s, float l)
  31 {
  32         wordwrap_buffer = "";
  33         wordwrap_cb(s, l, wordwrap_buffer_sprint);
  34         if(wordwrap_buffer != "")
  35                 sprint(self, strcat(wordwrap_buffer, "\n"));
  36         wordwrap_buffer = "";
  37         return;
  38 }
  39 #endif
  40 #endif
  41
  42 string unescape(string in)
  43 {
  44         float i, len;
  45         string str, s;
  46
  47         // but it doesn't seem to be necessary in my tests at least
  48         in = strzone(in);
  49
  50         len = strlen(in);
  51         str = "";
  52         for(i = 0; i < len; ++i)
  53         {
  54                 s = substring(in, i, 1);
  55                 if(s == "\\")
  56                 {
  57                         s = substring(in, i+1, 1);
  58                         if(s == "n")
  59                                 str = strcat(str, "\n");
  60                         else if(s == "\\")
  61                                 str = strcat(str, "\\");
  62                         else
  63                                 str = strcat(str, substring(in, i, 2));
  64                         ++i;
  65                 } else
  66                         str = strcat(str, s);
  67         }
  68
  69         strunzone(in);
  70         return str;
  71 }
  72
  73 void wordwrap_cb(string s, float l, void(string) callback)
  74 {
  75         string c;
  76         float lleft, i, j, wlen;
  77
  78         s = strzone(s);
  79         lleft = l;
  80         for (i = 0;i < strlen(s);++i)
  81         {
  82                 if (substring(s, i, 2) == "\\n")
  83                 {
  84                         callback("\n");
  85                         lleft = l;
  86                         ++i;
  87                 }
  88                 else if (substring(s, i, 1) == "\n")
  89                 {
  90                         callback("\n");
  91                         lleft = l;
  92                 }
  93                 else if (substring(s, i, 1) == " ")
  94                 {
  95                         if (lleft > 0)
  96                         {
  97                                 callback(" ");
  98                                 lleft = lleft - 1;
  99                         }
 100                 }
 101                 else
 102                 {
 103                         for (j = i+1;j < strlen(s);++j)
 104                                 //    ^^ this skips over the first character of a word, which
 105                                 //       is ALWAYS part of the word
 106                                 //       this is safe since if i+1 == strlen(s), i will become
 107                                 //       strlen(s)-1 at the end of this block and the function
 108                                 //       will terminate. A space can't be the first character we
 109                                 //       read here, and neither can a \n be the start, since these
 110                                 //       two cases have been handled above.
 111                         {
 112                                 c = substring(s, j, 1);
 113                                 if (c == " ")
 114                                         break;
 115                                 if (c == "\\")
 116                                         break;
 117                                 if (c == "\n")
 118                                         break;
 119                                 // we need to keep this tempstring alive even if substring is
 120                                 // called repeatedly, so call strcat even though we're not
 121                                 // doing anything
 122                                 callback("");
 123                         }
 124                         wlen = j - i;
 125                         if (lleft < wlen)
 126                         {
 127                                 callback("\n");
 128                                 lleft = l;
 129                         }
 130                         callback(substring(s, i, wlen));
 131                         lleft = lleft - wlen;
 132                         i = j - 1;
 133                 }
 134         }
 135         strunzone(s);
 136 }
 137
 138 float dist_point_line(vector p, vector l0, vector ldir)
 139 {
 140         ldir = normalize(ldir);
 141
 142         // remove the component in line direction
 143         p = p - (p * ldir) * ldir;
 144
 145         // vlen of the remaining vector
 146         return vlen(p);
 147 }
 148
 149 void depthfirst(entity start, .entity up, .entity downleft, .entity right, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
 150 {
 151         entity e;
 152         e = start;
 153         funcPre(pass, e);
 154         while(e.downleft)
 155         {
 156                 e = e.downleft;
 157                 funcPre(pass, e);
 158         }
 159         funcPost(pass, e);
 160         while(e != start)
 161         {
 162                 if(e.right)
 163                 {
 164                         e = e.right;
 165                         funcPre(pass, e);
 166                         while(e.downleft)
 167                         {
 168                                 e = e.downleft;
 169                                 funcPre(pass, e);
 170                         }
 171                 }
 172                 else
 173                         e = e.up;
 174                 funcPost(pass, e);
 175         }
 176 }
 177
 178 float median(float a, float b, float c)
 179 {
 180         if(a < c)
 181                 return bound(a, b, c);
 182         return bound(c, b, a);
 183 }
 184
 185 // converts a number to a string with the indicated number of decimals
 186 // works for up to 10 decimals!
 187 string ftos_decimals(float number, float decimals)
 188 {
 189         // we have sprintf...
 190         return sprintf("%.*f", decimals, number);
 191 }
 192
 193 float time;
 194 vector colormapPaletteColor(float c, float isPants)
 195 {
 196         switch(c)
 197         {
 198                 case  0: return '0.800000 0.800000 0.800000';
 199                 case  1: return '0.600000 0.400000 0.000000';
 200                 case  2: return '0.000000 1.000000 0.501961';
 201                 case  3: return '0.000000 1.000000 0.000000';
 202                 case  4: return '1.000000 0.000000 0.000000';
 203                 case  5: return '0.000000 0.658824 1.000000';
 204                 case  6: return '0.000000 1.000000 1.000000';
 205                 case  7: return '0.501961 1.000000 0.000000';
 206                 case  8: return '0.501961 0.000000 1.000000';
 207                 case  9: return '1.000000 0.000000 1.000000';
 208                 case 10: return '1.000000 0.000000 0.501961';
 209                 case 11: return '0.600000 0.600000 0.600000';
 210                 case 12: return '1.000000 1.000000 0.000000';
 211                 case 13: return '0.000000 0.313725 1.000000';
 212                 case 14: return '1.000000 0.501961 0.000000';
 213                 case 15:
 214                         if(isPants)
 215                                 return
 216                                           '1 0 0' * (0.502 + 0.498 * sin(time / 2.7182818285 + 0.0000000000))
 217                                         + '0 1 0' * (0.502 + 0.498 * sin(time / 2.7182818285 + 2.0943951024))
 218                                         + '0 0 1' * (0.502 + 0.498 * sin(time / 2.7182818285 + 4.1887902048));
 219                         else
 220                                 return
 221                                           '1 0 0' * (0.502 + 0.498 * sin(time / 3.1415926536 + 5.2359877560))
 222                                         + '0 1 0' * (0.502 + 0.498 * sin(time / 3.1415926536 + 3.1415926536))
 223                                         + '0 0 1' * (0.502 + 0.498 * sin(time / 3.1415926536 + 1.0471975512));
 224                 default: return '0.000 0.000 0.000';
 225         }
 226 }
 227
 228 // unzone the string, and return it as tempstring. Safe to be called on string_null
 229 string fstrunzone(string s)
 230 {
 231         string sc;
 232         if not(s)
 233                 return s;
 234         sc = strcat(s, "");
 235         strunzone(s);
 236         return sc;
 237 }
 238
 239 float fexists(string f)
 240 {
 241     float fh;
 242     fh = fopen(f, FILE_READ);
 243     if (fh < 0)
 244         return FALSE;
 245     fclose(fh);
 246     return TRUE;
 247 }
 248
 249 // Databases (hash tables)
 250 #define DB_BUCKETS 8192
 251 void db_save(float db, string pFilename)
 252 {
 253         float fh, i, n;
 254         fh = fopen(pFilename, FILE_WRITE);
 255         if(fh < 0)
 256         {
 257                 print(strcat("^1Can't write DB to ", pFilename));
 258                 return;
 259         }
 260         n = buf_getsize(db);
 261         fputs(fh, strcat(ftos(DB_BUCKETS), "\n"));
 262         for(i = 0; i < n; ++i)
 263                 fputs(fh, strcat(bufstr_get(db, i), "\n"));
 264         fclose(fh);
 265 }
 266
 267 float db_create()
 268 {
 269         return buf_create();
 270 }
 271
 272 float db_load(string pFilename)
 273 {
 274         float db, fh, i, j, n;
 275         string l;
 276         db = buf_create();
 277         if(db < 0)
 278                 return -1;
 279         fh = fopen(pFilename, FILE_READ);
 280         if(fh < 0)
 281                 return db;
 282         l = fgets(fh);
 283         if(stof(l) == DB_BUCKETS)
 284         {
 285                 i = 0;
 286                 while((l = fgets(fh)))
 287                 {
 288                         if(l != "")
 289                                 bufstr_set(db, i, l);
 290                         ++i;
 291                 }
 292         }
 293         else
 294         {
 295                 // different count of buckets, or a dump?
 296                 // need to reorganize the database then (SLOW)
 297                 //
 298                 // note: we also parse the first line (l) in case the DB file is
 299                 // missing the bucket count
 300                 do
 301                 {
 302                         n = tokenizebyseparator(l, "\\");
 303                         for(j = 2; j < n; j += 2)
 304                                 db_put(db, argv(j-1), uri_unescape(argv(j)));
 305                 }
 306                 while((l = fgets(fh)));
 307         }
 308         fclose(fh);
 309         return db;
 310 }
 311
 312 void db_dump(float db, string pFilename)
 313 {
 314         float fh, i, j, n, m;
 315         fh = fopen(pFilename, FILE_WRITE);
 316         if(fh < 0)
 317                 error(strcat("Can't dump DB to ", pFilename));
 318         n = buf_getsize(db);
 319         fputs(fh, "0\n");
 320         for(i = 0; i < n; ++i)
 321         {
 322                 m = tokenizebyseparator(bufstr_get(db, i), "\\");
 323                 for(j = 2; j < m; j += 2)
 324                         fputs(fh, strcat("\\", argv(j-1), "\\", argv(j), "\n"));
 325         }
 326         fclose(fh);
 327 }
 328
 329 void db_close(float db)
 330 {
 331         buf_del(db);
 332 }
 333
 334 string db_get(float db, string pKey)
 335 {
 336         float h;
 337         h = mod(crc16(FALSE, pKey), DB_BUCKETS);
 338         return uri_unescape(infoget(bufstr_get(db, h), pKey));
 339 }
 340
 341 void db_put(float db, string pKey, string pValue)
 342 {
 343         float h;
 344         h = mod(crc16(FALSE, pKey), DB_BUCKETS);
 345         bufstr_set(db, h, infoadd(bufstr_get(db, h), pKey, uri_escape(pValue)));
 346 }
 347
 348 void db_test()
 349 {
 350         float db, i;
 351         print("LOAD...\n");
 352         db = db_load("foo.db");
 353         print("LOADED. FILL...\n");
 354         for(i = 0; i < DB_BUCKETS; ++i)
 355                 db_put(db, ftos(random()), "X");
 356         print("FILLED. SAVE...\n");
 357         db_save(db, "foo.db");
 358         print("SAVED. CLOSE...\n");
 359         db_close(db);
 360         print("CLOSED.\n");
 361 }
 362
 363 // Multiline text file buffers
 364 float buf_load(string pFilename)
 365 {
 366         float buf, fh, i;
 367         string l;
 368         buf = buf_create();
 369         if(buf < 0)
 370                 return -1;
 371         fh = fopen(pFilename, FILE_READ);
 372         if(fh < 0)
 373         {
 374                 buf_del(buf);
 375                 return -1;
 376         }
 377         i = 0;
 378         while((l = fgets(fh)))
 379         {
 380                 bufstr_set(buf, i, l);
 381                 ++i;
 382         }
 383         fclose(fh);
 384         return buf;
 385 }
 386
 387 void buf_save(float buf, string pFilename)
 388 {
 389         float fh, i, n;
 390         fh = fopen(pFilename, FILE_WRITE);
 391         if(fh < 0)
 392                 error(strcat("Can't write buf to ", pFilename));
 393         n = buf_getsize(buf);
 394         for(i = 0; i < n; ++i)
 395                 fputs(fh, strcat(bufstr_get(buf, i), "\n"));
 396         fclose(fh);
 397 }
 398
 399 string GametypeNameFromType(float g)
 400 {
 401         if      (g == GAME_DEATHMATCH) return "dm";
 402         else if (g == GAME_TEAM_DEATHMATCH) return "tdm";
 403         else if (g == GAME_DOMINATION) return "dom";
 404         else if (g == GAME_CTF) return "ctf";
 405         else if (g == GAME_RUNEMATCH) return "rune";
 406         else if (g == GAME_LMS) return "lms";
 407         else if (g == GAME_ARENA) return "arena";
 408         else if (g == GAME_CA) return "ca";
 409         else if (g == GAME_KEYHUNT) return "kh";
 410         else if (g == GAME_ONSLAUGHT) return "ons";
 411         else if (g == GAME_ASSAULT) return "as";
 412         else if (g == GAME_RACE) return "rc";
 413         else if (g == GAME_NEXBALL) return "nexball";
 414         else if (g == GAME_CTS) return "cts";
 415         else if (g == GAME_FREEZETAG) return "freezetag";
 416         else if (g == GAME_KEEPAWAY) return "ka";
 417         return "dm";
 418 }
 419
 420 string mmsss(float tenths)
 421 {
 422         float minutes;
 423         string s;
 424         tenths = floor(tenths + 0.5);
 425         minutes = floor(tenths / 600);
 426         tenths -= minutes * 600;
 427         s = ftos(1000 + tenths);
 428         return strcat(ftos(minutes), ":", substring(s, 1, 2), ".", substring(s, 3, 1));
 429 }
 430
 431 string mmssss(float hundredths)
 432 {
 433         float minutes;
 434         string s;
 435         hundredths = floor(hundredths + 0.5);
 436         minutes = floor(hundredths / 6000);
 437         hundredths -= minutes * 6000;
 438         s = ftos(10000 + hundredths);
 439         return strcat(ftos(minutes), ":", substring(s, 1, 2), ".", substring(s, 3, 2));
 440 }
 441
 442 string ScoreString(float pFlags, float pValue)
 443 {
 444         string valstr;
 445         float l;
 446
 447         pValue = floor(pValue + 0.5); // round
 448
 449         if((pValue == 0) && (pFlags & (SFL_HIDE_ZERO | SFL_RANK | SFL_TIME)))
 450                 valstr = "";
 451         else if(pFlags & SFL_RANK)
 452         {
 453                 valstr = ftos(pValue);
 454                 l = strlen(valstr);
 455                 if((l >= 2) && (substring(valstr, l - 2, 1) == "1"))
 456                         valstr = strcat(valstr, "th");
 457                 else if(substring(valstr, l - 1, 1) == "1")
 458                         valstr = strcat(valstr, "st");
 459                 else if(substring(valstr, l - 1, 1) == "2")
 460                         valstr = strcat(valstr, "nd");
 461                 else if(substring(valstr, l - 1, 1) == "3")
 462                         valstr = strcat(valstr, "rd");
 463                 else
 464                         valstr = strcat(valstr, "th");
 465         }
 466         else if(pFlags & SFL_TIME)
 467                 valstr = TIME_ENCODED_TOSTRING(pValue);
 468         else
 469                 valstr = ftos(pValue);
 470
 471         return valstr;
 472 }
 473
 474 vector cross(vector a, vector b)
 475 {
 476         return
 477                 '1 0 0' * (a_y * b_z - a_z * b_y)
 478         +       '0 1 0' * (a_z * b_x - a_x * b_z)
 479         +       '0 0 1' * (a_x * b_y - a_y * b_x);
 480 }
 481
 482 // compressed vector format:
 483 // like MD3, just even shorter
 484 //   4 bit pitch (16 angles), 0 is -90, 8 is 0, 16 would be 90
 485 //   5 bit yaw (32 angles), 0=0, 8=90, 16=180, 24=270
 486 //   7 bit length (logarithmic encoding), 1/8 .. about 7844
 487 //     length = 2^(length_encoded/8) / 8
 488 // if pitch is 90, yaw does nothing and therefore indicates the sign (yaw is then either 11111 or 11110); 11111 is pointing DOWN
 489 // thus, valid values are from 0000.11110.0000000 to 1111.11111.1111111
 490 // the special value 0 indicates the zero vector
 491
 492 float lengthLogTable[128];
 493
 494 float invertLengthLog(float x)
 495 {
 496         float l, r, m, lerr, rerr;
 497
 498         if(x >= lengthLogTable[127])
 499                 return 127;
 500         if(x <= lengthLogTable[0])
 501                 return 0;
 502
 503         l = 0;
 504         r = 127;
 505
 506         while(r - l > 1)
 507         {
 508                 m = floor((l + r) / 2);
 509                 if(lengthLogTable[m] < x)
 510                         l = m;
 511                 else
 512                         r = m;
 513         }
 514
 515         // now: r is >=, l is <
 516         lerr = (x - lengthLogTable[l]);
 517         rerr = (lengthLogTable[r] - x);
 518         if(lerr < rerr)
 519                 return l;
 520         return r;
 521 }
 522
 523 vector decompressShortVector(float data)
 524 {
 525         vector out;
 526         float p, y, len;
 527         if(data == 0)
 528                 return '0 0 0';
 529         p   = (data & 0xF000) / 0x1000;
 530         y   = (data & 0x0F80) / 0x80;
 531         len = (data & 0x007F);
 532
 533         //print("\ndecompress: p ", ftos(p)); print("y ", ftos(y)); print("len ", ftos(len), "\n");
 534
 535         if(p == 0)
 536         {
 537                 out_x = 0;
 538                 out_y = 0;
 539                 if(y == 31)
 540                         out_z = -1;
 541                 else
 542                         out_z = +1;
 543         }
 544         else
 545         {
 546                 y   = .19634954084936207740 * y;
 547                 p = .19634954084936207740 * p - 1.57079632679489661922;
 548                 out_x = cos(y) *  cos(p);
 549                 out_y = sin(y) *  cos(p);
 550                 out_z =          -sin(p);
 551         }
 552
 553         //print("decompressed: ", vtos(out), "\n");
 554
 555         return out * lengthLogTable[len];
 556 }
 557
 558 float compressShortVector(vector vec)
 559 {
 560         vector ang;
 561         float p, y, len;
 562         if(vlen(vec) == 0)
 563                 return 0;
 564         //print("compress: ", vtos(vec), "\n");
 565         ang = vectoangles(vec);
 566         ang_x = -ang_x;
 567         if(ang_x < -90)
 568                 ang_x += 360;
 569         if(ang_x < -90 && ang_x > +90)
 570                 error("BOGUS vectoangles");
 571         //print("angles: ", vtos(ang), "\n");
 572
 573         p = floor(0.5 + (ang_x + 90) * 16 / 180) & 15; // -90..90 to 0..14
 574         if(p == 0)
 575         {
 576                 if(vec_z < 0)
 577                         y = 31;
 578                 else
 579                         y = 30;
 580         }
 581         else
 582                 y = floor(0.5 + ang_y * 32 / 360)          & 31; // 0..360 to 0..32
 583         len = invertLengthLog(vlen(vec));
 584
 585         //print("compressed: p ", ftos(p)); print("y ", ftos(y)); print("len ", ftos(len), "\n");
 586
 587         return (p * 0x1000) + (y * 0x80) + len;
 588 }
 589
 590 void compressShortVector_init()
 591 {
 592         float l, f, i;
 593         l = 1;
 594         f = pow(2, 1/8);
 595         for(i = 0; i < 128; ++i)
 596         {
 597                 lengthLogTable[i] = l;
 598                 l *= f;
 599         }
 600
 601         if(cvar("developer"))
 602         {
 603                 print("Verifying vector compression table...\n");
 604                 for(i = 0x0F00; i < 0xFFFF; ++i)
 605                         if(i != compressShortVector(decompressShortVector(i)))
 606                         {
 607                                 print("BROKEN vector compression: ", ftos(i));
 608                                 print(" -> ", vtos(decompressShortVector(i)));
 609                                 print(" -> ", ftos(compressShortVector(decompressShortVector(i))));
 610                                 print("\n");
 611                                 error("b0rk");
 612                         }
 613                 print("Done.\n");
 614         }
 615 }
 616
 617 #ifndef MENUQC
 618 float CheckWireframeBox(entity forent, vector v0, vector dvx, vector dvy, vector dvz)
 619 {
 620         traceline(v0, v0 + dvx, TRUE, forent); if(trace_fraction < 1) return 0;
 621         traceline(v0, v0 + dvy, TRUE, forent); if(trace_fraction < 1) return 0;
 622         traceline(v0, v0 + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 623         traceline(v0 + dvx, v0 + dvx + dvy, TRUE, forent); if(trace_fraction < 1) return 0;
 624         traceline(v0 + dvx, v0 + dvx + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 625         traceline(v0 + dvy, v0 + dvy + dvx, TRUE, forent); if(trace_fraction < 1) return 0;
 626         traceline(v0 + dvy, v0 + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 627         traceline(v0 + dvz, v0 + dvz + dvx, TRUE, forent); if(trace_fraction < 1) return 0;
 628         traceline(v0 + dvz, v0 + dvz + dvy, TRUE, forent); if(trace_fraction < 1) return 0;
 629         traceline(v0 + dvx + dvy, v0 + dvx + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 630         traceline(v0 + dvx + dvz, v0 + dvx + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 631         traceline(v0 + dvy + dvz, v0 + dvx + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 632         return 1;
 633 }
 634 #endif
 635
 636 string fixPriorityList(string order, float from, float to, float subtract, float complete)
 637 {
 638         string neworder;
 639         float i, n, w;
 640
 641         n = tokenize_console(order);
 642         neworder = "";
 643         for(i = 0; i < n; ++i)
 644         {
 645                 w = stof(argv(i));
 646                 if(w == floor(w))
 647                 {
 648                         if(w >= from && w <= to)
 649                                 neworder = strcat(neworder, ftos(w), " ");
 650                         else
 651                         {
 652                                 w -= subtract;
 653                                 if(w >= from && w <= to)
 654                                         neworder = strcat(neworder, ftos(w), " ");
 655                         }
 656                 }
 657         }
 658
 659         if(complete)
 660         {
 661                 n = tokenize_console(neworder);
 662                 for(w = to; w >= from; --w)
 663                 {
 664                         for(i = 0; i < n; ++i)
 665                                 if(stof(argv(i)) == w)
 666                                         break;
 667                         if(i == n) // not found
 668                                 neworder = strcat(neworder, ftos(w), " ");
 669                 }
 670         }
 671
 672         return substring(neworder, 0, strlen(neworder) - 1);
 673 }
 674
 675 string mapPriorityList(string order, string(string) mapfunc)
 676 {
 677         string neworder;
 678         float i, n;
 679
 680         n = tokenize_console(order);
 681         neworder = "";
 682         for(i = 0; i < n; ++i)
 683                 neworder = strcat(neworder, mapfunc(argv(i)), " ");
 684
 685         return substring(neworder, 0, strlen(neworder) - 1);
 686 }
 687
 688 string swapInPriorityList(string order, float i, float j)
 689 {
 690         string s;
 691         float w, n;
 692
 693         n = tokenize_console(order);
 694
 695         if(i >= 0 && i < n && j >= 0 && j < n && i != j)
 696         {
 697                 s = "";
 698                 for(w = 0; w < n; ++w)
 699                 {
 700                         if(w == i)
 701                                 s = strcat(s, argv(j), " ");
 702                         else if(w == j)
 703                                 s = strcat(s, argv(i), " ");
 704                         else
 705                                 s = strcat(s, argv(w), " ");
 706                 }
 707                 return substring(s, 0, strlen(s) - 1);
 708         }
 709
 710         return order;
 711 }
 712
 713 float cvar_value_issafe(string s)
 714 {
 715         if(strstrofs(s, "\"", 0) >= 0)
 716                 return 0;
 717         if(strstrofs(s, "\\", 0) >= 0)
 718                 return 0;
 719         if(strstrofs(s, ";", 0) >= 0)
 720                 return 0;
 721         if(strstrofs(s, "$", 0) >= 0)
 722                 return 0;
 723         if(strstrofs(s, "\r", 0) >= 0)
 724                 return 0;
 725         if(strstrofs(s, "\n", 0) >= 0)
 726                 return 0;
 727         return 1;
 728 }
 729
 730 #ifndef MENUQC
 731 void get_mi_min_max(float mode)
 732 {
 733         vector mi, ma;
 734
 735         if(mi_shortname)
 736                 strunzone(mi_shortname);
 737         mi_shortname = mapname;
 738         if(!strcasecmp(substring(mi_shortname, 0, 5), "maps/"))
 739                 mi_shortname = substring(mi_shortname, 5, strlen(mi_shortname) - 5);
 740         if(!strcasecmp(substring(mi_shortname, strlen(mi_shortname) - 4, 4), ".bsp"))
 741                 mi_shortname = substring(mi_shortname, 0, strlen(mi_shortname) - 4);
 742         mi_shortname = strzone(mi_shortname);
 743
 744 #ifdef CSQC
 745         mi = world.mins;
 746         ma = world.maxs;
 747 #else
 748         mi = world.absmin;
 749         ma = world.absmax;
 750 #endif
 751
 752         mi_min = mi;
 753         mi_max = ma;
 754         MapInfo_Get_ByName(mi_shortname, 0, 0);
 755         if(MapInfo_Map_mins_x < MapInfo_Map_maxs_x)
 756         {
 757                 mi_min = MapInfo_Map_mins;
 758                 mi_max = MapInfo_Map_maxs;
 759         }
 760         else
 761         {
 762                 // not specified
 763                 if(mode)
 764                 {
 765                         // be clever
 766                         tracebox('1 0 0' * mi_x,
 767                                          '0 1 0' * mi_y + '0 0 1' * mi_z,
 768                                          '0 1 0' * ma_y + '0 0 1' * ma_z,
 769                                          '1 0 0' * ma_x,
 770                                          MOVE_WORLDONLY,
 771                                          world);
 772                         if(!trace_startsolid)
 773                                 mi_min_x = trace_endpos_x;
 774
 775                         tracebox('0 1 0' * mi_y,
 776                                          '1 0 0' * mi_x + '0 0 1' * mi_z,
 777                                          '1 0 0' * ma_x + '0 0 1' * ma_z,
 778                                          '0 1 0' * ma_y,
 779                                          MOVE_WORLDONLY,
 780                                          world);
 781                         if(!trace_startsolid)
 782                                 mi_min_y = trace_endpos_y;
 783
 784                         tracebox('0 0 1' * mi_z,
 785                                          '1 0 0' * mi_x + '0 1 0' * mi_y,
 786                                          '1 0 0' * ma_x + '0 1 0' * ma_y,
 787                                          '0 0 1' * ma_z,
 788                                          MOVE_WORLDONLY,
 789                                          world);
 790                         if(!trace_startsolid)
 791                                 mi_min_z = trace_endpos_z;
 792
 793                         tracebox('1 0 0' * ma_x,
 794                                          '0 1 0' * mi_y + '0 0 1' * mi_z,
 795                                          '0 1 0' * ma_y + '0 0 1' * ma_z,
 796                                          '1 0 0' * mi_x,
 797                                          MOVE_WORLDONLY,
 798                                          world);
 799                         if(!trace_startsolid)
 800                                 mi_max_x = trace_endpos_x;
 801
 802                         tracebox('0 1 0' * ma_y,
 803                                          '1 0 0' * mi_x + '0 0 1' * mi_z,
 804                                          '1 0 0' * ma_x + '0 0 1' * ma_z,
 805                                          '0 1 0' * mi_y,
 806                                          MOVE_WORLDONLY,
 807                                          world);
 808                         if(!trace_startsolid)
 809                                 mi_max_y = trace_endpos_y;
 810
 811                         tracebox('0 0 1' * ma_z,
 812                                          '1 0 0' * mi_x + '0 1 0' * mi_y,
 813                                          '1 0 0' * ma_x + '0 1 0' * ma_y,
 814                                          '0 0 1' * mi_z,
 815                                          MOVE_WORLDONLY,
 816                                          world);
 817                         if(!trace_startsolid)
 818                                 mi_max_z = trace_endpos_z;
 819                 }
 820         }
 821 }
 822
 823 void get_mi_min_max_texcoords(float mode)
 824 {
 825         vector extend;
 826
 827         get_mi_min_max(mode);
 828
 829         mi_picmin = mi_min;
 830         mi_picmax = mi_max;
 831
 832         // extend mi_picmax to get a square aspect ratio
 833         // center the map in that area
 834         extend = mi_picmax - mi_picmin;
 835         if(extend_y > extend_x)
 836         {
 837                 mi_picmin_x -= (extend_y - extend_x) * 0.5;
 838                 mi_picmax_x += (extend_y - extend_x) * 0.5;
 839         }
 840         else
 841         {
 842                 mi_picmin_y -= (extend_x - extend_y) * 0.5;
 843                 mi_picmax_y += (extend_x - extend_y) * 0.5;
 844         }
 845
 846         // add another some percent
 847         extend = (mi_picmax - mi_picmin) * (1 / 64.0);
 848         mi_picmin -= extend;
 849         mi_picmax += extend;
 850
 851         // calculate the texcoords
 852         mi_pictexcoord0 = mi_pictexcoord1 = mi_pictexcoord2 = mi_pictexcoord3 = '0 0 0';
 853         // first the two corners of the origin
 854         mi_pictexcoord0_x = (mi_min_x - mi_picmin_x) / (mi_picmax_x - mi_picmin_x);
 855         mi_pictexcoord0_y = (mi_min_y - mi_picmin_y) / (mi_picmax_y - mi_picmin_y);
 856         mi_pictexcoord2_x = (mi_max_x - mi_picmin_x) / (mi_picmax_x - mi_picmin_x);
 857         mi_pictexcoord2_y = (mi_max_y - mi_picmin_y) / (mi_picmax_y - mi_picmin_y);
 858         // then the other corners
 859         mi_pictexcoord1_x = mi_pictexcoord0_x;
 860         mi_pictexcoord1_y = mi_pictexcoord2_y;
 861         mi_pictexcoord3_x = mi_pictexcoord2_x;
 862         mi_pictexcoord3_y = mi_pictexcoord0_y;
 863 }
 864 #endif
 865
 866 void cvar_settemp(string cv, string val)
 867 {
 868         entity e;
 869         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
 870                 if(e.netname == cv)
 871                         goto saved;
 872         e = spawn();
 873         e.classname = "saved_cvar_value";
 874         e.netname = strzone(cv);
 875         e.message = strzone(cvar_string(cv));
 876 :saved
 877         cvar_set(cv, val);
 878 }
 879
 880 void cvar_settemp_restore()
 881 {
 882         entity e;
 883         while((e = find(world, classname, "saved_cvar_value")))
 884         {
 885                 cvar_set(e.netname, e.message);
 886                 remove(e);
 887         }
 888 }
 889
 890 float almost_equals(float a, float b)
 891 {
 892         float eps;
 893         eps = (max(a, -a) + max(b, -b)) * 0.001;
 894         if(a - b < eps && b - a < eps)
 895                 return TRUE;
 896         return FALSE;
 897 }
 898
 899 float almost_in_bounds(float a, float b, float c)
 900 {
 901         float eps;
 902         eps = (max(a, -a) + max(c, -c)) * 0.001;
 903         return b == median(a - eps, b, c + eps);
 904 }
 905
 906 float power2of(float e)
 907 {
 908         return pow(2, e);
 909 }
 910 float log2of(float x)
 911 {
 912         // NOTE: generated code
 913         if(x > 2048)
 914                 if(x > 131072)
 915                         if(x > 1048576)
 916                                 if(x > 4194304)
 917                                         return 23;
 918                                 else
 919                                         if(x > 2097152)
 920                                                 return 22;
 921                                         else
 922                                                 return 21;
 923                         else
 924                                 if(x > 524288)
 925                                         return 20;
 926                                 else
 927                                         if(x > 262144)
 928                                                 return 19;
 929                                         else
 930                                                 return 18;
 931                 else
 932                         if(x > 16384)
 933                                 if(x > 65536)
 934                                         return 17;
 935                                 else
 936                                         if(x > 32768)
 937                                                 return 16;
 938                                         else
 939                                                 return 15;
 940                         else
 941                                 if(x > 8192)
 942                                         return 14;
 943                                 else
 944                                         if(x > 4096)
 945                                                 return 13;
 946                                         else
 947                                                 return 12;
 948         else
 949                 if(x > 32)
 950                         if(x > 256)
 951                                 if(x > 1024)
 952                                         return 11;
 953                                 else
 954                                         if(x > 512)
 955                                                 return 10;
 956                                         else
 957                                                 return 9;
 958                         else
 959                                 if(x > 128)
 960                                         return 8;
 961                                 else
 962                                         if(x > 64)
 963                                                 return 7;
 964                                         else
 965                                                 return 6;
 966                 else
 967                         if(x > 4)
 968                                 if(x > 16)
 969                                         return 5;
 970                                 else
 971                                         if(x > 8)
 972                                                 return 4;
 973                                         else
 974                                                 return 3;
 975                         else
 976                                 if(x > 2)
 977                                         return 2;
 978                                 else
 979                                         if(x > 1)
 980                                                 return 1;
 981                                         else
 982                                                 return 0;
 983 }
 984
 985 float rgb_mi_ma_to_hue(vector rgb, float mi, float ma)
 986 {
 987         if(mi == ma)
 988                 return 0;
 989         else if(ma == rgb_x)
 990         {
 991                 if(rgb_y >= rgb_z)
 992                         return (rgb_y - rgb_z) / (ma - mi);
 993                 else
 994                         return (rgb_y - rgb_z) / (ma - mi) + 6;
 995         }
 996         else if(ma == rgb_y)
 997                 return (rgb_z - rgb_x) / (ma - mi) + 2;
 998         else // if(ma == rgb_z)
 999                 return (rgb_x - rgb_y) / (ma - mi) + 4;
1000 }
1001
1002 vector hue_mi_ma_to_rgb(float hue, float mi, float ma)
1003 {
1004         vector rgb;
1005
1006         hue -= 6 * floor(hue / 6);
1007
1008         //else if(ma == rgb_x)
1009         //      hue = 60 * (rgb_y - rgb_z) / (ma - mi);
1010         if(hue <= 1)
1011         {
1012                 rgb_x = ma;
1013                 rgb_y = hue * (ma - mi) + mi;
1014                 rgb_z = mi;
1015         }
1016         //else if(ma == rgb_y)
1017         //      hue = 60 * (rgb_z - rgb_x) / (ma - mi) + 120;
1018         else if(hue <= 2)
1019         {
1020                 rgb_x = (2 - hue) * (ma - mi) + mi;
1021                 rgb_y = ma;
1022                 rgb_z = mi;
1023         }
1024         else if(hue <= 3)
1025         {
1026                 rgb_x = mi;
1027                 rgb_y = ma;
1028                 rgb_z = (hue - 2) * (ma - mi) + mi;
1029         }
1030         //else // if(ma == rgb_z)
1031         //      hue = 60 * (rgb_x - rgb_y) / (ma - mi) + 240;
1032         else if(hue <= 4)
1033         {
1034                 rgb_x = mi;
1035                 rgb_y = (4 - hue) * (ma - mi) + mi;
1036                 rgb_z = ma;
1037         }
1038         else if(hue <= 5)
1039         {
1040                 rgb_x = (hue - 4) * (ma - mi) + mi;
1041                 rgb_y = mi;
1042                 rgb_z = ma;
1043         }
1044         //else if(ma == rgb_x)
1045         //      hue = 60 * (rgb_y - rgb_z) / (ma - mi);
1046         else // if(hue <= 6)
1047         {
1048                 rgb_x = ma;
1049                 rgb_y = mi;
1050                 rgb_z = (6 - hue) * (ma - mi) + mi;
1051         }
1052
1053         return rgb;
1054 }
1055
1056 vector rgb_to_hsv(vector rgb)
1057 {
1058         float mi, ma;
1059         vector hsv;
1060
1061         mi = min(rgb_x, rgb_y, rgb_z);
1062         ma = max(rgb_x, rgb_y, rgb_z);
1063
1064         hsv_x = rgb_mi_ma_to_hue(rgb, mi, ma);
1065         hsv_z = ma;
1066
1067         if(ma == 0)
1068                 hsv_y = 0;
1069         else
1070                 hsv_y = 1 - mi/ma;
1071
1072         return hsv;
1073 }
1074
1075 vector hsv_to_rgb(vector hsv)
1076 {
1077         return hue_mi_ma_to_rgb(hsv_x, hsv_z * (1 - hsv_y), hsv_z);
1078 }
1079
1080 vector rgb_to_hsl(vector rgb)
1081 {
1082         float mi, ma;
1083         vector hsl;
1084
1085         mi = min(rgb_x, rgb_y, rgb_z);
1086         ma = max(rgb_x, rgb_y, rgb_z);
1087
1088         hsl_x = rgb_mi_ma_to_hue(rgb, mi, ma);
1089
1090         hsl_z = 0.5 * (mi + ma);
1091         if(mi == ma)
1092                 hsl_y = 0;
1093         else if(hsl_z <= 0.5)
1094                 hsl_y = (ma - mi) / (2*hsl_z);
1095         else // if(hsl_z > 0.5)
1096                 hsl_y = (ma - mi) / (2 - 2*hsl_z);
1097
1098         return hsl;
1099 }
1100
1101 vector hsl_to_rgb(vector hsl)
1102 {
1103         float mi, ma, maminusmi;
1104
1105         if(hsl_z <= 0.5)
1106                 maminusmi = hsl_y * 2 * hsl_z;
1107         else
1108                 maminusmi = hsl_y * (2 - 2 * hsl_z);
1109
1110         // hsl_z     = 0.5 * mi + 0.5 * ma
1111         // maminusmi =     - mi +       ma
1112         mi = hsl_z - 0.5 * maminusmi;
1113         ma = hsl_z + 0.5 * maminusmi;
1114
1115         return hue_mi_ma_to_rgb(hsl_x, mi, ma);
1116 }
1117
1118 string rgb_to_hexcolor(vector rgb)
1119 {
1120         return
1121                 strcat(
1122                         "^x",
1123                         DEC_TO_HEXDIGIT(floor(rgb_x * 15 + 0.5)),
1124                         DEC_TO_HEXDIGIT(floor(rgb_y * 15 + 0.5)),
1125                         DEC_TO_HEXDIGIT(floor(rgb_z * 15 + 0.5))
1126                 );
1127 }
1128
1129 // requires that m2>m1 in all coordinates, and that m4>m3
1130 float boxesoverlap(vector m1, vector m2, vector m3, vector m4) {return m2_x >= m3_x && m1_x <= m4_x && m2_y >= m3_y && m1_y <= m4_y && m2_z >= m3_z && m1_z <= m4_z;}
1131
1132 // requires the same, but is a stronger condition
1133 float boxinsidebox(vector smins, vector smaxs, vector bmins, vector bmaxs) {return smins_x >= bmins_x && smaxs_x <= bmaxs_x && smins_y >= bmins_y && smaxs_y <= bmaxs_y && smins_z >= bmins_z && smaxs_z <= bmaxs_z;}
1134
1135 #ifndef MENUQC
1136 #endif
1137
1138 float textLengthUpToWidth(string theText, float maxWidth, vector theSize, textLengthUpToWidth_widthFunction_t w)
1139 {
1140         // STOP.
1141         // The following function is SLOW.
1142         // For your safety and for the protection of those around you...
1143         // DO NOT CALL THIS AT HOME.
1144         // No really, don't.
1145         if(w(theText, theSize) <= maxWidth)
1146                 return strlen(theText); // yeah!
1147
1148         // binary search for right place to cut string
1149         float ch;
1150         float left, right, middle; // this always works
1151         left = 0;
1152         right = strlen(theText); // this always fails
1153         do
1154         {
1155                 middle = floor((left + right) / 2);
1156                 if(w(substring(theText, 0, middle), theSize) <= maxWidth)
1157                         left = middle;
1158                 else
1159                         right = middle;
1160         }
1161         while(left < right - 1);
1162
1163         if(w("^7", theSize) == 0) // detect color codes support in the width function
1164         {
1165                 // NOTE: when color codes are involved, this binary search is,
1166                 // mathematically, BROKEN. However, it is obviously guaranteed to
1167                 // terminate, as the range still halves each time - but nevertheless, it is
1168                 // guaranteed that it finds ONE valid cutoff place (where "left" is in
1169                 // range, and "right" is outside).
1170
1171                 // terencehill: the following code detects truncated ^xrgb tags (e.g. ^x or ^x4)
1172                 // and decrease left on the basis of the chars detected of the truncated tag
1173                 // Even if the ^xrgb tag is not complete/correct, left is decreased
1174                 // (sometimes too much but with a correct result)
1175                 // it fixes also ^[0-9]
1176                 while(left >= 1 && substring(theText, left-1, 1) == "^")
1177                         left-=1;
1178
1179                 if (left >= 2 && substring(theText, left-2, 2) == "^x") // ^x/
1180                         left-=2;
1181                 else if (left >= 3 && substring(theText, left-3, 2) == "^x")
1182                         {
1183                                 ch = str2chr(theText, left-1);
1184                                 if( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xr/
1185                                         left-=3;
1186                         }
1187                 else if (left >= 4 && substring(theText, left-4, 2) == "^x")
1188                         {
1189                                 ch = str2chr(theText, left-2);
1190                                 if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') )
1191                                 {
1192                                         ch = str2chr(theText, left-1);
1193                                         if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xrg/
1194                                                 left-=4;
1195                                 }
1196                         }
1197         }
1198
1199         return left;
1200 }
1201
1202 float textLengthUpToLength(string theText, float maxWidth, textLengthUpToLength_lenFunction_t w)
1203 {
1204         // STOP.
1205         // The following function is SLOW.
1206         // For your safety and for the protection of those around you...
1207         // DO NOT CALL THIS AT HOME.
1208         // No really, don't.
1209         if(w(theText) <= maxWidth)
1210                 return strlen(theText); // yeah!
1211
1212         // binary search for right place to cut string
1213         float ch;
1214         float left, right, middle; // this always works
1215         left = 0;
1216         right = strlen(theText); // this always fails
1217         do
1218         {
1219                 middle = floor((left + right) / 2);
1220                 if(w(substring(theText, 0, middle)) <= maxWidth)
1221                         left = middle;
1222                 else
1223                         right = middle;
1224         }
1225         while(left < right - 1);
1226
1227         if(w("^7") == 0) // detect color codes support in the width function
1228         {
1229                 // NOTE: when color codes are involved, this binary search is,
1230                 // mathematically, BROKEN. However, it is obviously guaranteed to
1231                 // terminate, as the range still halves each time - but nevertheless, it is
1232                 // guaranteed that it finds ONE valid cutoff place (where "left" is in
1233                 // range, and "right" is outside).
1234
1235                 // terencehill: the following code detects truncated ^xrgb tags (e.g. ^x or ^x4)
1236                 // and decrease left on the basis of the chars detected of the truncated tag
1237                 // Even if the ^xrgb tag is not complete/correct, left is decreased
1238                 // (sometimes too much but with a correct result)
1239                 // it fixes also ^[0-9]
1240                 while(left >= 1 && substring(theText, left-1, 1) == "^")
1241                         left-=1;
1242
1243                 if (left >= 2 && substring(theText, left-2, 2) == "^x") // ^x/
1244                         left-=2;
1245                 else if (left >= 3 && substring(theText, left-3, 2) == "^x")
1246                         {
1247                                 ch = str2chr(theText, left-1);
1248                                 if( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xr/
1249                                         left-=3;
1250                         }
1251                 else if (left >= 4 && substring(theText, left-4, 2) == "^x")
1252                         {
1253                                 ch = str2chr(theText, left-2);
1254                                 if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') )
1255                                 {
1256                                         ch = str2chr(theText, left-1);
1257                                         if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xrg/
1258                                                 left-=4;
1259                                 }
1260                         }
1261         }
1262
1263         return left;
1264 }
1265
1266 string find_last_color_code(string s)
1267 {
1268         float start, len, i, carets;
1269         start = strstrofs(s, "^", 0);
1270         if (start == -1) // no caret found
1271                 return "";
1272         len = strlen(s)-1;
1273         for(i = len; i >= start; --i)
1274         {
1275                 if(substring(s, i, 1) != "^")
1276                         continue;
1277
1278                 carets = 1;
1279                 while (i-carets >= start && substring(s, i-carets, 1) == "^")
1280                         ++carets;
1281
1282                 // check if carets aren't all escaped
1283                 if (carets == 1 || mod(carets, 2) == 1) // first check is just an optimization
1284                 {
1285                         if(i+1 <= len)
1286                         if(strstrofs("0123456789", substring(s, i+1, 1), 0) >= 0)
1287                                 return substring(s, i, 2);
1288
1289                         if(i+4 <= len)
1290                         if(substring(s, i+1, 1) == "x")
1291                         if(strstrofs("0123456789abcdefABCDEF", substring(s, i+2, 1), 0) >= 0)
1292                         if(strstrofs("0123456789abcdefABCDEF", substring(s, i+3, 1), 0) >= 0)
1293                         if(strstrofs("0123456789abcdefABCDEF", substring(s, i+4, 1), 0) >= 0)
1294                                 return substring(s, i, 5);
1295                 }
1296                 i -= carets; // this also skips one char before the carets
1297         }
1298
1299         return "";
1300 }
1301
1302 string getWrappedLine(float w, vector theFontSize, textLengthUpToWidth_widthFunction_t tw)
1303 {
1304         float cantake;
1305         float take;
1306         string s;
1307
1308         s = getWrappedLine_remaining;
1309
1310         if(w <= 0)
1311         {
1312                 getWrappedLine_remaining = string_null;
1313                 return s; // the line has no size ANYWAY, nothing would be displayed.
1314         }
1315
1316         cantake = textLengthUpToWidth(s, w, theFontSize, tw);
1317         if(cantake > 0 && cantake < strlen(s))
1318         {
1319                 take = cantake - 1;
1320                 while(take > 0 && substring(s, take, 1) != " ")
1321                         --take;
1322                 if(take == 0)
1323                 {
1324                         getWrappedLine_remaining = substring(s, cantake, strlen(s) - cantake);
1325                         if(getWrappedLine_remaining == "")
1326                                 getWrappedLine_remaining = string_null;
1327                         else if (tw("^7", theFontSize) == 0)
1328                                 getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, cantake)), getWrappedLine_remaining);
1329                         return substring(s, 0, cantake);
1330                 }
1331                 else
1332                 {
1333                         getWrappedLine_remaining = substring(s, take + 1, strlen(s) - take);
1334                         if(getWrappedLine_remaining == "")
1335                                 getWrappedLine_remaining = string_null;
1336                         else if (tw("^7", theFontSize) == 0)
1337                                 getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, take)), getWrappedLine_remaining);
1338                         return substring(s, 0, take);
1339                 }
1340         }
1341         else
1342         {
1343                 getWrappedLine_remaining = string_null;
1344                 return s;
1345         }
1346 }
1347
1348 string getWrappedLineLen(float w, textLengthUpToLength_lenFunction_t tw)
1349 {
1350         float cantake;
1351         float take;
1352         string s;
1353
1354         s = getWrappedLine_remaining;
1355
1356         if(w <= 0)
1357         {
1358                 getWrappedLine_remaining = string_null;
1359                 return s; // the line has no size ANYWAY, nothing would be displayed.
1360         }
1361
1362         cantake = textLengthUpToLength(s, w, tw);
1363         if(cantake > 0 && cantake < strlen(s))
1364         {
1365                 take = cantake - 1;
1366                 while(take > 0 && substring(s, take, 1) != " ")
1367                         --take;
1368                 if(take == 0)
1369                 {
1370                         getWrappedLine_remaining = substring(s, cantake, strlen(s) - cantake);
1371                         if(getWrappedLine_remaining == "")
1372                                 getWrappedLine_remaining = string_null;
1373                         else if (tw("^7") == 0)
1374                                 getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, cantake)), getWrappedLine_remaining);
1375                         return substring(s, 0, cantake);
1376                 }
1377                 else
1378                 {
1379                         getWrappedLine_remaining = substring(s, take + 1, strlen(s) - take);
1380                         if(getWrappedLine_remaining == "")
1381                                 getWrappedLine_remaining = string_null;
1382                         else if (tw("^7") == 0)
1383                                 getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, take)), getWrappedLine_remaining);
1384                         return substring(s, 0, take);
1385                 }
1386         }
1387         else
1388         {
1389                 getWrappedLine_remaining = string_null;
1390                 return s;
1391         }
1392 }
1393
1394 string textShortenToWidth(string theText, float maxWidth, vector theFontSize, textLengthUpToWidth_widthFunction_t tw)
1395 {
1396         if(tw(theText, theFontSize) <= maxWidth)
1397                 return theText;
1398         else
1399                 return strcat(substring(theText, 0, textLengthUpToWidth(theText, maxWidth - tw("...", theFontSize), theFontSize, tw)), "...");
1400 }
1401
1402 string textShortenToLength(string theText, float maxWidth, textLengthUpToLength_lenFunction_t tw)
1403 {
1404         if(tw(theText) <= maxWidth)
1405                 return theText;
1406         else
1407                 return strcat(substring(theText, 0, textLengthUpToLength(theText, maxWidth - tw("..."), tw)), "...");
1408 }
1409
1410 float isGametypeInFilter(float gt, float tp, float ts, string pattern)
1411 {
1412         string subpattern, subpattern2, subpattern3, subpattern4;
1413         subpattern = strcat(",", GametypeNameFromType(gt), ",");
1414         if(tp)
1415                 subpattern2 = ",teams,";
1416         else
1417                 subpattern2 = ",noteams,";
1418         if(ts)
1419                 subpattern3 = ",teamspawns,";
1420         else
1421                 subpattern3 = ",noteamspawns,";
1422         if(gt == GAME_RACE || gt == GAME_CTS)
1423                 subpattern4 = ",race,";
1424         else
1425                 subpattern4 = string_null;
1426
1427         if(substring(pattern, 0, 1) == "-")
1428         {
1429                 pattern = substring(pattern, 1, strlen(pattern) - 1);
1430                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) >= 0)
1431                         return 0;
1432                 if(strstrofs(strcat(",", pattern, ","), subpattern2, 0) >= 0)
1433                         return 0;
1434                 if(strstrofs(strcat(",", pattern, ","), subpattern3, 0) >= 0)
1435                         return 0;
1436                 if(subpattern4 && strstrofs(strcat(",", pattern, ","), subpattern4, 0) >= 0)
1437                         return 0;
1438         }
1439         else
1440         {
1441                 if(substring(pattern, 0, 1) == "+")
1442                         pattern = substring(pattern, 1, strlen(pattern) - 1);
1443                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) < 0)
1444                 if(strstrofs(strcat(",", pattern, ","), subpattern2, 0) < 0)
1445                 if(strstrofs(strcat(",", pattern, ","), subpattern3, 0) < 0)
1446                 if((!subpattern4) || strstrofs(strcat(",", pattern, ","), subpattern4, 0) < 0)
1447                         return 0;
1448         }
1449         return 1;
1450 }
1451
1452 void shuffle(float n, swapfunc_t swap, entity pass)
1453 {
1454         float i, j;
1455         for(i = 1; i < n; ++i)
1456         {
1457                 // swap i-th item at a random position from 0 to i
1458                 // proof for even distribution:
1459                 //   n = 1: obvious
1460                 //   n -> n+1:
1461                 //     item n+1 gets at any position with chance 1/(n+1)
1462                 //     all others will get their 1/n chance reduced by factor n/(n+1)
1463                 //     to be on place n+1, their chance will be 1/(n+1)
1464                 //     1/n * n/(n+1) = 1/(n+1)
1465                 //     q.e.d.
1466                 j = floor(random() * (i + 1));
1467                 if(j != i)
1468                         swap(j, i, pass);
1469         }
1470 }
1471
1472 string substring_range(string s, float b, float e)
1473 {
1474         return substring(s, b, e - b);
1475 }
1476
1477 string swapwords(string str, float i, float j)
1478 {
1479         float n;
1480         string s1, s2, s3, s4, s5;
1481         float si, ei, sj, ej, s0, en;
1482         n = tokenizebyseparator(str, " "); // must match g_maplist processing in ShuffleMaplist and "shuffle"
1483         si = argv_start_index(i);
1484         sj = argv_start_index(j);
1485         ei = argv_end_index(i);
1486         ej = argv_end_index(j);
1487         s0 = argv_start_index(0);
1488         en = argv_end_index(n-1);
1489         s1 = substring_range(str, s0, si);
1490         s2 = substring_range(str, si, ei);
1491         s3 = substring_range(str, ei, sj);
1492         s4 = substring_range(str, sj, ej);
1493         s5 = substring_range(str, ej, en);
1494         return strcat(s1, s4, s3, s2, s5);
1495 }
1496
1497 string _shufflewords_str;
1498 void _shufflewords_swapfunc(float i, float j, entity pass)
1499 {
1500         _shufflewords_str = swapwords(_shufflewords_str, i, j);
1501 }
1502 string shufflewords(string str)
1503 {
1504         float n;
1505         _shufflewords_str = str;
1506         n = tokenizebyseparator(str, " ");
1507         shuffle(n, _shufflewords_swapfunc, world);
1508         str = _shufflewords_str;
1509         _shufflewords_str = string_null;
1510         return str;
1511 }
1512
1513 vector solve_quadratic(float a, float b, float c) // ax^2 + bx + c = 0
1514 {
1515         vector v;
1516         float D;
1517         v = '0 0 0';
1518         if(a == 0)
1519         {
1520                 if(b != 0)
1521                 {
1522                         v_x = v_y = -c / b;
1523                         v_z = 1;
1524                 }
1525                 else
1526                 {
1527                         if(c == 0)
1528                         {
1529                                 // actually, every number solves the equation!
1530                                 v_z = 1;
1531                         }
1532                 }
1533         }
1534         else
1535         {
1536                 D = b*b - 4*a*c;
1537                 if(D >= 0)
1538                 {
1539                         D = sqrt(D);
1540                         if(a > 0) // put the smaller solution first
1541                         {
1542                                 v_x = ((-b)-D) / (2*a);
1543                                 v_y = ((-b)+D) / (2*a);
1544                         }
1545                         else
1546                         {
1547                                 v_x = (-b+D) / (2*a);
1548                                 v_y = (-b-D) / (2*a);
1549                         }
1550                         v_z = 1;
1551                 }
1552                 else
1553                 {
1554                         // complex solutions!
1555                         D = sqrt(-D);
1556                         v_x = -b / (2*a);
1557                         if(a > 0)
1558                                 v_y =  D / (2*a);
1559                         else
1560                                 v_y = -D / (2*a);
1561                         v_z = 0;
1562                 }
1563         }
1564         return v;
1565 }
1566
1567 void check_unacceptable_compiler_bugs()
1568 {
1569         if(cvar("_allow_unacceptable_compiler_bugs"))
1570                 return;
1571         tokenize_console("foo bar");
1572         if(strcat(argv(0), substring("foo bar", 4, 7 - argv_start_index(1))) == "barbar")
1573                 error("fteqcc bug introduced with revision 3178 detected. Please upgrade fteqcc to a later revision, downgrade fteqcc to revision 3177, or pester Spike until he fixes it. You can set _allow_unacceptable_compiler_bugs 1 to skip this check, but expect stuff to be horribly broken then.");
1574 }
1575
1576 float compressShotOrigin(vector v)
1577 {
1578         float x, y, z;
1579         x = rint(v_x * 2);
1580         y = rint(v_y * 4) + 128;
1581         z = rint(v_z * 4) + 128;
1582         if(x > 255 || x < 0)
1583         {
1584                 print("shot origin ", vtos(v), " x out of bounds\n");
1585                 x = bound(0, x, 255);
1586         }
1587         if(y > 255 || y < 0)
1588         {
1589                 print("shot origin ", vtos(v), " y out of bounds\n");
1590                 y = bound(0, y, 255);
1591         }
1592         if(z > 255 || z < 0)
1593         {
1594                 print("shot origin ", vtos(v), " z out of bounds\n");
1595                 z = bound(0, z, 255);
1596         }
1597         return x * 0x10000 + y * 0x100 + z;
1598 }
1599 vector decompressShotOrigin(float f)
1600 {
1601         vector v;
1602         v_x = ((f & 0xFF0000) / 0x10000) / 2;
1603         v_y = ((f & 0xFF00) / 0x100 - 128) / 4;
1604         v_z = ((f & 0xFF) - 128) / 4;
1605         return v;
1606 }
1607
1608 void heapsort(float n, swapfunc_t swap, comparefunc_t cmp, entity pass)
1609 {
1610         float start, end, root, child;
1611
1612         // heapify
1613         start = floor((n - 2) / 2);
1614         while(start >= 0)
1615         {
1616                 // siftdown(start, count-1);
1617                 root = start;
1618                 while(root * 2 + 1 <= n-1)
1619                 {
1620                         child = root * 2 + 1;
1621                         if(child < n-1)
1622                                 if(cmp(child, child+1, pass) < 0)
1623                                         ++child;
1624                         if(cmp(root, child, pass) < 0)
1625                         {
1626                                 swap(root, child, pass);
1627                                 root = child;
1628                         }
1629                         else
1630                                 break;
1631                 }
1632                 // end of siftdown
1633                 --start;
1634         }
1635
1636         // extract
1637         end = n - 1;
1638         while(end > 0)
1639         {
1640                 swap(0, end, pass);
1641                 --end;
1642                 // siftdown(0, end);
1643                 root = 0;
1644                 while(root * 2 + 1 <= end)
1645                 {
1646                         child = root * 2 + 1;
1647                         if(child < end && cmp(child, child+1, pass) < 0)
1648                                 ++child;
1649                         if(cmp(root, child, pass) < 0)
1650                         {
1651                                 swap(root, child, pass);
1652                                 root = child;
1653                         }
1654                         else
1655                                 break;
1656                 }
1657                 // end of siftdown
1658         }
1659 }
1660
1661 void RandomSelection_Init()
1662 {
1663         RandomSelection_totalweight = 0;
1664         RandomSelection_chosen_ent = world;
1665         RandomSelection_chosen_float = 0;
1666         RandomSelection_chosen_string = string_null;
1667         RandomSelection_best_priority = -1;
1668 }
1669 void RandomSelection_Add(entity e, float f, string s, float weight, float priority)
1670 {
1671         if(priority > RandomSelection_best_priority)
1672         {
1673                 RandomSelection_best_priority = priority;
1674                 RandomSelection_chosen_ent = e;
1675                 RandomSelection_chosen_float = f;
1676                 RandomSelection_chosen_string = s;
1677                 RandomSelection_totalweight = weight;
1678         }
1679         else if(priority == RandomSelection_best_priority)
1680         {
1681                 RandomSelection_totalweight += weight;
1682                 if(random() * RandomSelection_totalweight <= weight)
1683                 {
1684                         RandomSelection_chosen_ent = e;
1685                         RandomSelection_chosen_float = f;
1686                         RandomSelection_chosen_string = s;
1687                 }
1688         }
1689 }
1690
1691 vector healtharmor_maxdamage(float h, float a, float armorblock)
1692 {
1693         // NOTE: we'll always choose the SMALLER value...
1694         float healthdamage, armordamage, armorideal;
1695         vector v;
1696         healthdamage = (h - 1) / (1 - armorblock); // damage we can take if we could use more health
1697         armordamage = a + (h - 1); // damage we can take if we could use more armor
1698         armorideal = healthdamage * armorblock;
1699         v_y = armorideal;
1700         if(armordamage < healthdamage)
1701         {
1702                 v_x = armordamage;
1703                 v_z = 1;
1704         }
1705         else
1706         {
1707                 v_x = healthdamage;
1708                 v_z = 0;
1709         }
1710         return v;
1711 }
1712
1713 vector healtharmor_applydamage(float a, float armorblock, float damage)
1714 {
1715         vector v;
1716         v_y = bound(0, damage * armorblock, a); // save
1717         v_x = bound(0, damage - v_y, damage); // take
1718         v_z = 0;
1719         return v;
1720 }
1721
1722 string getcurrentmod()
1723 {
1724         float n;
1725         string m;
1726         m = cvar_string("fs_gamedir");
1727         n = tokenize_console(m);
1728         if(n == 0)
1729                 return "data";
1730         else
1731                 return argv(n - 1);
1732 }
1733
1734 #ifndef MENUQC
1735 #ifdef CSQC
1736 float ReadInt24_t()
1737 {
1738         float v;
1739         v = ReadShort() * 256; // note: this is signed
1740         v += ReadByte(); // note: this is unsigned
1741         return v;
1742 }
1743 #else
1744 void WriteInt24_t(float dst, float val)
1745 {
1746         float v;
1747         WriteShort(dst, (v = floor(val / 256)));
1748         WriteByte(dst, val - v * 256); // 0..255
1749 }
1750 #endif
1751 #endif
1752
1753 float float2range11(float f)
1754 {
1755         // continuous function mapping all reals into -1..1
1756         return f / (fabs(f) + 1);
1757 }
1758
1759 float float2range01(float f)
1760 {
1761         // continuous function mapping all reals into 0..1
1762         return 0.5 + 0.5 * float2range11(f);
1763 }
1764
1765 // from the GNU Scientific Library
1766 float gsl_ran_gaussian_lastvalue;
1767 float gsl_ran_gaussian_lastvalue_set;
1768 float gsl_ran_gaussian(float sigma)
1769 {
1770         float a, b;
1771         if(gsl_ran_gaussian_lastvalue_set)
1772         {
1773                 gsl_ran_gaussian_lastvalue_set = 0;
1774                 return sigma * gsl_ran_gaussian_lastvalue;
1775         }
1776         else
1777         {
1778                 a = random() * 2 * M_PI;
1779                 b = sqrt(-2 * log(random()));
1780                 gsl_ran_gaussian_lastvalue = cos(a) * b;
1781                 gsl_ran_gaussian_lastvalue_set = 1;
1782                 return sigma * sin(a) * b;
1783         }
1784 }
1785
1786 string car(string s)
1787 {
1788         float o;
1789         o = strstrofs(s, " ", 0);
1790         if(o < 0)
1791                 return s;
1792         return substring(s, 0, o);
1793 }
1794 string cdr(string s)
1795 {
1796         float o;
1797         o = strstrofs(s, " ", 0);
1798         if(o < 0)
1799                 return string_null;
1800         return substring(s, o + 1, strlen(s) - (o + 1));
1801 }
1802 float matchacl(string acl, string str)
1803 {
1804         string t, s;
1805         float r, d;
1806         r = 0;
1807         while(acl)
1808         {
1809                 t = car(acl); acl = cdr(acl);
1810                 d = 1;
1811                 if(substring(t, 0, 1) == "-")
1812                 {
1813                         d = -1;
1814                         t = substring(t, 1, strlen(t) - 1);
1815                 }
1816                 else if(substring(t, 0, 1) == "+")
1817                         t = substring(t, 1, strlen(t) - 1);
1818                 if(substring(t, -1, 1) == "*")
1819                 {
1820                         t = substring(t, 0, strlen(t) - 1);
1821                         s = substring(s, 0, strlen(t));
1822                 }
1823                 else
1824                         s = str;
1825
1826                 if(s == t)
1827                 {
1828                         r = d;
1829                 }
1830         }
1831         return r;
1832 }
1833 float startsWith(string haystack, string needle)
1834 {
1835         return substring(haystack, 0, strlen(needle)) == needle;
1836 }
1837 float startsWithNocase(string haystack, string needle)
1838 {
1839         return strcasecmp(substring(haystack, 0, strlen(needle)), needle) == 0;
1840 }
1841
1842 string get_model_datafilename(string m, float sk, string fil)
1843 {
1844         if(m)
1845                 m = strcat(m, "_");
1846         else
1847                 m = "models/player/*_";
1848         if(sk >= 0)
1849                 m = strcat(m, ftos(sk));
1850         else
1851                 m = strcat(m, "*");
1852         return strcat(m, ".", fil);
1853 }
1854
1855 float get_model_parameters(string m, float sk)
1856 {
1857         string fn, s, c;
1858         float fh;
1859
1860         get_model_parameters_modelname = string_null;
1861         get_model_parameters_modelskin = -1;
1862         get_model_parameters_name = string_null;
1863         get_model_parameters_species = -1;
1864         get_model_parameters_sex = string_null;
1865         get_model_parameters_weight = -1;
1866         get_model_parameters_age = -1;
1867         get_model_parameters_desc = string_null;
1868
1869         if not(m)
1870                 return 1;
1871         if(sk < 0)
1872         {
1873                 if(substring(m, -4, -1) != ".txt")
1874                         return 0;
1875                 if(substring(m, -6, 1) != "_")
1876                         return 0;
1877                 sk = stof(substring(m, -5, 1));
1878                 m = substring(m, 0, -7);
1879         }
1880
1881         fn = get_model_datafilename(m, sk, "txt");
1882         fh = fopen(fn, FILE_READ);
1883         if(fh < 0)
1884         {
1885                 sk = 0;
1886                 fn = get_model_datafilename(m, sk, "txt");
1887                 fh = fopen(fn, FILE_READ);
1888                 if(fh < 0)
1889                         return 0;
1890         }
1891
1892         get_model_parameters_modelname = m;
1893         get_model_parameters_modelskin = sk;
1894         while((s = fgets(fh)))
1895         {
1896                 if(s == "")
1897                         break; // next lines will be description
1898                 c = car(s);
1899                 s = cdr(s);
1900                 if(c == "name")
1901                         get_model_parameters_name = s;
1902                 if(c == "species")
1903                         switch(s)
1904                         {
1905                                 case "human":       get_model_parameters_species = SPECIES_HUMAN;       break;
1906                                 case "alien":       get_model_parameters_species = SPECIES_ALIEN;       break;
1907                                 case "robot_shiny": get_model_parameters_species = SPECIES_ROBOT_SHINY; break;
1908                                 case "robot_rusty": get_model_parameters_species = SPECIES_ROBOT_RUSTY; break;
1909                                 case "robot_solid": get_model_parameters_species = SPECIES_ROBOT_SOLID; break;
1910                                 case "animal":      get_model_parameters_species = SPECIES_ANIMAL;      break;
1911                                 case "reserved":    get_model_parameters_species = SPECIES_RESERVED;    break;
1912                         }
1913                 if(c == "sex")
1914                         get_model_parameters_sex = s;
1915                 if(c == "weight")
1916                         get_model_parameters_weight = stof(s);
1917                 if(c == "age")
1918                         get_model_parameters_age = stof(s);
1919         }
1920
1921         while((s = fgets(fh)))
1922         {
1923                 if(get_model_parameters_desc)
1924                         get_model_parameters_desc = strcat(get_model_parameters_desc, "\n");
1925                 if(s != "")
1926                         get_model_parameters_desc = strcat(get_model_parameters_desc, s);
1927         }
1928
1929         fclose(fh);
1930
1931         return 1;
1932 }
1933
1934 vector vec2(vector v)
1935 {
1936         v_z = 0;
1937         return v;
1938 }
1939
1940 #ifndef MENUQC
1941 vector NearestPointOnBox(entity box, vector org)
1942 {
1943         vector m1, m2, nearest;
1944
1945         m1 = box.mins + box.origin;
1946         m2 = box.maxs + box.origin;
1947
1948         nearest_x = bound(m1_x, org_x, m2_x);
1949         nearest_y = bound(m1_y, org_y, m2_y);
1950         nearest_z = bound(m1_z, org_z, m2_z);
1951
1952         return nearest;
1953 }
1954 #endif
1955
1956 float vercmp_recursive(string v1, string v2)
1957 {
1958         float dot1, dot2;
1959         string s1, s2;
1960         float r;
1961
1962         dot1 = strstrofs(v1, ".", 0);
1963         dot2 = strstrofs(v2, ".", 0);
1964         if(dot1 == -1)
1965                 s1 = v1;
1966         else
1967                 s1 = substring(v1, 0, dot1);
1968         if(dot2 == -1)
1969                 s2 = v2;
1970         else
1971                 s2 = substring(v2, 0, dot2);
1972
1973         r = stof(s1) - stof(s2);
1974         if(r != 0)
1975                 return r;
1976
1977         r = strcasecmp(s1, s2);
1978         if(r != 0)
1979                 return r;
1980
1981         if(dot1 == -1)
1982                 if(dot2 == -1)
1983                         return 0;
1984                 else
1985                         return -1;
1986         else
1987                 if(dot2 == -1)
1988                         return 1;
1989                 else
1990                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1991 }
1992
1993 float vercmp(string v1, string v2)
1994 {
1995         if(strcasecmp(v1, v2) == 0) // early out check
1996                 return 0;
1997
1998         // "git" beats all
1999         if(v1 == "git")
2000                 return 1;
2001         if(v2 == "git")
2002                 return -1;
2003
2004         return vercmp_recursive(v1, v2);
2005 }
2006
2007 float u8_strsize(string s)
2008 {
2009         float l, i, c;
2010         l = 0;
2011         for(i = 0; ; ++i)
2012         {
2013                 c = str2chr(s, i);
2014                 if(c <= 0)
2015                         break;
2016                 ++l;
2017                 if(c >= 0x80)
2018                         ++l;
2019                 if(c >= 0x800)
2020                         ++l;
2021                 if(c >= 0x10000)
2022                         ++l;
2023         }
2024         return l;
2025 }
2026
2027 // translation helpers
2028 string language_filename(string s)
2029 {
2030         string fn;
2031         float fh;
2032         fn = prvm_language;
2033         if(fn == "" || fn == "dump")
2034                 return s;
2035         fn = strcat(s, ".", fn);
2036         if((fh = fopen(fn, FILE_READ)) >= 0)
2037         {
2038                 fclose(fh);
2039                 return fn;
2040         }
2041         return s;
2042 }
2043 string CTX(string s)
2044 {
2045         float p = strstrofs(s, "^", 0);
2046         if(p < 0)
2047                 return s;
2048         return substring(s, p+1, -1);
2049 }
2050
2051 // x-encoding (encoding as zero length invisible string)
2052 const string XENCODE_2  = "xX";
2053 const string XENCODE_22 = "0123456789abcdefABCDEF";
2054 string xencode(float f)
2055 {
2056         float a, b, c, d;
2057         d = mod(f, 22); f = floor(f / 22);
2058         c = mod(f, 22); f = floor(f / 22);
2059         b = mod(f, 22); f = floor(f / 22);
2060         a = mod(f,  2); // f = floor(f /  2);
2061         return strcat(
2062                 "^",
2063                 substring(XENCODE_2,  a, 1),
2064                 substring(XENCODE_22, b, 1),
2065                 substring(XENCODE_22, c, 1),
2066                 substring(XENCODE_22, d, 1)
2067         );
2068 }
2069 float xdecode(string s)
2070 {
2071         float a, b, c, d;
2072         if(substring(s, 0, 1) != "^")
2073                 return -1;
2074         if(strlen(s) < 5)
2075                 return -1;
2076         a = strstrofs(XENCODE_2,  substring(s, 1, 1), 0);
2077         b = strstrofs(XENCODE_22, substring(s, 2, 1), 0);
2078         c = strstrofs(XENCODE_22, substring(s, 3, 1), 0);
2079         d = strstrofs(XENCODE_22, substring(s, 4, 1), 0);
2080         if(a < 0 || b < 0 || c < 0 || d < 0)
2081                 return -1;
2082         return ((a * 22 + b) * 22 + c) * 22 + d;
2083 }
2084
2085 float lowestbit(float f)
2086 {
2087         f &~= f * 2;
2088         f &~= f * 4;
2089         f &~= f * 16;
2090         f &~= f * 256;
2091         f &~= f * 65536;
2092         return f;
2093 }
2094
2095 #ifdef CSQC
2096 entity ReadCSQCEntity()
2097 {
2098         float f;
2099         f = ReadShort();
2100         if(f == 0)
2101                 return world;
2102         return findfloat(world, entnum, f);
2103 }
2104 #endif
2105
2106 float shutdown_running;
2107 #ifdef SVQC
2108 void SV_Shutdown()
2109 #endif
2110 #ifdef CSQC
2111 void CSQC_Shutdown()
2112 #endif
2113 #ifdef MENUQC
2114 void m_shutdown()
2115 #endif
2116 {
2117         if(shutdown_running)
2118         {
2119                 print("Recursive shutdown detected! Only restoring cvars...\n");
2120         }
2121         else
2122         {
2123                 shutdown_running = 1;
2124                 Shutdown();
2125         }
2126         cvar_settemp_restore(); // this must be done LAST, but in any case
2127 }