qcsrc/common/vehicles/cl_vehicles.qc

   1 const string vCROSS_BURST = "gfx/vehicles/crosshair_burst.tga";
   2 const string vCROSS_DROP  = "gfx/vehicles/crosshair_drop.tga";
   3 const string vCROSS_GUIDE = "gfx/vehicles/crosshair_guide.tga";
   4 const string vCROSS_HEAL  = "gfx/vehicles/crosshair_heal.tga";
   5 const string vCROSS_HINT  = "gfx/vehicles/crosshair_hint.tga";
   6 const string vCROSS_LOCK  = "gfx/vehicles/crosshair_lock.tga";
   7 const string vCROSS_RAIN  = "gfx/vehicles/crosshair_rain.tga";
   8
   9 entity dropmark;
  10
  11 const int MAX_AXH = 4;
  12 entity AuxiliaryXhair[MAX_AXH];
  13
  14 .string axh_image;
  15 .float  axh_fadetime;
  16 .int    axh_drawflag;
  17
  18 float alarm1time;
  19 float alarm2time;
  20
  21 void vehicle_alarm(entity e, int ch, string s0und)
  22 {
  23         if(!autocvar_cl_vehicles_alarm)
  24                 return;
  25
  26         _sound(e, ch, s0und, VOL_BASEVOICE, ATTEN_NONE);
  27 }
  28
  29 void AuxiliaryXhair_Draw2D(entity this)
  30 {
  31         if (scoreboard_showscores)
  32                 return;
  33
  34         vector size = draw_getimagesize(self.axh_image) * autocvar_cl_vehicles_crosshair_size;
  35         vector pos = project_3d_to_2d(self.move_origin) - 0.5 * size;
  36
  37         if (!(pos.z < 0 || pos.x < 0 || pos.y < 0 || pos.x > vid_conwidth || pos.y > vid_conheight))
  38         {
  39                 pos.z = 0;
  40                 size.z = 0;
  41                 drawpic(pos, self.axh_image, size, self.colormod, autocvar_crosshair_alpha * self.alpha, self.axh_drawflag);
  42         }
  43
  44         if(time - self.cnt > self.axh_fadetime)
  45                 self.draw2d = func_null;
  46 }
  47
  48 void Net_AuXair2(bool bIsNew)
  49 {
  50         int axh_id      = bound(0, ReadByte(), MAX_AXH);
  51         entity axh              = AuxiliaryXhair[axh_id];
  52
  53         if(axh == world || wasfreed(axh))  // MADNESS? THIS IS QQQQCCCCCCCCC (wasfreed, why do you exsist?)
  54         {
  55                 axh                                     = spawn();
  56                 axh.draw2d                      = func_null;
  57                 axh.drawmask            = MASK_NORMAL;
  58                 axh.axh_drawflag        = DRAWFLAG_ADDITIVE;
  59                 axh.axh_fadetime        = 0.1;
  60                 axh.axh_image           = vCROSS_HINT;
  61                 axh.alpha                       = 1;
  62                 AuxiliaryXhair[axh_id] = axh;
  63         }
  64
  65         axh.move_origin_x       = ReadCoord();
  66         axh.move_origin_y       = ReadCoord();
  67         axh.move_origin_z       = ReadCoord();
  68         axh.colormod_x          = ReadByte() / 255;
  69         axh.colormod_y          = ReadByte() / 255;
  70         axh.colormod_z          = ReadByte() / 255;
  71         axh.cnt                         = time;
  72         axh.draw2d                      = AuxiliaryXhair_Draw2D;
  73 }
  74
  75 void Net_VehicleSetup()
  76 {SELFPARAM();
  77         int hud_id = ReadByte();
  78
  79         // hud_id == 0 means we exited a vehicle, so stop alarm sound/s
  80         if(hud_id == 0)
  81         {
  82                 sound(self, CH_TRIGGER_SINGLE, SND_Null, VOL_BASEVOICE, ATTEN_NONE);
  83                 sound(self, CH_PAIN_SINGLE, SND_Null, VOL_BASEVOICE, ATTEN_NONE);
  84                 return;
  85         }
  86
  87         // Init auxiliary crosshairs
  88         for(int i = 0; i < MAX_AXH; ++i)
  89         {
  90                 entity axh = AuxiliaryXhair[i];
  91
  92                 if(axh != world && !wasfreed(axh))  // MADNESS? THIS IS QQQQCCCCCCCCC (wasfreed, why do you exsist?)
  93                         remove(axh);
  94
  95                 axh              = spawn();
  96                 axh.draw2d       = func_null;
  97                 axh.drawmask     = MASK_NORMAL;
  98                 axh.axh_drawflag = DRAWFLAG_NORMAL;
  99                 axh.axh_fadetime = 0.1;
 100                 axh.axh_image    = vCROSS_HINT;
 101                 axh.alpha        = 1;
 102                 AuxiliaryXhair[i] = axh;
 103         }
 104
 105         if(hud_id == HUD_BUMBLEBEE_GUN)
 106         {
 107                 AuxiliaryXhair[0].axh_image = vCROSS_BURST; // Plasma cannons
 108                 AuxiliaryXhair[1].axh_image = vCROSS_BURST; // Raygun
 109         } else {
 110                 Vehicle info = get_vehicleinfo(hud_id);
 111         info.vr_setup(info);
 112         }
 113 }
 114
 115 void Vehicles_drawHUD(
 116         string vehicle,
 117         string vehicleWeapon1,
 118         string vehicleWeapon2,
 119         string iconAmmo1,
 120         vector colorAmmo1,
 121         string iconAmmo2,
 122         vector colorAmmo2)
 123 {
 124         SELFPARAM();
 125         if(scoreboard_showscores)
 126                 return;
 127
 128         // Initialize
 129         vector hudSize = '0 0 0';
 130         vector hudPos  = '0 0 0';
 131         vector tmpSize = '0 0 0';
 132         vector tmpPos  = '0 0 0';
 133
 134         float hudAlpha = autocvar_hud_panel_fg_alpha;
 135         float barAlpha = autocvar_hud_progressbar_alpha * hudAlpha;
 136         float blinkValue = 0.55 + sin(time * 7) * 0.45;
 137
 138         float health  = getstati(STAT_VEHICLESTAT_HEALTH)  * 0.01;
 139         float shield  = getstati(STAT_VEHICLESTAT_SHIELD)  * 0.01;
 140         float energy  = getstati(STAT_VEHICLESTAT_ENERGY)  * 0.01;
 141         float ammo1   = getstati(STAT_VEHICLESTAT_AMMO1)   * 0.01;
 142         float reload1 = getstati(STAT_VEHICLESTAT_RELOAD1) * 0.01;
 143         float ammo2   = getstati(STAT_VEHICLESTAT_AMMO2)   * 0.01;
 144         float reload2 = getstati(STAT_VEHICLESTAT_RELOAD2) * 0.01;
 145
 146         // HACK to deal with the inconsistent use of the vehicle stats
 147         ammo1 = (ammo1) ? ammo1 : energy;
 148
 149         // Frame
 150         string frame = strcat(hud_skin_path, "/vehicle_frame");
 151         if (precache_pic(frame) == "")
 152                 frame = "gfx/hud/default/vehicle_frame";
 153
 154         hudSize  = draw_getimagesize(frame) * autocvar_cl_vehicles_hudscale;
 155         hudPos.x = (vid_conwidth - hudSize.x) / 2;
 156         hudPos.y = vid_conheight - hudSize.y;
 157
 158         if(teamplay && autocvar_hud_panel_bg_color_team)
 159                 drawpic(hudPos, frame, hudSize, myteamcolors * autocvar_hud_panel_bg_color_team, autocvar_hud_panel_bg_alpha, DRAWFLAG_NORMAL);
 160         else
 161                 drawpic(hudPos, frame, hudSize, autocvar_hud_panel_bg_color, autocvar_hud_panel_bg_alpha, DRAWFLAG_NORMAL);
 162
 163         if(!autocvar__vehicles_shownchasemessage && time < vh_notice_time)
 164         {
 165                 float tmpblinkValue = 0.55 + sin(time * 3) * 0.45;
 166                 tmpPos.x = hudPos.x + hudSize.x * (96/256) - tmpSize.x;
 167                 tmpPos.y = hudPos.y;
 168                 tmpSize = '1 1 1' * hud_fontsize;
 169                 drawstring(tmpPos, sprintf(_("Press %s"), getcommandkey("dropweapon", "dropweapon")), tmpSize, '1 0 0' + '0 1 1' * tmpblinkValue, hudAlpha, DRAWFLAG_NORMAL);
 170         }
 171
 172         // Model
 173         tmpSize.x = hudSize.x / 3;
 174         tmpSize.y = hudSize.y;
 175         tmpPos.x  = hudPos.x + hudSize.x / 3;
 176         tmpPos.y  = hudPos.y;
 177
 178         if(health < 0.25)
 179                 drawpic_skin(tmpPos, vehicle, tmpSize, '1 0 0' + '0 1 1' * blinkValue, hudAlpha, DRAWFLAG_NORMAL);
 180         else
 181                 drawpic_skin(tmpPos, vehicle, tmpSize, '1 1 1' * health  + '1 0 0' * (1 - health), hudAlpha, DRAWFLAG_NORMAL);
 182
 183         if(vehicleWeapon1)
 184                 drawpic_skin(tmpPos, vehicleWeapon1, tmpSize, '1 1 1' * ammo1 + '1 0 0' * (1 - ammo1), hudAlpha, DRAWFLAG_NORMAL);
 185         if(vehicleWeapon2)
 186                 drawpic_skin(tmpPos, vehicleWeapon2, tmpSize, '1 1 1' * ammo2 + '1 0 0' * (1 - ammo2), hudAlpha, DRAWFLAG_NORMAL);
 187
 188         drawpic_skin(tmpPos, "vehicle_shield", tmpSize, '1 1 1' * shield + '1 0 0' * (1 - shield), hudAlpha * shield, DRAWFLAG_NORMAL);
 189
 190         // Health bar
 191         tmpSize.y = hudSize.y / 2;
 192         tmpPos.x  = hudPos.x + hudSize.x * (32/768);
 193         tmpPos.y  = hudPos.y;
 194
 195         drawsetcliparea(tmpPos.x + (tmpSize.x * (1 - health)), tmpPos.y, tmpSize.x, tmpSize.y);
 196         drawpic_skin(tmpPos, "vehicle_bar_northwest", tmpSize, autocvar_hud_progressbar_health_color, barAlpha, DRAWFLAG_NORMAL);
 197
 198         // Shield bar
 199         tmpPos.y = hudPos.y + hudSize.y / 2;
 200
 201         drawsetcliparea(tmpPos.x + (tmpSize.x * (1 - shield)), tmpPos.y, tmpSize.x, tmpSize.y);
 202         drawpic_skin(tmpPos, "vehicle_bar_southwest", tmpSize, autocvar_hud_progressbar_armor_color, barAlpha, DRAWFLAG_NORMAL);
 203
 204         // Ammo1 bar
 205         tmpPos.x = hudPos.x + hudSize.x * (480/768);
 206         tmpPos.y = hudPos.y;
 207
 208         if(ammo1)
 209                 drawsetcliparea(tmpPos.x, tmpPos.y, tmpSize.x * ammo1, tmpSize.y);
 210         else
 211                 drawsetcliparea(tmpPos.x, tmpPos.y, tmpSize.x * reload1, tmpSize.y);
 212
 213         drawpic_skin(tmpPos, "vehicle_bar_northeast", tmpSize, colorAmmo1, barAlpha, DRAWFLAG_NORMAL);
 214
 215         // Ammo2 bar
 216         tmpPos.y = hudPos.y + hudSize.y / 2;
 217
 218         if(ammo2)
 219                 drawsetcliparea(tmpPos.x, tmpPos.y, tmpSize.x * ammo2, tmpSize.y);
 220         else
 221                 drawsetcliparea(tmpPos.x, tmpPos.y, tmpSize.x * reload2, tmpSize.y);
 222
 223         drawpic_skin(tmpPos, "vehicle_bar_southeast", tmpSize, colorAmmo2, barAlpha, DRAWFLAG_NORMAL);
 224         drawresetcliparea();
 225
 226         // Health icon
 227         tmpSize.x = hudSize.x * (80/768);
 228         tmpSize.y = hudSize.y * (80/256);
 229         tmpPos.x  = hudPos.x + hudSize.x * (64/768);
 230         tmpPos.y  = hudPos.y + hudSize.y * (48/256);
 231
 232         if(health < 0.25)
 233         {
 234                 if(alarm1time < time)
 235                 {
 236                         alarm1time = time + 2;
 237                         vehicle_alarm(self, CH_PAIN_SINGLE, SND(VEH_ALARM));
 238                 }
 239                 drawpic_skin(tmpPos, "vehicle_icon_health", tmpSize, '1 1 1', hudAlpha * blinkValue, DRAWFLAG_NORMAL);
 240         }
 241         else
 242         {
 243                 if(alarm1time)
 244                 {
 245                         vehicle_alarm(self, CH_PAIN_SINGLE, SND(Null));
 246                         alarm1time = 0;
 247                 }
 248                 drawpic_skin(tmpPos, "vehicle_icon_health", tmpSize, '1 1 1', hudAlpha, DRAWFLAG_NORMAL);
 249         }
 250
 251         // Shield icon
 252         tmpPos.y = hudPos.y + hudSize.y / 2;
 253
 254         if(shield < 0.25)
 255         {
 256                 if(alarm2time < time)
 257                 {
 258                         alarm2time = time + 1;
 259                         vehicle_alarm(self, CH_TRIGGER_SINGLE, SND(VEH_ALARM_SHIELD));
 260                 }
 261                 drawpic_skin(tmpPos, "vehicle_icon_shield", tmpSize, '1 1 1', hudAlpha * blinkValue, DRAWFLAG_NORMAL);
 262         }
 263         else
 264         {
 265                 if(alarm2time)
 266                 {
 267                         vehicle_alarm(self, CH_TRIGGER_SINGLE, SND(Null));
 268                         alarm2time = 0;
 269                 }
 270                 drawpic_skin(tmpPos, "vehicle_icon_shield", tmpSize, '1 1 1', hudAlpha, DRAWFLAG_NORMAL);
 271         }
 272
 273         // Ammo1 icon
 274         tmpPos.x = hudPos.x + hudSize.x * (624/768);
 275         tmpPos.y = hudPos.y + hudSize.y * (48/256);
 276
 277         if(iconAmmo1)
 278         {
 279                 if(ammo1)
 280                         drawpic_skin(tmpPos, iconAmmo1, tmpSize, '1 1 1', hudAlpha, DRAWFLAG_NORMAL);
 281                 else
 282                         drawpic_skin(tmpPos, iconAmmo1, tmpSize, '1 1 1', hudAlpha * 0.2, DRAWFLAG_NORMAL);
 283         }
 284
 285         // Ammo2 icon
 286         tmpPos.y = hudPos.y + hudSize.y / 2;
 287
 288         if(iconAmmo2)
 289         {
 290                 if(ammo2)
 291                         drawpic_skin(tmpPos, iconAmmo2, tmpSize, '1 1 1', hudAlpha, DRAWFLAG_NORMAL);
 292                 else
 293                         drawpic_skin(tmpPos, iconAmmo2, tmpSize, '1 1 1', hudAlpha * 0.2, DRAWFLAG_NORMAL);
 294         }
 295
 296         // Bumblebee gunner crosshairs
 297         if(hud == VEH_BUMBLEBEE.vehicleid)
 298         {
 299                 tmpSize = '1 1 1' * hud_fontsize;
 300                 tmpPos.x = hudPos.x + hudSize.x * (520/768);
 301
 302                 if(!AuxiliaryXhair[1].draw2d)
 303                 {
 304                         tmpPos.y = hudPos.y + hudSize.y * (96/256) - tmpSize.y;
 305                         drawstring(tmpPos, _("No right gunner!"), tmpSize, '1 1 1', hudAlpha * blinkValue, DRAWFLAG_NORMAL);
 306                 }
 307
 308                 if(!AuxiliaryXhair[2].draw2d)
 309                 {
 310                         tmpPos.y = hudPos.y + hudSize.y * (160/256);
 311                         drawstring(tmpPos, _("No left gunner!"), tmpSize, '1 1 1', hudAlpha * blinkValue, DRAWFLAG_NORMAL);
 312                 }
 313         }
 314 }
 315
 316 void Vehicles_drawCrosshair(string crosshair)
 317 {
 318         SELFPARAM();
 319         vector tmpSize = '0 0 0';
 320         vector tmpPos  = '0 0 0';
 321
 322         // Raptor bomb crosshair
 323         if(hud == VEH_RAPTOR.vehicleid && weapon2mode != RSM_FLARE)
 324         {
 325                 vector where;
 326
 327                 if(!dropmark)
 328                 {
 329                         dropmark = spawn();
 330                         dropmark.owner = self;
 331                         dropmark.gravity = 1;
 332                 }
 333
 334                 float reload2 = getstati(STAT_VEHICLESTAT_RELOAD2) * 0.01;
 335                 if(reload2 == 1)
 336                 {
 337                         setorigin(dropmark, pmove_org);
 338                         dropmark.velocity = pmove_vel;
 339                         tracetoss(dropmark, self);
 340
 341                         where = project_3d_to_2d(trace_endpos);
 342
 343                         setorigin(dropmark, trace_endpos);
 344                         tmpSize = draw_getimagesize(vCROSS_DROP) * autocvar_cl_vehicles_crosshair_size;
 345
 346                         if (!(where.z < 0 || where.x < 0 || where.y < 0 || where.x > vid_conwidth || where.y > vid_conheight))
 347                         {
 348                                 where.x -= tmpSize.x * 0.5;
 349                                 where.y -= tmpSize.y * 0.5;
 350                                 where.z = 0;
 351                                 drawpic(where, vCROSS_DROP, tmpSize, '0 1 0', autocvar_crosshair_alpha * 0.9, DRAWFLAG_ADDITIVE);
 352                                 drawpic(where, vCROSS_DROP, tmpSize, '0 1 0', autocvar_crosshair_alpha * 0.6, DRAWFLAG_NORMAL); // Ensure visibility against bright bg
 353                         }
 354                         dropmark.cnt = time + 5;
 355                 }
 356                 else
 357                 {
 358                         if(dropmark.cnt > time)
 359                         {
 360                                 where = project_3d_to_2d(dropmark.origin);
 361                                 tmpSize = draw_getimagesize(vCROSS_DROP) * autocvar_cl_vehicles_crosshair_size * 1.25;
 362
 363                                 if (!(where.z < 0 || where.x < 0 || where.y < 0 || where.x > vid_conwidth || where.y > vid_conheight))
 364                                 {
 365                                         where.x -= tmpSize.x * 0.5;
 366                                         where.y -= tmpSize.y * 0.5;
 367                                         where.z = 0;
 368                                         drawpic(where, vCROSS_DROP, tmpSize, '1 0 0', autocvar_crosshair_alpha * 0.9, DRAWFLAG_ADDITIVE);
 369                                         drawpic(where, vCROSS_DROP, tmpSize, '1 0 0', autocvar_crosshair_alpha * 0.6, DRAWFLAG_NORMAL); // Ensure visibility against bright bg
 370                                 }
 371                         }
 372                 }
 373         }
 374
 375         // Crosshair
 376         if(crosshair)
 377         {
 378                 tmpSize  = draw_getimagesize(crosshair) * autocvar_cl_vehicles_crosshair_size;
 379                 tmpPos.x = (vid_conwidth - tmpSize.x) / 2;
 380                 tmpPos.y = (vid_conheight - tmpSize.y) / 2;
 381
 382                 drawpic(tmpPos, crosshair, tmpSize, '1 1 1', autocvar_crosshair_alpha, DRAWFLAG_NORMAL);
 383         }
 384 }