qcsrc/common/weapons/all.qc

   1 #include "all.qh"
   2 #ifndef WEAPONS_ALL_C
   3 #define WEAPONS_ALL_C
   4
   5 #if defined(CSQC)
   6         #include <client/main.qh>
   7         #include <common/constants.qh>
   8         #include <common/deathtypes/all.qh>
   9         #include <common/physics/movetypes/movetypes.qh>
  10         #include <common/stats.qh>
  11         #include <common/util.qh>
  12         #include <common/weapons/calculations.qc>
  13         #include <common/weapons/weapon/_mod.inc>
  14         #include <lib/csqcmodel/cl_model.qh>
  15         #include <lib/csqcmodel/interpolate.qh>
  16         #include <lib/warpzone/anglestransform.qh>
  17         #include <lib/warpzone/client.qh>
  18         #include <lib/warpzone/common.qh>
  19 #elif defined(MENUQC)
  20         #include <common/weapons/weapon/_mod.inc>
  21 #elif defined(SVQC)
  22         #include <common/constants.qh>
  23         #include <common/deathtypes/all.qh>
  24         #include <common/items/_mod.qh>
  25         #include <common/mapinfo.qh>
  26         #include <common/monsters/_mod.qh>
  27         #include <common/notifications/all.qh>
  28         #include <common/stats.qh>
  29         #include <common/teams.qh>
  30         #include <common/util.qh>
  31         #include <common/weapons/calculations.qc>
  32         #include <common/weapons/config.qc>
  33         #include <common/weapons/config.qh>
  34         #include <common/weapons/weapon/_mod.inc>
  35         #include <lib/csqcmodel/sv_model.qh>
  36         #include <lib/warpzone/anglestransform.qh>
  37         #include <lib/warpzone/common.qh>
  38         #include <lib/warpzone/server.qh>
  39         #include <lib/warpzone/util_server.qh>
  40         #include <server/command/_mod.qh>
  41         #include <server/hook.qh>
  42         #include <server/items/spawning.qh>
  43         #include <server/mutators/_mod.qh>
  44         #include <server/portals.qh>
  45         #include <server/weapons/common.qh>
  46         #include <server/weapons/csqcprojectile.qh>
  47         #include <server/weapons/tracing.qh>
  48 #endif
  49
  50
  51 // WEAPON PLUGIN SYSTEM
  52
  53 WepSet _WepSet_FromWeapon(int a)
  54 {
  55         a -= WEP_FIRST;
  56         if (REGISTRY_MAX(Weapons) > 24)
  57                 if (a >= 24)
  58                 {
  59                         a -= 24;
  60                         if (REGISTRY_MAX(Weapons) > 48)
  61                                 if (a >= 24)
  62                                 {
  63                                         a -= 24;
  64                                         return '0 0 1' * BIT(a);
  65                                 }
  66                         return '0 1 0' * BIT(a);
  67                 }
  68         return '1 0 0' * BIT(a);
  69 }
  70 #ifdef SVQC
  71         void WriteWepSet(float dst, WepSet w)
  72         {
  73                 if (REGISTRY_MAX(Weapons) > 48) WriteInt72_t(dst, w);
  74                 else if (REGISTRY_MAX(Weapons) > 24) WriteInt48_t(dst, w);
  75                 else WriteInt24_t(dst, w.x);
  76         }
  77 #endif
  78 #ifdef CSQC
  79         WepSet WepSet_GetFromStat()
  80         {
  81                 return STAT(WEAPONS);
  82         }
  83         WepSet WepSet_GetFromStat_InMap()
  84         {
  85                 return STAT(WEAPONSINMAP);
  86         }
  87         WepSet ReadWepSet()
  88         {
  89                 if (REGISTRY_MAX(Weapons) > 48) return ReadInt72_t();
  90                 if (REGISTRY_MAX(Weapons) > 24) return ReadInt48_t();
  91                 return ReadInt24_t() * '1 0 0';
  92         }
  93 #endif
  94
  95 string W_FixWeaponOrder(string order, float complete)
  96 {
  97         return fixPriorityList(order, WEP_FIRST, WEP_LAST, WEP_IMPULSE_BEGIN - WEP_FIRST, complete);
  98 }
  99 string W_NameWeaponOrder_MapFunc(string s)
 100 {
 101         int i = stof(s);
 102         if (s == "0" || i)
 103         {
 104                 entity wi = REGISTRY_GET(Weapons, i);
 105                 if (wi != WEP_Null) return wi.netname;
 106         }
 107         return s;
 108 }
 109
 110 string W_UndeprecateName(string s)
 111 {
 112         switch (s)
 113         {
 114                 case "nex": return "vortex";
 115                 case "rocketlauncher": return "devastator";
 116                 case "laser": return "blaster";
 117                 case "minstanex": return "vaporizer";
 118                 case "grenadelauncher": return "mortar";
 119                 case "uzi": return "machinegun";
 120                 case "hmg": return "okhmg";
 121                 case "rpc": return "okrpc";
 122                 default: return s;
 123         }
 124 }
 125 string W_NameWeaponOrder(string order)
 126 {
 127         return mapPriorityList(order, W_NameWeaponOrder_MapFunc);
 128 }
 129 string W_NumberWeaponOrder_MapFunc(string s)
 130 {
 131         if (s == "0" || stof(s)) return s;
 132         s = W_UndeprecateName(s);
 133         FOREACH(Weapons, it != WEP_Null && it.netname == s, return ftos(i));
 134         return s;
 135 }
 136 string W_NumberWeaponOrder(string order)
 137 {
 138         return mapPriorityList(order, W_NumberWeaponOrder_MapFunc);
 139 }
 140
 141 float W_FixWeaponOrder_BuildImpulseList_buf[REGISTRY_MAX(Weapons)];
 142 string W_FixWeaponOrder_BuildImpulseList_order;
 143 void W_FixWeaponOrder_BuildImpulseList_swap(int i, int j, entity pass)
 144 {
 145         float h;
 146         h = W_FixWeaponOrder_BuildImpulseList_buf[i];
 147         W_FixWeaponOrder_BuildImpulseList_buf[i] = W_FixWeaponOrder_BuildImpulseList_buf[j];
 148         W_FixWeaponOrder_BuildImpulseList_buf[j] = h;
 149 }
 150 float W_FixWeaponOrder_BuildImpulseList_cmp(int i, int j, entity pass)
 151 {
 152         int si = W_FixWeaponOrder_BuildImpulseList_buf[i];
 153         Weapon e1 = REGISTRY_GET(Weapons, si);
 154         int sj = W_FixWeaponOrder_BuildImpulseList_buf[j];
 155         Weapon e2 = REGISTRY_GET(Weapons, sj);
 156         int d = (e1.impulse + 9) % 10 - (e2.impulse + 9) % 10;
 157         if (d != 0) return -d;  // high impulse first!
 158         string s = strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " ");
 159         return strstrofs(s, sprintf(" %d ", si), 0)
 160                 - strstrofs(s, sprintf(" %d ", sj), 0); // low char index first!
 161 }
 162 string W_FixWeaponOrder_BuildImpulseList(string o)
 163 {
 164         int i;
 165         W_FixWeaponOrder_BuildImpulseList_order = o;
 166         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 167                 W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST] = i;
 168         heapsort(WEP_LAST - WEP_FIRST + 1, W_FixWeaponOrder_BuildImpulseList_swap, W_FixWeaponOrder_BuildImpulseList_cmp,
 169                 NULL);
 170         o = "";
 171         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 172                 o = strcat(o, " ", ftos(W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST]));
 173         W_FixWeaponOrder_BuildImpulseList_order = string_null;
 174         return substring(o, 1, -1);
 175 }
 176
 177 string W_FixWeaponOrder_AllowIncomplete(entity this, string order)
 178 {
 179         return W_FixWeaponOrder(order, 0);
 180 }
 181
 182 string W_FixWeaponOrder_ForceComplete(string order)
 183 {
 184         if (order == "") order = W_NumberWeaponOrder(cvar_defstring("cl_weaponpriority"));
 185         return W_FixWeaponOrder(order, 1);
 186 }
 187
 188 WepSet W_RandomWeapons(entity e, WepSet remaining, int n)
 189 {
 190         WepSet result = '0 0 0';
 191         for (int j = 0; j < n; ++j)
 192         {
 193                 RandomSelection_Init();
 194                 FOREACH(Weapons, it != WEP_Null, {
 195                         if (remaining & (it.m_wepset))
 196                                 RandomSelection_AddEnt(it, 1, 1);
 197                 });
 198                 Weapon w = RandomSelection_chosen_ent;
 199                 result |= WepSet_FromWeapon(w);
 200                 remaining &= ~WepSet_FromWeapon(w);
 201         }
 202         return result;
 203 }
 204
 205 // TODO: registry handles for below functions
 206 string GetAmmoPicture(Resource ammotype)
 207 {
 208         switch (ammotype)
 209         {
 210                 case RES_SHELLS:  return ITEM_Shells.m_icon;
 211                 case RES_BULLETS: return ITEM_Bullets.m_icon;
 212                 case RES_ROCKETS: return ITEM_Rockets.m_icon;
 213                 case RES_CELLS:   return ITEM_Cells.m_icon;
 214                 case RES_PLASMA:  return ITEM_Plasma.m_icon;
 215                 case RES_FUEL:    return ITEM_JetpackFuel.m_icon;
 216                 default: return "";  // wtf, no ammo type?
 217         }
 218 }
 219
 220 string GetAmmoName(Resource ammotype)
 221 {
 222         switch (ammotype)
 223         {
 224                 case RES_SHELLS:  return ITEM_Shells.m_name;
 225                 case RES_BULLETS: return ITEM_Bullets.m_name;
 226                 case RES_ROCKETS: return ITEM_Rockets.m_name;
 227                 case RES_CELLS:   return ITEM_Cells.m_name;
 228                 case RES_PLASMA:  return ITEM_Plasma.m_name;
 229                 case RES_FUEL:    return ITEM_JetpackFuel.m_name;
 230                 default:          return "batteries";
 231         }
 232 }
 233
 234 entity GetAmmoItem(Resource ammotype)
 235 {
 236         switch (ammotype)
 237         {
 238                 case RES_SHELLS:  return ITEM_Shells;
 239                 case RES_BULLETS: return ITEM_Bullets;
 240                 case RES_ROCKETS: return ITEM_Rockets;
 241                 case RES_CELLS:   return ITEM_Cells;
 242                 case RES_PLASMA:  return ITEM_Plasma;
 243                 case RES_FUEL:    return ITEM_JetpackFuel;
 244         }
 245         LOG_WARNF("Invalid ammo type %d ", ammotype.m_id);
 246         return NULL;
 247         // WEAPONTODO: use this generic func to reduce duplication ?
 248         // GetAmmoPicture  GetAmmoName  notif_arg_item_wepammo  ammo_pickupevalfunc ?
 249 }
 250
 251 #ifdef CSQC
 252 Resource GetAmmoTypeFromNum(int i)
 253 {
 254         switch (i)
 255         {
 256                 case 0: return RES_SHELLS;
 257                 case 1: return RES_BULLETS;
 258                 case 2: return RES_ROCKETS;
 259                 case 3: return RES_CELLS;
 260                 case 4: return RES_PLASMA;
 261                 case 5: return RES_FUEL;
 262                 default: return RES_NONE;
 263         }
 264 }
 265
 266 int GetAmmoStat(Resource ammotype)
 267 {
 268         switch (ammotype)
 269         {
 270                 case RES_SHELLS: return STAT_SHELLS;
 271                 case RES_BULLETS: return STAT_NAILS;
 272                 case RES_ROCKETS: return STAT_ROCKETS;
 273                 case RES_CELLS: return STAT_CELLS;
 274                 case RES_PLASMA: return STAT_PLASMA.m_id;
 275                 case RES_FUEL: return STAT_FUEL.m_id;
 276                 default: return -1;
 277         }
 278 }
 279 #endif
 280
 281 string W_Sound(string w_snd)
 282 {
 283         string output = strcat("weapons/", w_snd);
 284         MUTATOR_CALLHOOK(WeaponSound, w_snd, output);
 285         return M_ARGV(1, string);
 286 }
 287
 288 string W_Model(string w_mdl)
 289 {
 290         string output = strcat("models/weapons/", w_mdl);
 291         MUTATOR_CALLHOOK(WeaponModel, w_mdl, output);
 292         return M_ARGV(1, string);
 293 }
 294
 295 #ifdef GAMEQC
 296 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float algn)
 297 {
 298         switch (algn)
 299         {
 300                 default:
 301                 case 3:
 302                         // right alignment
 303                         break;
 304                 case 4:
 305                         // left
 306                         vecs.y = -vecs.y;
 307                         break;
 308                 case 1:
 309                 case 2:
 310                         // center
 311                         vecs.y = 0;
 312                         vecs.z -= 2;
 313                         break;
 314         }
 315         return vecs;
 316 }
 317
 318 vector shotorg_adjust_values(vector vecs, bool y_is_right, bool visual, int algn)
 319 {
 320         string s;
 321         if (visual)
 322         {
 323                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 324         }
 325         else if (STAT(SHOOTFROMEYE))
 326         {
 327                 vecs.y = vecs.z = 0;
 328         }
 329         else if (STAT(SHOOTFROMCENTER))
 330         {
 331                 vecs.y = 0;
 332                 vecs.z -= 2;
 333         }
 334         else if ((s = G_SHOOTFROMFIXEDORIGIN) != "")
 335         {
 336                 vector v = stov(s);
 337                 if (y_is_right) v.y = -v.y;
 338                 if (v.x != 0) vecs.x = v.x;
 339                 vecs.y = v.y;
 340                 vecs.z = v.z;
 341         }
 342         else  // just do the same as top
 343         {
 344                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 345         }
 346
 347         return vecs;
 348 }
 349
 350 #define shotorg_adjust shotorg_adjust_values
 351
 352 /**
 353  * supported formats:
 354  *
 355  * 1. simple animated model, muzzle flash handling on h_ model:
 356  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 357  *      tags:
 358  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 359  *        shell = casings ejection point (must be on the right hand side of the gun)
 360  *        weapon = attachment for v_tuba.md3
 361  *    v_tuba.md3 - first and third person model
 362  *    g_tuba.md3 - pickup model
 363  *
 364  * 2. simple animated model, muzzle flash handling on v_ model:
 365  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 366  *      tags:
 367  *        weapon = attachment for v_tuba.md3
 368  *    v_tuba.md3 - first and third person model
 369  *      tags:
 370  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 371  *        shell = casings ejection point (must be on the right hand side of the gun)
 372  *    g_tuba.md3 - pickup model
 373  *
 374  * 3. fully animated model, muzzle flash handling on h_ model:
 375  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 376  *      tags:
 377  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 378  *        shell = casings ejection point (must be on the right hand side of the gun)
 379  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 380  *    v_tuba.md3 - third person model
 381  *    g_tuba.md3 - pickup model
 382  *
 383  * 4. fully animated model, muzzle flash handling on v_ model:
 384  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 385  *      tags:
 386  *        shot = muzzle end (shot origin)
 387  *        shell = casings ejection point (must be on the right hand side of the gun)
 388  *    v_tuba.md3 - third person model
 389  *      tags:
 390  *        shot = muzzle end (for muzzle flashes)
 391  *    g_tuba.md3 - pickup model
 392  *
 393  * writes:
 394  *   this.origin, this.angles
 395  *   this.weaponchild
 396  *   this.movedir, this.view_ofs, this.movedir_aligned
 397  *   this.spawnorigin (SVQC only)
 398  *   attachment stuff
 399  *   anim stuff
 400  * to free:
 401  *   call again with ""
 402  *   remove the ent
 403  */
 404 void CL_WeaponEntity_SetModel(entity this, string name, bool _anim)
 405 {
 406         if (name == "")
 407         {
 408                 vector oldmin = this.mins, oldmax = this.maxs;
 409                 setmodel(this, MDL_Null);
 410                 setsize(this, oldmin, oldmax);
 411                 if (this.weaponchild) delete(this.weaponchild);
 412                 this.weaponchild = NULL;
 413                 this.movedir = '0 0 0';
 414 #ifdef SVQC
 415                 this.spawnorigin = '0 0 0';
 416 #endif
 417                 this.oldorigin = '0 0 0';
 418                 this.anim_fire1  = '0 1 0.01';
 419                 this.anim_fire2  = '0 1 0.01';
 420                 this.anim_idle   = '0 1 0.01';
 421                 this.anim_reload = '0 1 0.01';
 422         }
 423         else
 424         {
 425                 // if there is a child entity, hide it until we're sure we use it
 426                 if (this.weaponchild) this.weaponchild.model = "";
 427                 _setmodel(this, W_Model(strcat("v_", name, ".md3")));
 428                 int v_shot_idx;  // used later
 429                 (v_shot_idx = gettagindex(this, "shot")) || (v_shot_idx = gettagindex(this, "tag_shot"));
 430
 431                 _setmodel(this, W_Model(strcat("h_", name, ".iqm")));
 432                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 433                 this.anim_fire1  = animfixfps(this, '0 1 0.01', '0 0 0');
 434                 this.anim_fire2  = animfixfps(this, '1 1 0.01', '0 0 0');
 435                 this.anim_idle   = animfixfps(this, '2 1 0.01', '0 0 0');
 436                 this.anim_reload = animfixfps(this, '3 1 0.01', '0 0 0');
 437
 438                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 439                 // if we don't, this is a "real" animated model
 440                 string t;
 441                 if ((t = "weapon", gettagindex(this, t)) || (t = "tag_weapon", gettagindex(this, t)))
 442                 {
 443                         if (!this.weaponchild)
 444                         {
 445                                 this.weaponchild = new(weaponchild);
 446 #ifdef CSQC
 447                                 this.weaponchild.drawmask = MASK_NORMAL;
 448                                 this.weaponchild.renderflags |= RF_VIEWMODEL;
 449 #endif
 450                         }
 451                         _setmodel(this.weaponchild, W_Model(strcat("v_", name, ".md3")));
 452                         setsize(this.weaponchild, '0 0 0', '0 0 0');
 453                         setattachment(this.weaponchild, this, t);
 454                 }
 455                 else
 456                 {
 457                         if (this.weaponchild) delete(this.weaponchild);
 458                         this.weaponchild = NULL;
 459                 }
 460
 461                 setsize(this, '0 0 0', '0 0 0');
 462                 setorigin(this, '0 0 0');
 463                 this.angles = '0 0 0';
 464                 this.frame = 0;
 465 #ifdef SVQC
 466                 this.viewmodelforclient = NULL;
 467 #else
 468                 this.renderflags &= ~RF_VIEWMODEL;
 469 #endif
 470                 if (v_shot_idx)  // v_ model attached to invisible h_ model
 471                 {
 472                         this.movedir = gettaginfo(this.weaponchild, v_shot_idx);
 473                 }
 474                 else
 475                 {
 476                         int idx;
 477                         if ((idx = gettagindex(this, "shot")) || (idx = gettagindex(this, "tag_shot")))
 478                         {
 479                                 this.movedir = gettaginfo(this, idx);
 480                         }
 481                         else
 482                         {
 483                                 LOG_WARNF("weapon model %s does not support the 'shot' tag, will display shots TOTALLY wrong",
 484                                         this.model);
 485                                 this.movedir = '0 0 0';
 486                         }
 487                 }
 488 #ifdef SVQC
 489                 {
 490                         int idx = 0;
 491                         // v_ model attached to invisible h_ model
 492                         if (this.weaponchild
 493                                 && ((idx = gettagindex(this.weaponchild, "shell")) || (idx = gettagindex(this.weaponchild, "tag_shell"))))
 494                         {
 495                                 this.spawnorigin = gettaginfo(this.weaponchild, idx);
 496                         }
 497                         else if ((idx = gettagindex(this, "shell")) || (idx = gettagindex(this, "tag_shell")))
 498                         {
 499                                 this.spawnorigin = gettaginfo(this, idx);
 500                         }
 501                         else
 502                         {
 503                                 LOG_WARNF("weapon model %s does not support the 'shell' tag, will display casings wrong",
 504                                         this.model);
 505                                 this.spawnorigin = this.movedir;
 506                         }
 507                 }
 508 #endif
 509                 if (v_shot_idx)
 510                 {
 511                         this.oldorigin = '0 0 0';  // use regular attachment
 512                 }
 513                 else
 514                 {
 515                         int idx;
 516                         if (this.weaponchild)
 517                                 (idx = gettagindex(this, "weapon")) || (idx = gettagindex(this, "tag_weapon"));
 518                         else
 519                                 (idx = gettagindex(this, "handle")) || (idx = gettagindex(this, "tag_handle"));
 520                         if (idx)
 521                         {
 522                                 this.oldorigin = this.movedir - gettaginfo(this, idx);
 523                         }
 524                         else
 525                         {
 526                                 LOG_WARNF(
 527                                         "weapon model %s does not support the 'handle' tag "
 528                                         "and neither does the v_ model support the 'shot' tag, "
 529                                         "will display muzzle flashes TOTALLY wrong\n",
 530                                         this.model);
 531                                 this.oldorigin = '0 0 0';  // there is no way to recover from this
 532                         }
 533                 }
 534
 535 #ifdef SVQC
 536                 this.viewmodelforclient = this.owner;
 537 #else
 538                 this.renderflags |= RF_VIEWMODEL;
 539 #endif
 540         }
 541
 542         this.view_ofs = '0 0 0';
 543         this.movedir_aligned = this.movedir;
 544
 545         if (this.movedir.x >= 0)
 546         {
 547                 //int algn = STAT(GUNALIGN, this.owner);
 548                 int algn = W_GunAlign(this, STAT(GUNALIGN, this.owner));
 549         #ifdef SVQC
 550                 this.m_gunalign = algn;
 551         #endif
 552                 vector v = this.movedir;
 553                 this.movedir = shotorg_adjust(v, false, false, algn);
 554                 this.movedir_aligned = shotorg_adjust(v, false, true, algn);
 555                 this.view_ofs = this.movedir_aligned - v;
 556         }
 557         int compressed_shotorg = compressShotOrigin(this.movedir);
 558         // make them match perfectly
 559 #ifdef SVQC
 560         // null during init
 561         if (this.owner) STAT(SHOTORG, this.owner) = compressed_shotorg;
 562 #endif
 563         this.movedir = decompressShotOrigin(compressed_shotorg);
 564
 565 #ifdef SVQC
 566         this.spawnorigin += this.view_ofs;  // offset the casings origin by the same amount
 567 #endif
 568
 569         // check if an instant weapon switch occurred
 570         setorigin(this, this.view_ofs);
 571         if (!_anim) return;
 572         // reset animstate now
 573         this.wframe = WFRAME_IDLE;
 574         setanim(this, this.anim_idle, true, false, true);
 575 }
 576 #endif
 577
 578 #ifdef GAMEQC
 579
 580 REGISTER_NET_TEMP(wframe)
 581 #ifdef CSQC
 582 NET_HANDLE(wframe, bool isNew)
 583 {
 584         WFRAME fr = ReadByte();
 585         float t = ReadFloat();
 586         int slot = ReadByte();
 587         bool restartanim = ReadByte();
 588         entity wepent = viewmodels[slot];
 589         if(fr == WFRAME_IDLE)
 590                 wepent.animstate_looping = false; // we don't need to enforce idle animation
 591         else
 592         {
 593                 vector a = '0 0 0';
 594                 switch(fr)
 595                 {
 596                         default:
 597                         case WFRAME_IDLE: a = wepent.anim_idle; break;
 598                         case WFRAME_FIRE1: a = wepent.anim_fire1; break;
 599                         case WFRAME_FIRE2: a = wepent.anim_fire2; break;
 600                         case WFRAME_RELOAD: a = wepent.anim_reload; break;
 601                 }
 602                 a.z *= t;
 603                 anim_set(wepent, a, !restartanim, restartanim, restartanim);
 604         }
 605         wepent.state = ReadByte();
 606         wepent.weapon_nextthink = ReadFloat();
 607         switch (wepent.state)
 608         {
 609                 case WS_RAISE:
 610                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_raise;
 611                         break;
 612                 case WS_DROP:
 613                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_drop;
 614                         break;
 615                 default:
 616                         wepent.weapon_switchdelay = 0;
 617                         break;
 618         }
 619         return true;
 620 }
 621 #endif
 622
 623 #ifdef SVQC
 624 void wframe_send(entity actor, entity weaponentity, int wepframe, float attackrate, bool restartanim)
 625 {
 626         if (!IS_REAL_CLIENT(actor)) return;
 627         int channel = MSG_ONE;
 628         msg_entity = actor;
 629         WriteHeader(channel, wframe);
 630         WriteByte(channel, wepframe);
 631         WriteFloat(channel, attackrate);
 632         WriteByte(channel, weaponslot(weaponentity.weaponentity_fld));
 633         WriteByte(channel, restartanim);
 634         WriteByte(channel, weaponentity.state);
 635         WriteFloat(channel, weaponentity.weapon_nextthink);
 636 }
 637 #endif
 638
 639 REGISTER_NET_C2S(w_whereis)
 640 #ifdef SVQC
 641 void Weapon_whereis(Weapon this, entity cl);
 642 NET_HANDLE(w_whereis, bool)
 643 {
 644         Weapon wpn = ReadRegistered(Weapons);
 645         if (wpn != WEP_Null) Weapon_whereis(wpn, sender);
 646         return true;
 647 }
 648 #else
 649 void w_whereis(Weapon this)
 650 {
 651         int channel = MSG_C2S;
 652         WriteHeader(channel, w_whereis);
 653         WriteRegistered(Weapons, channel, this);
 654 }
 655 CLIENT_COMMAND(weapon_find, "Show spawn locations of a weapon")
 656 {
 657         switch (request)
 658         {
 659                 case CMD_REQUEST_COMMAND:
 660                 {
 661                         string s = argv(1);
 662                         if (s == "all")
 663                         {
 664                                 FOREACH(Weapons, it != WEP_Null, w_whereis(it));
 665                                 return;
 666                         }
 667                         if (s == "unowned")
 668                         {
 669                                 FOREACH(Weapons, it != WEP_Null && !(STAT(WEAPONS) & it.m_wepset), w_whereis(it));
 670                                 return;
 671                         }
 672                         FOREACH(Weapons, it != WEP_Null && it.netname == s,
 673                         {
 674                                 w_whereis(it);
 675                                 return;
 676                         });
 677                 }
 678                 default:
 679                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 680                 case CMD_REQUEST_USAGE:
 681                 {
 682                         LOG_HELP("Usage:^3 cl_cmd weapon_find <weapon>");
 683                         LOG_HELP("  Where <weapon> is the lowercase weapon name, 'all' or 'unowned'.");
 684                         return;
 685                 }
 686         }
 687 }
 688 #endif
 689
 690 #ifdef SVQC
 691 void W_MuzzleFlash_Model_AttachToShotorg(entity actor, .entity weaponentity, entity flash, vector offset)
 692 {
 693         flash.owner = actor;
 694         flash.angles_z = random() * 360;
 695
 696         entity view = actor.(weaponentity);
 697         entity exterior = actor.exteriorweaponentity;
 698
 699         if (view.oldorigin.x > 0)
 700         {
 701                 setattachment(flash, exterior, "");
 702                 setorigin(flash, view.oldorigin + offset);
 703         }
 704         else
 705         {
 706                 if (gettagindex(exterior, "shot")) setattachment(flash, exterior, "shot");
 707                 else setattachment(flash, exterior, "tag_shot");
 708                 setorigin(flash, offset);
 709         }
 710 }
 711 #elif defined(CSQC)
 712 void W_MuzzleFlash_Model_AttachToShotorg(entity wepent, entity flash, vector offset)
 713 {
 714         flash.owner = wepent;
 715         flash.angles_z = random() * 360;
 716
 717         if (gettagindex(wepent, "shot")) setattachment(flash, wepent, "shot");
 718         else setattachment(flash, wepent, "tag_shot");
 719         setorigin(flash, offset);
 720 }
 721 #endif
 722
 723 void W_MuzzleFlash_Model_Think(entity this)
 724 {
 725         this.frame += 2;
 726         this.scale *= 0.5;
 727         this.alpha -= 0.25;
 728         this.nextthink = time + 0.05;
 729
 730         if(this.alpha <= 0)
 731         {
 732                 setthink(this, SUB_Remove);
 733                 this.nextthink = time;
 734                 this.realowner.muzzle_flash = NULL;
 735                 return;
 736         }
 737 }
 738
 739 void W_MuzzleFlash_Model(entity wepent, entity muzzlemodel)
 740 {
 741         if(wepent.muzzle_flash == NULL)
 742                 wepent.muzzle_flash = spawn();
 743
 744         entity flash = wepent.muzzle_flash;
 745         setmodel(flash, muzzlemodel); // precision set below
 746
 747         flash.scale = 0.75;
 748         setthink(flash, W_MuzzleFlash_Model_Think);
 749         flash.nextthink = time + 0.02;
 750         flash.frame = 2;
 751         flash.alpha = 0.75;
 752         flash.angles_z = random() * 180;
 753         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
 754         flash.owner = flash.realowner = wepent;
 755
 756 #ifdef CSQC
 757         flash.drawmask = MASK_NORMAL;
 758 #endif
 759 }
 760
 761 REGISTER_NET_TEMP(w_muzzleflash)
 762
 763 #ifdef SVQC
 764 void W_MuzzleFlash(Weapon thiswep, entity actor, .entity weaponentity, vector shotorg, vector shotdir)
 765 {
 766         // don't show an exterior muzzle effect for the off-hand
 767         if(weaponslot(weaponentity) == 0)
 768         {
 769                 Send_Effect_Except(thiswep.m_muzzleeffect, shotorg, shotdir * 1000, 1, actor);
 770
 771                 if(thiswep.m_muzzlemodel != MDL_Null)
 772                 {
 773                         W_MuzzleFlash_Model(actor.exteriorweaponentity, thiswep.m_muzzlemodel);
 774                         W_MuzzleFlash_Model_AttachToShotorg(actor, weaponentity, actor.exteriorweaponentity.muzzle_flash, '5 0 0');
 775                 }
 776         }
 777
 778         FOREACH_CLIENT(it == actor || (IS_SPEC(it) && it.enemy == actor),
 779         {
 780                 if(!IS_REAL_CLIENT(it))
 781                         continue;
 782                 int channel = MSG_ONE;
 783                 msg_entity = it;
 784                 WriteHeader(channel, w_muzzleflash);
 785                 WriteByte(channel, thiswep.m_id);
 786                 WriteByte(channel, weaponslot(weaponentity));
 787                 WriteVector(channel, shotorg);
 788         });
 789 }
 790 #elif defined(CSQC)
 791 NET_HANDLE(w_muzzleflash, bool isNew)
 792 {
 793         return = true;
 794         int weapon_id = ReadByte();
 795         int slot = ReadByte();
 796         vector sv_shotorg = ReadVector();
 797
 798         Weapon thiswep = REGISTRY_GET(Weapons, weapon_id);
 799         vector viewangles = getpropertyvec(VF_CL_VIEWANGLES);
 800         vector forward, right, up;
 801         MAKE_VECTORS(viewangles, forward, right, up);
 802
 803         if(autocvar_chase_active)
 804         {
 805                 // in third person mode, show the muzzle flash from the server side weapon position
 806                 // we don't have a view model to reference in this case
 807                 pointparticles(thiswep.m_muzzleeffect, sv_shotorg, forward * 1000, 1);
 808                 return;
 809         }
 810         if(!autocvar_r_drawviewmodel) return;
 811
 812         entity wepent = viewmodels[slot];
 813         // get the local player entity to calculate shot origin
 814         entity rlplayer = CSQCModel_server2csqc(player_localentnum - 1);
 815         if(!rlplayer)
 816                 rlplayer = csqcplayer; // fall back to the global
 817
 818         vector md = wepent.movedir_aligned;
 819         vector vecs = ((md.x > 0) ? md : '0 0 0');
 820         vector dv = forward * vecs.x + right * -vecs.y + up * vecs.z;
 821         vector org = rlplayer.origin + rlplayer.view_ofs + dv;
 822
 823         pointparticles(thiswep.m_muzzleeffect, org, forward * 1000, 1);
 824
 825         if(thiswep.m_muzzlemodel != MDL_Null)
 826         {
 827                 W_MuzzleFlash_Model(wepent, thiswep.m_muzzlemodel);
 828                 W_MuzzleFlash_Model_AttachToShotorg(wepent, wepent.muzzle_flash, '5 0 0');
 829         }
 830 }
 831 #endif
 832
 833
 834 #endif
 835
 836 #endif
 837
 838 #ifdef SVQC
 839 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(entity this, string wo)
 840 {
 841         string o = W_FixWeaponOrder_ForceComplete(wo);
 842         strcpy(CS_CVAR(this).weaponorder_byimpulse, W_FixWeaponOrder_BuildImpulseList(o));
 843         return o;
 844 }
 845 #endif
 846
 847 #ifdef CSQC
 848 REPLICATE(cvar_cl_accuracy_data_share, bool, "cl_accuracy_data_share");
 849 REPLICATE(cvar_cl_accuracy_data_receive, bool, "cl_accuracy_data_receive");
 850 #endif
 851
 852 #ifdef GAMEQC
 853 REPLICATE(cvar_cl_gunalign, int, "cl_gunalign");
 854 REPLICATE(cvar_cl_weapon_switch_reload, bool, "cl_weapon_switch_reload");
 855 REPLICATE(cvar_cl_weapon_switch_fallback_to_impulse, bool, "cl_weapon_switch_fallback_to_impulse");
 856 REPLICATE(cvar_cl_weaponimpulsemode, int, "cl_weaponimpulsemode");
 857 REPLICATE(cvar_cl_weaponpriority, string, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 858 REPLICATE(cvar_cl_weaponpriorities[0], string, "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 859 REPLICATE(cvar_cl_weaponpriorities[1], string, "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 860 REPLICATE(cvar_cl_weaponpriorities[2], string, "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 861 REPLICATE(cvar_cl_weaponpriorities[3], string, "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 862 REPLICATE(cvar_cl_weaponpriorities[4], string, "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 863 REPLICATE(cvar_cl_weaponpriorities[5], string, "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 864 REPLICATE(cvar_cl_weaponpriorities[6], string, "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 865 REPLICATE(cvar_cl_weaponpriorities[7], string, "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 866 REPLICATE(cvar_cl_weaponpriorities[8], string, "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 867 REPLICATE(cvar_cl_weaponpriorities[9], string, "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 868 #endif