qcsrc/common/vehicles/unit/racer.qc

   1 #ifndef VEHICLE_RACER
   2 #define VEHICLE_RACER
   3 REGISTER_VEHICLE(
   4 /* VEH_##id   */ RACER,
   5 /* function   */ v_racer,
   6 /* spawnflags */ VHF_DMGSHAKE | VHF_DMGROLL,
   7 /* mins,maxs  */ '-120 -120 -40' * 0.5, '120 120 40' * 0.5,
   8 /* model          */ "models/vehicles/wakizashi.dpm",
   9 /* head_model */ "null",
  10 /* hud_model  */ "models/vehicles/wakizashi_cockpit.dpm",
  11 /* tags           */ "", "", "tag_viewport",
  12 /* netname        */ "racer",
  13 /* fullname   */ _("Racer")
  14 );
  15 #endif
  16
  17 #ifdef IMPLEMENTATION
  18 #ifdef SVQC
  19 #include "../../effects.qh"
  20 #include "../../triggers/trigger/impulse.qh"
  21
  22 bool autocvar_g_vehicle_racer;
  23
  24 float autocvar_g_vehicle_racer_speed_afterburn;
  25 float autocvar_g_vehicle_racer_afterburn_cost;
  26
  27 float autocvar_g_vehicle_racer_waterburn_cost;
  28 float autocvar_g_vehicle_racer_waterburn_speed;
  29
  30 float autocvar_g_vehicle_racer_water_speed_forward;
  31 float autocvar_g_vehicle_racer_water_speed_strafe;
  32
  33 float autocvar_g_vehicle_racer_pitchlimit = 30;
  34
  35 float autocvar_g_vehicle_racer_water_downforce = 0.03;
  36 float autocvar_g_vehicle_racer_water_upforcedamper = 15;
  37
  38 float autocvar_g_vehicle_racer_anglestabilizer;
  39 float autocvar_g_vehicle_racer_downforce;
  40
  41 float autocvar_g_vehicle_racer_speed_forward;
  42 float autocvar_g_vehicle_racer_speed_strafe;
  43 float autocvar_g_vehicle_racer_springlength;
  44 float autocvar_g_vehicle_racer_upforcedamper;
  45 float autocvar_g_vehicle_racer_friction;
  46
  47 float autocvar_g_vehicle_racer_water_time = 5;
  48
  49 float autocvar_g_vehicle_racer_hovertype;
  50 float autocvar_g_vehicle_racer_hoverpower;
  51
  52 float autocvar_g_vehicle_racer_turnroll;
  53 float autocvar_g_vehicle_racer_turnspeed;
  54 float autocvar_g_vehicle_racer_pitchspeed;
  55
  56 float autocvar_g_vehicle_racer_energy;
  57 float autocvar_g_vehicle_racer_energy_regen;
  58 float autocvar_g_vehicle_racer_energy_regen_pause;
  59
  60 float autocvar_g_vehicle_racer_health;
  61 float autocvar_g_vehicle_racer_health_regen;
  62 float autocvar_g_vehicle_racer_health_regen_pause;
  63
  64 float autocvar_g_vehicle_racer_shield;
  65 float autocvar_g_vehicle_racer_shield_regen;
  66 float autocvar_g_vehicle_racer_shield_regen_pause;
  67
  68 float autocvar_g_vehicle_racer_cannon_cost;
  69 float autocvar_g_vehicle_racer_cannon_damage;
  70 float autocvar_g_vehicle_racer_cannon_radius;
  71 float autocvar_g_vehicle_racer_cannon_refire;
  72 float autocvar_g_vehicle_racer_cannon_speed;
  73 float autocvar_g_vehicle_racer_cannon_spread;
  74 float autocvar_g_vehicle_racer_cannon_force;
  75
  76 float autocvar_g_vehicle_racer_rocket_accel;
  77 float autocvar_g_vehicle_racer_rocket_damage;
  78 float autocvar_g_vehicle_racer_rocket_radius;
  79 float autocvar_g_vehicle_racer_rocket_force;
  80 float autocvar_g_vehicle_racer_rocket_refire;
  81 float autocvar_g_vehicle_racer_rocket_speed;
  82 float autocvar_g_vehicle_racer_rocket_turnrate;
  83
  84 float autocvar_g_vehicle_racer_rocket_locktarget;
  85 float autocvar_g_vehicle_racer_rocket_locking_time;
  86 float autocvar_g_vehicle_racer_rocket_locking_releasetime;
  87 float autocvar_g_vehicle_racer_rocket_locked_time;
  88 float autocvar_g_vehicle_racer_rocket_locked_maxangle;
  89 float autocvar_g_vehicle_racer_rocket_climbspeed;
  90
  91 float autocvar_g_vehicle_racer_respawntime;
  92
  93 float autocvar_g_vehicle_racer_blowup_radius;
  94 float autocvar_g_vehicle_racer_blowup_coredamage;
  95 float autocvar_g_vehicle_racer_blowup_edgedamage;
  96 float autocvar_g_vehicle_racer_blowup_forceintensity;
  97
  98 float autocvar_g_vehicle_racer_bouncefactor;
  99 float autocvar_g_vehicle_racer_bouncestop;
 100 vector autocvar_g_vehicle_racer_bouncepain;
 101
 102 .float racer_watertime;
 103
 104 var vector racer_force_from_tag(string tag_name, float spring_length, float max_power);
 105
 106 void racer_align4point(float _delta)
 107 {
 108         vector push_vector;
 109         float fl_push, fr_push, bl_push, br_push;
 110
 111         push_vector  = racer_force_from_tag("tag_engine_fr", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 112         fr_push   = force_fromtag_normpower;
 113         //vehicles_sweap_collision(force_fromtag_origin, self.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 114
 115         push_vector += racer_force_from_tag("tag_engine_fl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 116         fl_push   = force_fromtag_normpower;
 117         //vehicles_sweap_collision(force_fromtag_origin, self.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 118
 119         push_vector += racer_force_from_tag("tag_engine_br", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 120         br_push   = force_fromtag_normpower;
 121         //vehicles_sweap_collision(force_fromtag_origin, self.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 122
 123         push_vector += racer_force_from_tag("tag_engine_bl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 124         bl_push   = force_fromtag_normpower;
 125         //vehicles_sweap_collision(force_fromtag_origin, self.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 126
 127         self.velocity += push_vector * _delta;
 128
 129         float uforce = autocvar_g_vehicle_racer_upforcedamper;
 130
 131         int cont = pointcontents(self.origin - '0 0 64');
 132         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 133         {
 134                 uforce = autocvar_g_vehicle_racer_water_upforcedamper;
 135
 136                 if(self.owner.BUTTON_CROUCH && time < self.air_finished)
 137                         self.velocity_z += 30;
 138                 else
 139                         self.velocity_z += 200;
 140         }
 141
 142
 143         // Anti ocilation
 144         if(self.velocity_z > 0)
 145                 self.velocity_z *= 1 - uforce * _delta;
 146
 147         push_vector_x =  (fl_push - bl_push);
 148         push_vector_x += (fr_push - br_push);
 149         push_vector_x *= 360;
 150
 151         push_vector_z = (fr_push - fl_push);
 152         push_vector_z += (br_push - bl_push);
 153         push_vector_z *= 360;
 154
 155         // Apply angle diffrance
 156         self.angles_z += push_vector_z * _delta;
 157         self.angles_x += push_vector_x * _delta;
 158
 159         // Apply stabilizer
 160         self.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * _delta);
 161         self.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * _delta);
 162 }
 163
 164 void racer_fire_cannon(string tagname)
 165 {
 166         vector v;
 167         entity bolt;
 168
 169         v = gettaginfo(self, gettagindex(self, tagname));
 170         bolt = vehicles_projectile("wakizashi_gun_muzzleflash", "weapons/lasergun_fire.wav",
 171                                                    v, normalize(v_forward + randomvec() * autocvar_g_vehicle_racer_cannon_spread) * autocvar_g_vehicle_racer_cannon_speed,
 172                                                    autocvar_g_vehicle_racer_cannon_damage, autocvar_g_vehicle_racer_cannon_radius, autocvar_g_vehicle_racer_cannon_force,  0,
 173                                                    DEATH_VH_WAKI_GUN, PROJECTILE_WAKICANNON, 0, true, true, self.owner);
 174
 175         // Fix z-aim (for chase mode)
 176         v = normalize(trace_endpos - bolt.origin);
 177         v_forward_z = v_z * 0.5;
 178         bolt.velocity = v_forward * autocvar_g_vehicle_racer_cannon_speed;
 179 }
 180
 181 void racer_rocket_groundhugger()
 182 {
 183         vector olddir, newdir;
 184         float oldvel, newvel;
 185
 186         self.nextthink  = time;
 187
 188         if(self.owner.deadflag != DEAD_NO || self.cnt < time)
 189         {
 190                 self.use();
 191                 return;
 192         }
 193
 194         if(!self.realowner.vehicle)
 195         {
 196                 UpdateCSQCProjectile(self);
 197                 return;
 198         }
 199
 200         olddir = normalize(self.velocity);
 201         oldvel = vlen(self.velocity);
 202         newvel = oldvel + self.lip;
 203
 204         tracebox(self.origin, self.mins, self.maxs, self.origin + olddir * 64, MOVE_WORLDONLY,self);
 205         if(trace_fraction <= 0.5)
 206         {
 207                 // Hitting somethign soon, just speed ahead
 208                 self.velocity = olddir * newvel;
 209                 UpdateCSQCProjectile(self);
 210                 return;
 211         }
 212
 213         traceline(trace_endpos, trace_endpos - '0 0 64', MOVE_NORMAL, self);
 214         if(trace_fraction != 1.0)
 215         {
 216                 newdir = normalize(trace_endpos + '0 0 64' - self.origin) * autocvar_g_vehicle_racer_rocket_turnrate;
 217                 self.velocity = normalize(olddir + newdir) * newvel;
 218         }
 219         else
 220         {
 221                 self.velocity = olddir * newvel;
 222                 self.velocity_z -= 1600 * sys_frametime; // 2x grav looks better for this one
 223         }
 224
 225         int cont = pointcontents(self.origin - '0 0 32');
 226         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 227                 self.velocity_z += 200;
 228
 229         UpdateCSQCProjectile(self);
 230         return;
 231 }
 232
 233 void racer_rocket_tracker()
 234 {
 235         vector olddir, newdir;
 236         float oldvel, newvel;
 237
 238         self.nextthink  = time;
 239
 240         if (self.owner.deadflag != DEAD_NO || self.cnt < time)
 241         {
 242                 self.use();
 243                 return;
 244         }
 245
 246         if(!self.realowner.vehicle)
 247         {
 248                 UpdateCSQCProjectile(self);
 249                 return;
 250         }
 251
 252         olddir = normalize(self.velocity);
 253         oldvel = vlen(self.velocity);
 254         newvel = oldvel + self.lip;
 255         makevectors(vectoangles(olddir));
 256
 257         float time_to_impact = min(vlen(self.enemy.origin - self.origin) / vlen(self.velocity), 1);
 258         vector predicted_origin = self.enemy.origin + self.enemy.velocity * time_to_impact;
 259
 260         traceline(self.origin, self.origin + v_forward * 64 - '0 0 32', MOVE_NORMAL, self);
 261         newdir = normalize(predicted_origin - self.origin);
 262
 263         //vector
 264         float height_diff = predicted_origin_z - self.origin_z;
 265
 266         if(vlen(newdir - v_forward) > autocvar_g_vehicle_racer_rocket_locked_maxangle)
 267         {
 268                 //bprint("Target lost!\n");
 269                 //dprint("OF:", ftos(vlen(newdir - v_forward)), "\n");
 270                 self.think = racer_rocket_groundhugger;
 271                 return;
 272         }
 273
 274         if(trace_fraction != 1.0 && trace_ent != self.enemy)
 275                 newdir_z += 16 * sys_frametime;
 276
 277         self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_racer_rocket_turnrate) * newvel;
 278         self.velocity_z -= 800 * sys_frametime;
 279         self.velocity_z += max(height_diff, autocvar_g_vehicle_racer_rocket_climbspeed) * sys_frametime ;
 280
 281         UpdateCSQCProjectile(self);
 282         return;
 283 }
 284
 285 void racer_fire_rocket(string tagname, entity trg)
 286 {
 287         vector v = gettaginfo(self, gettagindex(self, tagname));
 288         entity rocket = vehicles_projectile("wakizashi_rocket_launch", "weapons/rocket_fire.wav",
 289                                                    v, v_forward * autocvar_g_vehicle_racer_rocket_speed,
 290                                                    autocvar_g_vehicle_racer_rocket_damage, autocvar_g_vehicle_racer_rocket_radius, autocvar_g_vehicle_racer_rocket_force, 3,
 291                                                    DEATH_VH_WAKI_ROCKET, PROJECTILE_WAKIROCKET, 20, false, false, self.owner);
 292
 293         rocket.lip                        = autocvar_g_vehicle_racer_rocket_accel * sys_frametime;
 294         rocket.wait                      = autocvar_g_vehicle_racer_rocket_turnrate;
 295         rocket.nextthink                = time;
 296         rocket.enemy                    = trg;
 297         rocket.cnt                        = time + 15;
 298
 299         if(trg)
 300                 rocket.think                    = racer_rocket_tracker;
 301         else
 302                 rocket.think                    = racer_rocket_groundhugger;
 303 }
 304
 305 float racer_frame()
 306 {
 307         entity player, racer;
 308         vector df;
 309         float ftmp;
 310
 311         if(intermission_running)
 312         {
 313                 self.vehicle.velocity = '0 0 0';
 314                 self.vehicle.avelocity = '0 0 0';
 315                 return 1;
 316         }
 317
 318         player  = self;
 319         racer   = self.vehicle;
 320         self    = racer;
 321
 322         vehicles_painframe();
 323
 324         if(pointcontents(racer.origin) != CONTENT_WATER)
 325                 racer.air_finished = time + autocvar_g_vehicle_racer_water_time;
 326
 327         if(racer.deadflag != DEAD_NO)
 328         {
 329                 self = player;
 330                 player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 331                 return 1;
 332         }
 333
 334         racer_align4point(PHYS_INPUT_TIMELENGTH);
 335
 336         player.BUTTON_ZOOM = player.BUTTON_CROUCH = 0;
 337
 338         crosshair_trace(player);
 339
 340         racer.angles_x *= -1;
 341
 342         // Yaw
 343         ftmp = autocvar_g_vehicle_racer_turnspeed * PHYS_INPUT_TIMELENGTH;
 344         ftmp = bound(-ftmp, shortangle_f(player.v_angle_y - racer.angles_y, racer.angles_y), ftmp);
 345         racer.angles_y = anglemods(racer.angles_y + ftmp);
 346
 347         // Roll
 348         racer.angles_z += -ftmp * autocvar_g_vehicle_racer_turnroll * PHYS_INPUT_TIMELENGTH;
 349
 350         // Pitch
 351         ftmp = autocvar_g_vehicle_racer_pitchspeed  * PHYS_INPUT_TIMELENGTH;
 352         ftmp = bound(-ftmp, shortangle_f(player.v_angle_x - racer.angles_x, racer.angles_x), ftmp);
 353         racer.angles_x = bound(-autocvar_g_vehicle_racer_pitchlimit, anglemods(racer.angles_x + ftmp), autocvar_g_vehicle_racer_pitchlimit);
 354
 355         makevectors(racer.angles);
 356         racer.angles_x *= -1;
 357
 358         //ftmp = racer.velocity_z;
 359         df = racer.velocity * -autocvar_g_vehicle_racer_friction;
 360         //racer.velocity_z = ftmp;
 361
 362         int cont = pointcontents(racer.origin);
 363         if(vlen(player.movement) != 0)
 364         {
 365                 if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 366                 {
 367                         if(player.movement_x) { df += v_forward * ((player.movement_x > 0) ? autocvar_g_vehicle_racer_water_speed_forward : -autocvar_g_vehicle_racer_water_speed_forward); }
 368                         if(player.movement_y) { df += v_right * ((player.movement_y > 0) ? autocvar_g_vehicle_racer_water_speed_strafe : -autocvar_g_vehicle_racer_water_speed_strafe); }
 369                 }
 370                 else
 371                 {
 372                         if(player.movement_x) { df += v_forward * ((player.movement_x > 0) ? autocvar_g_vehicle_racer_speed_forward : -autocvar_g_vehicle_racer_speed_forward); }
 373                         if(player.movement_y) { df += v_right * ((player.movement_y > 0) ? autocvar_g_vehicle_racer_speed_strafe : -autocvar_g_vehicle_racer_speed_strafe); }
 374                 }
 375
 376 #ifdef SVQC
 377                 if(self.sound_nexttime < time || self.sounds != 1)
 378                 {
 379                         self.sounds = 1;
 380                         self.sound_nexttime = time + 10.922667; //soundlength("vehicles/racer_move.wav");
 381                         sound (self, CH_TRIGGER_SINGLE, "vehicles/racer_move.wav", VOL_VEHICLEENGINE, ATTEN_NORM);
 382                 }
 383 #endif
 384         }
 385 #ifdef SVQC
 386         else
 387         {
 388                 if(self.sound_nexttime < time || self.sounds != 0)
 389                 {
 390                         self.sounds = 0;
 391                         self.sound_nexttime = time + 11.888604; //soundlength("vehicles/racer_idle.wav");
 392                         sound (self, CH_TRIGGER_SINGLE, "vehicles/racer_idle.wav", VOL_VEHICLEENGINE, ATTEN_NORM);
 393                 }
 394         }
 395 #endif
 396
 397         // Afterburn
 398         if (PHYS_INPUT_BUTTON_JUMP(player) && racer.vehicle_energy >= (autocvar_g_vehicle_racer_afterburn_cost * PHYS_INPUT_TIMELENGTH))
 399         {
 400 #ifdef SVQC
 401                 if(time - racer.wait > 0.2)
 402                         pointparticles(particleeffectnum("wakizashi_booster_smoke"), self.origin - v_forward * 32, v_forward  * vlen(self.velocity), 1);
 403 #endif
 404
 405                 racer.wait = time;
 406
 407                 if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 408                 {
 409                         racer.vehicle_energy -= autocvar_g_vehicle_racer_waterburn_cost * PHYS_INPUT_TIMELENGTH;
 410                         df += (v_forward * autocvar_g_vehicle_racer_waterburn_speed);
 411                 }
 412                 else
 413                 {
 414                         racer.vehicle_energy -= autocvar_g_vehicle_racer_afterburn_cost * PHYS_INPUT_TIMELENGTH;
 415                         df += (v_forward * autocvar_g_vehicle_racer_speed_afterburn);
 416                 }
 417
 418 #ifdef SVQC
 419                 if(racer.invincible_finished < time)
 420                 {
 421                         traceline(racer.origin, racer.origin - '0 0 256', MOVE_NORMAL, self);
 422                         if(trace_fraction != 1.0)
 423                                 pointparticles(particleeffectnum("smoke_small"), trace_endpos, '0 0 0', 1);
 424
 425                         racer.invincible_finished = time + 0.1 + (random() * 0.1);
 426                 }
 427
 428                 if(racer.strength_finished < time)
 429                 {
 430                         racer.strength_finished = time + 10.922667; //soundlength("vehicles/racer_boost.wav");
 431                         sound (racer.tur_head, CH_TRIGGER_SINGLE, "vehicles/racer_boost.wav", VOL_VEHICLEENGINE, ATTEN_NORM);
 432                 }
 433 #endif
 434         }
 435         else
 436         {
 437                 racer.strength_finished = 0;
 438                 sound (racer.tur_head, CH_TRIGGER_SINGLE, "misc/null.wav", VOL_VEHICLEENGINE, ATTEN_NORM);
 439         }
 440
 441         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 442                 racer.racer_watertime = time;
 443
 444         float dforce = autocvar_g_vehicle_racer_downforce;
 445         if(time - racer.racer_watertime <= 3)
 446                 dforce = autocvar_g_vehicle_racer_water_downforce;
 447
 448         df -= v_up * (vlen(racer.velocity) * dforce);
 449         player.movement = racer.velocity += df * PHYS_INPUT_TIMELENGTH;
 450
 451 #ifdef SVQC
 452         if(!forbidWeaponUse(player))
 453         if(player.BUTTON_ATCK)
 454         if(time > racer.attack_finished_single)
 455         if(racer.vehicle_energy >= autocvar_g_vehicle_racer_cannon_cost)
 456         {
 457                 racer.vehicle_energy -= autocvar_g_vehicle_racer_cannon_cost;
 458                 racer.wait = time;
 459
 460                 crosshair_trace(player);
 461                 if(racer.cnt)
 462                 {
 463                         racer_fire_cannon("tag_fire1");
 464                         racer.cnt = 0;
 465                 }
 466                 else
 467                 {
 468                         racer_fire_cannon("tag_fire2");
 469                         racer.cnt = 1;
 470                 }
 471                 racer.attack_finished_single = time + autocvar_g_vehicle_racer_cannon_refire;
 472         }
 473
 474         if(autocvar_g_vehicle_racer_rocket_locktarget)
 475         {
 476                 vehicles_locktarget((1 / autocvar_g_vehicle_racer_rocket_locking_time) * frametime,
 477                                                  (1 / autocvar_g_vehicle_racer_rocket_locking_releasetime) * frametime,
 478                                                  autocvar_g_vehicle_racer_rocket_locked_time);
 479
 480                 if(self.lock_target)
 481                 {
 482                         if(racer.lock_strength == 1)
 483                                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '1 0 0', 0);
 484                         else if(self.lock_strength > 0.5)
 485                                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 1 0', 0);
 486                         else if(self.lock_strength < 0.5)
 487                                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 0 1', 0);
 488                 }
 489         }
 490
 491         if(!forbidWeaponUse(player))
 492         if(time > racer.delay)
 493         if(player.BUTTON_ATCK2)
 494         {
 495                 racer.misc_bulletcounter += 1;
 496                 racer.delay = time + 0.3;
 497
 498                 if(racer.misc_bulletcounter == 1)
 499                 {
 500                         racer_fire_rocket("tag_rocket_r", (racer.lock_strength == 1 && racer.lock_target) ? racer.lock_target : world);
 501                         player.vehicle_ammo2 = 50;
 502                 }
 503                 else if(racer.misc_bulletcounter == 2)
 504                 {
 505                         racer_fire_rocket("tag_rocket_l", (racer.lock_strength == 1 && racer.lock_target) ? racer.lock_target : world);
 506                         racer.lock_strength  = 0;
 507                         racer.lock_target       = world;
 508                         racer.misc_bulletcounter = 0;
 509                         racer.delay = time + autocvar_g_vehicle_racer_rocket_refire;
 510                         racer.lip = time;
 511                         player.vehicle_ammo2 = 0;
 512                 }
 513         }
 514         else if(racer.misc_bulletcounter == 0)
 515                 player.vehicle_ammo2 = 100;
 516
 517         player.vehicle_reload2 = bound(0, 100 * ((time - racer.lip) / (racer.delay - racer.lip)), 100);
 518
 519         if(racer.vehicle_flags  & VHF_SHIELDREGEN)
 520                 vehicles_regen(racer.dmg_time, vehicle_shield, autocvar_g_vehicle_racer_shield, autocvar_g_vehicle_racer_shield_regen_pause, autocvar_g_vehicle_racer_shield_regen, frametime, true);
 521
 522         if(racer.vehicle_flags  & VHF_HEALTHREGEN)
 523                 vehicles_regen(racer.dmg_time, vehicle_health, autocvar_g_vehicle_racer_health, autocvar_g_vehicle_racer_health_regen_pause, autocvar_g_vehicle_racer_health_regen, frametime, false);
 524
 525         if(racer.vehicle_flags  & VHF_ENERGYREGEN)
 526                 vehicles_regen(racer.wait, vehicle_energy, autocvar_g_vehicle_racer_energy, autocvar_g_vehicle_racer_energy_regen_pause, autocvar_g_vehicle_racer_energy_regen, frametime, false);
 527
 528
 529         VEHICLE_UPDATE_PLAYER(player, health, racer);
 530         VEHICLE_UPDATE_PLAYER(player, energy, racer);
 531
 532         if(racer.vehicle_flags & VHF_HASSHIELD)
 533                 VEHICLE_UPDATE_PLAYER(player, shield, racer);
 534
 535         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 536 #endif
 537
 538         setorigin(player,racer.origin + '0 0 32');
 539         player.velocity = racer.velocity;
 540
 541         self = player;
 542         return 1;
 543 }
 544
 545 void racer_think()
 546 {
 547         self.nextthink = time;
 548
 549         float pushdeltatime = time - self.lastpushtime;
 550         if (pushdeltatime > 0.15) pushdeltatime = 0;
 551         self.lastpushtime = time;
 552         if(!pushdeltatime) return;
 553
 554         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * autocvar_g_vehicle_racer_springlength), MOVE_NOMONSTERS, self);
 555
 556         vector df = self.velocity * -autocvar_g_vehicle_racer_friction;
 557         df_z += (1 - trace_fraction) * autocvar_g_vehicle_racer_hoverpower + sin(time * 2) * (autocvar_g_vehicle_racer_springlength * 2);
 558
 559         float forced = autocvar_g_vehicle_racer_upforcedamper;
 560
 561         int cont = pointcontents(self.origin - '0 0 64');
 562         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 563         {
 564                 forced = autocvar_g_vehicle_racer_water_upforcedamper;
 565                 self.velocity_z += 200;
 566         }
 567
 568         self.velocity += df * pushdeltatime;
 569         if(self.velocity_z > 0)
 570                 self.velocity_z *= 1 - forced * pushdeltatime;
 571
 572         self.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * pushdeltatime);
 573         self.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * pushdeltatime);
 574
 575         CSQCMODEL_AUTOUPDATE();
 576 }
 577
 578 void racer_exit(float eject)
 579 {
 580         vector spot;
 581
 582         self.think        = racer_think;
 583         self.nextthink  = time;
 584         self.movetype   = MOVETYPE_BOUNCE;
 585         sound (self.tur_head, CH_TRIGGER_SINGLE, "misc/null.wav", VOL_VEHICLEENGINE, ATTEN_NORM);
 586
 587         if(!self.owner)
 588                 return;
 589
 590         makevectors(self.angles);
 591         if(eject)
 592         {
 593                 spot = self.origin + v_forward * 100 + '0 0 64';
 594                 spot = vehicles_findgoodexit(spot);
 595                 setorigin(self.owner , spot);
 596                 self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 597                 self.owner.oldvelocity = self.owner.velocity;
 598         }
 599         else
 600         {
 601                 if(vlen(self.velocity) > 2 * autocvar_sv_maxairspeed)
 602                 {
 603                         self.owner.velocity = normalize(self.velocity) * autocvar_sv_maxairspeed * 2;
 604                         self.owner.velocity_z += 200;
 605                         spot = self.origin + v_forward * 32 + '0 0 32';
 606                         spot = vehicles_findgoodexit(spot);
 607                 }
 608                 else
 609                 {
 610                         self.owner.velocity = self.velocity * 0.5;
 611                         self.owner.velocity_z += 10;
 612                         spot = self.origin - v_forward * 200 + '0 0 32';
 613                         spot = vehicles_findgoodexit(spot);
 614                 }
 615                 self.owner.oldvelocity = self.owner.velocity;
 616                 setorigin(self.owner , spot);
 617         }
 618         antilag_clear(self.owner);
 619         self.owner = world;
 620 }
 621
 622 void racer_blowup()
 623 {
 624         self.deadflag   = DEAD_DEAD;
 625         self.vehicle_exit(VHEF_NORMAL);
 626
 627         RadiusDamage (self, self.enemy, autocvar_g_vehicle_racer_blowup_coredamage,
 628                                         autocvar_g_vehicle_racer_blowup_edgedamage,
 629                                         autocvar_g_vehicle_racer_blowup_radius, world, world,
 630                                         autocvar_g_vehicle_racer_blowup_forceintensity,
 631                                         DEATH_VH_WAKI_DEATH, world);
 632
 633         self.nextthink  = time + autocvar_g_vehicle_racer_respawntime;
 634         self.think        = vehicles_spawn;
 635         self.movetype   = MOVETYPE_NONE;
 636         self.effects    = EF_NODRAW;
 637
 638         self.colormod  = '0 0 0';
 639         self.avelocity = '0 0 0';
 640         self.velocity  = '0 0 0';
 641
 642         setorigin(self, self.pos1);
 643 }
 644
 645 void racer_blowup_think()
 646 {
 647         self.nextthink = time;
 648
 649         if(time >= self.delay)
 650                 racer_blowup();
 651
 652         CSQCMODEL_AUTOUPDATE();
 653 }
 654
 655 void racer_deadtouch()
 656 {
 657         self.avelocity_x *= 0.7;
 658         self.cnt -= 1;
 659         if(self.cnt <= 0)
 660                 racer_blowup();
 661 }
 662
 663 void spawnfunc_vehicle_racer()
 664 {
 665         if(!autocvar_g_vehicle_racer) { remove(self); return; }
 666         if(!vehicle_initialize(VEH_RACER, false)) { remove(self); return; }
 667 }
 668
 669 #endif // SVQC
 670
 671 #ifdef CSQC
 672 #if 0
 673 void racer_draw()
 674 {
 675         float pushdeltatime = time - self.lastpushtime;
 676         if (pushdeltatime > 0.15) pushdeltatime = 0;
 677         self.lastpushtime = time;
 678         if(!pushdeltatime) return;
 679
 680         tracebox(self.move_origin, self.mins, self.maxs, self.move_origin - ('0 0 1' * getstatf(STAT_VEH_RACER_SPRINGLENGTH)), MOVE_NOMONSTERS, self);
 681
 682         vector df = self.move_velocity * -getstatf(STAT_VEH_RACER_FRICTION);
 683         df_z += (1 - trace_fraction) * getstatf(STAT_VEH_RACER_HOVERPOWER) + sin(time * 2) * (getstatf(STAT_VEH_RACER_SPRINGLENGTH) * 2);
 684
 685         float forced = getstatf(STAT_VEH_RACER_UPFORCEDAMPER);
 686
 687         int cont = pointcontents(self.move_origin - '0 0 64');
 688         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 689         {
 690                 forced = getstatf(STAT_VEH_RACER_WATER_UPFORCEDAMPER);
 691                 self.move_velocity_z += 200;
 692         }
 693
 694         self.move_velocity += df * pushdeltatime;
 695         if(self.move_velocity_z > 0)
 696                 self.move_velocity_z *= 1 - forced * pushdeltatime;
 697
 698         self.move_angles_x *= 1 - (getstatf(STAT_VEH_RACER_ANGLESTABILIZER) * pushdeltatime);
 699         self.move_angles_z *= 1 - (getstatf(STAT_VEH_RACER_ANGLESTABILIZER) * pushdeltatime);
 700
 701         Movetype_Physics_MatchServer(false);
 702 }
 703 #endif
 704 #endif
 705
 706 bool v_racer(int req)
 707 {
 708         switch(req)
 709         {
 710                 case VR_IMPACT:
 711                 {
 712                 #ifdef SVQC
 713                         if(autocvar_g_vehicle_racer_bouncepain)
 714                                 vehicles_impact(autocvar_g_vehicle_racer_bouncepain_x, autocvar_g_vehicle_racer_bouncepain_y, autocvar_g_vehicle_racer_bouncepain_z);
 715                 #endif
 716                         return true;
 717                 }
 718
 719                 case VR_ENTER:
 720                 {
 721                 #ifdef SVQC
 722                         self.movetype = MOVETYPE_BOUNCE;
 723                         self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_racer_health)  * 100;
 724                         self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_racer_shield)  * 100;
 725
 726                         if(self.owner.flagcarried)
 727                            setorigin(self.owner.flagcarried, '-190 0 96');
 728                 #elif defined(CSQC)
 729
 730                         self.move_movetype = MOVETYPE_BOUNCE;
 731                 #endif
 732
 733                         return true;
 734                 }
 735
 736                 case VR_SPAWN:
 737                 {
 738                 #ifdef SVQC
 739                         if(self.scale != 0.5)
 740                         {
 741                                 if(autocvar_g_vehicle_racer_hovertype != 0)
 742                                         racer_force_from_tag = vehicles_force_fromtag_maglev;
 743                                 else
 744                                         racer_force_from_tag = vehicles_force_fromtag_hover;
 745
 746                                 // FIXME: this be hakkz, fix the models insted (scale body, add tag_viewport to the hudmodel).
 747                                 self.scale = 0.5;
 748                                 setattachment(self.vehicle_hudmodel, self, "");
 749                                 setattachment(self.vehicle_viewport, self, "tag_viewport");
 750
 751                                 self.mass                          = 900;
 752                         }
 753
 754                         self.think                = racer_think;
 755                         self.nextthink    = time;
 756                         self.vehicle_health = autocvar_g_vehicle_racer_health;
 757                         self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 758
 759                         self.movetype     = MOVETYPE_TOSS;
 760                         self.solid                = SOLID_SLIDEBOX;
 761                         self.delay                = time;
 762                         self.scale                = 0.5;
 763
 764                         self.PlayerPhysplug = racer_frame;
 765
 766                         self.bouncefactor = autocvar_g_vehicle_racer_bouncefactor;
 767                         self.bouncestop = autocvar_g_vehicle_racer_bouncestop;
 768                         self.damageforcescale = 0.5;
 769                         self.vehicle_health = autocvar_g_vehicle_racer_health;
 770                         self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 771                 #endif
 772                         return true;
 773                 }
 774
 775                 case VR_DEATH:
 776                 {
 777                 #ifdef SVQC
 778                         self.SendEntity         = func_null; // stop networking this racer (for now)
 779                         self.health                     = 0;
 780                         self.event_damage       = func_null;
 781                         self.solid                      = SOLID_CORPSE;
 782                         self.takedamage         = DAMAGE_NO;
 783                         self.deadflag           = DEAD_DYING;
 784                         self.movetype           = MOVETYPE_BOUNCE;
 785                         self.wait                       = time;
 786                         self.delay                      = 2 + time + random() * 3;
 787                         self.cnt                        = 1 + random() * 2;
 788                         self.touch                      = racer_deadtouch;
 789
 790                         Send_Effect("explosion_medium", self.origin, '0 0 0', 1);
 791
 792                         if(random() < 0.5)
 793                                 self.avelocity_z = 32;
 794                         else
 795                                 self.avelocity_z = -32;
 796
 797                         self.avelocity_x = -vlen(self.velocity) * 0.2;
 798                         self.velocity += '0 0 700';
 799                         self.colormod = '-0.5 -0.5 -0.5';
 800
 801                         self.think = racer_blowup_think;
 802                         self.nextthink = time;
 803                 #endif
 804                         return true;
 805                 }
 806
 807 #ifdef CSQC
 808                 case VR_HUD:
 809                 {
 810                         Vehicles_drawHUD("vehicle_racer", "vehicle_racer_weapon1", "vehicle_racer_weapon2",
 811                                                          "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 812                                                          "vehicle_icon_ammo2", autocvar_hud_progressbar_vehicles_ammo2_color,
 813                                                          vCROSS_GUIDE);
 814                         return true;
 815                 }
 816 #endif
 817                 case VR_SETUP:
 818                 {
 819                 #ifdef SVQC
 820                         self.vehicle_exit = racer_exit;
 821                 #endif
 822
 823                 #ifdef SVQC
 824                         // we have no need to network energy
 825                         if(autocvar_g_vehicle_racer_energy)
 826                         if(autocvar_g_vehicle_racer_energy_regen)
 827                                 self.vehicle_flags |= VHF_ENERGYREGEN;
 828
 829                         if(autocvar_g_vehicle_racer_shield)
 830                                 self.vehicle_flags |= VHF_HASSHIELD;
 831
 832                         if(autocvar_g_vehicle_racer_shield_regen)
 833                                 self.vehicle_flags |= VHF_SHIELDREGEN;
 834
 835                         if(autocvar_g_vehicle_racer_health_regen)
 836                                 self.vehicle_flags |= VHF_HEALTHREGEN;
 837
 838                         self.respawntime = autocvar_g_vehicle_racer_respawntime;
 839                         self.vehicle_health = autocvar_g_vehicle_racer_health;
 840                         self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 841                         self.max_health = self.vehicle_health;
 842                 #endif
 843
 844                 #ifdef CSQC
 845                         AuxiliaryXhair[0].axh_image = vCROSS_LOCK; // Rocket
 846                 #endif
 847                         return true;
 848                 }
 849
 850                 case VR_PRECACHE:
 851                 {
 852                 #ifdef SVQC
 853                         precache_sound ("weapons/lasergun_fire.wav");
 854                         precache_sound ("weapons/rocket_fire.wav");
 855
 856                         precache_sound ("vehicles/racer_idle.wav");
 857                         precache_sound ("vehicles/racer_move.wav");
 858                         precache_sound ("vehicles/racer_boost.wav");
 859
 860                         precache_model ("models/vhshield.md3");
 861                 #endif
 862
 863                         precache_model ("models/vehicles/wakizashi.dpm");
 864                         precache_model ("models/vehicles/wakizashi_cockpit.dpm");
 865                         return true;
 866                 }
 867         }
 868
 869         return true;
 870 }
 871
 872 #endif // REGISTER_VEHICLE