qcsrc/common/weapons/all.qh

   1 #ifndef WEAPONS_ALL_H
   2 #define WEAPONS_ALL_H
   3
   4 #include <common/command/all.qh>
   5 #include <common/stats.qh>
   6 #include "config.qh"
   7
   8 // weapon sets
   9 USING(WepSet, vector);
  10 #ifdef SVQC
  11 void WriteWepSet(float dest, WepSet w);
  12 #endif
  13
  14 #ifdef CSQC
  15 WepSet WepSet_GetFromStat();
  16 WepSet WepSet_GetFromStat_InMap();
  17 WepSet ReadWepSet();
  18 #endif
  19
  20 #include "weapon.qh"
  21
  22 #ifndef MENUQC
  23 #include "calculations.qh"
  24 #include <common/models/all.qh>
  25 #endif
  26
  27 #include <common/util.qh>
  28
  29 #ifdef SVQC
  30 #include <server/bot/aim.qh>
  31 #endif
  32
  33 REGISTRY(Weapons, 72) // Increase as needed. Can be up to 72.
  34 #define Weapons_from(i) _Weapons_from(i, WEP_Null)
  35 REGISTER_REGISTRY(Weapons)
  36 STATIC_INIT(WeaponPickup) { FOREACH(Weapons, true, it.m_pickup = NEW(WeaponPickup, it)); }
  37
  38 .WepSet m_wepset;
  39 #define WEPSET(id) (WEP_##id.m_wepset)
  40 #define WepSet_FromWeapon(it) ((it).m_wepset)
  41 WepSet _WepSet_FromWeapon(int i);
  42
  43 GENERIC_COMMAND(dumpweapons, "Dump all weapons into weapons_dump.txt") // WEAPONTODO: make this work with other progs than just server
  44 {
  45     switch(request)
  46     {
  47         case CMD_REQUEST_COMMAND:
  48         {
  49             #ifdef SVQC
  50             wep_config_file = -1;
  51             wep_config_alsoprint = -1;
  52             string filename = argv(1);
  53
  54             if(filename == "")
  55             {
  56                 filename = "weapons_dump.cfg";
  57                 wep_config_alsoprint = false;
  58             }
  59             else if(filename == "-")
  60             {
  61                 filename = "weapons_dump.cfg";
  62                 wep_config_alsoprint = true;
  63             }
  64             wep_config_file = fopen(filename, FILE_WRITE);
  65
  66             if(wep_config_file >= 0)
  67             {
  68                 Dump_Weapon_Settings();
  69                 LOG_INFO(sprintf("Dumping weapons... File located in ^2data/data/%s^7.\n", filename));
  70                 fclose(wep_config_file);
  71                 wep_config_file = -1;
  72                 wep_config_alsoprint = -1;
  73             }
  74             else
  75             {
  76                 LOG_INFO(sprintf("^1Error: ^7Could not open file '%s'!\n", filename));
  77             }
  78             #else
  79             LOG_INFO(_("Weapons dump command only works with sv_cmd.\n"));
  80             #endif
  81             return;
  82         }
  83
  84         default:
  85         case CMD_REQUEST_USAGE:
  86         {
  87             LOG_INFO(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " dumpweapons [filename]"));
  88             LOG_INFO("  Where 'filename' is the file to write (default is weapons_dump.cfg),\n");
  89             LOG_INFO("  if supplied with '-' output to console as well as default,\n");
  90             LOG_INFO("  if left blank, it will only write to default.\n");
  91             return;
  92         }
  93     }
  94 }
  95
  96 #ifdef SVQC
  97 entity W_PROP_reloader;
  98 float autocvar_w_prop_interval = 5;
  99 .void(Weapon this, int) wr_net;
 100 void W_PROP_reload(int chan, entity to)
 101 {
 102     W_PROP_reloader.nextthink = time + autocvar_w_prop_interval;
 103     msg_entity = to;
 104     FOREACH(Weapons, true, {
 105         it.wr_update(it);
 106         void(Weapon, int) f = it.wr_net;
 107         if (f) f(it, chan);
 108     });
 109 }
 110 void W_PROP_think(entity this)
 111 {
 112     W_PROP_reload(MSG_ALL, NULL);
 113 }
 114 STATIC_INIT_LATE(W_PROP_reloader)
 115 {
 116     entity e = W_PROP_reloader = new_pure(W_PROP_reloader);
 117     WITHSELF(e, (setthink(e, W_PROP_think))(e));
 118 }
 119 #endif
 120
 121 #define REGISTER_WEAPON(...) EVAL_REGISTER_WEAPON(OVERLOAD(REGISTER_WEAPON, __VA_ARGS__))
 122 #define EVAL_REGISTER_WEAPON(...) __VA_ARGS__
 123 #define REGISTER_WEAPON_2(id, inst) REGISTER(Weapons, WEP, id, m_id, inst)
 124 /** TODO: deprecated - remove */
 125 #define REGISTER_WEAPON_3(id, sname, inst) \
 126     REGISTER_WEAPON_2(id, inst); \
 127     [[alias("WEP_" #id)]] Weapon _wep_##sname
 128
 129 REGISTER_WEAPON(Null, NEW(Weapon));
 130
 131 Weapon Weapons_fromstr(string s)
 132 {
 133     FOREACH(Weapons, it != WEP_Null && it.netname == s, return it);
 134     return NULL;
 135 }
 136
 137
 138 // legacy w_prop mappings
 139 #define X(fld, T) .T fld; .T wepvar_##fld = fld;
 140 X(switchdelay_drop, float)
 141 X(switchdelay_raise, float)
 142 X(weaponreplace, string)
 143 X(weaponstartoverride, float)
 144 X(weaponstart, float)
 145 X(weaponthrowable, float)
 146 X(reload_ammo, float)
 147 .float reloading_ammo = reload_ammo;
 148 X(reload_time, float)
 149 .float reloading_time = reload_time;
 150 #undef X
 151
 152
 153
 154 #define W_PROPS(L, class, prefix) \
 155     L(W_PROP_BEGIN, W_PROP, W_PROP_END, class, prefix) \
 156     L(W_CONFIG_BEGIN, W_CONFIG, W_CONFIG_END, class, prefix) \
 157     L(W_UPDATE_BEGIN, W_UPDATE, W_UPDATE_END, class, prefix) \
 158     L(W_NET_BEGIN, W_NET, W_NET_END, class, prefix) \
 159     /**/ \
 160
 161
 162     #define W_PROP(class, wepname, fld, T, m)       W_PROP_##m(class, fld, T, wepname)
 163     #define W_PROP_NONE(class, fld, T, wepname)     _W_PROP(class, fld, T, wepname)
 164     #define W_PROP_PRI(class, fld, T, wepname)      _W_PROP(class, primary_##fld, T, wepname)
 165     #define W_PROP_SEC(class, fld, T, wepname)      _W_PROP(class, secondary_##fld, T, wepname)
 166     #define W_PROP_BOTH(class, fld, T, wepname) \
 167             W_PROP_PRI(class, fld, T, wepname) \
 168             W_PROP_SEC(class, fld, T, wepname)
 169     #define W_PROP_BEGIN(class)
 170         #define _W_PROP(class, fld, T, wepname) \
 171             /* static */ T _W_PROP_CVAR(wepname, fld); \
 172             ATTRIB(class, wepvar_##fld, T, _W_PROP_CVAR(wepname, fld));
 173         #define _W_PROP_CVAR(wepname, fld) autocvar_g_balance_##wepname##_##fld
 174     #define W_PROP_END()
 175
 176
 177
 178     #define W_CONFIG(class, wepname, fld, T, m)     W_CONFIG_##m(class, fld, T, wepname)
 179     #define W_CONFIG_NONE(class, fld, T, wepname)   _W_CONFIG(class, fld, T, wepname)
 180     #define W_CONFIG_PRI(class, fld, T, wepname)    _W_CONFIG(class, primary_##fld, T, wepname)
 181     #define W_CONFIG_SEC(class, fld, T, wepname)    _W_CONFIG(class, secondary_##fld, T, wepname)
 182     #define W_CONFIG_BOTH(class, fld, T, wepname) \
 183             W_CONFIG_PRI(class, fld, T, wepname) \
 184             W_CONFIG_SEC(class, fld, T, wepname)
 185     #define W_CONFIG_BEGIN(class) METHOD(class, wr_config, void(class this)) {
 186         #ifdef SVQC
 187             #define _W_CONFIG(class, fld, T, wepname) if (#wepname == this.netname) WEP_CONFIG_WRITE_CVARS(wepname, fld, T);
 188         #else
 189             #define _W_CONFIG(class, fld, T, wepname)
 190         #endif
 191     #define W_CONFIG_END() }
 192
 193
 194     #define W_UPDATE(class, wepname, fld, T, m)     W_UPDATE_##m(class, fld, T, wepname)
 195     #define W_UPDATE_NONE(class, fld, T, wepname)   _W_UPDATE(class, fld, T, wepname)
 196     #define W_UPDATE_PRI(class, fld, T, wepname)    _W_UPDATE(class, primary_##fld, T, wepname)
 197     #define W_UPDATE_SEC(class, fld, T, wepname)    _W_UPDATE(class, secondary_##fld, T, wepname)
 198     #define W_UPDATE_BOTH(class, fld, T, wepname) \
 199             W_UPDATE_PRI(class, fld, T, wepname) \
 200             W_UPDATE_SEC(class, fld, T, wepname)
 201     .entity baseline, baseline_target;
 202     #define W_UPDATE_BEGIN(class) \
 203         METHOD(class, wr_update, void(class this)) \
 204         { \
 205             noref entity b = this.baseline; \
 206             if (!b) \
 207             { \
 208                 b = this.baseline = new_pure(baseline); \
 209                 b.baseline_target = this; \
 210             }
 211         #ifdef SVQC
 212             #define _W_UPDATE(class, fld, T, wepname) \
 213                 { \
 214                     T it = _W_PROP_CVAR(wepname, fld); \
 215                     b.wepvar_##fld = this.wepvar_##fld; \
 216                     this.wepvar_##fld = it; \
 217                 }
 218         #else
 219             #define _W_UPDATE(class, fld, T, wepname)
 220         #endif
 221     #define W_UPDATE_END() }
 222
 223
 224     #define W_NET(class, wepname, fld, T, m)     W_NET_##m(class, fld, T, wepname)
 225     #define W_NET_NONE(class, fld, T, wepname)   _W_NET(class, fld, T, wepname)
 226     #define W_NET_PRI(class, fld, T, wepname)    _W_NET(class, primary_##fld, T, wepname)
 227     #define W_NET_SEC(class, fld, T, wepname)    _W_NET(class, secondary_##fld, T, wepname)
 228     #define W_NET_BOTH(class, fld, T, wepname) \
 229             W_NET_PRI(class, fld, T, wepname) \
 230             W_NET_SEC(class, fld, T, wepname)
 231     REGISTER_NET_TEMP(WeaponUpdate)
 232     #if defined(CSQC)
 233         #define W_NET_BEGIN(class) METHOD(class, wr_net, void(class this, int i)) { int n = 0;
 234             #define _W_NET(class, fld, T, wepname) \
 235             { \
 236                 if (++n == i) this.wepvar_##fld = Read_##T(); \
 237             }
 238             .void(Weapon this, int i) wr_net;
 239             NET_HANDLE(WeaponUpdate, bool isnew)
 240             {
 241                 Weapon w = Weapons_from(ReadByte());
 242                 for (int i; (i = ReadByte()); )
 243                 {
 244                     w.wr_net(w, i);
 245                 }
 246                 return true;
 247             }
 248         #define W_NET_END() }
 249     #elif defined(SVQC)
 250         #define W_NET_BEGIN(class) \
 251             METHOD(class, wr_net, void(class this, int chan)) \
 252             { \
 253                 bool commit = false; \
 254                 int i = 0;
 255     #define _W_NET(class, fld, T, wepname) \
 256                 { \
 257                     ++i; \
 258                     T it = this.wepvar_##fld; \
 259                     if (chan == MSG_ONE || it != this.baseline.wepvar_##fld) \
 260                     { \
 261                         if (!commit) { commit = true; WriteHeader(chan, WeaponUpdate); WriteByte(chan, this.m_id); } \
 262                         WriteByte(chan, i); Write_##T(chan, it); \
 263                     } \
 264                 }
 265     #define W_NET_END() \
 266                 if (commit) WriteByte(chan, 0); \
 267             }
 268     #else
 269         #define W_NET_BEGIN(class)
 270             #define _W_NET(class, fld, T, wepname)
 271         #define W_NET_END()
 272     #endif
 273
 274
 275
 276 // read cvars from weapon settings
 277 #define WEP_CVAR(wepname, name) (_wep_##wepname.wepvar_##name)
 278 #define WEP_CVAR_PRI(wepname, name) WEP_CVAR(wepname, primary_##name)
 279 #define WEP_CVAR_SEC(wepname, name) WEP_CVAR(wepname, secondary_##name)
 280 #define WEP_CVAR_BOTH(wepname, isprimary, name) ((isprimary) ? WEP_CVAR_PRI(wepname, name) : WEP_CVAR_SEC(wepname, name))
 281
 282 const int WEP_FIRST = 1;
 283 #define WEP_LAST (Weapons_COUNT - 1)
 284 WepSet WEPSET_ALL;
 285 WepSet WEPSET_SUPERWEAPONS;
 286
 287 #include "all.inc"
 288
 289 // TODO: remove after 0.8.2. Retains impulse number compatibility because 0.8.1 clients don't reload the weapons.cfg
 290 #define WEP_HARDCODED_IMPULSES 20
 291
 292 // TODO: invert after 0.8.2. Will require moving 'best weapon' impulses
 293 #define WEP_IMPULSE_BEGIN 230
 294 #define WEP_IMPULSE_END bound(WEP_IMPULSE_BEGIN, WEP_IMPULSE_BEGIN + (Weapons_COUNT - 1) - 1, 253)
 295
 296 REGISTRY_SORT(Weapons, WEP_HARDCODED_IMPULSES + 1)
 297 REGISTRY_CHECK(Weapons)
 298
 299 STATIC_INIT(register_weapons_done)
 300 {
 301     FOREACH(Weapons, true, {
 302         WepSet set = it.m_wepset = _WepSet_FromWeapon(it.m_id = i);
 303         WEPSET_ALL |= set;
 304         if ((it.spawnflags) & WEP_FLAG_SUPERWEAPON) WEPSET_SUPERWEAPONS |= set;
 305         it.weapons = set;
 306         if (it == WEP_Null) continue;
 307         int imp = WEP_IMPULSE_BEGIN + it.m_id - 1;
 308         if (imp <= WEP_IMPULSE_END)
 309             localcmd(sprintf("alias weapon_%s \"impulse %d\"\n", it.netname, imp));
 310         else
 311             LOG_TRACEF("Impulse limit exceeded, weapon will not be directly accessible: %s\n", it.netname);
 312     });
 313     #ifdef CSQC
 314     FOREACH(Weapons, true, it.wr_init(it));
 315     #endif
 316     weaponorder_byid = "";
 317     for (int i = Weapons_MAX - 1; i >= 1; --i)
 318         if (Weapons_from(i))
 319             weaponorder_byid = strcat(weaponorder_byid, " ", ftos(i));
 320     weaponorder_byid = strzone(substring(weaponorder_byid, 1, -1));
 321 }
 322
 323 #ifndef MENUQC
 324
 325 .entity weaponchild;
 326 .entity exteriorweaponentity;
 327 vector weaponentity_glowmod(Weapon wep, int c)
 328 {
 329     vector g;
 330     if (!(g = wep.wr_glow(wep))) g = colormapPaletteColor(c & 0x0F, true) * 2;
 331     return g;
 332 }
 333
 334 //.int weapon; // current weapon
 335 .string weaponname; // name of .weapon
 336
 337 .vector spawnorigin; // for casings
 338
 339 // weapon animation vectors:
 340 .vector anim_fire1;
 341 .vector anim_fire2;
 342 .vector anim_idle;
 343 .vector anim_reload;
 344
 345 // static frame globals
 346
 347 ENUMCLASS(WFRAME)
 348 CASE(WFRAME, DONTCHANGE)
 349 CASE(WFRAME, FIRE1)
 350 CASE(WFRAME, FIRE2)
 351 CASE(WFRAME, IDLE)
 352 CASE(WFRAME, RELOAD)
 353 ENUMCLASS_END(WFRAME)
 354
 355 .WFRAME wframe;
 356
 357 vector shotorg_adjust_values(vector vecs, bool y_is_right, bool visual, int algn);
 358 void CL_WeaponEntity_SetModel(entity this, string name, bool _anim);
 359 #endif
 360
 361 #endif