qcsrc/common/vehicles/vehicle/racer.qc

   1 #ifndef VEHICLE_RACER
   2 #define VEHICLE_RACER
   3
   4 CLASS(Racer, Vehicle)
   5 /* spawnflags */ ATTRIB(Racer, spawnflags, int, VHF_DMGSHAKE | VHF_DMGROLL);
   6 /* mins       */ ATTRIB(Racer, mins, vector, '-120 -120 -40' * 0.5);
   7 /* maxs       */ ATTRIB(Racer, maxs, vector, '120 120 40' * 0.5);
   8 /* model          */ ATTRIB(Racer, mdl, string, "models/vehicles/wakizashi.dpm");
   9 /* model          */ ATTRIB(Racer, model, string, "models/vehicles/wakizashi.dpm");
  10 /* head_model */ ATTRIB(Racer, head_model, string, "null");
  11 /* hud_model  */ ATTRIB(Racer, hud_model, string, "models/vehicles/wakizashi_cockpit.dpm");
  12 /* tags       */ ATTRIB(Racer, tag_head, string, "");
  13 /* tags       */ ATTRIB(Racer, tag_hud, string, "");
  14 /* tags       */ ATTRIB(Racer, tag_hview, string, "tag_viewport");
  15 /* netname    */ ATTRIB(Racer, netname, string, "racer");
  16 /* fullname   */ ATTRIB(Racer, vehicle_name, string, _("Racer"));
  17 /* icon       */ ATTRIB(Racer, m_icon, string, "vehicle_racer");
  18 ENDCLASS(Racer)
  19
  20 REGISTER_VEHICLE(RACER, NEW(Racer));
  21
  22 #include "../../weapons/all.qh"
  23
  24 CLASS(RacerAttack, PortoLaunch)
  25 /* flags     */ ATTRIB(RacerAttack, spawnflags, int, WEP_TYPE_OTHER);
  26 /* impulse   */ ATTRIB(RacerAttack, impulse, int, 3);
  27 /* refname   */ ATTRIB(RacerAttack, netname, string, "racercannon");
  28 /* wepname   */ ATTRIB(RacerAttack, message, string, _("Racer cannon"));
  29 ENDCLASS(RacerAttack)
  30 REGISTER_WEAPON(RACER, NEW(RacerAttack));
  31
  32 #endif
  33
  34 #ifdef IMPLEMENTATION
  35 #ifdef SVQC
  36 #include "../../effects/effects.qh"
  37 #include "../../triggers/trigger/impulse.qh"
  38
  39 void racer_fire_cannon(string tagname);
  40 METHOD(RacerAttack, wr_think, bool(entity thiswep, bool fire1, bool fire2)) {
  41         SELFPARAM();
  42         if (fire1)
  43         if (weapon_prepareattack(0, 0)) {
  44                 W_SetupShot_Dir(self, v_forward, false, 0, W_Sound("lasergun_fire"), CH_WEAPON_B, 0);
  45                 racer_fire_cannon("tag_fire1");
  46                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(machinegun, sustained_refire), w_ready);
  47         }
  48         return true;
  49 }
  50
  51 bool autocvar_g_vehicle_racer;
  52
  53 float autocvar_g_vehicle_racer_speed_afterburn;
  54 float autocvar_g_vehicle_racer_afterburn_cost;
  55
  56 float autocvar_g_vehicle_racer_waterburn_cost;
  57 float autocvar_g_vehicle_racer_waterburn_speed;
  58
  59 float autocvar_g_vehicle_racer_water_speed_forward;
  60 float autocvar_g_vehicle_racer_water_speed_strafe;
  61
  62 float autocvar_g_vehicle_racer_pitchlimit = 30;
  63
  64 float autocvar_g_vehicle_racer_water_downforce = 0.03;
  65 float autocvar_g_vehicle_racer_water_upforcedamper = 15;
  66
  67 float autocvar_g_vehicle_racer_anglestabilizer;
  68 float autocvar_g_vehicle_racer_downforce;
  69
  70 float autocvar_g_vehicle_racer_speed_forward;
  71 float autocvar_g_vehicle_racer_speed_strafe;
  72 float autocvar_g_vehicle_racer_springlength;
  73 float autocvar_g_vehicle_racer_upforcedamper;
  74 float autocvar_g_vehicle_racer_friction;
  75
  76 float autocvar_g_vehicle_racer_water_time = 5;
  77
  78 float autocvar_g_vehicle_racer_hovertype;
  79 float autocvar_g_vehicle_racer_hoverpower;
  80
  81 float autocvar_g_vehicle_racer_turnroll;
  82 float autocvar_g_vehicle_racer_turnspeed;
  83 float autocvar_g_vehicle_racer_pitchspeed;
  84
  85 float autocvar_g_vehicle_racer_energy;
  86 float autocvar_g_vehicle_racer_energy_regen;
  87 float autocvar_g_vehicle_racer_energy_regen_pause;
  88
  89 float autocvar_g_vehicle_racer_health;
  90 float autocvar_g_vehicle_racer_health_regen;
  91 float autocvar_g_vehicle_racer_health_regen_pause;
  92
  93 float autocvar_g_vehicle_racer_shield;
  94 float autocvar_g_vehicle_racer_shield_regen;
  95 float autocvar_g_vehicle_racer_shield_regen_pause;
  96
  97 float autocvar_g_vehicle_racer_cannon_cost;
  98 float autocvar_g_vehicle_racer_cannon_damage;
  99 float autocvar_g_vehicle_racer_cannon_radius;
 100 float autocvar_g_vehicle_racer_cannon_refire;
 101 float autocvar_g_vehicle_racer_cannon_speed;
 102 float autocvar_g_vehicle_racer_cannon_spread;
 103 float autocvar_g_vehicle_racer_cannon_force;
 104
 105 float autocvar_g_vehicle_racer_rocket_accel;
 106 float autocvar_g_vehicle_racer_rocket_damage;
 107 float autocvar_g_vehicle_racer_rocket_radius;
 108 float autocvar_g_vehicle_racer_rocket_force;
 109 float autocvar_g_vehicle_racer_rocket_refire;
 110 float autocvar_g_vehicle_racer_rocket_speed;
 111 float autocvar_g_vehicle_racer_rocket_turnrate;
 112
 113 float autocvar_g_vehicle_racer_rocket_locktarget;
 114 float autocvar_g_vehicle_racer_rocket_locking_time;
 115 float autocvar_g_vehicle_racer_rocket_locking_releasetime;
 116 float autocvar_g_vehicle_racer_rocket_locked_time;
 117 float autocvar_g_vehicle_racer_rocket_locked_maxangle;
 118 float autocvar_g_vehicle_racer_rocket_climbspeed;
 119
 120 float autocvar_g_vehicle_racer_respawntime;
 121
 122 float autocvar_g_vehicle_racer_blowup_radius;
 123 float autocvar_g_vehicle_racer_blowup_coredamage;
 124 float autocvar_g_vehicle_racer_blowup_edgedamage;
 125 float autocvar_g_vehicle_racer_blowup_forceintensity;
 126
 127 float autocvar_g_vehicle_racer_bouncefactor;
 128 float autocvar_g_vehicle_racer_bouncestop;
 129 vector autocvar_g_vehicle_racer_bouncepain;
 130
 131 .float racer_watertime;
 132
 133 var vector racer_force_from_tag(string tag_name, float spring_length, float max_power);
 134
 135 void racer_align4point(float _delta)
 136 {SELFPARAM();
 137         vector push_vector;
 138         float fl_push, fr_push, bl_push, br_push;
 139
 140         push_vector  = racer_force_from_tag("tag_engine_fr", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 141         fr_push   = force_fromtag_normpower;
 142         //vehicles_sweap_collision(force_fromtag_origin, self.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 143
 144         push_vector += racer_force_from_tag("tag_engine_fl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 145         fl_push   = force_fromtag_normpower;
 146         //vehicles_sweap_collision(force_fromtag_origin, self.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 147
 148         push_vector += racer_force_from_tag("tag_engine_br", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 149         br_push   = force_fromtag_normpower;
 150         //vehicles_sweap_collision(force_fromtag_origin, self.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 151
 152         push_vector += racer_force_from_tag("tag_engine_bl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 153         bl_push   = force_fromtag_normpower;
 154         //vehicles_sweap_collision(force_fromtag_origin, self.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 155
 156         self.velocity += push_vector * _delta;
 157
 158         float uforce = autocvar_g_vehicle_racer_upforcedamper;
 159
 160         int cont = pointcontents(self.origin - '0 0 64');
 161         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 162         {
 163                 uforce = autocvar_g_vehicle_racer_water_upforcedamper;
 164
 165                 if(self.owner.BUTTON_CROUCH && time < self.air_finished)
 166                         self.velocity_z += 30;
 167                 else
 168                         self.velocity_z += 200;
 169         }
 170
 171
 172         // Anti ocilation
 173         if(self.velocity_z > 0)
 174                 self.velocity_z *= 1 - uforce * _delta;
 175
 176         push_vector_x =  (fl_push - bl_push);
 177         push_vector_x += (fr_push - br_push);
 178         push_vector_x *= 360;
 179
 180         push_vector_z = (fr_push - fl_push);
 181         push_vector_z += (br_push - bl_push);
 182         push_vector_z *= 360;
 183
 184         // Apply angle diffrance
 185         self.angles_z += push_vector_z * _delta;
 186         self.angles_x += push_vector_x * _delta;
 187
 188         // Apply stabilizer
 189         self.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * _delta);
 190         self.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * _delta);
 191 }
 192
 193 void racer_fire_cannon(string tagname)
 194 {SELFPARAM();
 195         vector v;
 196         entity bolt;
 197
 198         v = gettaginfo(self, gettagindex(self, tagname));
 199         bolt = vehicles_projectile(EFFECT_RACER_MUZZLEFLASH.eent_eff_name, SND(LASERGUN_FIRE),
 200                                                    v, normalize(v_forward + randomvec() * autocvar_g_vehicle_racer_cannon_spread) * autocvar_g_vehicle_racer_cannon_speed,
 201                                                    autocvar_g_vehicle_racer_cannon_damage, autocvar_g_vehicle_racer_cannon_radius, autocvar_g_vehicle_racer_cannon_force,  0,
 202                                                    DEATH_VH_WAKI_GUN, PROJECTILE_WAKICANNON, 0, true, true, self.owner);
 203
 204         // Fix z-aim (for chase mode)
 205         v = normalize(trace_endpos - bolt.origin);
 206         v_forward_z = v_z * 0.5;
 207         bolt.velocity = v_forward * autocvar_g_vehicle_racer_cannon_speed;
 208 }
 209
 210 void racer_rocket_groundhugger()
 211 {SELFPARAM();
 212         vector olddir, newdir;
 213         float oldvel, newvel;
 214
 215         self.nextthink  = time;
 216
 217         if(self.owner.deadflag != DEAD_NO || self.cnt < time)
 218         {
 219                 self.use();
 220                 return;
 221         }
 222
 223         if(!self.realowner.vehicle)
 224         {
 225                 UpdateCSQCProjectile(self);
 226                 return;
 227         }
 228
 229         olddir = normalize(self.velocity);
 230         oldvel = vlen(self.velocity);
 231         newvel = oldvel + self.lip;
 232
 233         tracebox(self.origin, self.mins, self.maxs, self.origin + olddir * 64, MOVE_WORLDONLY,self);
 234         if(trace_fraction <= 0.5)
 235         {
 236                 // Hitting somethign soon, just speed ahead
 237                 self.velocity = olddir * newvel;
 238                 UpdateCSQCProjectile(self);
 239                 return;
 240         }
 241
 242         traceline(trace_endpos, trace_endpos - '0 0 64', MOVE_NORMAL, self);
 243         if(trace_fraction != 1.0)
 244         {
 245                 newdir = normalize(trace_endpos + '0 0 64' - self.origin) * autocvar_g_vehicle_racer_rocket_turnrate;
 246                 self.velocity = normalize(olddir + newdir) * newvel;
 247         }
 248         else
 249         {
 250                 self.velocity = olddir * newvel;
 251                 self.velocity_z -= 1600 * sys_frametime; // 2x grav looks better for this one
 252         }
 253
 254         int cont = pointcontents(self.origin - '0 0 32');
 255         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 256                 self.velocity_z += 200;
 257
 258         UpdateCSQCProjectile(self);
 259         return;
 260 }
 261
 262 void racer_rocket_tracker()
 263 {SELFPARAM();
 264         vector olddir, newdir;
 265         float oldvel, newvel;
 266
 267         self.nextthink  = time;
 268
 269         if (self.owner.deadflag != DEAD_NO || self.cnt < time)
 270         {
 271                 self.use();
 272                 return;
 273         }
 274
 275         if(!self.realowner.vehicle)
 276         {
 277                 UpdateCSQCProjectile(self);
 278                 return;
 279         }
 280
 281         olddir = normalize(self.velocity);
 282         oldvel = vlen(self.velocity);
 283         newvel = oldvel + self.lip;
 284         makevectors(vectoangles(olddir));
 285
 286         float time_to_impact = min(vlen(self.enemy.origin - self.origin) / vlen(self.velocity), 1);
 287         vector predicted_origin = self.enemy.origin + self.enemy.velocity * time_to_impact;
 288
 289         traceline(self.origin, self.origin + v_forward * 64 - '0 0 32', MOVE_NORMAL, self);
 290         newdir = normalize(predicted_origin - self.origin);
 291
 292         //vector
 293         float height_diff = predicted_origin_z - self.origin_z;
 294
 295         if(vlen(newdir - v_forward) > autocvar_g_vehicle_racer_rocket_locked_maxangle)
 296         {
 297                 //bprint("Target lost!\n");
 298                 //dprint("OF:", ftos(vlen(newdir - v_forward)), "\n");
 299                 self.think = racer_rocket_groundhugger;
 300                 return;
 301         }
 302
 303         if(trace_fraction != 1.0 && trace_ent != self.enemy)
 304                 newdir_z += 16 * sys_frametime;
 305
 306         self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_racer_rocket_turnrate) * newvel;
 307         self.velocity_z -= 800 * sys_frametime;
 308         self.velocity_z += max(height_diff, autocvar_g_vehicle_racer_rocket_climbspeed) * sys_frametime ;
 309
 310         UpdateCSQCProjectile(self);
 311         return;
 312 }
 313
 314 void racer_fire_rocket(string tagname, entity trg)
 315 {SELFPARAM();
 316         vector v = gettaginfo(self, gettagindex(self, tagname));
 317         entity rocket = vehicles_projectile(EFFECT_RACER_ROCKETLAUNCH.eent_eff_name, SND(ROCKET_FIRE),
 318                                                    v, v_forward * autocvar_g_vehicle_racer_rocket_speed,
 319                                                    autocvar_g_vehicle_racer_rocket_damage, autocvar_g_vehicle_racer_rocket_radius, autocvar_g_vehicle_racer_rocket_force, 3,
 320                                                    DEATH_VH_WAKI_ROCKET, PROJECTILE_WAKIROCKET, 20, false, false, self.owner);
 321
 322         rocket.lip                        = autocvar_g_vehicle_racer_rocket_accel * sys_frametime;
 323         rocket.wait                      = autocvar_g_vehicle_racer_rocket_turnrate;
 324         rocket.nextthink                = time;
 325         rocket.enemy                    = trg;
 326         rocket.cnt                        = time + 15;
 327
 328         if(trg)
 329                 rocket.think                    = racer_rocket_tracker;
 330         else
 331                 rocket.think                    = racer_rocket_groundhugger;
 332 }
 333
 334 float racer_frame()
 335 {SELFPARAM();
 336         entity player, racer;
 337         vector df;
 338         float ftmp;
 339
 340         if(intermission_running)
 341         {
 342                 self.vehicle.velocity = '0 0 0';
 343                 self.vehicle.avelocity = '0 0 0';
 344                 return 1;
 345         }
 346
 347         player  = self;
 348         racer   = self.vehicle;
 349         setself(racer);
 350
 351         vehicles_painframe();
 352
 353         if(pointcontents(racer.origin) != CONTENT_WATER)
 354                 racer.air_finished = time + autocvar_g_vehicle_racer_water_time;
 355
 356         if(racer.deadflag != DEAD_NO)
 357         {
 358                 setself(player);
 359                 player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 360                 return 1;
 361         }
 362
 363         racer_align4point(PHYS_INPUT_TIMELENGTH);
 364
 365         player.BUTTON_ZOOM = player.BUTTON_CROUCH = 0;
 366
 367         crosshair_trace(player);
 368
 369         racer.angles_x *= -1;
 370
 371         // Yaw
 372         ftmp = autocvar_g_vehicle_racer_turnspeed * PHYS_INPUT_TIMELENGTH;
 373         ftmp = bound(-ftmp, shortangle_f(player.v_angle_y - racer.angles_y, racer.angles_y), ftmp);
 374         racer.angles_y = anglemods(racer.angles_y + ftmp);
 375
 376         // Roll
 377         racer.angles_z += -ftmp * autocvar_g_vehicle_racer_turnroll * PHYS_INPUT_TIMELENGTH;
 378
 379         // Pitch
 380         ftmp = autocvar_g_vehicle_racer_pitchspeed  * PHYS_INPUT_TIMELENGTH;
 381         ftmp = bound(-ftmp, shortangle_f(player.v_angle_x - racer.angles_x, racer.angles_x), ftmp);
 382         racer.angles_x = bound(-autocvar_g_vehicle_racer_pitchlimit, anglemods(racer.angles_x + ftmp), autocvar_g_vehicle_racer_pitchlimit);
 383
 384         makevectors(racer.angles);
 385         racer.angles_x *= -1;
 386
 387         //ftmp = racer.velocity_z;
 388         df = racer.velocity * -autocvar_g_vehicle_racer_friction;
 389         //racer.velocity_z = ftmp;
 390
 391         int cont = pointcontents(racer.origin);
 392         if(vlen(player.movement) != 0)
 393         {
 394                 if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 395                 {
 396                         if(player.movement_x) { df += v_forward * ((player.movement_x > 0) ? autocvar_g_vehicle_racer_water_speed_forward : -autocvar_g_vehicle_racer_water_speed_forward); }
 397                         if(player.movement_y) { df += v_right * ((player.movement_y > 0) ? autocvar_g_vehicle_racer_water_speed_strafe : -autocvar_g_vehicle_racer_water_speed_strafe); }
 398                 }
 399                 else
 400                 {
 401                         if(player.movement_x) { df += v_forward * ((player.movement_x > 0) ? autocvar_g_vehicle_racer_speed_forward : -autocvar_g_vehicle_racer_speed_forward); }
 402                         if(player.movement_y) { df += v_right * ((player.movement_y > 0) ? autocvar_g_vehicle_racer_speed_strafe : -autocvar_g_vehicle_racer_speed_strafe); }
 403                 }
 404
 405 #ifdef SVQC
 406                 if(self.sound_nexttime < time || self.sounds != 1)
 407                 {
 408                         self.sounds = 1;
 409                         self.sound_nexttime = time + 10.922667; //soundlength("vehicles/racer_move.wav");
 410                         sound (self, CH_TRIGGER_SINGLE, SND_VEH_RACER_MOVE, VOL_VEHICLEENGINE, ATTEN_NORM);
 411                 }
 412 #endif
 413         }
 414 #ifdef SVQC
 415         else
 416         {
 417                 if(self.sound_nexttime < time || self.sounds != 0)
 418                 {
 419                         self.sounds = 0;
 420                         self.sound_nexttime = time + 11.888604; //soundlength("vehicles/racer_idle.wav");
 421                         sound (self, CH_TRIGGER_SINGLE, SND_VEH_RACER_IDLE, VOL_VEHICLEENGINE, ATTEN_NORM);
 422                 }
 423         }
 424 #endif
 425
 426         // Afterburn
 427         if (PHYS_INPUT_BUTTON_JUMP(player) && racer.vehicle_energy >= (autocvar_g_vehicle_racer_afterburn_cost * PHYS_INPUT_TIMELENGTH))
 428         {
 429 #ifdef SVQC
 430                 if(time - racer.wait > 0.2)
 431                         pointparticles(particleeffectnum(EFFECT_RACER_BOOSTER), self.origin - v_forward * 32, v_forward  * vlen(self.velocity), 1);
 432 #endif
 433
 434                 racer.wait = time;
 435
 436                 if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 437                 {
 438                         racer.vehicle_energy -= autocvar_g_vehicle_racer_waterburn_cost * PHYS_INPUT_TIMELENGTH;
 439                         df += (v_forward * autocvar_g_vehicle_racer_waterburn_speed);
 440                 }
 441                 else
 442                 {
 443                         racer.vehicle_energy -= autocvar_g_vehicle_racer_afterburn_cost * PHYS_INPUT_TIMELENGTH;
 444                         df += (v_forward * autocvar_g_vehicle_racer_speed_afterburn);
 445                 }
 446
 447 #ifdef SVQC
 448                 if(racer.invincible_finished < time)
 449                 {
 450                         traceline(racer.origin, racer.origin - '0 0 256', MOVE_NORMAL, self);
 451                         if(trace_fraction != 1.0)
 452                                 pointparticles(particleeffectnum(EFFECT_SMOKE_SMALL), trace_endpos, '0 0 0', 1);
 453
 454                         racer.invincible_finished = time + 0.1 + (random() * 0.1);
 455                 }
 456
 457                 if(racer.strength_finished < time)
 458                 {
 459                         racer.strength_finished = time + 10.922667; //soundlength("vehicles/racer_boost.wav");
 460                         sound (racer.tur_head, CH_TRIGGER_SINGLE, SND_VEH_RACER_BOOST, VOL_VEHICLEENGINE, ATTEN_NORM);
 461                 }
 462 #endif
 463         }
 464         else
 465         {
 466                 racer.strength_finished = 0;
 467                 sound (racer.tur_head, CH_TRIGGER_SINGLE, SND_Null, VOL_VEHICLEENGINE, ATTEN_NORM);
 468         }
 469
 470         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 471                 racer.racer_watertime = time;
 472
 473         float dforce = autocvar_g_vehicle_racer_downforce;
 474         if(time - racer.racer_watertime <= 3)
 475                 dforce = autocvar_g_vehicle_racer_water_downforce;
 476
 477         df -= v_up * (vlen(racer.velocity) * dforce);
 478         player.movement = racer.velocity += df * PHYS_INPUT_TIMELENGTH;
 479
 480 #ifdef SVQC
 481         if(!forbidWeaponUse(player))
 482         if(player.BUTTON_ATCK)
 483         if(time > racer.attack_finished_single)
 484         if(racer.vehicle_energy >= autocvar_g_vehicle_racer_cannon_cost)
 485         {
 486                 racer.vehicle_energy -= autocvar_g_vehicle_racer_cannon_cost;
 487                 racer.wait = time;
 488
 489                 crosshair_trace(player);
 490                 if(racer.cnt)
 491                 {
 492                         racer_fire_cannon("tag_fire1");
 493                         racer.cnt = 0;
 494                 }
 495                 else
 496                 {
 497                         racer_fire_cannon("tag_fire2");
 498                         racer.cnt = 1;
 499                 }
 500                 racer.attack_finished_single = time + autocvar_g_vehicle_racer_cannon_refire;
 501         }
 502
 503         if(autocvar_g_vehicle_racer_rocket_locktarget)
 504         {
 505                 vehicles_locktarget((1 / autocvar_g_vehicle_racer_rocket_locking_time) * frametime,
 506                                                  (1 / autocvar_g_vehicle_racer_rocket_locking_releasetime) * frametime,
 507                                                  autocvar_g_vehicle_racer_rocket_locked_time);
 508
 509                 if(self.lock_target)
 510                 {
 511                         if(racer.lock_strength == 1)
 512                                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '1 0 0', 0);
 513                         else if(self.lock_strength > 0.5)
 514                                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 1 0', 0);
 515                         else if(self.lock_strength < 0.5)
 516                                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 0 1', 0);
 517                 }
 518         }
 519
 520         if(!forbidWeaponUse(player))
 521         if(time > racer.delay)
 522         if(player.BUTTON_ATCK2)
 523         {
 524                 racer.misc_bulletcounter += 1;
 525                 racer.delay = time + 0.3;
 526
 527                 if(racer.misc_bulletcounter == 1)
 528                 {
 529                         racer_fire_rocket("tag_rocket_r", (racer.lock_strength == 1 && racer.lock_target) ? racer.lock_target : world);
 530                         player.vehicle_ammo2 = 50;
 531                 }
 532                 else if(racer.misc_bulletcounter == 2)
 533                 {
 534                         racer_fire_rocket("tag_rocket_l", (racer.lock_strength == 1 && racer.lock_target) ? racer.lock_target : world);
 535                         racer.lock_strength  = 0;
 536                         racer.lock_target       = world;
 537                         racer.misc_bulletcounter = 0;
 538                         racer.delay = time + autocvar_g_vehicle_racer_rocket_refire;
 539                         racer.lip = time;
 540                         player.vehicle_ammo2 = 0;
 541                 }
 542         }
 543         else if(racer.misc_bulletcounter == 0)
 544                 player.vehicle_ammo2 = 100;
 545
 546         player.vehicle_reload2 = bound(0, 100 * ((time - racer.lip) / (racer.delay - racer.lip)), 100);
 547
 548         if(racer.vehicle_flags  & VHF_SHIELDREGEN)
 549                 vehicles_regen(racer.dmg_time, vehicle_shield, autocvar_g_vehicle_racer_shield, autocvar_g_vehicle_racer_shield_regen_pause, autocvar_g_vehicle_racer_shield_regen, frametime, true);
 550
 551         if(racer.vehicle_flags  & VHF_HEALTHREGEN)
 552                 vehicles_regen(racer.dmg_time, vehicle_health, autocvar_g_vehicle_racer_health, autocvar_g_vehicle_racer_health_regen_pause, autocvar_g_vehicle_racer_health_regen, frametime, false);
 553
 554         if(racer.vehicle_flags  & VHF_ENERGYREGEN)
 555                 vehicles_regen(racer.wait, vehicle_energy, autocvar_g_vehicle_racer_energy, autocvar_g_vehicle_racer_energy_regen_pause, autocvar_g_vehicle_racer_energy_regen, frametime, false);
 556
 557
 558         VEHICLE_UPDATE_PLAYER(player, health, racer);
 559         VEHICLE_UPDATE_PLAYER(player, energy, racer);
 560
 561         if(racer.vehicle_flags & VHF_HASSHIELD)
 562                 VEHICLE_UPDATE_PLAYER(player, shield, racer);
 563
 564         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 565 #endif
 566
 567         setorigin(player,racer.origin + '0 0 32');
 568         player.velocity = racer.velocity;
 569
 570         setself(player);
 571         return 1;
 572 }
 573
 574 void racer_think()
 575 {SELFPARAM();
 576         self.nextthink = time;
 577
 578         float pushdeltatime = time - self.lastpushtime;
 579         if (pushdeltatime > 0.15) pushdeltatime = 0;
 580         self.lastpushtime = time;
 581         if(!pushdeltatime) return;
 582
 583         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * autocvar_g_vehicle_racer_springlength), MOVE_NOMONSTERS, self);
 584
 585         vector df = self.velocity * -autocvar_g_vehicle_racer_friction;
 586         df_z += (1 - trace_fraction) * autocvar_g_vehicle_racer_hoverpower + sin(time * 2) * (autocvar_g_vehicle_racer_springlength * 2);
 587
 588         float forced = autocvar_g_vehicle_racer_upforcedamper;
 589
 590         int cont = pointcontents(self.origin - '0 0 64');
 591         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 592         {
 593                 forced = autocvar_g_vehicle_racer_water_upforcedamper;
 594                 self.velocity_z += 200;
 595         }
 596
 597         self.velocity += df * pushdeltatime;
 598         if(self.velocity_z > 0)
 599                 self.velocity_z *= 1 - forced * pushdeltatime;
 600
 601         self.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * pushdeltatime);
 602         self.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * pushdeltatime);
 603
 604         CSQCMODEL_AUTOUPDATE(self);
 605 }
 606
 607 void racer_exit(float eject)
 608 {SELFPARAM();
 609         vector spot;
 610
 611         self.think        = racer_think;
 612         self.nextthink  = time;
 613         self.movetype   = MOVETYPE_BOUNCE;
 614         sound (self.tur_head, CH_TRIGGER_SINGLE, SND_Null, VOL_VEHICLEENGINE, ATTEN_NORM);
 615
 616         if(!self.owner)
 617                 return;
 618
 619         makevectors(self.angles);
 620         if(eject)
 621         {
 622                 spot = self.origin + v_forward * 100 + '0 0 64';
 623                 spot = vehicles_findgoodexit(spot);
 624                 setorigin(self.owner , spot);
 625                 self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 626                 self.owner.oldvelocity = self.owner.velocity;
 627         }
 628         else
 629         {
 630                 if(vlen(self.velocity) > 2 * autocvar_sv_maxairspeed)
 631                 {
 632                         self.owner.velocity = normalize(self.velocity) * autocvar_sv_maxairspeed * 2;
 633                         self.owner.velocity_z += 200;
 634                         spot = self.origin + v_forward * 32 + '0 0 32';
 635                         spot = vehicles_findgoodexit(spot);
 636                 }
 637                 else
 638                 {
 639                         self.owner.velocity = self.velocity * 0.5;
 640                         self.owner.velocity_z += 10;
 641                         spot = self.origin - v_forward * 200 + '0 0 32';
 642                         spot = vehicles_findgoodexit(spot);
 643                 }
 644                 self.owner.oldvelocity = self.owner.velocity;
 645                 setorigin(self.owner , spot);
 646         }
 647         antilag_clear(self.owner);
 648         self.owner = world;
 649 }
 650
 651 void racer_blowup()
 652 {SELFPARAM();
 653         self.deadflag   = DEAD_DEAD;
 654         self.vehicle_exit(VHEF_NORMAL);
 655
 656         RadiusDamage (self, self.enemy, autocvar_g_vehicle_racer_blowup_coredamage,
 657                                         autocvar_g_vehicle_racer_blowup_edgedamage,
 658                                         autocvar_g_vehicle_racer_blowup_radius, world, world,
 659                                         autocvar_g_vehicle_racer_blowup_forceintensity,
 660                                         DEATH_VH_WAKI_DEATH, world);
 661
 662         self.nextthink  = time + autocvar_g_vehicle_racer_respawntime;
 663         self.think        = vehicles_spawn;
 664         self.movetype   = MOVETYPE_NONE;
 665         self.effects    = EF_NODRAW;
 666
 667         self.colormod  = '0 0 0';
 668         self.avelocity = '0 0 0';
 669         self.velocity  = '0 0 0';
 670
 671         setorigin(self, self.pos1);
 672 }
 673
 674 void racer_blowup_think()
 675 {SELFPARAM();
 676         self.nextthink = time;
 677
 678         if(time >= self.delay)
 679                 racer_blowup();
 680
 681         CSQCMODEL_AUTOUPDATE(self);
 682 }
 683
 684 void racer_deadtouch()
 685 {SELFPARAM();
 686         self.avelocity_x *= 0.7;
 687         self.cnt -= 1;
 688         if(self.cnt <= 0)
 689                 racer_blowup();
 690 }
 691
 692 void spawnfunc_vehicle_racer()
 693 {SELFPARAM();
 694         if(!autocvar_g_vehicle_racer) { remove(self); return; }
 695         if(!vehicle_initialize(VEH_RACER, false)) { remove(self); return; }
 696 }
 697
 698 #endif // SVQC
 699
 700 #ifdef CSQC
 701 #if 0
 702 void racer_draw()
 703 {SELFPARAM();
 704         float pushdeltatime = time - self.lastpushtime;
 705         if (pushdeltatime > 0.15) pushdeltatime = 0;
 706         self.lastpushtime = time;
 707         if(!pushdeltatime) return;
 708
 709         tracebox(self.move_origin, self.mins, self.maxs, self.move_origin - ('0 0 1' * getstatf(STAT_VEH_RACER_SPRINGLENGTH)), MOVE_NOMONSTERS, self);
 710
 711         vector df = self.move_velocity * -getstatf(STAT_VEH_RACER_FRICTION);
 712         df_z += (1 - trace_fraction) * getstatf(STAT_VEH_RACER_HOVERPOWER) + sin(time * 2) * (getstatf(STAT_VEH_RACER_SPRINGLENGTH) * 2);
 713
 714         float forced = getstatf(STAT_VEH_RACER_UPFORCEDAMPER);
 715
 716         int cont = pointcontents(self.move_origin - '0 0 64');
 717         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 718         {
 719                 forced = getstatf(STAT_VEH_RACER_WATER_UPFORCEDAMPER);
 720                 self.move_velocity_z += 200;
 721         }
 722
 723         self.move_velocity += df * pushdeltatime;
 724         if(self.move_velocity_z > 0)
 725                 self.move_velocity_z *= 1 - forced * pushdeltatime;
 726
 727         self.move_angles_x *= 1 - (getstatf(STAT_VEH_RACER_ANGLESTABILIZER) * pushdeltatime);
 728         self.move_angles_z *= 1 - (getstatf(STAT_VEH_RACER_ANGLESTABILIZER) * pushdeltatime);
 729
 730         Movetype_Physics_MatchServer(false);
 731 }
 732 #endif
 733 #endif
 734
 735                 METHOD(Racer, vr_impact, bool(Racer thisveh))
 736                 {
 737                 #ifdef SVQC
 738                         if(autocvar_g_vehicle_racer_bouncepain)
 739                                 vehicles_impact(autocvar_g_vehicle_racer_bouncepain_x, autocvar_g_vehicle_racer_bouncepain_y, autocvar_g_vehicle_racer_bouncepain_z);
 740                 #endif
 741                         return true;
 742                 }
 743
 744                 METHOD(Racer, vr_enter, bool(Racer thisveh))
 745                 {
 746                 #ifdef SVQC
 747                         self.movetype = MOVETYPE_BOUNCE;
 748                         self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_racer_health)  * 100;
 749                         self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_racer_shield)  * 100;
 750
 751                         if(self.owner.flagcarried)
 752                            setorigin(self.owner.flagcarried, '-190 0 96');
 753                 #elif defined(CSQC)
 754
 755                         self.move_movetype = MOVETYPE_BOUNCE;
 756                 #endif
 757
 758                         return true;
 759                 }
 760
 761                 METHOD(Racer, vr_spawn, bool(Racer thisveh))
 762                 {
 763                 #ifdef SVQC
 764                         if(self.scale != 0.5)
 765                         {
 766                                 if(autocvar_g_vehicle_racer_hovertype != 0)
 767                                         racer_force_from_tag = vehicles_force_fromtag_maglev;
 768                                 else
 769                                         racer_force_from_tag = vehicles_force_fromtag_hover;
 770
 771                                 // FIXME: this be hakkz, fix the models insted (scale body, add tag_viewport to the hudmodel).
 772                                 self.scale = 0.5;
 773                                 setattachment(self.vehicle_hudmodel, self, "");
 774                                 setattachment(self.vehicle_viewport, self, "tag_viewport");
 775
 776                                 self.mass                          = 900;
 777                         }
 778
 779                         self.think                = racer_think;
 780                         self.nextthink    = time;
 781                         self.vehicle_health = autocvar_g_vehicle_racer_health;
 782                         self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 783
 784                         self.movetype     = MOVETYPE_TOSS;
 785                         self.solid                = SOLID_SLIDEBOX;
 786                         self.delay                = time;
 787                         self.scale                = 0.5;
 788
 789                         self.PlayerPhysplug = racer_frame;
 790
 791                         self.bouncefactor = autocvar_g_vehicle_racer_bouncefactor;
 792                         self.bouncestop = autocvar_g_vehicle_racer_bouncestop;
 793                         self.damageforcescale = 0.5;
 794                         self.vehicle_health = autocvar_g_vehicle_racer_health;
 795                         self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 796                 #endif
 797                         return true;
 798                 }
 799
 800                 METHOD(Racer, vr_death, bool(Racer thisveh))
 801                 {
 802                 #ifdef SVQC
 803                         self.SendEntity         = func_null; // stop networking this racer (for now)
 804                         self.health                     = 0;
 805                         self.event_damage       = func_null;
 806                         self.solid                      = SOLID_CORPSE;
 807                         self.takedamage         = DAMAGE_NO;
 808                         self.deadflag           = DEAD_DYING;
 809                         self.movetype           = MOVETYPE_BOUNCE;
 810                         self.wait                       = time;
 811                         self.delay                      = 2 + time + random() * 3;
 812                         self.cnt                        = 1 + random() * 2;
 813                         self.touch                      = racer_deadtouch;
 814
 815                         Send_Effect(EFFECT_EXPLOSION_MEDIUM, self.origin, '0 0 0', 1);
 816
 817                         if(random() < 0.5)
 818                                 self.avelocity_z = 32;
 819                         else
 820                                 self.avelocity_z = -32;
 821
 822                         self.avelocity_x = -vlen(self.velocity) * 0.2;
 823                         self.velocity += '0 0 700';
 824                         self.colormod = '-0.5 -0.5 -0.5';
 825
 826                         self.think = racer_blowup_think;
 827                         self.nextthink = time;
 828                 #endif
 829                         return true;
 830                 }
 831
 832 #ifdef CSQC
 833                 METHOD(Racer, vr_hud, bool(Racer thisveh))
 834                 {
 835                         Vehicles_drawHUD(VEH_RACER.m_icon, "vehicle_racer_weapon1", "vehicle_racer_weapon2",
 836                                                          "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 837                                                          "vehicle_icon_ammo2", autocvar_hud_progressbar_vehicles_ammo2_color,
 838                                                          vCROSS_GUIDE);
 839                         return true;
 840                 }
 841 #endif
 842                 METHOD(Racer, vr_setup, bool(Racer thisveh))
 843                 {
 844                 #ifdef SVQC
 845                         self.vehicle_exit = racer_exit;
 846                 #endif
 847
 848                 #ifdef SVQC
 849                         // we have no need to network energy
 850                         if(autocvar_g_vehicle_racer_energy)
 851                         if(autocvar_g_vehicle_racer_energy_regen)
 852                                 self.vehicle_flags |= VHF_ENERGYREGEN;
 853
 854                         if(autocvar_g_vehicle_racer_shield)
 855                                 self.vehicle_flags |= VHF_HASSHIELD;
 856
 857                         if(autocvar_g_vehicle_racer_shield_regen)
 858                                 self.vehicle_flags |= VHF_SHIELDREGEN;
 859
 860                         if(autocvar_g_vehicle_racer_health_regen)
 861                                 self.vehicle_flags |= VHF_HEALTHREGEN;
 862
 863                         self.respawntime = autocvar_g_vehicle_racer_respawntime;
 864                         self.vehicle_health = autocvar_g_vehicle_racer_health;
 865                         self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 866                         self.max_health = self.vehicle_health;
 867                 #endif
 868
 869                 #ifdef CSQC
 870                         AuxiliaryXhair[0].axh_image = vCROSS_LOCK; // Rocket
 871                 #endif
 872                         return true;
 873                 }
 874
 875                 METHOD(Racer, vr_precache, bool(Racer thisveh))
 876                 {
 877                         return true;
 878                 }
 879
 880 #endif // REGISTER_VEHICLE