qcsrc/common/vehicles/vehicle/raptor.qc

   1 #ifndef VEHICLE_RAPTOR
   2 #define VEHICLE_RAPTOR
   3 #include "raptor.qh"
   4
   5 #include "raptor_weapons.qc"
   6
   7 CLASS(Raptor, Vehicle)
   8 /* spawnflags */ ATTRIB(Raptor, spawnflags, int, VHF_DMGSHAKE | VHF_DMGROLL);
   9 /* mins       */ ATTRIB(Raptor, mins, vector, '-80 -80 0');
  10 /* maxs       */ ATTRIB(Raptor, maxs, vector, '80 80 70');
  11 /* model          */ ATTRIB(Raptor, mdl, string, "models/vehicles/raptor.dpm");
  12 /* model          */ ATTRIB(Raptor, model, string, "models/vehicles/raptor.dpm");
  13 /* head_model */ ATTRIB(Raptor, head_model, string, "");
  14 /* hud_model  */ ATTRIB(Raptor, hud_model, string, "models/vehicles/raptor_cockpit.dpm");
  15 /* tags       */ ATTRIB(Raptor, tag_head, string, "");
  16 /* tags       */ ATTRIB(Raptor, tag_hud, string, "tag_hud");
  17 /* tags       */ ATTRIB(Raptor, tag_view, string, "tag_camera");
  18 /* netname    */ ATTRIB(Raptor, netname, string, "raptor");
  19 /* fullname   */ ATTRIB(Raptor, vehicle_name, string, _("Raptor"));
  20 /* icon       */ ATTRIB(Raptor, m_icon, string, "vehicle_raptor");
  21 ENDCLASS(Raptor)
  22 REGISTER_VEHICLE(RAPTOR, NEW(Raptor));
  23
  24 #endif
  25
  26 #ifdef IMPLEMENTATION
  27
  28 #include "raptor_weapons.qc"
  29
  30 #ifdef SVQC
  31
  32 bool autocvar_g_vehicle_raptor;
  33
  34 float autocvar_g_vehicle_raptor_respawntime;
  35 float autocvar_g_vehicle_raptor_takeofftime;
  36
  37 float autocvar_g_vehicle_raptor_movestyle;
  38 float autocvar_g_vehicle_raptor_turnspeed;
  39 float autocvar_g_vehicle_raptor_pitchspeed;
  40 float autocvar_g_vehicle_raptor_pitchlimit;
  41
  42 float autocvar_g_vehicle_raptor_speed_forward;
  43 float autocvar_g_vehicle_raptor_speed_strafe;
  44 float autocvar_g_vehicle_raptor_speed_up;
  45 float autocvar_g_vehicle_raptor_speed_down;
  46 float autocvar_g_vehicle_raptor_friction;
  47
  48 float autocvar_g_vehicle_raptor_cannon_turnspeed;
  49 float autocvar_g_vehicle_raptor_cannon_turnlimit;
  50 float autocvar_g_vehicle_raptor_cannon_pitchlimit_up;
  51 float autocvar_g_vehicle_raptor_cannon_pitchlimit_down;
  52
  53 float autocvar_g_vehicle_raptor_cannon_locktarget;
  54 float autocvar_g_vehicle_raptor_cannon_locking_time;
  55 float autocvar_g_vehicle_raptor_cannon_locking_releasetime;
  56 float autocvar_g_vehicle_raptor_cannon_locked_time;
  57 float autocvar_g_vehicle_raptor_cannon_predicttarget;
  58
  59 float autocvar_g_vehicle_raptor_energy;
  60 float autocvar_g_vehicle_raptor_energy_regen;
  61 float autocvar_g_vehicle_raptor_energy_regen_pause;
  62
  63 float autocvar_g_vehicle_raptor_health;
  64 float autocvar_g_vehicle_raptor_health_regen;
  65 float autocvar_g_vehicle_raptor_health_regen_pause;
  66
  67 float autocvar_g_vehicle_raptor_shield;
  68 float autocvar_g_vehicle_raptor_shield_regen;
  69 float autocvar_g_vehicle_raptor_shield_regen_pause;
  70
  71 float autocvar_g_vehicle_raptor_bouncefactor;
  72 float autocvar_g_vehicle_raptor_bouncestop;
  73 vector autocvar_g_vehicle_raptor_bouncepain;
  74
  75 .entity bomb1;
  76 .entity bomb2;
  77
  78 float raptor_altitude(float amax)
  79 {SELFPARAM();
  80         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * amax), MOVE_WORLDONLY, self);
  81         return vlen(self.origin - trace_endpos);
  82 }
  83
  84 void raptor_land()
  85 {SELFPARAM();
  86         float hgt;
  87
  88         hgt = raptor_altitude(512);
  89         self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
  90         self.angles_x *= 0.95;
  91         self.angles_z *= 0.95;
  92
  93         if(hgt < 128)
  94         if(hgt > 0)
  95                 self.frame = (hgt / 128) * 25;
  96
  97         self.bomb1.gun1.avelocity_y = 90 + ((self.frame / 25) * 2000);
  98         self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
  99
 100         if(hgt < 16)
 101         {
 102                 self.movetype = MOVETYPE_TOSS;
 103                 self.think      = vehicles_think;
 104                 self.frame      = 0;
 105         }
 106
 107         self.nextthink  = time;
 108
 109         CSQCMODEL_AUTOUPDATE(self);
 110 }
 111
 112 void raptor_exit(float eject)
 113 {SELFPARAM();
 114         vector spot;
 115         self.tur_head.exteriormodeltoclient = world;
 116
 117         if(!IS_DEAD(self))
 118         {
 119                 self.think        = raptor_land;
 120                 self.nextthink  = time;
 121         }
 122
 123         if(!self.owner)
 124                 return;
 125
 126         makevectors(self.angles);
 127         if(eject)
 128         {
 129                 spot = self.origin + v_forward * 100 + '0 0 64';
 130                 spot = vehicles_findgoodexit(spot);
 131                 setorigin(self.owner , spot);
 132                 self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 133                 self.owner.oldvelocity = self.owner.velocity;
 134         }
 135         else
 136         {
 137                 if(vlen(self.velocity) > 2 * autocvar_sv_maxairspeed)
 138                 {
 139                         self.owner.velocity = normalize(self.velocity) * autocvar_sv_maxairspeed * 2;
 140                         self.owner.velocity_z += 200;
 141                         spot = self.origin + v_forward * 32 + '0 0 64';
 142                         spot = vehicles_findgoodexit(spot);
 143                 }
 144                 else
 145                 {
 146                         self.owner.velocity = self.velocity * 0.5;
 147                         self.owner.velocity_z += 10;
 148                         spot = self.origin - v_forward * 200 + '0 0 64';
 149                         spot = vehicles_findgoodexit(spot);
 150                 }
 151                 self.owner.oldvelocity = self.owner.velocity;
 152                 setorigin(self.owner , spot);
 153         }
 154
 155         antilag_clear(self.owner);
 156         self.owner = world;
 157 }
 158
 159 float raptor_frame()
 160 {SELFPARAM();
 161         entity player, raptor;
 162         float ftmp = 0;
 163         vector df;
 164
 165         if(intermission_running)
 166         {
 167                 self.vehicle.velocity = '0 0 0';
 168                 self.vehicle.avelocity = '0 0 0';
 169                 return 1;
 170         }
 171
 172         player = self;
 173         raptor = self.vehicle;
 174         setself(raptor);
 175
 176         vehicles_frame(raptor, player);
 177
 178         /*
 179         ftmp = vlen(self.velocity);
 180         if(ftmp > autocvar_g_vehicle_raptor_speed_forward)
 181                 ftmp = 1;
 182         else
 183                 ftmp = ftmp / autocvar_g_vehicle_raptor_speed_forward;
 184         */
 185
 186         if(self.sound_nexttime < time)
 187         {
 188                 self.sound_nexttime = time + 7.955812;
 189                 //sound (self.tur_head, CH_TRIGGER_SINGLE, SND_VEH_RAPTOR_FLY, 1 - ftmp,   ATTEN_NORM );
 190                 sound (self, CH_TRIGGER_SINGLE, SND_VEH_RAPTOR_SPEED, 1, ATTEN_NORM);
 191                 self.wait = ftmp;
 192         }
 193         /*
 194         else if(fabs(ftmp - self.wait) > 0.2)
 195         {
 196                 sound (self.tur_head, CH_TRIGGER_SINGLE, SND_Null, 1 - ftmp,   ATTEN_NORM );
 197                 sound (self, CH_TRIGGER_SINGLE, SND_Null, ftmp, ATTEN_NORM);
 198                 self.wait = ftmp;
 199         }
 200         */
 201
 202         if(IS_DEAD(raptor))
 203         {
 204                 setself(player);
 205                 player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 206                 return 1;
 207         }
 208         crosshair_trace(player);
 209
 210         //if(time - self.lastteleporttime < 1)
 211         //{
 212                 if(raptor.angles_z > 50 || raptor.angles_z < -50)
 213                 {
 214                         if(player.BUTTON_JUMP)
 215                         {
 216                                 player.BUTTON_CROUCH = true;
 217                                 player.BUTTON_JUMP = false;
 218                         }
 219                 }
 220         //}
 221
 222         vector vang;
 223         vang = raptor.angles;
 224         df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 225         vang_x *= -1;
 226         df_x *= -1;
 227         if(df_x > 180)  df_x -= 360;
 228         if(df_x < -180) df_x += 360;
 229         if(df_y > 180)  df_y -= 360;
 230         if(df_y < -180) df_y += 360;
 231
 232         ftmp = shortangle_f(player.v_angle_y - vang_y, vang_y);
 233         if(ftmp > 180)  ftmp -= 360; if(ftmp < -180) ftmp += 360;
 234         raptor.avelocity_y = bound(-autocvar_g_vehicle_raptor_turnspeed, ftmp + raptor.avelocity_y * 0.9, autocvar_g_vehicle_raptor_turnspeed);
 235
 236         // Pitch
 237         ftmp = 0;
 238         if(player.movement_x > 0 && vang_x < autocvar_g_vehicle_raptor_pitchlimit) ftmp = 5;
 239         else if(player.movement_x < 0 && vang_x > -autocvar_g_vehicle_raptor_pitchlimit) ftmp = -20;
 240
 241         df_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x , autocvar_g_vehicle_raptor_pitchlimit);
 242         ftmp = vang_x - bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x + ftmp, autocvar_g_vehicle_raptor_pitchlimit);
 243         raptor.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchspeed, ftmp + raptor.avelocity_x * 0.9, autocvar_g_vehicle_raptor_pitchspeed);
 244
 245         raptor.angles_x = anglemods(raptor.angles_x);
 246         raptor.angles_y = anglemods(raptor.angles_y);
 247         raptor.angles_z = anglemods(raptor.angles_z);
 248
 249         if(autocvar_g_vehicle_raptor_movestyle == 1)
 250                 makevectors('0 1 0' * raptor.angles_y);
 251         else
 252                 makevectors(player.v_angle);
 253
 254         df = raptor.velocity * -autocvar_g_vehicle_raptor_friction;
 255
 256         if(player.movement_x != 0)
 257         {
 258                 if(player.movement_x > 0)
 259                         df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 260                 else if(player.movement_x < 0)
 261                         df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 262         }
 263
 264         if(player.movement_y != 0)
 265         {
 266                 if(player.movement_y < 0)
 267                         df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 268                 else if(player.movement_y > 0)
 269                         df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 270
 271                 raptor.angles_z = bound(-30,raptor.angles_z + (player.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 272         }
 273         else
 274         {
 275                 raptor.angles_z *= 0.95;
 276                 if(raptor.angles_z >= -1 && raptor.angles_z <= -1)
 277                         raptor.angles_z = 0;
 278         }
 279
 280         if(player.BUTTON_CROUCH)
 281                 df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 282         else if (player.BUTTON_JUMP)
 283                 df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 284
 285         raptor.velocity  += df * frametime;
 286         player.velocity = player.movement  = raptor.velocity;
 287         setorigin(player, raptor.origin + '0 0 32');
 288
 289         player.vehicle_weapon2mode = raptor.vehicle_weapon2mode;
 290
 291         vector vf, ad;
 292         // Target lock & predict
 293         if(autocvar_g_vehicle_raptor_cannon_locktarget == 2)
 294         {
 295                 if(raptor.gun1.lock_time < time || IS_DEAD(raptor.gun1.enemy) || STAT(FROZEN, raptor.gun1.enemy))
 296                         raptor.gun1.enemy = world;
 297
 298                 if(trace_ent)
 299                 if(trace_ent.movetype)
 300                 if(trace_ent.takedamage)
 301                 if(!IS_DEAD(trace_ent) && !STAT(FROZEN, trace_ent))
 302                 {
 303                         if(teamplay)
 304                         {
 305                                 if(trace_ent.team != player.team)
 306                                 {
 307                                         raptor.gun1.enemy = trace_ent;
 308                                         raptor.gun1.lock_time = time + 5;
 309                                 }
 310                         }
 311                         else
 312                         {
 313                                 raptor.gun1.enemy = trace_ent;
 314                                 raptor.gun1.lock_time = time + 0.5;
 315                         }
 316                 }
 317
 318                 if(raptor.gun1.enemy)
 319                 {
 320                         float distance, impact_time;
 321
 322                         vf = real_origin(raptor.gun1.enemy);
 323                         UpdateAuxiliaryXhair(player, vf, '1 0 0', 1);
 324                         vector _vel = raptor.gun1.enemy.velocity;
 325                         if(raptor.gun1.enemy.movetype == MOVETYPE_WALK)
 326                                 _vel_z *= 0.1;
 327
 328                         if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 329                         {
 330                                 ad = vf;
 331                                 distance = vlen(ad - player.origin);
 332                                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 333                                 ad = vf + _vel * impact_time;
 334                                 trace_endpos = ad;
 335                         }
 336                         else
 337                                 trace_endpos = vf;
 338                 }
 339         }
 340         else if(autocvar_g_vehicle_raptor_cannon_locktarget == 1)
 341         {
 342
 343                 vehicles_locktarget((1 / autocvar_g_vehicle_raptor_cannon_locking_time) * frametime,
 344                                                          (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * frametime,
 345                                                          autocvar_g_vehicle_raptor_cannon_locked_time);
 346
 347                 if(self.lock_target != world)
 348                 if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 349                 if(self.lock_strength == 1)
 350                 {
 351                         float i, distance, impact_time;
 352
 353                         vf = real_origin(raptor.lock_target);
 354                         ad = vf;
 355                         for(i = 0; i < 4; ++i)
 356                         {
 357                                 distance = vlen(ad - raptor.origin);
 358                                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 359                                 ad = vf + raptor.lock_target.velocity * impact_time;
 360                         }
 361                         trace_endpos = ad;
 362                 }
 363
 364                 if(self.lock_target)
 365                 {
 366                         if(raptor.lock_strength == 1)
 367                                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '1 0 0', 1);
 368                         else if(self.lock_strength > 0.5)
 369                                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 1 0', 1);
 370                         else if(self.lock_strength < 0.5)
 371                                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 0 1', 1);
 372                 }
 373         }
 374
 375
 376         vehicle_aimturret(raptor, trace_endpos, raptor.gun1, "fire1",
 377                                                   autocvar_g_vehicle_raptor_cannon_pitchlimit_down * -1,  autocvar_g_vehicle_raptor_cannon_pitchlimit_up,
 378                                                   autocvar_g_vehicle_raptor_cannon_turnlimit * -1,  autocvar_g_vehicle_raptor_cannon_turnlimit,  autocvar_g_vehicle_raptor_cannon_turnspeed);
 379
 380         vehicle_aimturret(raptor, trace_endpos, raptor.gun2, "fire1",
 381                                                   autocvar_g_vehicle_raptor_cannon_pitchlimit_down * -1,  autocvar_g_vehicle_raptor_cannon_pitchlimit_up,
 382                                                   autocvar_g_vehicle_raptor_cannon_turnlimit * -1,  autocvar_g_vehicle_raptor_cannon_turnlimit,  autocvar_g_vehicle_raptor_cannon_turnspeed);
 383
 384         /*
 385         ad = ad * 0.5;
 386         v_forward = vf * 0.5;
 387         traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, raptor);
 388         UpdateAuxiliaryXhair(player, trace_endpos, '0 1 0', 0);
 389         */
 390
 391         Weapon wep1 = WEP_RAPTOR;
 392         if(!forbidWeaponUse(player))
 393         if(player.BUTTON_ATCK)
 394         if (wep1.wr_checkammo1(wep1))
 395         {
 396             .entity weaponentity = weaponentities[0];
 397                 wep1.wr_think(wep1, self, weaponentity, 1);
 398         }
 399
 400         if(self.vehicle_flags  & VHF_SHIELDREGEN)
 401                 vehicles_regen(raptor.dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime, true);
 402
 403         if(self.vehicle_flags  & VHF_HEALTHREGEN)
 404                 vehicles_regen(raptor.dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime, false);
 405
 406         if(self.vehicle_flags  & VHF_ENERGYREGEN)
 407                 vehicles_regen(raptor.cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime, false);
 408
 409         Weapon wep2a = WEP_RAPTOR_BOMB;
 410         if(!forbidWeaponUse(player))
 411         if(raptor.vehicle_weapon2mode == RSM_BOMB)
 412         {
 413                 if(time > raptor.lip + autocvar_g_vehicle_raptor_bombs_refire)
 414                 if(player.BUTTON_ATCK2)
 415                 {
 416                     .entity weaponentity = weaponentities[1];
 417                         wep2a.wr_think(wep2a, self, weaponentity, 2);
 418                         raptor.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 419                         raptor.lip   = time;
 420                 }
 421         }
 422         else
 423         {
 424                 Weapon wep2b = WEP_RAPTOR_FLARE;
 425                 if(time > raptor.lip + autocvar_g_vehicle_raptor_flare_refire)
 426                 if(player.BUTTON_ATCK2)
 427                 {
 428                     .entity weaponentity = weaponentities[1];
 429                         wep2b.wr_think(wep2b, self, weaponentity, 2);
 430                         raptor.delay = time + autocvar_g_vehicle_raptor_flare_refire;
 431                         raptor.lip   = time;
 432                 }
 433         }
 434
 435         raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 436         player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 437         player.vehicle_ammo2 = (player.vehicle_reload2 == 100) ? 100 : 0;
 438
 439         if(self.bomb1.cnt < time)
 440         {
 441                 entity _missile = findchainentity(enemy, raptor);
 442                 float _incomming = 0;
 443                 while(_missile)
 444                 {
 445                         if(_missile.flags & FL_PROJECTILE)
 446                         if(MISSILE_IS_TRACKING(_missile))
 447                         if(vlen(self.origin - _missile.origin) < 2 * autocvar_g_vehicle_raptor_flare_range)
 448                                 ++_incomming;
 449
 450                         _missile = _missile.chain;
 451                 }
 452
 453                 if(_incomming)
 454                         sound(self, CH_PAIN_SINGLE, SND_VEH_MISSILE_ALARM, VOL_BASE, ATTEN_NONE);
 455
 456                 self.bomb1.cnt = time + 1;
 457         }
 458
 459
 460         VEHICLE_UPDATE_PLAYER(player, health, raptor);
 461         VEHICLE_UPDATE_PLAYER(player, energy, raptor);
 462         if(self.vehicle_flags & VHF_HASSHIELD)
 463                 VEHICLE_UPDATE_PLAYER(player, shield, raptor);
 464
 465         player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 466
 467         setself(player);
 468         return 1;
 469 }
 470
 471 float raptor_takeoff()
 472 {SELFPARAM();
 473         entity player, raptor;
 474
 475         player = self;
 476         raptor = self.vehicle;
 477         setself(raptor);
 478
 479         self.nextthink = time;
 480         CSQCMODEL_AUTOUPDATE(self);
 481         self.nextthink = 0; // will this work?
 482
 483         if(self.sound_nexttime < time)
 484         {
 485                 self.sound_nexttime = time + 7.955812; //soundlength("vehicles/raptor_fly.wav");
 486                 sound (self, CH_TRIGGER_SINGLE, SND_VEH_RAPTOR_SPEED, VOL_VEHICLEENGINE, ATTEN_NORM);
 487         }
 488
 489         // Takeoff sequense
 490         if(raptor.frame < 25)
 491         {
 492                 raptor.frame += 25 / (autocvar_g_vehicle_raptor_takeofftime / sys_frametime);
 493                 raptor.velocity_z = min(raptor.velocity_z * 1.5, 256);
 494                 self.bomb1.gun1.avelocity_y = 90 + ((raptor.frame / 25) * 25000);
 495                 self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 496                 player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 497
 498                 setorigin(player, raptor.origin + '0 0 32');
 499         }
 500         else
 501                 player.PlayerPhysplug = raptor_frame;
 502
 503         if(self.vehicle_flags  & VHF_SHIELDREGEN)
 504                 vehicles_regen(raptor.dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime, true);
 505
 506         if(self.vehicle_flags  & VHF_HEALTHREGEN)
 507                 vehicles_regen(raptor.dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime, false);
 508
 509         if(self.vehicle_flags  & VHF_ENERGYREGEN)
 510                 vehicles_regen(raptor.cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime, false);
 511
 512
 513         raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 514         player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 515         player.vehicle_ammo2 = (player.vehicle_reload2 == 100) ? 100 : 0;
 516
 517         VEHICLE_UPDATE_PLAYER(player, health, raptor);
 518         VEHICLE_UPDATE_PLAYER(player, energy, raptor);
 519         if(self.vehicle_flags & VHF_HASSHIELD)
 520                 VEHICLE_UPDATE_PLAYER(player, shield, raptor);
 521
 522         player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 523         setself(player);
 524         return 1;
 525 }
 526
 527 void raptor_blowup()
 528 {SELFPARAM();
 529         self.deadflag   = DEAD_DEAD;
 530         self.vehicle_exit(VHEF_NORMAL);
 531         RadiusDamage (self, self.enemy, 250, 15, 250, world, world, 250, DEATH_VH_RAPT_DEATH.m_id, world);
 532
 533         self.alpha                = -1;
 534         self.movetype      = MOVETYPE_NONE;
 535         self.effects            = EF_NODRAW;
 536         self.colormod      = '0 0 0';
 537         self.avelocity    = '0 0 0';
 538         self.velocity      = '0 0 0';
 539
 540         setorigin(self, self.pos1);
 541         self.touch = func_null;
 542         self.nextthink = 0;
 543 }
 544
 545 void raptor_diethink()
 546 {SELFPARAM();
 547         if(time >= self.wait)
 548                 self.think = raptor_blowup;
 549
 550         if(random() < 0.05)
 551         {
 552                 sound (self, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 553                 Send_Effect(EFFECT_EXPLOSION_SMALL, randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 554         }
 555         self.nextthink = time;
 556
 557         CSQCMODEL_AUTOUPDATE(self);
 558 }
 559
 560 // If we dont do this ever now and then, the raptors rotors
 561 // stop working, presumably due to angle overflow. cute.
 562 void raptor_rotor_anglefix()
 563 {SELFPARAM();
 564         self.gun1.angles_y = anglemods(self.gun1.angles_y);
 565         self.gun2.angles_y = anglemods(self.gun2.angles_y);
 566         self.nextthink = time + 15;
 567 }
 568
 569 float raptor_impulse(float _imp)
 570 {SELFPARAM();
 571         switch(_imp)
 572         {
 573                 case IMP_weapon_group_1.impulse:
 574                         self.vehicle.vehicle_weapon2mode = RSM_BOMB;
 575                         CSQCVehicleSetup(self, 0);
 576                         return true;
 577                 case IMP_weapon_group_2.impulse:
 578                         self.vehicle.vehicle_weapon2mode = RSM_FLARE;
 579                         CSQCVehicleSetup(self, 0);
 580                         return true;
 581
 582                 case IMP_weapon_next_byid.impulse:
 583                 case IMP_weapon_next_bypriority.impulse:
 584                 case IMP_weapon_next_bygroup.impulse:
 585                         self.vehicle.vehicle_weapon2mode += 1;
 586                         if(self.vehicle.vehicle_weapon2mode > RSM_LAST)
 587                                 self.vehicle.vehicle_weapon2mode = RSM_FIRST;
 588
 589                         CSQCVehicleSetup(self, 0);
 590                         return true;
 591                 case IMP_weapon_last.impulse:
 592                 case IMP_weapon_prev_byid.impulse:
 593                 case IMP_weapon_prev_bypriority.impulse:
 594                 case IMP_weapon_prev_bygroup.impulse:
 595                         self.vehicle.vehicle_weapon2mode -= 1;
 596                         if(self.vehicle.vehicle_weapon2mode < RSM_FIRST)
 597                                 self.vehicle.vehicle_weapon2mode = RSM_LAST;
 598
 599                         CSQCVehicleSetup(self, 0);
 600                         return true;
 601
 602                 /*
 603                 case IMP_weapon_drop.impulse: // toss gun, could be used to exit?
 604                         break;
 605                 case IMP_weapon_reload.impulse: // Manual minigun reload?
 606                         break;
 607                 */
 608         }
 609         return false;
 610 }
 611
 612 spawnfunc(vehicle_raptor)
 613 {
 614         if(!autocvar_g_vehicle_raptor) { remove(self); return; }
 615         if(!vehicle_initialize(VEH_RAPTOR, false)) { remove(self); return; }
 616 }
 617
 618                 METHOD(Raptor, vr_impact, void(Raptor thisveh))
 619                 {
 620                         if(autocvar_g_vehicle_raptor_bouncepain)
 621                                 vehicles_impact(autocvar_g_vehicle_raptor_bouncepain_x, autocvar_g_vehicle_raptor_bouncepain_y, autocvar_g_vehicle_raptor_bouncepain_z);
 622                 }
 623                 METHOD(Raptor, vr_enter, void(Raptor thisveh))
 624                 {
 625                         self.vehicle_weapon2mode = RSM_BOMB;
 626                         self.owner.PlayerPhysplug = raptor_takeoff;
 627                         self.movetype      = MOVETYPE_BOUNCEMISSILE;
 628                         self.solid                = SOLID_SLIDEBOX;
 629                         self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_raptor_health) * 100;
 630                         self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_raptor_shield) * 100;
 631                         self.velocity_z = 1; // Nudge upwards to takeoff sequense can work.
 632                         self.tur_head.exteriormodeltoclient = self.owner;
 633
 634                         self.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 635                         self.lip   = time;
 636
 637                         if(self.owner.flagcarried)
 638                            setorigin(self.owner.flagcarried, '-20 0 96');
 639
 640                         CSQCVehicleSetup(self.owner, 0);
 641                 }
 642                 METHOD(Raptor, vr_death, void(Raptor thisveh))
 643                 {
 644                         self.health                             = 0;
 645                         self.event_damage               = func_null;
 646                         self.solid                              = SOLID_CORPSE;
 647                         self.takedamage                 = DAMAGE_NO;
 648                         self.deadflag                   = DEAD_DYING;
 649                         self.movetype                   = MOVETYPE_BOUNCE;
 650                         self.think                              = raptor_diethink;
 651                         self.nextthink                  = time;
 652                         self.wait                               = time + 5 + (random() * 5);
 653
 654                         Send_Effect(EFFECT_EXPLOSION_MEDIUM, findbetterlocation (self.origin, 16), '0 0 0', 1);
 655
 656                         self.velocity_z += 600;
 657
 658                         self.avelocity = '0 0.5 1' * (random() * 400);
 659                         self.avelocity -= '0 0.5 1' * (random() * 400);
 660
 661                         self.colormod = '-0.5 -0.5 -0.5';
 662                         self.touch = raptor_blowup;
 663                 }
 664                 METHOD(Raptor, vr_spawn, void(Raptor thisveh))
 665                 {
 666                         if(!self.gun1)
 667                         {
 668                                 entity spinner;
 669                                 vector ofs;
 670
 671                                 //FIXME: Camera is in a bad place in HUD model.
 672                                 //setorigin(self.vehicle_viewport, '25 0 5');
 673
 674                                 self.vehicles_impulse   = raptor_impulse;
 675
 676                                 self.frame = 0;
 677
 678                                 self.bomb1 = new(raptor_bomb);
 679                                 self.bomb2 = new(raptor_bomb);
 680                                 self.gun1  = new(raptor_gun);
 681                                 self.gun2  = new(raptor_gun);
 682
 683                                 setmodel(self.bomb1, MDL_VEH_RAPTOR_CB_FOLDED);
 684                                 setmodel(self.bomb2, MDL_VEH_RAPTOR_CB_FOLDED);
 685                                 setmodel(self.gun1, MDL_VEH_RAPTOR_GUN);
 686                                 setmodel(self.gun2, MDL_VEH_RAPTOR_GUN);
 687                                 setmodel(self.tur_head, MDL_VEH_RAPTOR_TAIL);
 688
 689                                 setattachment(self.bomb1, self, "bombmount_left");
 690                                 setattachment(self.bomb2, self, "bombmount_right");
 691                                 setattachment(self.tur_head, self,"root");
 692
 693                                 // FIXMODEL Guns mounts to angled bones
 694                                 self.bomb1.angles = self.angles;
 695                                 self.angles = '0 0 0';
 696                                 // This messes up gun-aim, so work arround it.
 697                                 //setattachment(self.gun1, self, "gunmount_left");
 698                                 ofs = gettaginfo(self, gettagindex(self, "gunmount_left"));
 699                                 ofs -= self.origin;
 700                                 setattachment(self.gun1, self, "");
 701                                 setorigin(self.gun1, ofs);
 702
 703                                 //setattachment(self.gun2, self, "gunmount_right");
 704                                 ofs = gettaginfo(self, gettagindex(self, "gunmount_right"));
 705                                 ofs -= self.origin;
 706                                 setattachment(self.gun2, self, "");
 707                                 setorigin(self.gun2, ofs);
 708
 709                                 self.angles = self.bomb1.angles;
 710                                 self.bomb1.angles = '0 0 0';
 711
 712                                 spinner = new(raptor_spinner);
 713                                 spinner.owner = self;
 714                                 setmodel(spinner, MDL_VEH_RAPTOR_PROP);
 715                                 setattachment(spinner, self, "engine_left");
 716                                 spinner.movetype = MOVETYPE_NOCLIP;
 717                                 spinner.avelocity = '0 90 0';
 718                                 self.bomb1.gun1 = spinner;
 719
 720                                 spinner = new(raptor_spinner);
 721                                 spinner.owner = self;
 722                                 setmodel(spinner, MDL_VEH_RAPTOR_PROP);
 723                                 setattachment(spinner, self, "engine_right");
 724                                 spinner.movetype = MOVETYPE_NOCLIP;
 725                                 spinner.avelocity = '0 -90 0';
 726                                 self.bomb1.gun2 = spinner;
 727
 728                                 // Sigh.
 729                                 self.bomb1.think = raptor_rotor_anglefix;
 730                                 self.bomb1.nextthink = time;
 731
 732                                 self.mass                          = 1 ;
 733                         }
 734
 735                         self.frame                = 0;
 736                         self.vehicle_health = autocvar_g_vehicle_raptor_health;
 737                         self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 738                         self.movetype      = MOVETYPE_TOSS;
 739                         self.solid                = SOLID_SLIDEBOX;
 740                         self.vehicle_energy = 1;
 741
 742                         self.PlayerPhysplug = raptor_frame;
 743
 744                         self.bomb1.gun1.avelocity_y = 90;
 745                         self.bomb1.gun2.avelocity_y = -90;
 746
 747                         self.delay = time;
 748
 749                         self.bouncefactor = autocvar_g_vehicle_raptor_bouncefactor;
 750                         self.bouncestop = autocvar_g_vehicle_raptor_bouncestop;
 751                         self.damageforcescale = 0.25;
 752                         self.vehicle_health = autocvar_g_vehicle_raptor_health;
 753                         self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 754                 }
 755                 METHOD(Raptor, vr_setup, void(Raptor thisveh))
 756                 {
 757                         if(autocvar_g_vehicle_raptor_shield)
 758                                 self.vehicle_flags |= VHF_HASSHIELD;
 759
 760                         if(autocvar_g_vehicle_raptor_shield_regen)
 761                                 self.vehicle_flags |= VHF_SHIELDREGEN;
 762
 763                         if(autocvar_g_vehicle_raptor_health_regen)
 764                                 self.vehicle_flags |= VHF_HEALTHREGEN;
 765
 766                         if(autocvar_g_vehicle_raptor_energy_regen)
 767                                 self.vehicle_flags |= VHF_ENERGYREGEN;
 768
 769                         self.vehicle_exit = raptor_exit;
 770                         self.respawntime = autocvar_g_vehicle_raptor_respawntime;
 771                         self.vehicle_health = autocvar_g_vehicle_raptor_health;
 772                         self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 773                         self.max_health = self.vehicle_health;
 774                 }
 775
 776 #endif
 777 #ifdef CSQC
 778
 779                 METHOD(Raptor, vr_hud, void(Raptor thisveh))
 780                 {
 781                         Vehicles_drawHUD(VEH_RAPTOR.m_icon, "vehicle_raptor_weapon1", "vehicle_raptor_weapon2",
 782                                                          "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 783                                                          "vehicle_icon_ammo2", autocvar_hud_progressbar_vehicles_ammo2_color);
 784                 }
 785                 METHOD(Raptor, vr_crosshair, void(Raptor thisveh))
 786                 {
 787                         string crosshair;
 788
 789                         switch(weapon2mode)
 790                         {
 791                                 case RSM_FLARE: crosshair = vCROSS_RAIN;  break;
 792                                 case RSM_BOMB:  crosshair = vCROSS_BURST; break;
 793                                 default:        crosshair = vCROSS_BURST;
 794                         }
 795
 796                         vector tmpSize = '0 0 0';
 797                         if(weapon2mode != RSM_FLARE)
 798                         {
 799                                 vector where;
 800
 801                                 if(!dropmark)
 802                                 {
 803                                         dropmark = spawn();
 804                                         dropmark.owner = self;
 805                                         dropmark.gravity = 1;
 806                                 }
 807
 808                                 float reload2 = STAT(VEHICLESTAT_RELOAD2) * 0.01;
 809                                 if(reload2 == 1)
 810                                 {
 811                                         setorigin(dropmark, pmove_org);
 812                                         dropmark.velocity = pmove_vel;
 813                                         tracetoss(dropmark, self);
 814
 815                                         where = project_3d_to_2d(trace_endpos);
 816
 817                                         setorigin(dropmark, trace_endpos);
 818                                         tmpSize = draw_getimagesize(vCROSS_DROP) * autocvar_cl_vehicles_crosshair_size;
 819
 820                                         if (!(where.z < 0 || where.x < 0 || where.y < 0 || where.x > vid_conwidth || where.y > vid_conheight))
 821                                         {
 822                                                 where.x -= tmpSize.x * 0.5;
 823                                                 where.y -= tmpSize.y * 0.5;
 824                                                 where.z = 0;
 825                                                 drawpic(where, vCROSS_DROP, tmpSize, '0 1 0', autocvar_crosshair_alpha * 0.9, DRAWFLAG_ADDITIVE);
 826                                                 drawpic(where, vCROSS_DROP, tmpSize, '0 1 0', autocvar_crosshair_alpha * 0.6, DRAWFLAG_NORMAL); // Ensure visibility against bright bg
 827                                         }
 828                                         dropmark.cnt = time + 5;
 829                                 }
 830                                 else
 831                                 {
 832                                         if(dropmark.cnt > time)
 833                                         {
 834                                                 where = project_3d_to_2d(dropmark.origin);
 835                                                 tmpSize = draw_getimagesize(vCROSS_DROP) * autocvar_cl_vehicles_crosshair_size * 1.25;
 836
 837                                                 if (!(where.z < 0 || where.x < 0 || where.y < 0 || where.x > vid_conwidth || where.y > vid_conheight))
 838                                                 {
 839                                                         where.x -= tmpSize.x * 0.5;
 840                                                         where.y -= tmpSize.y * 0.5;
 841                                                         where.z = 0;
 842                                                         drawpic(where, vCROSS_DROP, tmpSize, '1 0 0', autocvar_crosshair_alpha * 0.9, DRAWFLAG_ADDITIVE);
 843                                                         drawpic(where, vCROSS_DROP, tmpSize, '1 0 0', autocvar_crosshair_alpha * 0.6, DRAWFLAG_NORMAL); // Ensure visibility against bright bg
 844                                                 }
 845                                         }
 846                                 }
 847                         }
 848
 849                         Vehicles_drawCrosshair(crosshair);
 850                 }
 851                 METHOD(Raptor, vr_setup, void(Raptor thisveh))
 852                 {
 853                         AuxiliaryXhair[1].axh_image = vCROSS_LOCK;
 854                 }
 855
 856 #endif
 857 #endif