qcsrc/common/vehicles/vehicle/bumblebee.qc

   1 #ifndef VEHICLE_BUMBLEBEE
   2 #define VEHICLE_BUMBLEBEE
   3 #include "bumblebee.qh"
   4
   5 #include "bumblebee_weapons.qh"
   6
   7 CLASS(Bumblebee, Vehicle)
   8 /* spawnflags */ ATTRIB(Bumblebee, spawnflags, int, VHF_DMGSHAKE);
   9 /* mins       */ ATTRIB(Bumblebee, mins, vector, '-245 -130 -130');
  10 /* maxs       */ ATTRIB(Bumblebee, maxs, vector, '230 130 130');
  11 /* view offset*/ ATTRIB(Bumblebee, view_ofs, vector, '0 0 300');
  12 /* view dist  */ ATTRIB(Bumblebee, height, float, 450);
  13 /* model          */ ATTRIB(Bumblebee, mdl, string, "models/vehicles/bumblebee_body.dpm");
  14 /* model          */ ATTRIB(Bumblebee, model, string, "models/vehicles/bumblebee_body.dpm");
  15 /* head_model */ ATTRIB(Bumblebee, head_model, string, "");
  16 /* hud_model  */ ATTRIB(Bumblebee, hud_model, string, "models/vehicles/spiderbot_cockpit.dpm");
  17 /* tags       */ ATTRIB(Bumblebee, tag_head, string, "");
  18 /* tags       */ ATTRIB(Bumblebee, tag_hud, string, "");
  19 /* tags       */ ATTRIB(Bumblebee, tag_view, string, "tag_viewport");
  20 /* netname    */ ATTRIB(Bumblebee, netname, string, "bumblebee");
  21 /* fullname   */ ATTRIB(Bumblebee, vehicle_name, string, _("Bumblebee"));
  22 /* icon       */ ATTRIB(Bumblebee, m_icon, string, "vehicle_bumble");
  23 ENDCLASS(Bumblebee)
  24 REGISTER_VEHICLE(BUMBLEBEE, NEW(Bumblebee));
  25
  26 #endif
  27
  28 #ifdef IMPLEMENTATION
  29
  30 const float BRG_SETUP = 2;
  31 const float BRG_START = 4;
  32 const float BRG_END = 8;
  33
  34 #ifdef SVQC
  35 float autocvar_g_vehicle_bumblebee_respawntime = 60;
  36
  37 float autocvar_g_vehicle_bumblebee_speed_forward = 350;
  38 float autocvar_g_vehicle_bumblebee_speed_strafe = 350;
  39 float autocvar_g_vehicle_bumblebee_speed_up = 350;
  40 float autocvar_g_vehicle_bumblebee_speed_down = 350;
  41 float autocvar_g_vehicle_bumblebee_turnspeed = 120;
  42 float autocvar_g_vehicle_bumblebee_pitchspeed = 60;
  43 float autocvar_g_vehicle_bumblebee_pitchlimit = 60;
  44 float autocvar_g_vehicle_bumblebee_friction = 0.5;
  45
  46 float autocvar_g_vehicle_bumblebee_energy = 500;
  47 float autocvar_g_vehicle_bumblebee_energy_regen = 50;
  48 float autocvar_g_vehicle_bumblebee_energy_regen_pause = 1;
  49
  50 float autocvar_g_vehicle_bumblebee_health = 1000;
  51 float autocvar_g_vehicle_bumblebee_health_regen = 65;
  52 float autocvar_g_vehicle_bumblebee_health_regen_pause = 10;
  53
  54 float autocvar_g_vehicle_bumblebee_shield = 400;
  55 float autocvar_g_vehicle_bumblebee_shield_regen = 150;
  56 float autocvar_g_vehicle_bumblebee_shield_regen_pause = 0.75;
  57
  58 float autocvar_g_vehicle_bumblebee_cannon_ammo = 100;
  59 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen = 100;
  60 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause = 1;
  61
  62 float autocvar_g_vehicle_bumblebee_cannon_lock = 0;
  63
  64 float autocvar_g_vehicle_bumblebee_cannon_turnspeed = 160;
  65 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down = 60;
  66 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up = 60;
  67 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_in = 20;
  68 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_out = 80;
  69
  70
  71 float autocvar_g_vehicle_bumblebee_raygun_turnspeed = 180;
  72 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down = 20;
  73 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up = 5;
  74 float autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides = 35;
  75
  76 bool autocvar_g_vehicle_bumblebee_raygun = false;
  77 float autocvar_g_vehicle_bumblebee_raygun_range = 2048;
  78 float autocvar_g_vehicle_bumblebee_raygun_dps = 250;
  79 float autocvar_g_vehicle_bumblebee_raygun_aps = 100;
  80 float autocvar_g_vehicle_bumblebee_raygun_fps = 100;
  81
  82 float autocvar_g_vehicle_bumblebee_healgun_hps = 150;
  83 float autocvar_g_vehicle_bumblebee_healgun_hmax = 100;
  84 float autocvar_g_vehicle_bumblebee_healgun_aps = 75;
  85 float autocvar_g_vehicle_bumblebee_healgun_amax = 100;
  86 float autocvar_g_vehicle_bumblebee_healgun_sps = 100;
  87 float autocvar_g_vehicle_bumblebee_healgun_locktime = 2.5;
  88
  89 float autocvar_g_vehicle_bumblebee_blowup_radius = 500;
  90 float autocvar_g_vehicle_bumblebee_blowup_coredamage = 500;
  91 float autocvar_g_vehicle_bumblebee_blowup_edgedamage = 100;
  92 float autocvar_g_vehicle_bumblebee_blowup_forceintensity = 600;
  93 vector autocvar_g_vehicle_bumblebee_bouncepain = '1 100 200';
  94
  95 bool autocvar_g_vehicle_bumblebee = true;
  96
  97 bool bumblebee_gunner_frame(entity this)
  98 {
  99         entity vehic = this.vehicle.owner;
 100         entity gun = this.vehicle;
 101         return = true;
 102
 103         // this isn't technically a vehicle (yet), let's not do frame functions on it (yet)
 104         //vehicles_frame(gun, player);
 105
 106         vehic.solid = SOLID_NOT;
 107         //setorigin(this, vehic.origin);
 108         this.velocity = vehic.velocity;
 109
 110         float _in, _out;
 111         vehic.angles_x *= -1;
 112         makevectors(vehic.angles);
 113         vehic.angles_x *= -1;
 114         if(gun == vehic.gun1)
 115         {
 116                 _in = autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
 117                 _out = autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
 118                 setorigin(this, vehic.origin + v_up * -16 + v_forward * -16 + v_right * 128);
 119         }
 120         else
 121         {
 122                 _in = autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
 123                 _out = autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
 124                 setorigin(this, vehic.origin + v_up * -16 + v_forward * -16 + v_right * -128);
 125         }
 126
 127         crosshair_trace(this);
 128         vector _ct = trace_endpos;
 129         vector ad;
 130
 131         if(autocvar_g_vehicle_bumblebee_cannon_lock)
 132         {
 133                 if(gun.lock_time < time)
 134                         gun.enemy = world;
 135
 136                 if(trace_ent)
 137                         if(trace_ent.movetype)
 138                                 if(trace_ent.takedamage)
 139                                         if(!IS_DEAD(trace_ent) && !STAT(FROZEN, trace_ent))
 140                                         {
 141                                                 if(DIFF_TEAM(trace_ent, this))
 142                                                 {
 143                                                         gun.enemy = trace_ent;
 144                                                         gun.lock_time = time + 5;
 145                                                 }
 146                                         }
 147         }
 148
 149         if(gun.enemy)
 150         {
 151                 float distance, impact_time;
 152
 153                 vector vf = real_origin(gun.enemy);
 154                 vector _vel = gun.enemy.velocity;
 155                 if(gun.enemy.movetype == MOVETYPE_WALK)
 156                         _vel.z *= 0.1;
 157
 158
 159                 ad = vf;
 160                 distance = vlen(ad - this.origin);
 161                 impact_time = distance / autocvar_g_vehicle_bumblebee_cannon_speed;
 162                 ad = vf + _vel * impact_time;
 163                 trace_endpos = ad;
 164
 165
 166                 UpdateAuxiliaryXhair(this, ad, '1 0 1', 1);
 167                 vehicle_aimturret(vehic, trace_endpos, gun, "fire",
 168                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 169                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 170
 171         }
 172         else
 173                 vehicle_aimturret(vehic, _ct, gun, "fire",
 174                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 175                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 176
 177         if(!forbidWeaponUse(this))
 178         if(PHYS_INPUT_BUTTON_ATCK(this))
 179                 if(time > gun.attack_finished_single[0])
 180                         if(gun.vehicle_energy >= autocvar_g_vehicle_bumblebee_cannon_cost)
 181                         {
 182                                 gun.vehicle_energy -= autocvar_g_vehicle_bumblebee_cannon_cost;
 183                                 bumblebee_fire_cannon(vehic, gun, "fire", this);
 184                                 gun.delay = time;
 185                                 gun.attack_finished_single[0] = time + autocvar_g_vehicle_bumblebee_cannon_refire;
 186                         }
 187
 188         VEHICLE_UPDATE_PLAYER(this, vehic, health, bumblebee);
 189
 190         if(vehic.vehicle_flags & VHF_HASSHIELD)
 191                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, bumblebee);
 192
 193         ad = gettaginfo(gun, gettagindex(gun, "fire"));
 194         traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, gun);
 195
 196         UpdateAuxiliaryXhair(this, trace_endpos, ('1 0 0' * this.vehicle_reload1) + ('0 1 0' *(1 - this.vehicle_reload1)), 0);
 197
 198         if(vehic.owner)
 199                 UpdateAuxiliaryXhair(vehic.owner, trace_endpos, ('1 0 0' * this.vehicle_reload1) + ('0 1 0' *(1 - this.vehicle_reload1)), ((this == vehic.gunner1) ? 1 : 2));
 200
 201         vehic.solid = SOLID_BBOX;
 202         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 203         this.vehicle_energy = (gun.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 204 }
 205
 206 vector bumblebee_gunner_findgoodexit(vector prefer_spot, entity gunner, entity player)
 207 {
 208         //vector exitspot;
 209         float mysize;
 210
 211         tracebox(gunner.origin + '0 0 32', STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), prefer_spot, MOVE_NORMAL, player);
 212         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 213                 return prefer_spot;
 214
 215         mysize = 1.5 * vlen(STAT(PL_MAX, NULL) - STAT(PL_MIN, NULL)); // can't use gunner's size, as they don't have a size
 216         float i;
 217         vector v, v2;
 218         v2 = 0.5 * (gunner.absmin + gunner.absmax);
 219         for(i = 0; i < 100; ++i)
 220         {
 221                 v = randomvec();
 222                 v_z = 0;
 223                 v = v2 + normalize(v) * mysize;
 224                 tracebox(v2, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), v, MOVE_NORMAL, player);
 225                 if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 226                         return v;
 227         }
 228
 229         return prefer_spot; // this should be considered a fallback?!
 230 }
 231
 232 void bumblebee_gunner_exit(int _exitflag)
 233 {SELFPARAM();
 234         entity player = self;
 235         entity gunner = player.vehicle;
 236         entity vehic = gunner.owner;
 237
 238         if(IS_REAL_CLIENT(player))
 239         {
 240                 msg_entity = player;
 241                 WriteByte(MSG_ONE, SVC_SETVIEWPORT);
 242                 WriteEntity(MSG_ONE, player);
 243
 244                 WriteByte(MSG_ONE, SVC_SETVIEWANGLES);
 245                 WriteAngle(MSG_ONE, 0);
 246                 WriteAngle(MSG_ONE, vehic.angles.y);
 247                 WriteAngle(MSG_ONE, 0);
 248         }
 249
 250         CSQCVehicleSetup(player, HUD_NORMAL);
 251         setsize(player, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 252
 253         player.takedamage     = DAMAGE_AIM;
 254         player.solid          = SOLID_SLIDEBOX;
 255         player.movetype       = MOVETYPE_WALK;
 256         player.effects       &= ~EF_NODRAW;
 257         player.alpha          = 1;
 258         player.PlayerPhysplug = func_null;
 259         player.view_ofs       = STAT(PL_VIEW_OFS, NULL);
 260         player.event_damage   = PlayerDamage;
 261         player.hud            = HUD_NORMAL;
 262         player.teleportable       = TELEPORT_NORMAL;
 263         PS(player).m_switchweapon = gunner.m_switchweapon;
 264         player.vehicle_enter_delay = time + 2;
 265
 266         fixedmakevectors(vehic.angles);
 267
 268         if(player == vehic.gunner1) { vehic.gunner1 = world; }
 269         if(player == vehic.gunner2) { vehic.gunner2 = world; v_right *= -1; }
 270
 271         vector spot = real_origin(gunner);
 272         spot = spot + v_up * 128 + v_forward * 300 + v_right * 150;
 273         spot = bumblebee_gunner_findgoodexit(spot, gunner, player);
 274
 275         // TODO: figure a way to move player out of the gunner
 276
 277         player.velocity = 0.75 * vehic.velocity + normalize(spot - vehic.origin) * 200;
 278         player.velocity_z += 10;
 279
 280         gunner.phase = time + 5;
 281         gunner.vehicle_hudmodel.viewmodelforclient = gunner;
 282
 283         MUTATOR_CALLHOOK(VehicleExit, player, gunner);
 284
 285         player.vehicle = world;
 286 }
 287
 288 bool bumblebee_gunner_enter()
 289 {SELFPARAM();
 290         entity vehic = self;
 291         entity player = other;
 292         entity gunner = world;
 293
 294         if(!vehic.gunner1 && !vehic.gunner2 && ((time >= vehic.gun1.phase) + (time >= vehic.gun2.phase)) == 2)
 295         {
 296                 // we can have some fun
 297                 if(vlen2(real_origin(vehic.gun2) - player.origin) < vlen2(real_origin(vehic.gun1) - player.origin))
 298                 {
 299                         gunner = vehic.gun2;
 300                         vehic.gunner2 = player;
 301                 }
 302                 else
 303                 {
 304                         gunner = vehic.gun1;
 305                         vehic.gunner1 = player;
 306                 }
 307         }
 308         else if(!vehic.gunner1 && time >= vehic.gun1.phase)     { gunner = vehic.gun1; vehic.gunner1 = player; }
 309         else if(!vehic.gunner2 && time >= vehic.gun2.phase)             { gunner = vehic.gun2; vehic.gunner2 = player; }
 310         else { LOG_TRACE("Vehicle is full, fail\n"); return false; }
 311
 312         player.vehicle                  = gunner;
 313         player.angles                   = vehic.angles;
 314         player.takedamage               = DAMAGE_NO;
 315         player.solid                    = SOLID_NOT;
 316         player.alpha                    = -1;
 317         player.movetype                 = MOVETYPE_NOCLIP;
 318         player.event_damage     = func_null;
 319         player.view_ofs                 = '0 0 0';
 320         player.hud                              = gunner.hud;
 321         player.teleportable     = false;
 322         player.PlayerPhysplug   = gunner.PlayerPhysplug;
 323         player.vehicle_ammo1    = vehic.vehicle_ammo1;
 324         player.vehicle_ammo2    = vehic.vehicle_ammo2;
 325         player.vehicle_reload1  = vehic.vehicle_reload1;
 326         player.vehicle_reload2  = vehic.vehicle_reload2;
 327         player.vehicle_energy   = vehic.vehicle_energy;
 328         player.flags               &= ~FL_ONGROUND;
 329
 330         RemoveGrapplingHook(player);
 331
 332         gunner.m_switchweapon = PS(player).m_switchweapon;
 333         gunner.vehicle_exit = bumblebee_gunner_exit;
 334         gunner.vehicle_hudmodel.viewmodelforclient = player;
 335
 336         if(IS_REAL_CLIENT(player))
 337         {
 338                 msg_entity = player;
 339                 WriteByte(MSG_ONE,              SVC_SETVIEWPORT);
 340                 WriteEntity(MSG_ONE,    gunner.vehicle_viewport);
 341
 342                 WriteByte(MSG_ONE,              SVC_SETVIEWANGLES);
 343                 WriteAngle(MSG_ONE,     gunner.angles_x + vehic.angles_x); // tilt
 344                 WriteAngle(MSG_ONE,     gunner.angles_y + vehic.angles_y); // yaw
 345                 WriteAngle(MSG_ONE,     0); // roll
 346         }
 347
 348         CSQCVehicleSetup(player, player.hud);
 349
 350         MUTATOR_CALLHOOK(VehicleEnter, player, gunner);
 351
 352         return true;
 353 }
 354
 355 bool vehicles_valid_pilot()
 356 {SELFPARAM();
 357         if(IS_BOT_CLIENT(other) && !autocvar_g_vehicles_allow_bots)
 358                 return false;
 359
 360         if((!IS_PLAYER(other))
 361         || (IS_DEAD(other))
 362         || (other.vehicle)
 363         || (DIFF_TEAM(other, self))
 364         ) { return false; }
 365
 366         return true;
 367 }
 368
 369 void bumblebee_touch()
 370 {SELFPARAM();
 371         if(autocvar_g_vehicles_enter) { return; }
 372
 373         if(self.gunner1 != world && self.gunner2 != world)
 374         {
 375                 vehicles_touch();
 376                 return;
 377         }
 378
 379         if(vehicles_valid_pilot())
 380         {
 381                 float phase_time = (time >= self.gun1.phase) + (time >= self.gun2.phase);
 382
 383                 if(time >= other.vehicle_enter_delay && phase_time)
 384                 if(bumblebee_gunner_enter())
 385                         return;
 386         }
 387
 388         vehicles_touch();
 389 }
 390
 391 void bumblebee_regen(entity this)
 392 {
 393         if(this.gun1.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 394                 this.gun1.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 395                                                                            this.gun1.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * frametime);
 396
 397         if(this.gun2.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 398                 this.gun2.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 399                                                                            this.gun2.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * frametime);
 400
 401         if(this.vehicle_flags  & VHF_SHIELDREGEN)
 402                 vehicles_regen(this, this.dmg_time, vehicle_shield, autocvar_g_vehicle_bumblebee_shield, autocvar_g_vehicle_bumblebee_shield_regen_pause, autocvar_g_vehicle_bumblebee_shield_regen, frametime, true);
 403
 404         if(this.vehicle_flags  & VHF_HEALTHREGEN)
 405                 vehicles_regen(this, this.dmg_time, vehicle_health, autocvar_g_vehicle_bumblebee_health, autocvar_g_vehicle_bumblebee_health_regen_pause, autocvar_g_vehicle_bumblebee_health_regen, frametime, false);
 406
 407         if(this.vehicle_flags  & VHF_ENERGYREGEN)
 408                 vehicles_regen(this, this.wait, vehicle_energy, autocvar_g_vehicle_bumblebee_energy, autocvar_g_vehicle_bumblebee_energy_regen_pause, autocvar_g_vehicle_bumblebee_energy_regen, frametime, false);
 409
 410 }
 411
 412 bool bumblebee_pilot_frame(entity this)
 413 {
 414         entity vehic = this.vehicle;
 415         return = true;
 416
 417         if(intermission_running)
 418         {
 419                 vehic.velocity = '0 0 0';
 420                 vehic.avelocity = '0 0 0';
 421                 return;
 422         }
 423
 424         vehicles_frame(vehic, this);
 425
 426         if(IS_DEAD(vehic))
 427         {
 428                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 429                 return;
 430         }
 431
 432         bumblebee_regen(vehic);
 433
 434         crosshair_trace(this);
 435
 436         vector vang = vehic.angles;
 437         vector newvel = vectoangles(normalize(trace_endpos - vehic.origin + '0 0 32'));
 438         vang.x *= -1;
 439         newvel.x *= -1;
 440         if(newvel.x > 180)  newvel.x -= 360;
 441         if(newvel.x < -180) newvel.x += 360;
 442         if(newvel.y > 180)  newvel.y -= 360;
 443         if(newvel.y < -180) newvel.y += 360;
 444
 445         float ftmp = shortangle_f(this.v_angle.y - vang.y, vang.y);
 446         if(ftmp > 180)  ftmp -= 360;
 447         if(ftmp < -180) ftmp += 360;
 448         vehic.avelocity_y = bound(-autocvar_g_vehicle_bumblebee_turnspeed, ftmp + vehic.avelocity.y * 0.9, autocvar_g_vehicle_bumblebee_turnspeed);
 449
 450         // Pitch
 451         ftmp = 0;
 452         if(this.movement.x > 0 && vang.x < autocvar_g_vehicle_bumblebee_pitchlimit)
 453                 ftmp = 4;
 454         else if(this.movement.x < 0 && vang.x > -autocvar_g_vehicle_bumblebee_pitchlimit)
 455                 ftmp = -8;
 456
 457         newvel.x = bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel.x , autocvar_g_vehicle_bumblebee_pitchlimit);
 458         ftmp = vang.x - bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel.x + ftmp, autocvar_g_vehicle_bumblebee_pitchlimit);
 459         vehic.avelocity_x = bound(-autocvar_g_vehicle_bumblebee_pitchspeed, ftmp + vehic.avelocity.x * 0.9, autocvar_g_vehicle_bumblebee_pitchspeed);
 460
 461         vehic.angles_x = anglemods(vehic.angles.x);
 462         vehic.angles_y = anglemods(vehic.angles.y);
 463         vehic.angles_z = anglemods(vehic.angles.z);
 464
 465         makevectors('0 1 0' * vehic.angles.y);
 466         newvel = vehic.velocity * -autocvar_g_vehicle_bumblebee_friction;
 467
 468         if(this.movement.x != 0)
 469         {
 470                 if(this.movement.x > 0)
 471                         newvel += v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 472                 else if(this.movement.x < 0)
 473                         newvel -= v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 474         }
 475
 476         if(this.movement.y != 0)
 477         {
 478                 if(this.movement.y < 0)
 479                         newvel -= v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 480                 else if(this.movement.y > 0)
 481                         newvel += v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 482                 ftmp = newvel * v_right;
 483                 ftmp *= frametime * 0.1;
 484                 vehic.angles_z = bound(-15, vehic.angles.z + ftmp, 15);
 485         }
 486         else
 487         {
 488                 vehic.angles_z *= 0.95;
 489                 if(vehic.angles.z >= -1 && vehic.angles.z <= -1)
 490                         vehic.angles_z = 0;
 491         }
 492
 493         if(PHYS_INPUT_BUTTON_CROUCH(this))
 494                 newvel -=   v_up * autocvar_g_vehicle_bumblebee_speed_down;
 495         else if(PHYS_INPUT_BUTTON_JUMP(this))
 496                 newvel +=  v_up * autocvar_g_vehicle_bumblebee_speed_up;
 497
 498         vehic.velocity  += newvel * frametime;
 499         this.velocity = this.movement  = vehic.velocity;
 500
 501
 502         if(autocvar_g_vehicle_bumblebee_healgun_locktime)
 503         {
 504                 if(vehic.tur_head.lock_time < time || IS_DEAD(vehic.tur_head.enemy) || STAT(FROZEN, vehic.tur_head.enemy))
 505                         vehic.tur_head.enemy = world;
 506
 507                 if(trace_ent)
 508                 if(trace_ent.movetype)
 509                 if(trace_ent.takedamage)
 510                 if(!IS_DEAD(trace_ent) && !STAT(FROZEN, trace_ent))
 511                 {
 512                         if(teamplay)
 513                         {
 514                                 if(trace_ent.team == this.team)
 515                                 {
 516                                         vehic.tur_head.enemy = trace_ent;
 517                                         vehic.tur_head.lock_time = time + autocvar_g_vehicle_bumblebee_healgun_locktime;
 518                                 }
 519                         }
 520                         else
 521                         {
 522                                 vehic.tur_head.enemy = trace_ent;
 523                                 vehic.tur_head.lock_time = time + autocvar_g_vehicle_bumblebee_healgun_locktime;
 524                         }
 525                 }
 526
 527                 if(vehic.tur_head.enemy)
 528                 {
 529                         trace_endpos = real_origin(vehic.tur_head.enemy);
 530                         UpdateAuxiliaryXhair(this, trace_endpos, '0 0.75 0', 0);
 531                 }
 532         }
 533
 534         vang = vehicle_aimturret(vehic, trace_endpos, vehic.gun3, "fire",
 535                                           autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down * -1,  autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up,
 536                                           autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides * -1,  autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides,  autocvar_g_vehicle_bumblebee_raygun_turnspeed);
 537
 538         if(!forbidWeaponUse(this))
 539         if((PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) && (vehic.vehicle_energy > autocvar_g_vehicle_bumblebee_raygun_dps * sys_frametime || autocvar_g_vehicle_bumblebee_raygun == 0))
 540         {
 541                 vehic.gun3.enemy.realowner = this;
 542                 vehic.gun3.enemy.effects &= ~EF_NODRAW;
 543
 544                 vehic.gun3.enemy.hook_start = gettaginfo(vehic.gun3, gettagindex(vehic.gun3, "fire"));
 545                 vehic.gun3.enemy.SendFlags |= BRG_START;
 546
 547                 traceline(vehic.gun3.enemy.hook_start, vehic.gun3.enemy.hook_start + v_forward * autocvar_g_vehicle_bumblebee_raygun_range, MOVE_NORMAL, vehic);
 548
 549                 if(trace_ent)
 550                 {
 551                         if(autocvar_g_vehicle_bumblebee_raygun)
 552                         {
 553                                 Damage(trace_ent, vehic, this, autocvar_g_vehicle_bumblebee_raygun_dps * sys_frametime, DEATH_GENERIC.m_id, trace_endpos, v_forward * autocvar_g_vehicle_bumblebee_raygun_fps * sys_frametime);
 554                                 vehic.vehicle_energy -= autocvar_g_vehicle_bumblebee_raygun_aps * sys_frametime;
 555                         }
 556                         else
 557                         {
 558                                 if(!IS_DEAD(trace_ent))
 559                                         if((teamplay && trace_ent.team == this.team) || !teamplay)
 560                                         {
 561
 562                                                 if(trace_ent.vehicle_flags & VHF_ISVEHICLE)
 563                                                 {
 564                                                         if(autocvar_g_vehicle_bumblebee_healgun_sps && trace_ent.vehicle_health <= trace_ent.max_health)
 565                                                                 trace_ent.vehicle_shield = min(trace_ent.vehicle_shield + autocvar_g_vehicle_bumblebee_healgun_sps * frametime, trace_ent.tur_head.max_health);
 566
 567                                                         if(autocvar_g_vehicle_bumblebee_healgun_hps)
 568                                                                 trace_ent.vehicle_health = min(trace_ent.vehicle_health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, trace_ent.max_health);
 569                                                 }
 570                                                 else if(IS_CLIENT(trace_ent))
 571                                                 {
 572                                                         if(trace_ent.health <= autocvar_g_vehicle_bumblebee_healgun_hmax && autocvar_g_vehicle_bumblebee_healgun_hps)
 573                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, autocvar_g_vehicle_bumblebee_healgun_hmax);
 574
 575                                                         if(trace_ent.armorvalue <= autocvar_g_vehicle_bumblebee_healgun_amax && autocvar_g_vehicle_bumblebee_healgun_aps)
 576                                                                 trace_ent.armorvalue = min(trace_ent.armorvalue + autocvar_g_vehicle_bumblebee_healgun_aps * frametime, autocvar_g_vehicle_bumblebee_healgun_amax);
 577
 578                                                         trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, autocvar_g_vehicle_bumblebee_healgun_hmax);
 579                                                 }
 580                                                 else if(IS_TURRET(trace_ent))
 581                                                 {
 582                                                         if(trace_ent.health  <= trace_ent.max_health && autocvar_g_vehicle_bumblebee_healgun_hps)
 583                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, trace_ent.max_health);
 584                                                         //else ..hmmm what? ammo?
 585
 586                                                         trace_ent.SendFlags |= TNSF_STATUS;
 587                                                 }
 588                                         }
 589                         }
 590                 }
 591
 592                 vehic.gun3.enemy.hook_end = trace_endpos;
 593                 setorigin(vehic.gun3.enemy, trace_endpos);
 594                 vehic.gun3.enemy.SendFlags |= BRG_END;
 595
 596                 vehic.wait = time + 1;
 597         }
 598         else
 599                 vehic.gun3.enemy.effects |= EF_NODRAW;
 600         /*{
 601                 if(vehic.gun3.enemy)
 602                         remove(vehic.gun3.enemy);
 603
 604                 vehic.gun3.enemy = world;
 605         }
 606         */
 607
 608         VEHICLE_UPDATE_PLAYER(this, vehic, health, bumblebee);
 609         VEHICLE_UPDATE_PLAYER(this, vehic, energy, bumblebee);
 610
 611         this.vehicle_ammo1 = (vehic.gun1.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 612         this.vehicle_ammo2 = (vehic.gun2.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 613
 614         if(vehic.vehicle_flags & VHF_HASSHIELD)
 615                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, bumblebee);
 616
 617         vehic.angles_x *= -1;
 618         makevectors(vehic.angles);
 619         vehic.angles_x *= -1;
 620         setorigin(this, vehic.origin + v_up * 48 + v_forward * 160);
 621
 622         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 623 }
 624
 625 void bumblebee_land()
 626 {SELFPARAM();
 627         float hgt;
 628
 629         hgt = raptor_altitude(512);
 630         self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
 631         self.angles_x *= 0.95;
 632         self.angles_z *= 0.95;
 633
 634         if(hgt < 16)
 635                 self.think      = vehicles_think;
 636
 637         self.nextthink = time;
 638
 639         CSQCMODEL_AUTOUPDATE(self);
 640 }
 641
 642 void bumblebee_exit(float eject)
 643 {SELFPARAM();
 644         if(self.owner.vehicleid == VEH_BUMBLEBEE.vehicleid)
 645         {
 646                 bumblebee_gunner_exit(eject);
 647                 return;
 648         }
 649
 650         self.touch = vehicles_touch;
 651
 652         if(!IS_DEAD(self))
 653         {
 654                 self.think = bumblebee_land;
 655                 self.nextthink  = time;
 656         }
 657
 658         self.movetype = MOVETYPE_TOSS;
 659
 660         if(!self.owner)
 661                 return;
 662
 663         fixedmakevectors(self.angles);
 664         vector spot;
 665         if(vdist(self.velocity, >, autocvar_g_vehicle_bumblebee_speed_forward * 0.5))
 666                 spot = self.origin + v_up * 128 + v_forward * 300;
 667         else
 668                 spot = self.origin + v_up * 128 - v_forward * 300;
 669
 670         spot = vehicles_findgoodexit(spot);
 671
 672         // Hide beam
 673         if(self.gun3.enemy || !wasfreed(self.gun3.enemy)) {
 674                 self.gun3.enemy.effects |= EF_NODRAW;
 675         }
 676
 677         self.owner.velocity = 0.75 * self.vehicle.velocity + normalize(spot - self.vehicle.origin) * 200;
 678         self.owner.velocity_z += 10;
 679         setorigin(self.owner, spot);
 680
 681         antilag_clear(self.owner, CS(self.owner));
 682         self.owner = world;
 683 }
 684
 685 void bumblebee_blowup()
 686 {SELFPARAM();
 687         RadiusDamage(self, self.enemy, autocvar_g_vehicle_bumblebee_blowup_coredamage,
 688                                  autocvar_g_vehicle_bumblebee_blowup_edgedamage,
 689                                  autocvar_g_vehicle_bumblebee_blowup_radius, self, world,
 690                                  autocvar_g_vehicle_bumblebee_blowup_forceintensity,
 691                                  DEATH_VH_BUMB_DEATH.m_id, world);
 692
 693         sound(self, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 694         Send_Effect(EFFECT_EXPLOSION_BIG, (self.origin + '0 0 100') + (randomvec() * 80), '0 0 0', 1);
 695
 696         if(self.owner.deadflag == DEAD_DYING)
 697                 self.owner.deadflag = DEAD_DEAD;
 698
 699         remove(self);
 700 }
 701
 702 void bumblebee_diethink()
 703 {SELFPARAM();
 704         if(time >= self.wait)
 705                 self.think = bumblebee_blowup;
 706
 707         if(random() < 0.1)
 708         {
 709                 sound(self, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 710                 Send_Effect(EFFECT_EXPLOSION_SMALL, randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 711         }
 712
 713         self.nextthink = time + 0.1;
 714 }
 715
 716 spawnfunc(vehicle_bumblebee)
 717 {
 718         if(!autocvar_g_vehicle_bumblebee) { remove(self); return; }
 719         if(!vehicle_initialize(VEH_BUMBLEBEE, false)) { remove(self); return; }
 720 }
 721
 722 METHOD(Bumblebee, vr_impact, void(Bumblebee thisveh, entity instance))
 723 {
 724     if(autocvar_g_vehicle_bumblebee_bouncepain)
 725         vehicles_impact(autocvar_g_vehicle_bumblebee_bouncepain_x, autocvar_g_vehicle_bumblebee_bouncepain_y, autocvar_g_vehicle_bumblebee_bouncepain_z);
 726 }
 727 METHOD(Bumblebee, vr_enter, void(Bumblebee thisveh, entity instance))
 728 {
 729     SELFPARAM();
 730     self.touch = bumblebee_touch;
 731     self.nextthink = 0;
 732     self.movetype = MOVETYPE_BOUNCEMISSILE;
 733 }
 734 METHOD(Bumblebee, vr_think, void(Bumblebee thisveh, entity instance))
 735 {
 736     SELFPARAM();
 737     self.angles_z *= 0.8;
 738     self.angles_x *= 0.8;
 739
 740     self.nextthink = time;
 741
 742     if(!self.owner)
 743     {
 744         entity oldself = self;
 745         if(self.gunner1)
 746         {
 747             setself(self.gunner1);
 748             oldself.gun1.vehicle_exit(VHEF_EJECT);
 749             entity oldother = other;
 750             other = self;
 751             setself(oldself);
 752             self.phase = 0;
 753             self.touch();
 754             other = oldother;
 755             return;
 756         }
 757
 758         if(self.gunner2)
 759         {
 760             setself(self.gunner2);
 761             oldself.gun2.vehicle_exit(VHEF_EJECT);
 762             entity oldother = other;
 763             other = self;
 764             setself(oldself);
 765             self.phase = 0;
 766             self.touch();
 767             other = oldother;
 768             return;
 769         }
 770     }
 771 }
 772 METHOD(Bumblebee, vr_death, void(Bumblebee thisveh, entity instance))
 773 {
 774     SELFPARAM();
 775     entity oldself = self;
 776     setself(instance);
 777
 778     CSQCModel_UnlinkEntity(self);
 779
 780     // Hide beam
 781     if(self.gun3.enemy || !wasfreed(self.gun3.enemy))
 782         self.gun3.enemy.effects |= EF_NODRAW;
 783
 784     if(self.gunner1)
 785     {
 786         setself(self.gunner1);
 787         oldself.gun1.vehicle_exit(VHEF_EJECT);
 788         setself(oldself);
 789     }
 790
 791     if(self.gunner2)
 792     {
 793         setself(self.gunner2);
 794         oldself.gun2.vehicle_exit(VHEF_EJECT);
 795         setself(oldself);
 796     }
 797
 798     self.vehicle_exit(VHEF_EJECT);
 799
 800     fixedmakevectors(self.angles);
 801     vehicle_tossgib(self.gun1, self.velocity + v_right * 300 + v_up * 100 + randomvec() * 200, "cannon_right", rint(random()), rint(random()), 6, randomvec() * 200);
 802     vehicle_tossgib(self.gun2, self.velocity + v_right * -300 + v_up * 100 + randomvec() * 200, "cannon_left", rint(random()), rint(random()), 6, randomvec() * 200);
 803     vehicle_tossgib(self.gun3, self.velocity + v_forward * 300 + v_up * -100 + randomvec() * 200, "raygun", rint(random()), rint(random()), 6, randomvec() * 300);
 804
 805     entity _body = vehicle_tossgib(self, self.velocity + randomvec() * 200, "", rint(random()), rint(random()), 6, randomvec() * 100);
 806
 807     if(random() > 0.5)
 808         _body.touch = bumblebee_blowup;
 809     else
 810         _body.touch = func_null;
 811
 812     _body.think = bumblebee_diethink;
 813     _body.nextthink = time;
 814     _body.wait = time + 2 + (random() * 8);
 815     _body.owner = self;
 816     _body.enemy = self.enemy;
 817     _body.scale = 1.5;
 818     _body.angles = self.angles;
 819
 820     Send_Effect(EFFECT_EXPLOSION_MEDIUM, findbetterlocation(self.origin, 16), '0 0 0', 1);
 821
 822     self.health                 = 0;
 823     self.event_damage   = func_null;
 824     self.solid                  = SOLID_NOT;
 825     self.takedamage             = DAMAGE_NO;
 826     self.deadflag               = DEAD_DYING;
 827     self.movetype               = MOVETYPE_NONE;
 828     self.effects                = EF_NODRAW;
 829     self.colormod               = '0 0 0';
 830     self.avelocity              = '0 0 0';
 831     self.velocity               = '0 0 0';
 832     self.touch                  = func_null;
 833     self.nextthink              = 0;
 834
 835     setorigin(self, self.pos1);
 836
 837     setself(oldself);
 838 }
 839 METHOD(Bumblebee, vr_spawn, void(Bumblebee thisveh, entity instance))
 840 {
 841     SELFPARAM();
 842     if(!self.gun1)
 843     {
 844         // for some reason, autosizing of the shield entity refuses to work for this one so set it up in advance.
 845         self.vehicle_shieldent = spawn();
 846         self.vehicle_shieldent.effects = EF_LOWPRECISION;
 847         setmodel(self.vehicle_shieldent, MDL_VEH_BUMBLEBEE_SHIELD);
 848         setattachment(self.vehicle_shieldent, self, "");
 849         setorigin(self.vehicle_shieldent, real_origin(self) - self.origin);
 850         self.vehicle_shieldent.scale       = 512 / vlen(self.maxs - self.mins);
 851         self.vehicle_shieldent.think       = shieldhit_think;
 852         self.vehicle_shieldent.alpha = -1;
 853         self.vehicle_shieldent.effects = EF_LOWPRECISION | EF_NODRAW;
 854
 855         self.gun1 = new(vehicle_playerslot);
 856         self.gun2 = new(vehicle_playerslot);
 857         self.gun3 = new(bumblebee_raygun);
 858
 859         self.vehicle_flags |= VHF_MULTISLOT;
 860
 861         self.gun1.owner = self;
 862         self.gun2.owner = self;
 863         self.gun3.owner = self;
 864
 865         setmodel(self.gun1, MDL_VEH_BUMBLEBEE_CANNON_RIGHT);
 866         setmodel(self.gun2, MDL_VEH_BUMBLEBEE_CANNON_LEFT);
 867         setmodel(self.gun3, MDL_VEH_BUMBLEBEE_CANNON_CENTER);
 868
 869         setattachment(self.gun1, self, "cannon_right");
 870         setattachment(self.gun2, self, "cannon_left");
 871
 872         // Angled bones are no fun, messes up gun-aim; so work arround it.
 873         self.gun3.pos1 = self.angles;
 874         self.angles = '0 0 0';
 875         vector ofs = gettaginfo(self, gettagindex(self, "raygun"));
 876         ofs -= self.origin;
 877         setattachment(self.gun3, self, "");
 878         setorigin(self.gun3, ofs);
 879         self.angles = self.gun3.pos1;
 880
 881         vehicle_addplayerslot(self, self.gun1, HUD_BUMBLEBEE_GUN, "models/vehicles/wakizashi_cockpit.dpm", bumblebee_gunner_frame, bumblebee_gunner_exit, bumblebee_gunner_enter);
 882         vehicle_addplayerslot(self, self.gun2, HUD_BUMBLEBEE_GUN, "models/vehicles/wakizashi_cockpit.dpm", bumblebee_gunner_frame, bumblebee_gunner_exit, bumblebee_gunner_enter);
 883
 884         setorigin(self.vehicle_hudmodel, '50 0 -5');    // Move cockpit forward - down.
 885         setorigin(self.vehicle_viewport, '5 0 2');    // Move camera forward up
 886
 887         //fixme-model-bones
 888         setorigin(self.gun1.vehicle_hudmodel, '90 -27 -23');
 889         setorigin(self.gun1.vehicle_viewport, '-85 0 50');
 890         //fixme-model-bones
 891         setorigin(self.gun2.vehicle_hudmodel, '90 27 -23');
 892         setorigin(self.gun2.vehicle_viewport, '-85 0 50');
 893
 894         self.scale = 1.5;
 895
 896         // Raygun beam
 897         if(self.gun3.enemy == world)
 898         {
 899             self.gun3.enemy = spawn();
 900             Net_LinkEntity(self.gun3.enemy, true, 0, bumble_raygun_send);
 901             self.gun3.enemy.SendFlags = BRG_SETUP;
 902             self.gun3.enemy.cnt = autocvar_g_vehicle_bumblebee_raygun;
 903             self.gun3.enemy.effects = EF_NODRAW | EF_LOWPRECISION;
 904         }
 905     }
 906
 907     self.vehicle_health = autocvar_g_vehicle_bumblebee_health;
 908     self.vehicle_shield = autocvar_g_vehicle_bumblebee_shield;
 909     self.solid = SOLID_BBOX;
 910     self.movetype = MOVETYPE_TOSS;
 911     self.damageforcescale = 0.025;
 912
 913     self.PlayerPhysplug = bumblebee_pilot_frame;
 914
 915     setorigin(self, self.origin + '0 0 25');
 916 }
 917 METHOD(Bumblebee, vr_setup, void(Bumblebee thisveh, entity instance))
 918 {
 919     SELFPARAM();
 920     if(autocvar_g_vehicle_bumblebee_energy)
 921     if(autocvar_g_vehicle_bumblebee_energy_regen)
 922         self.vehicle_flags |= VHF_ENERGYREGEN;
 923
 924     if(autocvar_g_vehicle_bumblebee_shield)
 925         self.vehicle_flags |= VHF_HASSHIELD;
 926
 927     if(autocvar_g_vehicle_bumblebee_shield_regen)
 928         self.vehicle_flags |= VHF_SHIELDREGEN;
 929
 930     if(autocvar_g_vehicle_bumblebee_health_regen)
 931         self.vehicle_flags |= VHF_HEALTHREGEN;
 932
 933     self.vehicle_exit = bumblebee_exit;
 934     self.respawntime = autocvar_g_vehicle_bumblebee_respawntime;
 935     self.vehicle_health = autocvar_g_vehicle_bumblebee_health;
 936     self.max_health = self.vehicle_health;
 937     self.vehicle_shield = autocvar_g_vehicle_bumblebee_shield;
 938 }
 939
 940 #endif // SVQC
 941 #ifdef CSQC
 942
 943 void CSQC_BUMBLE_GUN_HUD()
 944 {
 945         Vehicles_drawHUD("vehicle_gunner", "vehicle_gunner_weapon1", string_null,
 946                                          "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 947                                          string_null, '0 0 0');
 948 }
 949
 950 METHOD(Bumblebee, vr_hud, void(Bumblebee thisveh))
 951 {
 952     Vehicles_drawHUD(VEH_BUMBLEBEE.m_icon, "vehicle_bumble_weapon1", "vehicle_bumble_weapon2",
 953                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 954                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color);
 955
 956     float hudAlpha = autocvar_hud_panel_fg_alpha;
 957     float blinkValue = 0.55 + sin(time * 7) * 0.45;
 958     vector tmpPos  = '0 0 0';
 959     vector tmpSize = '1 1 1' * hud_fontsize;
 960     tmpPos.x = vehicleHud_Pos.x + vehicleHud_Size.x * (520/768);
 961
 962     if(!AuxiliaryXhair[1].draw2d)
 963     {
 964         tmpPos.y = vehicleHud_Pos.y + vehicleHud_Size.y * (96/256) - tmpSize.y;
 965         drawstring(tmpPos, _("No right gunner!"), tmpSize, '1 1 1', hudAlpha * blinkValue, DRAWFLAG_NORMAL);
 966     }
 967
 968     if(!AuxiliaryXhair[2].draw2d)
 969     {
 970         tmpPos.y = vehicleHud_Pos.y + vehicleHud_Size.y * (160/256);
 971         drawstring(tmpPos, _("No left gunner!"), tmpSize, '1 1 1', hudAlpha * blinkValue, DRAWFLAG_NORMAL);
 972     }
 973 }
 974 METHOD(Bumblebee, vr_crosshair, void(Bumblebee thisveh))
 975 {
 976     Vehicles_drawCrosshair(vCROSS_HEAL);
 977 }
 978 METHOD(Bumblebee, vr_setup, void(Bumblebee thisveh, entity instance))
 979 {
 980     AuxiliaryXhair[0].axh_image = vCROSS_LOCK;  // Raygun-locked
 981     AuxiliaryXhair[1].axh_image = vCROSS_BURST; // Gunner1
 982     AuxiliaryXhair[2].axh_image = vCROSS_BURST; // Gunner2
 983 }
 984
 985 #endif
 986 #endif