qcsrc/common/vehicles/vehicle/raptor.qc

   1 #ifndef VEHICLE_RAPTOR
   2 #define VEHICLE_RAPTOR
   3 #include "raptor.qh"
   4
   5 #include "raptor_weapons.qc"
   6
   7 CLASS(Raptor, Vehicle)
   8 /* spawnflags */ ATTRIB(Raptor, spawnflags, int, VHF_DMGSHAKE | VHF_DMGROLL);
   9 /* mins       */ ATTRIB(Raptor, mins, vector, '-80 -80 0');
  10 /* maxs       */ ATTRIB(Raptor, maxs, vector, '80 80 70');
  11 /* model          */ ATTRIB(Raptor, mdl, string, "models/vehicles/raptor.dpm");
  12 /* model          */ ATTRIB(Raptor, model, string, "models/vehicles/raptor.dpm");
  13 /* head_model */ ATTRIB(Raptor, head_model, string, "");
  14 /* hud_model  */ ATTRIB(Raptor, hud_model, string, "models/vehicles/raptor_cockpit.dpm");
  15 /* tags       */ ATTRIB(Raptor, tag_head, string, "");
  16 /* tags       */ ATTRIB(Raptor, tag_hud, string, "tag_hud");
  17 /* tags       */ ATTRIB(Raptor, tag_view, string, "tag_camera");
  18 /* netname    */ ATTRIB(Raptor, netname, string, "raptor");
  19 /* fullname   */ ATTRIB(Raptor, vehicle_name, string, _("Raptor"));
  20 /* icon       */ ATTRIB(Raptor, m_icon, string, "vehicle_raptor");
  21 ENDCLASS(Raptor)
  22 REGISTER_VEHICLE(RAPTOR, NEW(Raptor));
  23
  24 #endif
  25
  26 #ifdef IMPLEMENTATION
  27
  28 #include "raptor_weapons.qc"
  29
  30 #ifdef SVQC
  31
  32 bool autocvar_g_vehicle_raptor;
  33
  34 float autocvar_g_vehicle_raptor_respawntime;
  35 float autocvar_g_vehicle_raptor_takeofftime;
  36
  37 float autocvar_g_vehicle_raptor_movestyle;
  38 float autocvar_g_vehicle_raptor_turnspeed;
  39 float autocvar_g_vehicle_raptor_pitchspeed;
  40 float autocvar_g_vehicle_raptor_pitchlimit;
  41
  42 float autocvar_g_vehicle_raptor_speed_forward;
  43 float autocvar_g_vehicle_raptor_speed_strafe;
  44 float autocvar_g_vehicle_raptor_speed_up;
  45 float autocvar_g_vehicle_raptor_speed_down;
  46 float autocvar_g_vehicle_raptor_friction;
  47
  48 float autocvar_g_vehicle_raptor_cannon_turnspeed;
  49 float autocvar_g_vehicle_raptor_cannon_turnlimit;
  50 float autocvar_g_vehicle_raptor_cannon_pitchlimit_up;
  51 float autocvar_g_vehicle_raptor_cannon_pitchlimit_down;
  52
  53 float autocvar_g_vehicle_raptor_cannon_locktarget;
  54 float autocvar_g_vehicle_raptor_cannon_locking_time;
  55 float autocvar_g_vehicle_raptor_cannon_locking_releasetime;
  56 float autocvar_g_vehicle_raptor_cannon_locked_time;
  57 float autocvar_g_vehicle_raptor_cannon_predicttarget;
  58
  59 float autocvar_g_vehicle_raptor_energy;
  60 float autocvar_g_vehicle_raptor_energy_regen;
  61 float autocvar_g_vehicle_raptor_energy_regen_pause;
  62
  63 float autocvar_g_vehicle_raptor_health;
  64 float autocvar_g_vehicle_raptor_health_regen;
  65 float autocvar_g_vehicle_raptor_health_regen_pause;
  66
  67 float autocvar_g_vehicle_raptor_shield;
  68 float autocvar_g_vehicle_raptor_shield_regen;
  69 float autocvar_g_vehicle_raptor_shield_regen_pause;
  70
  71 float autocvar_g_vehicle_raptor_bouncefactor;
  72 float autocvar_g_vehicle_raptor_bouncestop;
  73 vector autocvar_g_vehicle_raptor_bouncepain;
  74
  75 .entity bomb1;
  76 .entity bomb2;
  77
  78 float raptor_altitude(float amax)
  79 {SELFPARAM();
  80         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * amax), MOVE_WORLDONLY, self);
  81         return vlen(self.origin - trace_endpos);
  82 }
  83
  84 void raptor_land()
  85 {SELFPARAM();
  86         float hgt;
  87
  88         hgt = raptor_altitude(512);
  89         self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
  90         self.angles_x *= 0.95;
  91         self.angles_z *= 0.95;
  92
  93         if(hgt < 128)
  94         if(hgt > 0)
  95                 self.frame = (hgt / 128) * 25;
  96
  97         self.bomb1.gun1.avelocity_y = 90 + ((self.frame / 25) * 2000);
  98         self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
  99
 100         if(hgt < 16)
 101         {
 102                 self.movetype = MOVETYPE_TOSS;
 103                 self.think      = vehicles_think;
 104                 self.frame      = 0;
 105         }
 106
 107         self.nextthink  = time;
 108
 109         CSQCMODEL_AUTOUPDATE(self);
 110 }
 111
 112 void raptor_exit(float eject)
 113 {SELFPARAM();
 114         vector spot;
 115         self.tur_head.exteriormodeltoclient = world;
 116
 117         if(self.deadflag == DEAD_NO)
 118         {
 119                 self.think        = raptor_land;
 120                 self.nextthink  = time;
 121         }
 122
 123         if(!self.owner)
 124                 return;
 125
 126         makevectors(self.angles);
 127         if(eject)
 128         {
 129                 spot = self.origin + v_forward * 100 + '0 0 64';
 130                 spot = vehicles_findgoodexit(spot);
 131                 setorigin(self.owner , spot);
 132                 self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 133                 self.owner.oldvelocity = self.owner.velocity;
 134         }
 135         else
 136         {
 137                 if(vlen(self.velocity) > 2 * autocvar_sv_maxairspeed)
 138                 {
 139                         self.owner.velocity = normalize(self.velocity) * autocvar_sv_maxairspeed * 2;
 140                         self.owner.velocity_z += 200;
 141                         spot = self.origin + v_forward * 32 + '0 0 64';
 142                         spot = vehicles_findgoodexit(spot);
 143                 }
 144                 else
 145                 {
 146                         self.owner.velocity = self.velocity * 0.5;
 147                         self.owner.velocity_z += 10;
 148                         spot = self.origin - v_forward * 200 + '0 0 64';
 149                         spot = vehicles_findgoodexit(spot);
 150                 }
 151                 self.owner.oldvelocity = self.owner.velocity;
 152                 setorigin(self.owner , spot);
 153         }
 154
 155         antilag_clear(self.owner);
 156         self.owner = world;
 157 }
 158
 159 float raptor_frame()
 160 {SELFPARAM();
 161         entity player, raptor;
 162         float ftmp = 0;
 163         vector df;
 164
 165         if(intermission_running)
 166         {
 167                 self.vehicle.velocity = '0 0 0';
 168                 self.vehicle.avelocity = '0 0 0';
 169                 return 1;
 170         }
 171
 172         player = self;
 173         raptor = self.vehicle;
 174         setself(raptor);
 175
 176         vehicles_painframe();
 177         /*
 178         ftmp = vlen(self.velocity);
 179         if(ftmp > autocvar_g_vehicle_raptor_speed_forward)
 180                 ftmp = 1;
 181         else
 182                 ftmp = ftmp / autocvar_g_vehicle_raptor_speed_forward;
 183         */
 184
 185         if(self.sound_nexttime < time)
 186         {
 187                 self.sound_nexttime = time + 7.955812;
 188                 //sound (self.tur_head, CH_TRIGGER_SINGLE, SND_VEH_RAPTOR_FLY, 1 - ftmp,   ATTEN_NORM );
 189                 sound (self, CH_TRIGGER_SINGLE, SND_VEH_RAPTOR_SPEED, 1, ATTEN_NORM);
 190                 self.wait = ftmp;
 191         }
 192         /*
 193         else if(fabs(ftmp - self.wait) > 0.2)
 194         {
 195                 sound (self.tur_head, CH_TRIGGER_SINGLE, SND_Null, 1 - ftmp,   ATTEN_NORM );
 196                 sound (self, CH_TRIGGER_SINGLE, SND_Null, ftmp, ATTEN_NORM);
 197                 self.wait = ftmp;
 198         }
 199         */
 200
 201         if(raptor.deadflag != DEAD_NO)
 202         {
 203                 setself(player);
 204                 player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 205                 return 1;
 206         }
 207         crosshair_trace(player);
 208
 209         //if(time - self.lastteleporttime < 1)
 210         //{
 211                 if(raptor.angles_z > 50 || raptor.angles_z < -50)
 212                 {
 213                         if(player.BUTTON_JUMP)
 214                         {
 215                                 player.BUTTON_CROUCH = true;
 216                                 player.BUTTON_JUMP = false;
 217                         }
 218                 }
 219         //}
 220
 221         vector vang;
 222         vang = raptor.angles;
 223         df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 224         vang_x *= -1;
 225         df_x *= -1;
 226         if(df_x > 180)  df_x -= 360;
 227         if(df_x < -180) df_x += 360;
 228         if(df_y > 180)  df_y -= 360;
 229         if(df_y < -180) df_y += 360;
 230
 231         ftmp = shortangle_f(player.v_angle_y - vang_y, vang_y);
 232         if(ftmp > 180)  ftmp -= 360; if(ftmp < -180) ftmp += 360;
 233         raptor.avelocity_y = bound(-autocvar_g_vehicle_raptor_turnspeed, ftmp + raptor.avelocity_y * 0.9, autocvar_g_vehicle_raptor_turnspeed);
 234
 235         // Pitch
 236         ftmp = 0;
 237         if(player.movement_x > 0 && vang_x < autocvar_g_vehicle_raptor_pitchlimit) ftmp = 5;
 238         else if(player.movement_x < 0 && vang_x > -autocvar_g_vehicle_raptor_pitchlimit) ftmp = -20;
 239
 240         df_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x , autocvar_g_vehicle_raptor_pitchlimit);
 241         ftmp = vang_x - bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x + ftmp, autocvar_g_vehicle_raptor_pitchlimit);
 242         raptor.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchspeed, ftmp + raptor.avelocity_x * 0.9, autocvar_g_vehicle_raptor_pitchspeed);
 243
 244         raptor.angles_x = anglemods(raptor.angles_x);
 245         raptor.angles_y = anglemods(raptor.angles_y);
 246         raptor.angles_z = anglemods(raptor.angles_z);
 247
 248         if(autocvar_g_vehicle_raptor_movestyle == 1)
 249                 makevectors('0 1 0' * raptor.angles_y);
 250         else
 251                 makevectors(player.v_angle);
 252
 253         df = raptor.velocity * -autocvar_g_vehicle_raptor_friction;
 254
 255         if(player.movement_x != 0)
 256         {
 257                 if(player.movement_x > 0)
 258                         df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 259                 else if(player.movement_x < 0)
 260                         df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 261         }
 262
 263         if(player.movement_y != 0)
 264         {
 265                 if(player.movement_y < 0)
 266                         df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 267                 else if(player.movement_y > 0)
 268                         df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 269
 270                 raptor.angles_z = bound(-30,raptor.angles_z + (player.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 271         }
 272         else
 273         {
 274                 raptor.angles_z *= 0.95;
 275                 if(raptor.angles_z >= -1 && raptor.angles_z <= -1)
 276                         raptor.angles_z = 0;
 277         }
 278
 279         if(player.BUTTON_CROUCH)
 280                 df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 281         else if (player.BUTTON_JUMP)
 282                 df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 283
 284         raptor.velocity  += df * frametime;
 285         player.velocity = player.movement  = raptor.velocity;
 286         setorigin(player, raptor.origin + '0 0 32');
 287
 288         player.vehicle_weapon2mode = raptor.vehicle_weapon2mode;
 289
 290         vector vf, ad;
 291         // Target lock & predict
 292         if(autocvar_g_vehicle_raptor_cannon_locktarget == 2)
 293         {
 294                 if(raptor.gun1.lock_time < time || raptor.gun1.enemy.deadflag)
 295                         raptor.gun1.enemy = world;
 296
 297                 if(trace_ent)
 298                 if(trace_ent.movetype)
 299                 if(trace_ent.takedamage)
 300                 if(!trace_ent.deadflag)
 301                 {
 302                         if(teamplay)
 303                         {
 304                                 if(trace_ent.team != player.team)
 305                                 {
 306                                         raptor.gun1.enemy = trace_ent;
 307                                         raptor.gun1.lock_time = time + 5;
 308                                 }
 309                         }
 310                         else
 311                         {
 312                                 raptor.gun1.enemy = trace_ent;
 313                                 raptor.gun1.lock_time = time + 0.5;
 314                         }
 315                 }
 316
 317                 if(raptor.gun1.enemy)
 318                 {
 319                         float distance, impact_time;
 320
 321                         vf = real_origin(raptor.gun1.enemy);
 322                         UpdateAuxiliaryXhair(player, vf, '1 0 0', 1);
 323                         vector _vel = raptor.gun1.enemy.velocity;
 324                         if(raptor.gun1.enemy.movetype == MOVETYPE_WALK)
 325                                 _vel_z *= 0.1;
 326
 327                         if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 328                         {
 329                                 ad = vf;
 330                                 distance = vlen(ad - player.origin);
 331                                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 332                                 ad = vf + _vel * impact_time;
 333                                 trace_endpos = ad;
 334                         }
 335                         else
 336                                 trace_endpos = vf;
 337                 }
 338         }
 339         else if(autocvar_g_vehicle_raptor_cannon_locktarget == 1)
 340         {
 341
 342                 vehicles_locktarget((1 / autocvar_g_vehicle_raptor_cannon_locking_time) * frametime,
 343                                                          (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * frametime,
 344                                                          autocvar_g_vehicle_raptor_cannon_locked_time);
 345
 346                 if(self.lock_target != world)
 347                 if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 348                 if(self.lock_strength == 1)
 349                 {
 350                         float i, distance, impact_time;
 351
 352                         vf = real_origin(raptor.lock_target);
 353                         ad = vf;
 354                         for(i = 0; i < 4; ++i)
 355                         {
 356                                 distance = vlen(ad - raptor.origin);
 357                                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 358                                 ad = vf + raptor.lock_target.velocity * impact_time;
 359                         }
 360                         trace_endpos = ad;
 361                 }
 362
 363                 if(self.lock_target)
 364                 {
 365                         if(raptor.lock_strength == 1)
 366                                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '1 0 0', 1);
 367                         else if(self.lock_strength > 0.5)
 368                                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 1 0', 1);
 369                         else if(self.lock_strength < 0.5)
 370                                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 0 1', 1);
 371                 }
 372         }
 373
 374
 375         vehicle_aimturret(raptor, trace_endpos, raptor.gun1, "fire1",
 376                                                   autocvar_g_vehicle_raptor_cannon_pitchlimit_down * -1,  autocvar_g_vehicle_raptor_cannon_pitchlimit_up,
 377                                                   autocvar_g_vehicle_raptor_cannon_turnlimit * -1,  autocvar_g_vehicle_raptor_cannon_turnlimit,  autocvar_g_vehicle_raptor_cannon_turnspeed);
 378
 379         vehicle_aimturret(raptor, trace_endpos, raptor.gun2, "fire1",
 380                                                   autocvar_g_vehicle_raptor_cannon_pitchlimit_down * -1,  autocvar_g_vehicle_raptor_cannon_pitchlimit_up,
 381                                                   autocvar_g_vehicle_raptor_cannon_turnlimit * -1,  autocvar_g_vehicle_raptor_cannon_turnlimit,  autocvar_g_vehicle_raptor_cannon_turnspeed);
 382
 383         /*
 384         ad = ad * 0.5;
 385         v_forward = vf * 0.5;
 386         traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, raptor);
 387         UpdateAuxiliaryXhair(player, trace_endpos, '0 1 0', 0);
 388         */
 389
 390         Weapon wep1 = WEP_RAPTOR;
 391         if(!forbidWeaponUse(player))
 392         if(player.BUTTON_ATCK)
 393         if (wep1.wr_checkammo1(wep1))
 394         {
 395             .entity weaponentity = weaponentities[0];
 396                 wep1.wr_think(wep1, self, weaponentity, 1);
 397         }
 398
 399         if(self.vehicle_flags  & VHF_SHIELDREGEN)
 400                 vehicles_regen(raptor.dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime, true);
 401
 402         if(self.vehicle_flags  & VHF_HEALTHREGEN)
 403                 vehicles_regen(raptor.dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime, false);
 404
 405         if(self.vehicle_flags  & VHF_ENERGYREGEN)
 406                 vehicles_regen(raptor.cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime, false);
 407
 408         Weapon wep2a = WEP_RAPTOR_BOMB;
 409         if(!forbidWeaponUse(player))
 410         if(raptor.vehicle_weapon2mode == RSM_BOMB)
 411         {
 412                 if(time > raptor.lip + autocvar_g_vehicle_raptor_bombs_refire)
 413                 if(player.BUTTON_ATCK2)
 414                 {
 415                     .entity weaponentity = weaponentities[1];
 416                         wep2a.wr_think(wep2a, self, weaponentity, 2);
 417                         raptor.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 418                         raptor.lip   = time;
 419                 }
 420         }
 421         else
 422         {
 423                 Weapon wep2b = WEP_RAPTOR_FLARE;
 424                 if(time > raptor.lip + autocvar_g_vehicle_raptor_flare_refire)
 425                 if(player.BUTTON_ATCK2)
 426                 {
 427                     .entity weaponentity = weaponentities[1];
 428                         wep2b.wr_think(wep2b, self, weaponentity, 2);
 429                         raptor.delay = time + autocvar_g_vehicle_raptor_flare_refire;
 430                         raptor.lip   = time;
 431                 }
 432         }
 433
 434         raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 435         player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 436         player.vehicle_ammo2 = (player.vehicle_reload2 == 100) ? 100 : 0;
 437
 438         if(self.bomb1.cnt < time)
 439         {
 440                 entity _missile = findchainentity(enemy, raptor);
 441                 float _incomming = 0;
 442                 while(_missile)
 443                 {
 444                         if(_missile.flags & FL_PROJECTILE)
 445                         if(MISSILE_IS_TRACKING(_missile))
 446                         if(vlen(self.origin - _missile.origin) < 2 * autocvar_g_vehicle_raptor_flare_range)
 447                                 ++_incomming;
 448
 449                         _missile = _missile.chain;
 450                 }
 451
 452                 if(_incomming)
 453                         sound(self, CH_PAIN_SINGLE, SND_VEH_MISSILE_ALARM, VOL_BASE, ATTEN_NONE);
 454
 455                 self.bomb1.cnt = time + 1;
 456         }
 457
 458
 459         VEHICLE_UPDATE_PLAYER(player, health, raptor);
 460         VEHICLE_UPDATE_PLAYER(player, energy, raptor);
 461         if(self.vehicle_flags & VHF_HASSHIELD)
 462                 VEHICLE_UPDATE_PLAYER(player, shield, raptor);
 463
 464         player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 465
 466         setself(player);
 467         return 1;
 468 }
 469
 470 float raptor_takeoff()
 471 {SELFPARAM();
 472         entity player, raptor;
 473
 474         player = self;
 475         raptor = self.vehicle;
 476         setself(raptor);
 477
 478         self.nextthink = time;
 479         CSQCMODEL_AUTOUPDATE(self);
 480         self.nextthink = 0; // will this work?
 481
 482         if(self.sound_nexttime < time)
 483         {
 484                 self.sound_nexttime = time + 7.955812; //soundlength("vehicles/raptor_fly.wav");
 485                 sound (self, CH_TRIGGER_SINGLE, SND_VEH_RAPTOR_SPEED, VOL_VEHICLEENGINE, ATTEN_NORM);
 486         }
 487
 488         // Takeoff sequense
 489         if(raptor.frame < 25)
 490         {
 491                 raptor.frame += 25 / (autocvar_g_vehicle_raptor_takeofftime / sys_frametime);
 492                 raptor.velocity_z = min(raptor.velocity_z * 1.5, 256);
 493                 self.bomb1.gun1.avelocity_y = 90 + ((raptor.frame / 25) * 25000);
 494                 self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 495                 player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 496
 497                 setorigin(player, raptor.origin + '0 0 32');
 498         }
 499         else
 500                 player.PlayerPhysplug = raptor_frame;
 501
 502         if(self.vehicle_flags  & VHF_SHIELDREGEN)
 503                 vehicles_regen(raptor.dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime, true);
 504
 505         if(self.vehicle_flags  & VHF_HEALTHREGEN)
 506                 vehicles_regen(raptor.dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime, false);
 507
 508         if(self.vehicle_flags  & VHF_ENERGYREGEN)
 509                 vehicles_regen(raptor.cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime, false);
 510
 511
 512         raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 513         player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 514         player.vehicle_ammo2 = (player.vehicle_reload2 == 100) ? 100 : 0;
 515
 516         VEHICLE_UPDATE_PLAYER(player, health, raptor);
 517         VEHICLE_UPDATE_PLAYER(player, energy, raptor);
 518         if(self.vehicle_flags & VHF_HASSHIELD)
 519                 VEHICLE_UPDATE_PLAYER(player, shield, raptor);
 520
 521         player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 522         setself(player);
 523         return 1;
 524 }
 525
 526 void raptor_blowup()
 527 {SELFPARAM();
 528         self.deadflag   = DEAD_DEAD;
 529         self.vehicle_exit(VHEF_NORMAL);
 530         RadiusDamage (self, self.enemy, 250, 15, 250, world, world, 250, DEATH_VH_RAPT_DEATH.m_id, world);
 531
 532         self.alpha                = -1;
 533         self.movetype      = MOVETYPE_NONE;
 534         self.effects            = EF_NODRAW;
 535         self.colormod      = '0 0 0';
 536         self.avelocity    = '0 0 0';
 537         self.velocity      = '0 0 0';
 538
 539         setorigin(self, self.pos1);
 540         self.touch = func_null;
 541         self.nextthink = 0;
 542 }
 543
 544 void raptor_diethink()
 545 {SELFPARAM();
 546         if(time >= self.wait)
 547                 self.think = raptor_blowup;
 548
 549         if(random() < 0.05)
 550         {
 551                 sound (self, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 552                 Send_Effect(EFFECT_EXPLOSION_SMALL, randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 553         }
 554         self.nextthink = time;
 555
 556         CSQCMODEL_AUTOUPDATE(self);
 557 }
 558
 559 // If we dont do this ever now and then, the raptors rotors
 560 // stop working, presumably due to angle overflow. cute.
 561 void raptor_rotor_anglefix()
 562 {SELFPARAM();
 563         self.gun1.angles_y = anglemods(self.gun1.angles_y);
 564         self.gun2.angles_y = anglemods(self.gun2.angles_y);
 565         self.nextthink = time + 15;
 566 }
 567
 568 float raptor_impulse(float _imp)
 569 {SELFPARAM();
 570         switch(_imp)
 571         {
 572                 case 1:
 573                         self.vehicle.vehicle_weapon2mode = RSM_BOMB;
 574                         CSQCVehicleSetup(self, 0);
 575                         return true;
 576                 case 2:
 577                         self.vehicle.vehicle_weapon2mode = RSM_FLARE;
 578                         CSQCVehicleSetup(self, 0);
 579                         return true;
 580
 581                 case 10:
 582                 case 15:
 583                 case 18:
 584                         self.vehicle.vehicle_weapon2mode += 1;
 585                         if(self.vehicle.vehicle_weapon2mode > RSM_LAST)
 586                                 self.vehicle.vehicle_weapon2mode = RSM_FIRST;
 587
 588                         CSQCVehicleSetup(self, 0);
 589                         return true;
 590                 case 11:
 591                 case 12:
 592                 case 16:
 593                 case 19:
 594                         self.vehicle.vehicle_weapon2mode -= 1;
 595                         if(self.vehicle.vehicle_weapon2mode < RSM_FIRST)
 596                                 self.vehicle.vehicle_weapon2mode = RSM_LAST;
 597
 598                         CSQCVehicleSetup(self, 0);
 599                         return true;
 600
 601                 /*
 602                 case 17: // toss gun, could be used to exit?
 603                         break;
 604                 case 20: // Manual minigun reload?
 605                         break;
 606                 */
 607         }
 608         return false;
 609 }
 610
 611 spawnfunc(vehicle_raptor)
 612 {
 613         if(!autocvar_g_vehicle_raptor) { remove(self); return; }
 614         if(!vehicle_initialize(VEH_RAPTOR, false)) { remove(self); return; }
 615 }
 616
 617                 METHOD(Raptor, vr_impact, void(Raptor thisveh))
 618                 {
 619                         if(autocvar_g_vehicle_raptor_bouncepain)
 620                                 vehicles_impact(autocvar_g_vehicle_raptor_bouncepain_x, autocvar_g_vehicle_raptor_bouncepain_y, autocvar_g_vehicle_raptor_bouncepain_z);
 621                 }
 622                 METHOD(Raptor, vr_enter, void(Raptor thisveh))
 623                 {
 624                         self.vehicle_weapon2mode = RSM_BOMB;
 625                         self.owner.PlayerPhysplug = raptor_takeoff;
 626                         self.movetype      = MOVETYPE_BOUNCEMISSILE;
 627                         self.solid                = SOLID_SLIDEBOX;
 628                         self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_raptor_health) * 100;
 629                         self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_raptor_shield) * 100;
 630                         self.velocity_z = 1; // Nudge upwards to takeoff sequense can work.
 631                         self.tur_head.exteriormodeltoclient = self.owner;
 632
 633                         self.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 634                         self.lip   = time;
 635
 636                         if(self.owner.flagcarried)
 637                            setorigin(self.owner.flagcarried, '-20 0 96');
 638
 639                         CSQCVehicleSetup(self.owner, 0);
 640                 }
 641                 METHOD(Raptor, vr_death, void(Raptor thisveh))
 642                 {
 643                         self.health                             = 0;
 644                         self.event_damage               = func_null;
 645                         self.solid                              = SOLID_CORPSE;
 646                         self.takedamage                 = DAMAGE_NO;
 647                         self.deadflag                   = DEAD_DYING;
 648                         self.movetype                   = MOVETYPE_BOUNCE;
 649                         self.think                              = raptor_diethink;
 650                         self.nextthink                  = time;
 651                         self.wait                               = time + 5 + (random() * 5);
 652
 653                         Send_Effect(EFFECT_EXPLOSION_MEDIUM, findbetterlocation (self.origin, 16), '0 0 0', 1);
 654
 655                         self.velocity_z += 600;
 656
 657                         self.avelocity = '0 0.5 1' * (random() * 400);
 658                         self.avelocity -= '0 0.5 1' * (random() * 400);
 659
 660                         self.colormod = '-0.5 -0.5 -0.5';
 661                         self.touch = raptor_blowup;
 662                 }
 663                 METHOD(Raptor, vr_spawn, void(Raptor thisveh))
 664                 {
 665                         if(!self.gun1)
 666                         {
 667                                 entity spinner;
 668                                 vector ofs;
 669
 670                                 //FIXME: Camera is in a bad place in HUD model.
 671                                 //setorigin(self.vehicle_viewport, '25 0 5');
 672
 673                                 self.vehicles_impulse   = raptor_impulse;
 674
 675                                 self.frame = 0;
 676
 677                                 self.bomb1 = new(raptor_bomb);
 678                                 self.bomb2 = new(raptor_bomb);
 679                                 self.gun1  = new(raptor_gun);
 680                                 self.gun2  = new(raptor_gun);
 681
 682                                 setmodel(self.bomb1, MDL_VEH_RAPTOR_CB_FOLDED);
 683                                 setmodel(self.bomb2, MDL_VEH_RAPTOR_CB_FOLDED);
 684                                 setmodel(self.gun1, MDL_VEH_RAPTOR_GUN);
 685                                 setmodel(self.gun2, MDL_VEH_RAPTOR_GUN);
 686                                 setmodel(self.tur_head, MDL_VEH_RAPTOR_TAIL);
 687
 688                                 setattachment(self.bomb1, self, "bombmount_left");
 689                                 setattachment(self.bomb2, self, "bombmount_right");
 690                                 setattachment(self.tur_head, self,"root");
 691
 692                                 // FIXMODEL Guns mounts to angled bones
 693                                 self.bomb1.angles = self.angles;
 694                                 self.angles = '0 0 0';
 695                                 // This messes up gun-aim, so work arround it.
 696                                 //setattachment(self.gun1, self, "gunmount_left");
 697                                 ofs = gettaginfo(self, gettagindex(self, "gunmount_left"));
 698                                 ofs -= self.origin;
 699                                 setattachment(self.gun1, self, "");
 700                                 setorigin(self.gun1, ofs);
 701
 702                                 //setattachment(self.gun2, self, "gunmount_right");
 703                                 ofs = gettaginfo(self, gettagindex(self, "gunmount_right"));
 704                                 ofs -= self.origin;
 705                                 setattachment(self.gun2, self, "");
 706                                 setorigin(self.gun2, ofs);
 707
 708                                 self.angles = self.bomb1.angles;
 709                                 self.bomb1.angles = '0 0 0';
 710
 711                                 spinner = new(raptor_spinner);
 712                                 spinner.owner = self;
 713                                 setmodel(spinner, MDL_VEH_RAPTOR_PROP);
 714                                 setattachment(spinner, self, "engine_left");
 715                                 spinner.movetype = MOVETYPE_NOCLIP;
 716                                 spinner.avelocity = '0 90 0';
 717                                 self.bomb1.gun1 = spinner;
 718
 719                                 spinner = new(raptor_spinner);
 720                                 spinner.owner = self;
 721                                 setmodel(spinner, MDL_VEH_RAPTOR_PROP);
 722                                 setattachment(spinner, self, "engine_right");
 723                                 spinner.movetype = MOVETYPE_NOCLIP;
 724                                 spinner.avelocity = '0 -90 0';
 725                                 self.bomb1.gun2 = spinner;
 726
 727                                 // Sigh.
 728                                 self.bomb1.think = raptor_rotor_anglefix;
 729                                 self.bomb1.nextthink = time;
 730
 731                                 self.mass                          = 1 ;
 732                         }
 733
 734                         self.frame                = 0;
 735                         self.vehicle_health = autocvar_g_vehicle_raptor_health;
 736                         self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 737                         self.movetype      = MOVETYPE_TOSS;
 738                         self.solid                = SOLID_SLIDEBOX;
 739                         self.vehicle_energy = 1;
 740
 741                         self.PlayerPhysplug = raptor_frame;
 742
 743                         self.bomb1.gun1.avelocity_y = 90;
 744                         self.bomb1.gun2.avelocity_y = -90;
 745
 746                         self.delay = time;
 747
 748                         self.bouncefactor = autocvar_g_vehicle_raptor_bouncefactor;
 749                         self.bouncestop = autocvar_g_vehicle_raptor_bouncestop;
 750                         self.damageforcescale = 0.25;
 751                         self.vehicle_health = autocvar_g_vehicle_raptor_health;
 752                         self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 753                 }
 754                 METHOD(Raptor, vr_setup, void(Raptor thisveh))
 755                 {
 756                         if(autocvar_g_vehicle_raptor_shield)
 757                                 self.vehicle_flags |= VHF_HASSHIELD;
 758
 759                         if(autocvar_g_vehicle_raptor_shield_regen)
 760                                 self.vehicle_flags |= VHF_SHIELDREGEN;
 761
 762                         if(autocvar_g_vehicle_raptor_health_regen)
 763                                 self.vehicle_flags |= VHF_HEALTHREGEN;
 764
 765                         if(autocvar_g_vehicle_raptor_energy_regen)
 766                                 self.vehicle_flags |= VHF_ENERGYREGEN;
 767
 768                         self.vehicle_exit = raptor_exit;
 769                         self.respawntime = autocvar_g_vehicle_raptor_respawntime;
 770                         self.vehicle_health = autocvar_g_vehicle_raptor_health;
 771                         self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 772                         self.max_health = self.vehicle_health;
 773                 }
 774
 775 #endif
 776 #ifdef CSQC
 777
 778                 METHOD(Raptor, vr_hud, void(Raptor thisveh))
 779                 {
 780                         Vehicles_drawHUD(VEH_RAPTOR.m_icon, "vehicle_raptor_weapon1", "vehicle_raptor_weapon2",
 781                                                          "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 782                                                          "vehicle_icon_ammo2", autocvar_hud_progressbar_vehicles_ammo2_color);
 783                 }
 784                 METHOD(Raptor, vr_crosshair, void(Raptor thisveh))
 785                 {
 786                         string crosshair;
 787
 788                         switch(weapon2mode)
 789                         {
 790                                 case RSM_FLARE: crosshair = vCROSS_RAIN;  break;
 791                                 case RSM_BOMB:  crosshair = vCROSS_BURST; break;
 792                                 default:        crosshair = vCROSS_BURST;
 793                         }
 794
 795                         vector tmpSize = '0 0 0';
 796                         if(weapon2mode != RSM_FLARE)
 797                         {
 798                                 vector where;
 799
 800                                 if(!dropmark)
 801                                 {
 802                                         dropmark = spawn();
 803                                         dropmark.owner = self;
 804                                         dropmark.gravity = 1;
 805                                 }
 806
 807                                 float reload2 = getstati(STAT_VEHICLESTAT_RELOAD2) * 0.01;
 808                                 if(reload2 == 1)
 809                                 {
 810                                         setorigin(dropmark, pmove_org);
 811                                         dropmark.velocity = pmove_vel;
 812                                         tracetoss(dropmark, self);
 813
 814                                         where = project_3d_to_2d(trace_endpos);
 815
 816                                         setorigin(dropmark, trace_endpos);
 817                                         tmpSize = draw_getimagesize(vCROSS_DROP) * autocvar_cl_vehicles_crosshair_size;
 818
 819                                         if (!(where.z < 0 || where.x < 0 || where.y < 0 || where.x > vid_conwidth || where.y > vid_conheight))
 820                                         {
 821                                                 where.x -= tmpSize.x * 0.5;
 822                                                 where.y -= tmpSize.y * 0.5;
 823                                                 where.z = 0;
 824                                                 drawpic(where, vCROSS_DROP, tmpSize, '0 1 0', autocvar_crosshair_alpha * 0.9, DRAWFLAG_ADDITIVE);
 825                                                 drawpic(where, vCROSS_DROP, tmpSize, '0 1 0', autocvar_crosshair_alpha * 0.6, DRAWFLAG_NORMAL); // Ensure visibility against bright bg
 826                                         }
 827                                         dropmark.cnt = time + 5;
 828                                 }
 829                                 else
 830                                 {
 831                                         if(dropmark.cnt > time)
 832                                         {
 833                                                 where = project_3d_to_2d(dropmark.origin);
 834                                                 tmpSize = draw_getimagesize(vCROSS_DROP) * autocvar_cl_vehicles_crosshair_size * 1.25;
 835
 836                                                 if (!(where.z < 0 || where.x < 0 || where.y < 0 || where.x > vid_conwidth || where.y > vid_conheight))
 837                                                 {
 838                                                         where.x -= tmpSize.x * 0.5;
 839                                                         where.y -= tmpSize.y * 0.5;
 840                                                         where.z = 0;
 841                                                         drawpic(where, vCROSS_DROP, tmpSize, '1 0 0', autocvar_crosshair_alpha * 0.9, DRAWFLAG_ADDITIVE);
 842                                                         drawpic(where, vCROSS_DROP, tmpSize, '1 0 0', autocvar_crosshair_alpha * 0.6, DRAWFLAG_NORMAL); // Ensure visibility against bright bg
 843                                                 }
 844                                         }
 845                                 }
 846                         }
 847
 848                         Vehicles_drawCrosshair(crosshair);
 849                 }
 850                 METHOD(Raptor, vr_setup, void(Raptor thisveh))
 851                 {
 852                         AuxiliaryXhair[1].axh_image = vCROSS_LOCK;
 853                 }
 854
 855 #endif
 856 #endif