qcsrc/common/vehicles/unit/raptor.qc

   1 #ifndef VEHICLE_RAPTOR
   2 #define VEHICLE_RAPTOR
   3 #include "raptor.qh"
   4 REGISTER_VEHICLE_SIMPLE(
   5 /* VEH_##id   */ RAPTOR,
   6 /* function   */ v_raptor,
   7 /* spawnflags */ VHF_DMGSHAKE | VHF_DMGROLL,
   8 /* mins,maxs  */ '-80 -80 0', '80 80 70',
   9 /* model          */ "models/vehicles/raptor.dpm",
  10 /* head_model */ "",
  11 /* hud_model  */ "models/vehicles/raptor_cockpit.dpm",
  12 /* tags           */ "", "tag_hud", "tag_camera",
  13 /* netname        */ "raptor",
  14 /* fullname   */ _("Raptor")
  15 );
  16 #endif
  17
  18 #ifdef IMPLEMENTATION
  19
  20 #ifdef SVQC
  21 bool autocvar_g_vehicle_raptor;
  22
  23 float autocvar_g_vehicle_raptor_respawntime;
  24 float autocvar_g_vehicle_raptor_takeofftime;
  25
  26 float autocvar_g_vehicle_raptor_movestyle;
  27 float autocvar_g_vehicle_raptor_turnspeed;
  28 float autocvar_g_vehicle_raptor_pitchspeed;
  29 float autocvar_g_vehicle_raptor_pitchlimit;
  30
  31 float autocvar_g_vehicle_raptor_speed_forward;
  32 float autocvar_g_vehicle_raptor_speed_strafe;
  33 float autocvar_g_vehicle_raptor_speed_up;
  34 float autocvar_g_vehicle_raptor_speed_down;
  35 float autocvar_g_vehicle_raptor_friction;
  36
  37 float autocvar_g_vehicle_raptor_bomblets;
  38 float autocvar_g_vehicle_raptor_bomblet_alt;
  39 float autocvar_g_vehicle_raptor_bomblet_time;
  40 float autocvar_g_vehicle_raptor_bomblet_damage;
  41 float autocvar_g_vehicle_raptor_bomblet_spread;
  42 float autocvar_g_vehicle_raptor_bomblet_edgedamage;
  43 float autocvar_g_vehicle_raptor_bomblet_radius;
  44 float autocvar_g_vehicle_raptor_bomblet_force;
  45 float autocvar_g_vehicle_raptor_bomblet_explode_delay;
  46 float autocvar_g_vehicle_raptor_bombs_refire;
  47
  48 float autocvar_g_vehicle_raptor_flare_refire;
  49 float autocvar_g_vehicle_raptor_flare_lifetime;
  50 float autocvar_g_vehicle_raptor_flare_chase;
  51 float autocvar_g_vehicle_raptor_flare_range;
  52
  53 float autocvar_g_vehicle_raptor_cannon_turnspeed;
  54 float autocvar_g_vehicle_raptor_cannon_turnlimit;
  55 float autocvar_g_vehicle_raptor_cannon_pitchlimit_up;
  56 float autocvar_g_vehicle_raptor_cannon_pitchlimit_down;
  57
  58 float autocvar_g_vehicle_raptor_cannon_locktarget;
  59 float autocvar_g_vehicle_raptor_cannon_locking_time;
  60 float autocvar_g_vehicle_raptor_cannon_locking_releasetime;
  61 float autocvar_g_vehicle_raptor_cannon_locked_time;
  62 float autocvar_g_vehicle_raptor_cannon_predicttarget;
  63
  64 float autocvar_g_vehicle_raptor_cannon_cost;
  65 float autocvar_g_vehicle_raptor_cannon_damage;
  66 float autocvar_g_vehicle_raptor_cannon_radius;
  67 float autocvar_g_vehicle_raptor_cannon_refire;
  68 float autocvar_g_vehicle_raptor_cannon_speed;
  69 float autocvar_g_vehicle_raptor_cannon_spread;
  70 float autocvar_g_vehicle_raptor_cannon_force;
  71
  72 float autocvar_g_vehicle_raptor_energy;
  73 float autocvar_g_vehicle_raptor_energy_regen;
  74 float autocvar_g_vehicle_raptor_energy_regen_pause;
  75
  76 float autocvar_g_vehicle_raptor_health;
  77 float autocvar_g_vehicle_raptor_health_regen;
  78 float autocvar_g_vehicle_raptor_health_regen_pause;
  79
  80 float autocvar_g_vehicle_raptor_shield;
  81 float autocvar_g_vehicle_raptor_shield_regen;
  82 float autocvar_g_vehicle_raptor_shield_regen_pause;
  83
  84 float autocvar_g_vehicle_raptor_bouncefactor;
  85 float autocvar_g_vehicle_raptor_bouncestop;
  86 vector autocvar_g_vehicle_raptor_bouncepain;
  87
  88 .entity bomb1;
  89 .entity bomb2;
  90
  91 float raptor_altitude(float amax)
  92 {
  93         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * amax), MOVE_WORLDONLY, self);
  94         return vlen(self.origin - trace_endpos);
  95 }
  96
  97 void raptor_bomblet_boom()
  98 {
  99         RadiusDamage (self, self.realowner, autocvar_g_vehicle_raptor_bomblet_damage,
 100                                                                         autocvar_g_vehicle_raptor_bomblet_edgedamage,
 101                                                                         autocvar_g_vehicle_raptor_bomblet_radius, world, world,
 102                                                                         autocvar_g_vehicle_raptor_bomblet_force, DEATH_VH_RAPT_BOMB, world);
 103         remove(self);
 104 }
 105
 106 void raptor_bomblet_touch()
 107 {
 108         if(other == self.owner)
 109                 return;
 110
 111         PROJECTILE_TOUCH;
 112         self.think = raptor_bomblet_boom;
 113         self.nextthink = time + random() * autocvar_g_vehicle_raptor_bomblet_explode_delay;
 114 }
 115
 116 void raptor_bomb_burst()
 117 {
 118         if(self.cnt > time)
 119         if(autocvar_g_vehicle_raptor_bomblet_alt)
 120         {
 121                 self.nextthink = time;
 122                 traceline(self.origin, self.origin + (normalize(self.velocity) * autocvar_g_vehicle_raptor_bomblet_alt), MOVE_NORMAL, self);
 123                 if((trace_fraction == 1.0) || (vlen(self.origin - self.owner.origin) < autocvar_g_vehicle_raptor_bomblet_radius))
 124                 {
 125                         UpdateCSQCProjectile(self);
 126                         return;
 127                 }
 128         }
 129
 130         entity bomblet;
 131         float i;
 132
 133         Damage_DamageInfo(self.origin, 0, 0, 0, '0 0 0', DEATH_VH_RAPT_FRAGMENT, 0, self);
 134
 135         for(i = 0; i < autocvar_g_vehicle_raptor_bomblets; ++i)
 136         {
 137                 bomblet = spawn();
 138                 setorigin(bomblet, self.origin);
 139
 140                 bomblet.movetype        = MOVETYPE_TOSS;
 141                 bomblet.touch      = raptor_bomblet_touch;
 142                 bomblet.think      = raptor_bomblet_boom;
 143                 bomblet.nextthink   = time + 5;
 144                 bomblet.owner      = self.owner;
 145                 bomblet.realowner   = self.realowner;
 146                 bomblet.velocity        = normalize(normalize(self.velocity) + (randomvec() * autocvar_g_vehicle_raptor_bomblet_spread)) * vlen(self.velocity);
 147
 148                 PROJECTILE_MAKETRIGGER(bomblet);
 149                 CSQCProjectile(bomblet, true, PROJECTILE_RAPTORBOMBLET, true);
 150         }
 151
 152         remove(self);
 153 }
 154
 155 void raptor_bombdrop()
 156 {
 157         entity bomb_1, bomb_2;
 158
 159         bomb_1 = spawn();
 160         bomb_2 = spawn();
 161
 162         setorigin(bomb_1, gettaginfo(self, gettagindex(self, "bombmount_left")));
 163         setorigin(bomb_2, gettaginfo(self, gettagindex(self, "bombmount_right")));
 164
 165         bomb_1.movetype  = bomb_2.movetype   = MOVETYPE_BOUNCE;
 166         bomb_1.velocity  = bomb_2.velocity   = self.velocity;
 167         bomb_1.touch            = bomb_2.touch    = raptor_bomb_burst;
 168         bomb_1.think            = bomb_2.think    = raptor_bomb_burst;
 169         bomb_1.cnt                = bomb_2.cnt          = time + 10;
 170
 171         if(autocvar_g_vehicle_raptor_bomblet_alt)
 172                 bomb_1.nextthink = bomb_2.nextthink  = time;
 173         else
 174                 bomb_1.nextthink = bomb_2.nextthink  = time + autocvar_g_vehicle_raptor_bomblet_time;
 175
 176         bomb_1.owner     = bomb_2.owner   = self;
 177         bomb_1.realowner = bomb_2.realowner  = self.owner;
 178         bomb_1.solid     = bomb_2.solid   = SOLID_BBOX;
 179         bomb_1.gravity   = bomb_2.gravity       = 1;
 180
 181         PROJECTILE_MAKETRIGGER(bomb_1);
 182         PROJECTILE_MAKETRIGGER(bomb_2);
 183
 184         CSQCProjectile(bomb_1, true, PROJECTILE_RAPTORBOMB, true);
 185         CSQCProjectile(bomb_2, true, PROJECTILE_RAPTORBOMB, true);
 186 }
 187
 188
 189 void raptor_fire_cannon(entity gun, string tagname)
 190 {
 191         vehicles_projectile("raptor_cannon_muzzleflash", "weapons/lasergun_fire.wav",
 192                                                    gettaginfo(gun, gettagindex(gun, tagname)), normalize(v_forward + randomvec() * autocvar_g_vehicle_raptor_cannon_spread) * autocvar_g_vehicle_raptor_cannon_speed,
 193                                                    autocvar_g_vehicle_raptor_cannon_damage, autocvar_g_vehicle_raptor_cannon_radius, autocvar_g_vehicle_raptor_cannon_force,  0,
 194                                                    DEATH_VH_RAPT_CANNON, PROJECTILE_RAPTORCANNON, 0, true, true, self.owner);
 195 }
 196
 197 void raptor_land()
 198 {
 199         float hgt;
 200
 201         hgt = raptor_altitude(512);
 202         self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
 203         self.angles_x *= 0.95;
 204         self.angles_z *= 0.95;
 205
 206         if(hgt < 128)
 207         if(hgt > 0)
 208                 self.frame = (hgt / 128) * 25;
 209
 210         self.bomb1.gun1.avelocity_y = 90 + ((self.frame / 25) * 2000);
 211         self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 212
 213         if(hgt < 16)
 214         {
 215                 self.movetype = MOVETYPE_TOSS;
 216                 self.think      = vehicles_think;
 217                 self.frame      = 0;
 218         }
 219
 220         self.nextthink  = time;
 221
 222         CSQCMODEL_AUTOUPDATE();
 223 }
 224
 225 void raptor_exit(float eject)
 226 {
 227         vector spot;
 228         self.tur_head.exteriormodeltoclient = world;
 229
 230         if(self.deadflag == DEAD_NO)
 231         {
 232                 self.think        = raptor_land;
 233                 self.nextthink  = time;
 234         }
 235
 236         if(!self.owner)
 237                 return;
 238
 239         makevectors(self.angles);
 240         if(eject)
 241         {
 242                 spot = self.origin + v_forward * 100 + '0 0 64';
 243                 spot = vehicles_findgoodexit(spot);
 244                 setorigin(self.owner , spot);
 245                 self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 246                 self.owner.oldvelocity = self.owner.velocity;
 247         }
 248         else
 249         {
 250                 if(vlen(self.velocity) > 2 * autocvar_sv_maxairspeed)
 251                 {
 252                         self.owner.velocity = normalize(self.velocity) * autocvar_sv_maxairspeed * 2;
 253                         self.owner.velocity_z += 200;
 254                         spot = self.origin + v_forward * 32 + '0 0 64';
 255                         spot = vehicles_findgoodexit(spot);
 256                 }
 257                 else
 258                 {
 259                         self.owner.velocity = self.velocity * 0.5;
 260                         self.owner.velocity_z += 10;
 261                         spot = self.origin - v_forward * 200 + '0 0 64';
 262                         spot = vehicles_findgoodexit(spot);
 263                 }
 264                 self.owner.oldvelocity = self.owner.velocity;
 265                 setorigin(self.owner , spot);
 266         }
 267
 268         antilag_clear(self.owner);
 269         self.owner = world;
 270 }
 271
 272 void raptor_flare_touch()
 273 {
 274         remove(self);
 275 }
 276
 277 void raptor_flare_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 278 {
 279         self.health -= damage;
 280         if(self.health <= 0)
 281                 remove(self);
 282 }
 283
 284 void raptor_flare_think()
 285 {
 286         self.nextthink = time + 0.1;
 287         entity _missile = findchainentity(enemy, self.owner);
 288         while(_missile)
 289         {
 290                 if(_missile.flags & FL_PROJECTILE)
 291                 if(vlen(self.origin - _missile.origin) < autocvar_g_vehicle_raptor_flare_range)
 292                 if(random() > autocvar_g_vehicle_raptor_flare_chase)
 293                         _missile.enemy = self;
 294                 _missile = _missile.chain;
 295         }
 296
 297         if(self.tur_impacttime < time)
 298                 remove(self);
 299 }
 300
 301 float raptor_frame()
 302 {
 303         entity player, raptor;
 304         float ftmp = 0;
 305         vector df;
 306
 307         if(intermission_running)
 308         {
 309                 self.vehicle.velocity = '0 0 0';
 310                 self.vehicle.avelocity = '0 0 0';
 311                 return 1;
 312         }
 313
 314         player = self;
 315         raptor = self.vehicle;
 316         self   = raptor;
 317
 318         vehicles_painframe();
 319         /*
 320         ftmp = vlen(self.velocity);
 321         if(ftmp > autocvar_g_vehicle_raptor_speed_forward)
 322                 ftmp = 1;
 323         else
 324                 ftmp = ftmp / autocvar_g_vehicle_raptor_speed_forward;
 325         */
 326
 327         if(self.sound_nexttime < time)
 328         {
 329                 self.sound_nexttime = time + 7.955812;
 330                 //sound (self.tur_head, CH_TRIGGER_SINGLE, "vehicles/raptor_fly.wav", 1 - ftmp,   ATTEN_NORM );
 331                 sound (self, CH_TRIGGER_SINGLE, "vehicles/raptor_speed.wav", 1, ATTEN_NORM);
 332                 self.wait = ftmp;
 333         }
 334         /*
 335         else if(fabs(ftmp - self.wait) > 0.2)
 336         {
 337                 sound (self.tur_head, CH_TRIGGER_SINGLE, "", 1 - ftmp,   ATTEN_NORM );
 338                 sound (self, CH_TRIGGER_SINGLE, "", ftmp, ATTEN_NORM);
 339                 self.wait = ftmp;
 340         }
 341         */
 342
 343         if(raptor.deadflag != DEAD_NO)
 344         {
 345                 self = player;
 346                 player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 347                 return 1;
 348         }
 349         crosshair_trace(player);
 350
 351         //if(time - self.lastteleporttime < 1)
 352         //{
 353                 if(raptor.angles_z > 50 || raptor.angles_z < -50)
 354                 {
 355                         if(player.BUTTON_JUMP)
 356                         {
 357                                 player.BUTTON_CROUCH = true;
 358                                 player.BUTTON_JUMP = false;
 359                         }
 360                 }
 361         //}
 362
 363         vector vang;
 364         vang = raptor.angles;
 365         df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 366         vang_x *= -1;
 367         df_x *= -1;
 368         if(df_x > 180)  df_x -= 360;
 369         if(df_x < -180) df_x += 360;
 370         if(df_y > 180)  df_y -= 360;
 371         if(df_y < -180) df_y += 360;
 372
 373         ftmp = shortangle_f(player.v_angle_y - vang_y, vang_y);
 374         if(ftmp > 180)  ftmp -= 360; if(ftmp < -180) ftmp += 360;
 375         raptor.avelocity_y = bound(-autocvar_g_vehicle_raptor_turnspeed, ftmp + raptor.avelocity_y * 0.9, autocvar_g_vehicle_raptor_turnspeed);
 376
 377         // Pitch
 378         ftmp = 0;
 379         if(player.movement_x > 0 && vang_x < autocvar_g_vehicle_raptor_pitchlimit) ftmp = 5;
 380         else if(player.movement_x < 0 && vang_x > -autocvar_g_vehicle_raptor_pitchlimit) ftmp = -20;
 381
 382         df_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x , autocvar_g_vehicle_raptor_pitchlimit);
 383         ftmp = vang_x - bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x + ftmp, autocvar_g_vehicle_raptor_pitchlimit);
 384         raptor.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchspeed, ftmp + raptor.avelocity_x * 0.9, autocvar_g_vehicle_raptor_pitchspeed);
 385
 386         raptor.angles_x = anglemods(raptor.angles_x);
 387         raptor.angles_y = anglemods(raptor.angles_y);
 388         raptor.angles_z = anglemods(raptor.angles_z);
 389
 390         if(autocvar_g_vehicle_raptor_movestyle == 1)
 391                 makevectors('0 1 0' * raptor.angles_y);
 392         else
 393                 makevectors(player.v_angle);
 394
 395         df = raptor.velocity * -autocvar_g_vehicle_raptor_friction;
 396
 397         if(player.movement_x != 0)
 398         {
 399                 if(player.movement_x > 0)
 400                         df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 401                 else if(player.movement_x < 0)
 402                         df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 403         }
 404
 405         if(player.movement_y != 0)
 406         {
 407                 if(player.movement_y < 0)
 408                         df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 409                 else if(player.movement_y > 0)
 410                         df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 411
 412                 raptor.angles_z = bound(-30,raptor.angles_z + (player.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 413         }
 414         else
 415         {
 416                 raptor.angles_z *= 0.95;
 417                 if(raptor.angles_z >= -1 && raptor.angles_z <= -1)
 418                         raptor.angles_z = 0;
 419         }
 420
 421         if(player.BUTTON_CROUCH)
 422                 df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 423         else if (player.BUTTON_JUMP)
 424                 df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 425
 426         raptor.velocity  += df * frametime;
 427         player.velocity = player.movement  = raptor.velocity;
 428         setorigin(player, raptor.origin + '0 0 32');
 429
 430         player.vehicle_weapon2mode = raptor.vehicle_weapon2mode;
 431
 432         vector vf, ad;
 433         // Target lock & predict
 434         if(autocvar_g_vehicle_raptor_cannon_locktarget == 2)
 435         {
 436                 if(raptor.gun1.lock_time < time || raptor.gun1.enemy.deadflag)
 437                         raptor.gun1.enemy = world;
 438
 439                 if(trace_ent)
 440                 if(trace_ent.movetype)
 441                 if(trace_ent.takedamage)
 442                 if(!trace_ent.deadflag)
 443                 {
 444                         if(teamplay)
 445                         {
 446                                 if(trace_ent.team != player.team)
 447                                 {
 448                                         raptor.gun1.enemy = trace_ent;
 449                                         raptor.gun1.lock_time = time + 5;
 450                                 }
 451                         }
 452                         else
 453                         {
 454                                 raptor.gun1.enemy = trace_ent;
 455                                 raptor.gun1.lock_time = time + 0.5;
 456                         }
 457                 }
 458
 459                 if(raptor.gun1.enemy)
 460                 {
 461                         float distance, impact_time;
 462
 463                         vf = real_origin(raptor.gun1.enemy);
 464                         UpdateAuxiliaryXhair(player, vf, '1 0 0', 1);
 465                         vector _vel = raptor.gun1.enemy.velocity;
 466                         if(raptor.gun1.enemy.movetype == MOVETYPE_WALK)
 467                                 _vel_z *= 0.1;
 468
 469                         if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 470                         {
 471                                 ad = vf;
 472                                 distance = vlen(ad - player.origin);
 473                                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 474                                 ad = vf + _vel * impact_time;
 475                                 trace_endpos = ad;
 476                         }
 477                         else
 478                                 trace_endpos = vf;
 479                 }
 480         }
 481         else if(autocvar_g_vehicle_raptor_cannon_locktarget == 1)
 482         {
 483
 484                 vehicles_locktarget((1 / autocvar_g_vehicle_raptor_cannon_locking_time) * frametime,
 485                                                          (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * frametime,
 486                                                          autocvar_g_vehicle_raptor_cannon_locked_time);
 487
 488                 if(self.lock_target != world)
 489                 if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 490                 if(self.lock_strength == 1)
 491                 {
 492                         float i, distance, impact_time;
 493
 494                         vf = real_origin(raptor.lock_target);
 495                         ad = vf;
 496                         for(i = 0; i < 4; ++i)
 497                         {
 498                                 distance = vlen(ad - raptor.origin);
 499                                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 500                                 ad = vf + raptor.lock_target.velocity * impact_time;
 501                         }
 502                         trace_endpos = ad;
 503                 }
 504
 505                 if(self.lock_target)
 506                 {
 507                         if(raptor.lock_strength == 1)
 508                                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '1 0 0', 1);
 509                         else if(self.lock_strength > 0.5)
 510                                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 1 0', 1);
 511                         else if(self.lock_strength < 0.5)
 512                                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 0 1', 1);
 513                 }
 514         }
 515
 516
 517         vehicle_aimturret(raptor, trace_endpos, raptor.gun1, "fire1",
 518                                                   autocvar_g_vehicle_raptor_cannon_pitchlimit_down * -1,  autocvar_g_vehicle_raptor_cannon_pitchlimit_up,
 519                                                   autocvar_g_vehicle_raptor_cannon_turnlimit * -1,  autocvar_g_vehicle_raptor_cannon_turnlimit,  autocvar_g_vehicle_raptor_cannon_turnspeed);
 520
 521         vehicle_aimturret(raptor, trace_endpos, raptor.gun2, "fire1",
 522                                                   autocvar_g_vehicle_raptor_cannon_pitchlimit_down * -1,  autocvar_g_vehicle_raptor_cannon_pitchlimit_up,
 523                                                   autocvar_g_vehicle_raptor_cannon_turnlimit * -1,  autocvar_g_vehicle_raptor_cannon_turnlimit,  autocvar_g_vehicle_raptor_cannon_turnspeed);
 524
 525         /*
 526         ad = ad * 0.5;
 527         v_forward = vf * 0.5;
 528         traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, raptor);
 529         UpdateAuxiliaryXhair(player, trace_endpos, '0 1 0', 0);
 530         */
 531
 532         if(!forbidWeaponUse(player))
 533         if(player.BUTTON_ATCK)
 534         if(raptor.attack_finished_single <= time)
 535         if(raptor.vehicle_energy > autocvar_g_vehicle_raptor_cannon_cost)
 536         {
 537                 raptor.misc_bulletcounter += 1;
 538                 raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire;
 539                 if(raptor.misc_bulletcounter <= 2)
 540                         raptor_fire_cannon(self.gun1, "fire1");
 541                 else if(raptor.misc_bulletcounter == 3)
 542                         raptor_fire_cannon(self.gun2, "fire1");
 543                 else
 544                 {
 545                         raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire * 2;
 546                         raptor_fire_cannon(self.gun2, "fire1");
 547                         raptor.misc_bulletcounter = 0;
 548                 }
 549                 raptor.vehicle_energy -= autocvar_g_vehicle_raptor_cannon_cost;
 550                 self.cnt = time;
 551         }
 552
 553         if(self.vehicle_flags  & VHF_SHIELDREGEN)
 554                 vehicles_regen(raptor.dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime, true);
 555
 556         if(self.vehicle_flags  & VHF_HEALTHREGEN)
 557                 vehicles_regen(raptor.dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime, false);
 558
 559         if(self.vehicle_flags  & VHF_ENERGYREGEN)
 560                 vehicles_regen(raptor.cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime, false);
 561
 562         if(!forbidWeaponUse(player))
 563         if(raptor.vehicle_weapon2mode == RSM_BOMB)
 564         {
 565                 if(time > raptor.lip + autocvar_g_vehicle_raptor_bombs_refire)
 566                 if(player.BUTTON_ATCK2)
 567                 {
 568                         raptor_bombdrop();
 569                         raptor.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 570                         raptor.lip   = time;
 571                 }
 572         }
 573         else
 574         {
 575                 if(time > raptor.lip + autocvar_g_vehicle_raptor_flare_refire)
 576                 if(player.BUTTON_ATCK2)
 577                 {
 578                         float i;
 579                         entity _flare;
 580
 581                         for(i = 0; i < 3; ++i)
 582                         {
 583                         _flare = spawn();
 584                         setmodel(_flare, "models/runematch/rune.mdl");
 585                         _flare.effects = EF_LOWPRECISION | EF_FLAME;
 586                         _flare.scale = 0.5;
 587                         setorigin(_flare, self.origin - '0 0 16');
 588                         _flare.movetype = MOVETYPE_TOSS;
 589                         _flare.gravity = 0.15;
 590                         _flare.velocity = 0.25 * raptor.velocity + (v_forward + randomvec() * 0.25)* -500;
 591                         _flare.think = raptor_flare_think;
 592                         _flare.nextthink = time;
 593                         _flare.owner = raptor;
 594                         _flare.solid = SOLID_CORPSE;
 595                         _flare.takedamage = DAMAGE_YES;
 596                         _flare.event_damage = raptor_flare_damage;
 597                         _flare.health = 20;
 598                         _flare.tur_impacttime = time + autocvar_g_vehicle_raptor_flare_lifetime;
 599                         _flare.touch = raptor_flare_touch;
 600                         }
 601                         raptor.delay = time + autocvar_g_vehicle_raptor_flare_refire;
 602                         raptor.lip   = time;
 603                 }
 604         }
 605
 606         raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 607         player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 608         player.vehicle_ammo2 = (player.vehicle_reload2 == 100) ? 100 : 0;
 609
 610         if(self.bomb1.cnt < time)
 611         {
 612                 entity _missile = findchainentity(enemy, raptor);
 613                 float _incomming = 0;
 614                 while(_missile)
 615                 {
 616                         if(_missile.flags & FL_PROJECTILE)
 617                         if(MISSILE_IS_TRACKING(_missile))
 618                         if(vlen(self.origin - _missile.origin) < 2 * autocvar_g_vehicle_raptor_flare_range)
 619                                 ++_incomming;
 620
 621                         _missile = _missile.chain;
 622                 }
 623
 624                 if(_incomming)
 625                         sound(self, CH_PAIN_SINGLE, "vehicles/missile_alarm.wav", VOL_BASE, ATTEN_NONE);
 626
 627                 self.bomb1.cnt = time + 1;
 628         }
 629
 630
 631         VEHICLE_UPDATE_PLAYER(player, health, raptor);
 632         VEHICLE_UPDATE_PLAYER(player, energy, raptor);
 633         if(self.vehicle_flags & VHF_HASSHIELD)
 634                 VEHICLE_UPDATE_PLAYER(player, shield, raptor);
 635
 636         player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 637
 638         self = player;
 639         return 1;
 640 }
 641
 642 float raptor_takeoff()
 643 {
 644         entity player, raptor;
 645
 646         player = self;
 647         raptor = self.vehicle;
 648         self   = raptor;
 649
 650         self.nextthink = time;
 651         CSQCMODEL_AUTOUPDATE();
 652         self.nextthink = 0; // will this work?
 653
 654         if(self.sound_nexttime < time)
 655         {
 656                 self.sound_nexttime = time + 7.955812; //soundlength("vehicles/raptor_fly.wav");
 657                 sound (self, CH_TRIGGER_SINGLE, "vehicles/raptor_speed.wav", VOL_VEHICLEENGINE, ATTEN_NORM);
 658         }
 659
 660         // Takeoff sequense
 661         if(raptor.frame < 25)
 662         {
 663                 raptor.frame += 25 / (autocvar_g_vehicle_raptor_takeofftime / sys_frametime);
 664                 raptor.velocity_z = min(raptor.velocity_z * 1.5, 256);
 665                 self.bomb1.gun1.avelocity_y = 90 + ((raptor.frame / 25) * 25000);
 666                 self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 667                 player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 668
 669                 setorigin(player, raptor.origin + '0 0 32');
 670         }
 671         else
 672                 player.PlayerPhysplug = raptor_frame;
 673
 674         if(self.vehicle_flags  & VHF_SHIELDREGEN)
 675                 vehicles_regen(raptor.dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime, true);
 676
 677         if(self.vehicle_flags  & VHF_HEALTHREGEN)
 678                 vehicles_regen(raptor.dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime, false);
 679
 680         if(self.vehicle_flags  & VHF_ENERGYREGEN)
 681                 vehicles_regen(raptor.cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime, false);
 682
 683
 684         raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 685         player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 686         player.vehicle_ammo2 = (player.vehicle_reload2 == 100) ? 100 : 0;
 687
 688         VEHICLE_UPDATE_PLAYER(player, health, raptor);
 689         VEHICLE_UPDATE_PLAYER(player, energy, raptor);
 690         if(self.vehicle_flags & VHF_HASSHIELD)
 691                 VEHICLE_UPDATE_PLAYER(player, shield, raptor);
 692
 693         player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 694         self = player;
 695         return 1;
 696 }
 697
 698 void raptor_blowup()
 699 {
 700         self.deadflag   = DEAD_DEAD;
 701         self.vehicle_exit(VHEF_NORMAL);
 702         RadiusDamage (self, self.enemy, 250, 15, 250, world, world, 250, DEATH_VH_RAPT_DEATH, world);
 703
 704         self.alpha                = -1;
 705         self.movetype      = MOVETYPE_NONE;
 706         self.effects            = EF_NODRAW;
 707         self.colormod      = '0 0 0';
 708         self.avelocity    = '0 0 0';
 709         self.velocity      = '0 0 0';
 710
 711         setorigin(self, self.pos1);
 712         self.touch = func_null;
 713         self.nextthink = 0;
 714 }
 715
 716 void raptor_diethink()
 717 {
 718         if(time >= self.wait)
 719                 self.think = raptor_blowup;
 720
 721         if(random() < 0.05)
 722         {
 723                 sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
 724                 Send_Effect("explosion_small", randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 725         }
 726         self.nextthink = time;
 727
 728         CSQCMODEL_AUTOUPDATE();
 729 }
 730
 731 // If we dont do this ever now and then, the raptors rotors
 732 // stop working, presumably due to angle overflow. cute.
 733 void raptor_rotor_anglefix()
 734 {
 735         self.gun1.angles_y = anglemods(self.gun1.angles_y);
 736         self.gun2.angles_y = anglemods(self.gun2.angles_y);
 737         self.nextthink = time + 15;
 738 }
 739
 740 float raptor_impulse(float _imp)
 741 {
 742         switch(_imp)
 743         {
 744                 case 1:
 745                 case 230:
 746                         self.vehicle.vehicle_weapon2mode = RSM_BOMB;
 747                         CSQCVehicleSetup(self, 0);
 748                         return true;
 749                 case 2:
 750                 case 231:
 751                         self.vehicle.vehicle_weapon2mode = RSM_FLARE;
 752                         CSQCVehicleSetup(self, 0);
 753                         return true;
 754
 755                 case 10:
 756                 case 15:
 757                 case 18:
 758                         self.vehicle.vehicle_weapon2mode += 1;
 759                         if(self.vehicle.vehicle_weapon2mode > RSM_LAST)
 760                                 self.vehicle.vehicle_weapon2mode = RSM_FIRST;
 761
 762                         CSQCVehicleSetup(self, 0);
 763                         return true;
 764                 case 11:
 765                 case 12:
 766                 case 16:
 767                 case 19:
 768                         self.vehicle.vehicle_weapon2mode -= 1;
 769                         if(self.vehicle.vehicle_weapon2mode < RSM_FIRST)
 770                                 self.vehicle.vehicle_weapon2mode = RSM_LAST;
 771
 772                         CSQCVehicleSetup(self, 0);
 773                         return true;
 774
 775                 /*
 776                 case 17: // toss gun, could be used to exit?
 777                         break;
 778                 case 20: // Manual minigun reload?
 779                         break;
 780                 */
 781         }
 782         return false;
 783 }
 784
 785 void spawnfunc_vehicle_raptor()
 786 {
 787         if(!autocvar_g_vehicle_raptor) { remove(self); return; }
 788         if(!vehicle_initialize(VEH_RAPTOR, false)) { remove(self); return; }
 789 }
 790
 791 float v_raptor(float req)
 792 {
 793         switch(req)
 794         {
 795                 case VR_IMPACT:
 796                 {
 797                         if(autocvar_g_vehicle_raptor_bouncepain)
 798                                 vehicles_impact(autocvar_g_vehicle_raptor_bouncepain_x, autocvar_g_vehicle_raptor_bouncepain_y, autocvar_g_vehicle_raptor_bouncepain_z);
 799
 800                         return true;
 801                 }
 802                 case VR_ENTER:
 803                 {
 804                         self.vehicle_weapon2mode = RSM_BOMB;
 805                         self.owner.PlayerPhysplug = raptor_takeoff;
 806                         self.movetype      = MOVETYPE_BOUNCEMISSILE;
 807                         self.solid                = SOLID_SLIDEBOX;
 808                         self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_raptor_health) * 100;
 809                         self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_raptor_shield) * 100;
 810                         self.velocity_z = 1; // Nudge upwards to takeoff sequense can work.
 811                         self.tur_head.exteriormodeltoclient = self.owner;
 812
 813                         self.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 814                         self.lip   = time;
 815
 816                         if(self.owner.flagcarried)
 817                            setorigin(self.owner.flagcarried, '-20 0 96');
 818
 819                         CSQCVehicleSetup(self.owner, 0);
 820                         return true;
 821                 }
 822                 case VR_THINK:
 823                 {
 824                         return true;
 825                 }
 826                 case VR_DEATH:
 827                 {
 828                         self.health                             = 0;
 829                         self.event_damage               = func_null;
 830                         self.solid                              = SOLID_CORPSE;
 831                         self.takedamage                 = DAMAGE_NO;
 832                         self.deadflag                   = DEAD_DYING;
 833                         self.movetype                   = MOVETYPE_BOUNCE;
 834                         self.think                              = raptor_diethink;
 835                         self.nextthink                  = time;
 836                         self.wait                               = time + 5 + (random() * 5);
 837
 838                         Send_Effect("explosion_medium", findbetterlocation (self.origin, 16), '0 0 0', 1);
 839
 840                         self.velocity_z += 600;
 841
 842                         self.avelocity = '0 0.5 1' * (random() * 400);
 843                         self.avelocity -= '0 0.5 1' * (random() * 400);
 844
 845                         self.colormod = '-0.5 -0.5 -0.5';
 846                         self.touch = raptor_blowup;
 847                         return true;
 848                 }
 849                 case VR_SPAWN:
 850                 {
 851                         if(!self.gun1)
 852                         {
 853                                 entity spinner;
 854                                 vector ofs;
 855
 856                                 //FIXME: Camera is in a bad place in HUD model.
 857                                 //setorigin(self.vehicle_viewport, '25 0 5');
 858
 859                                 self.vehicles_impulse   = raptor_impulse;
 860
 861                                 self.frame = 0;
 862
 863                                 self.bomb1 = spawn();
 864                                 self.bomb2 = spawn();
 865                                 self.gun1  = spawn();
 866                                 self.gun2  = spawn();
 867
 868                                 setmodel(self.bomb1,"models/vehicles/clusterbomb_folded.md3");
 869                                 setmodel(self.bomb2,"models/vehicles/clusterbomb_folded.md3");
 870                                 setmodel(self.gun1, "models/vehicles/raptor_gun.dpm");
 871                                 setmodel(self.gun2, "models/vehicles/raptor_gun.dpm");
 872                                 setmodel(self.tur_head, "models/vehicles/raptor_body.dpm");
 873
 874                                 setattachment(self.bomb1, self, "bombmount_left");
 875                                 setattachment(self.bomb2, self, "bombmount_right");
 876                                 setattachment(self.tur_head, self,"root");
 877
 878                                 // FIXMODEL Guns mounts to angled bones
 879                                 self.bomb1.angles = self.angles;
 880                                 self.angles = '0 0 0';
 881                                 // This messes up gun-aim, so work arround it.
 882                                 //setattachment(self.gun1, self, "gunmount_left");
 883                                 ofs = gettaginfo(self, gettagindex(self, "gunmount_left"));
 884                                 ofs -= self.origin;
 885                                 setattachment(self.gun1, self, "");
 886                                 setorigin(self.gun1, ofs);
 887
 888                                 //setattachment(self.gun2, self, "gunmount_right");
 889                                 ofs = gettaginfo(self, gettagindex(self, "gunmount_right"));
 890                                 ofs -= self.origin;
 891                                 setattachment(self.gun2, self, "");
 892                                 setorigin(self.gun2, ofs);
 893
 894                                 self.angles = self.bomb1.angles;
 895                                 self.bomb1.angles = '0 0 0';
 896
 897                                 spinner = spawn();
 898                                 spinner.owner = self;
 899                                 setmodel(spinner,"models/vehicles/spinner.dpm");
 900                                 setattachment(spinner, self, "engine_left");
 901                                 spinner.movetype = MOVETYPE_NOCLIP;
 902                                 spinner.avelocity = '0 90 0';
 903                                 self.bomb1.gun1 = spinner;
 904
 905                                 spinner = spawn();
 906                                 spinner.owner = self;
 907                                 setmodel(spinner,"models/vehicles/spinner.dpm");
 908                                 setattachment(spinner, self, "engine_right");
 909                                 spinner.movetype = MOVETYPE_NOCLIP;
 910                                 spinner.avelocity = '0 -90 0';
 911                                 self.bomb1.gun2 = spinner;
 912
 913                                 // Sigh.
 914                                 self.bomb1.think = raptor_rotor_anglefix;
 915                                 self.bomb1.nextthink = time;
 916
 917                                 self.mass                          = 1 ;
 918                         }
 919
 920                         self.frame                = 0;
 921                         self.vehicle_health = autocvar_g_vehicle_raptor_health;
 922                         self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 923                         self.movetype      = MOVETYPE_TOSS;
 924                         self.solid                = SOLID_SLIDEBOX;
 925                         self.vehicle_energy = 1;
 926
 927                         self.PlayerPhysplug = raptor_frame;
 928
 929                         self.bomb1.gun1.avelocity_y = 90;
 930                         self.bomb1.gun2.avelocity_y = -90;
 931
 932                         self.delay = time;
 933
 934                         self.bouncefactor = autocvar_g_vehicle_raptor_bouncefactor;
 935                         self.bouncestop = autocvar_g_vehicle_raptor_bouncestop;
 936                         self.damageforcescale = 0.25;
 937                         self.vehicle_health = autocvar_g_vehicle_raptor_health;
 938                         self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 939                         return true;
 940                 }
 941                 case VR_SETUP:
 942                 {
 943                         if(autocvar_g_vehicle_raptor_shield)
 944                                 self.vehicle_flags |= VHF_HASSHIELD;
 945
 946                         if(autocvar_g_vehicle_raptor_shield_regen)
 947                                 self.vehicle_flags |= VHF_SHIELDREGEN;
 948
 949                         if(autocvar_g_vehicle_raptor_health_regen)
 950                                 self.vehicle_flags |= VHF_HEALTHREGEN;
 951
 952                         if(autocvar_g_vehicle_raptor_energy_regen)
 953                                 self.vehicle_flags |= VHF_ENERGYREGEN;
 954
 955                         self.vehicle_exit = raptor_exit;
 956                         self.respawntime = autocvar_g_vehicle_raptor_respawntime;
 957                         self.vehicle_health = autocvar_g_vehicle_raptor_health;
 958                         self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 959                         self.max_health = self.vehicle_health;
 960
 961                         return true;
 962                 }
 963                 case VR_PRECACHE:
 964                 {
 965                         precache_model ("models/vehicles/raptor.dpm");
 966                         precache_model ("models/vehicles/raptor_gun.dpm");
 967                         precache_model ("models/vehicles/spinner.dpm");
 968                         precache_model ("models/vehicles/raptor_cockpit.dpm");
 969                         precache_model ("models/vehicles/clusterbomb_folded.md3");
 970                         precache_model ("models/vehicles/raptor_body.dpm");
 971
 972                         precache_sound ("vehicles/raptor_fly.wav");
 973                         precache_sound ("vehicles/raptor_speed.wav");
 974                         precache_sound ("vehicles/missile_alarm.wav");
 975
 976                         return true;
 977                 }
 978         }
 979
 980         return true;
 981 }
 982
 983 #endif // SVQC
 984 #ifdef CSQC
 985
 986 void RaptorCBShellfragDraw()
 987 {
 988         if(wasfreed(self))
 989                 return;
 990
 991         Movetype_Physics_MatchTicrate(autocvar_cl_gibs_ticrate, autocvar_cl_gibs_sloppy);
 992         self.move_avelocity += randomvec() * 15;
 993         self.renderflags = 0;
 994
 995         if(self.cnt < time)
 996                 self.alpha = bound(0, self.nextthink - time, 1);
 997
 998         if(self.alpha < ALPHA_MIN_VISIBLE)
 999                 remove(self);
1000 }
1001
1002 void RaptorCBShellfragToss(vector _org, vector _vel, vector _ang)
1003 {
1004         entity sfrag;
1005
1006         sfrag = spawn();
1007         setmodel(sfrag, "models/vehicles/clusterbomb_fragment.md3");
1008         setorigin(sfrag, _org);
1009
1010         sfrag.move_movetype = MOVETYPE_BOUNCE;
1011         sfrag.gravity = 0.15;
1012         sfrag.solid = SOLID_CORPSE;
1013
1014         sfrag.draw = RaptorCBShellfragDraw;
1015
1016         sfrag.move_origin = sfrag.origin = _org;
1017         sfrag.move_velocity = _vel;
1018         sfrag.move_avelocity = prandomvec() * vlen(sfrag.move_velocity);
1019         sfrag.angles = self.move_angles = _ang;
1020
1021         sfrag.move_time = time;
1022         sfrag.damageforcescale = 4;
1023
1024         sfrag.nextthink = time + 3;
1025         sfrag.cnt = time + 2;
1026         sfrag.alpha = 1;
1027         sfrag.drawmask = MASK_NORMAL;
1028 }
1029
1030 float v_raptor(float req)
1031 {
1032         switch(req)
1033         {
1034                 case VR_HUD:
1035                 {
1036                         string crosshair;
1037
1038                         switch(weapon2mode)
1039                         {
1040                                 case RSM_FLARE: crosshair = vCROSS_RAIN;  break;
1041                                 case RSM_BOMB:  crosshair = vCROSS_BURST; break;
1042                                 default:        crosshair = vCROSS_BURST;
1043                         }
1044
1045                         Vehicles_drawHUD("vehicle_raptor", "vehicle_raptor_weapon1", "vehicle_raptor_weapon2",
1046                                                          "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
1047                                                          "vehicle_icon_ammo2", autocvar_hud_progressbar_vehicles_ammo2_color,
1048                                                          crosshair);
1049                         return true;
1050                 }
1051                 case VR_SETUP:
1052                 {
1053                         AuxiliaryXhair[1].axh_image = vCROSS_LOCK;
1054                         return true;
1055                 }
1056                 case VR_PRECACHE:
1057                 {
1058                         return true;
1059                 }
1060         }
1061
1062         return true;
1063 }
1064
1065 #endif // CSQC
1066 #endif // REGISTER_VEHICLE