qcsrc/common/weapons/w_blaster.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ BLASTER,
   4 /* function  */ W_Blaster,
   5 /* ammotype  */ ammo_none,
   6 /* impulse   */ 1,
   7 /* flags     */ WEP_FLAG_NORMAL | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating    */ 0,
   9 /* color     */ '1 0.5 0.5',
  10 /* modelname */ "laser",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairlaser 0.4",
  13 /* wepimg    */ "weaponlaser",
  14 /* refname   */ "blaster",
  15 /* wepname   */ _("Blaster")
  16 );
  17
  18 #define BLASTER_SETTINGS(w_cvar,w_prop) BLASTER_SETTINGS_LIST(w_cvar, w_prop, BLASTER, blaster)
  19 #define BLASTER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  20         w_cvar(id, sn, BOTH, animtime) \
  21         w_cvar(id, sn, BOTH, damage) \
  22         w_cvar(id, sn, BOTH, delay) \
  23         w_cvar(id, sn, BOTH, edgedamage) \
  24         w_cvar(id, sn, BOTH, force) \
  25         w_cvar(id, sn, BOTH, lifetime) \
  26         w_cvar(id, sn, BOTH, radius) \
  27         w_cvar(id, sn, BOTH, refire) \
  28         w_cvar(id, sn, BOTH, shotangle) \
  29         w_cvar(id, sn, BOTH, speed) \
  30         w_cvar(id, sn, BOTH, spread) \
  31         w_cvar(id, sn, NONE, secondary) \
  32         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  33         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  34         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  35         w_prop(id, sn, float,  weaponstart, weaponstart) \
  36         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  37
  38 #ifdef SVQC
  39 BLASTER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  40 .float blaster_damage;
  41 .float blaster_edgedamage;
  42 .float blaster_radius;
  43 .float blaster_force;
  44 .float blaster_lifetime;
  45 #endif
  46 #else
  47 #ifdef SVQC
  48 void spawnfunc_weapon_blaster() { weapon_defaultspawnfunc(WEP_BLASTER); }
  49 void spawnfunc_weapon_laser() { spawnfunc_weapon_blaster(); }
  50
  51 void W_Blaster_Touch()
  52 {
  53         PROJECTILE_TOUCH;
  54
  55         self.event_damage = func_null;
  56
  57         RadiusDamage(
  58                 self,
  59                 self.realowner,
  60                 self.blaster_damage,
  61                 self.blaster_edgedamage,
  62                 self.blaster_radius,
  63                 world,
  64                 world,
  65                 self.blaster_force,
  66                 self.projectiledeathtype,
  67                 other
  68         );
  69
  70         remove(self);
  71 }
  72
  73 void W_Blaster_Think()
  74 {
  75         self.movetype = MOVETYPE_FLY;
  76         self.think = SUB_Remove;
  77         self.nextthink = time + self.blaster_lifetime;
  78         CSQCProjectile(self, TRUE, PROJECTILE_BLASTER, TRUE);
  79 }
  80
  81 void W_Blaster_Attack(
  82         float atk_shotangle,
  83         float atk_damage,
  84         float atk_edgedamage,
  85         float atk_radius,
  86         float atk_force,
  87         float atk_speed,
  88         float atk_spread,
  89         float atk_delay,
  90         float atk_lifetime)
  91 {
  92         vector s_forward = v_forward * cos(atk_shotangle * DEG2RAD) + v_up * sin(atk_shotangle * DEG2RAD);
  93
  94         W_SetupShot_Dir(self, s_forward, FALSE, 3, "weapons/lasergun_fire.wav", CH_WEAPON_B, atk_damage);
  95         pointparticles(particleeffectnum("laser_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  96
  97         entity missile = spawn();
  98         missile.owner = missile.realowner = self;
  99         missile.classname = "blasterbolt";
 100         missile.bot_dodge = TRUE;
 101         missile.bot_dodgerating = atk_damage;
 102         PROJECTILE_MAKETRIGGER(missile);
 103
 104         missile.blaster_damage = atk_damage;
 105         missile.blaster_edgedamage = atk_edgedamage;
 106         missile.blaster_radius = atk_radius;
 107         missile.blaster_force = atk_force;
 108         missile.blaster_lifetime = atk_lifetime;
 109
 110         setorigin(missile, w_shotorg);
 111         setsize(missile, '0 0 0', '0 0 0');
 112
 113         W_SetupProjVelocity_Explicit(
 114                 missile,
 115                 w_shotdir,
 116                 v_up,
 117                 atk_speed,
 118                 0,
 119                 0,
 120                 atk_spread,
 121                 FALSE
 122         );
 123
 124         missile.angles = vectoangles(missile.velocity);
 125
 126         //missile.glow_color = 250; // 244, 250
 127         //missile.glow_size = 120;
 128
 129         missile.touch = W_Blaster_Touch;
 130         missile.flags = FL_PROJECTILE;
 131         missile.missile_flags = MIF_SPLASH;
 132         missile.projectiledeathtype = WEP_BLASTER;
 133         missile.think = W_Blaster_Think;
 134         missile.nextthink = time + atk_delay;
 135
 136         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 137
 138         if(time >= missile.nextthink)
 139         {
 140                 entity oldself;
 141                 oldself = self;
 142                 self = missile;
 143                 self.think();
 144                 self = oldself;
 145         }
 146 }
 147 float W_Blaster(float request)
 148 {
 149         switch(request)
 150         {
 151                 case WR_AIM:
 152                 {
 153                         if(WEP_CVAR(blaster, secondary))
 154                         {
 155                                 if((random() * (WEP_CVAR_PRI(blaster, damage) + WEP_CVAR_SEC(blaster, damage))) > WEP_CVAR_PRI(blaster, damage))
 156                                         { self.BUTTON_ATCK2 = bot_aim(WEP_CVAR_SEC(blaster, speed), 0, WEP_CVAR_SEC(blaster, lifetime), FALSE); }
 157                                 else
 158                                         { self.BUTTON_ATCK = bot_aim(WEP_CVAR_PRI(blaster, speed), 0, WEP_CVAR_PRI(blaster, lifetime), FALSE); }
 159                         }
 160                         else
 161                                 { self.BUTTON_ATCK = bot_aim(WEP_CVAR_PRI(blaster, speed), 0, WEP_CVAR_PRI(blaster, lifetime), FALSE); }
 162
 163                         return TRUE;
 164                 }
 165
 166                 case WR_THINK:
 167                 {
 168                         if(self.BUTTON_ATCK)
 169                         {
 170                                 if(weapon_prepareattack(0, WEP_CVAR_PRI(blaster, refire)))
 171                                 {
 172                                         W_Blaster_Attack(
 173                                                 WEP_CVAR_PRI(blaster, shotangle),
 174                                                 WEP_CVAR_PRI(blaster, damage),
 175                                                 WEP_CVAR_PRI(blaster, edgedamage),
 176                                                 WEP_CVAR_PRI(blaster, radius),
 177                                                 WEP_CVAR_PRI(blaster, force),
 178                                                 WEP_CVAR_PRI(blaster, speed),
 179                                                 WEP_CVAR_PRI(blaster, spread),
 180                                                 WEP_CVAR_PRI(blaster, delay),
 181                                                 WEP_CVAR_PRI(blaster, lifetime)
 182                                         );
 183                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(blaster, animtime), w_ready);
 184                                 }
 185                         }
 186                         else if(self.BUTTON_ATCK2)
 187                         {
 188                                 switch(WEP_CVAR(blaster, secondary))
 189                                 {
 190                                         case 0: // switch to last used weapon
 191                                         {
 192                                                 if(self.switchweapon == WEP_BLASTER) // don't do this if already switching
 193                                                         W_LastWeapon();
 194                                                 break;
 195                                         }
 196
 197                                         case 1: // normal projectile secondary
 198                                         {
 199                                                 if(weapon_prepareattack(1, WEP_CVAR_SEC(blaster, refire)))
 200                                                 {
 201                                                         W_Blaster_Attack(
 202                                                                 WEP_CVAR_SEC(blaster, shotangle),
 203                                                                 WEP_CVAR_SEC(blaster, damage),
 204                                                                 WEP_CVAR_SEC(blaster, edgedamage),
 205                                                                 WEP_CVAR_SEC(blaster, radius),
 206                                                                 WEP_CVAR_SEC(blaster, force),
 207                                                                 WEP_CVAR_SEC(blaster, speed),
 208                                                                 WEP_CVAR_SEC(blaster, spread),
 209                                                                 WEP_CVAR_SEC(blaster, delay),
 210                                                                 WEP_CVAR_SEC(blaster, lifetime)
 211                                                         );
 212                                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(blaster, animtime), w_ready);
 213                                                 }
 214
 215                                                 break;
 216                                         }
 217                                 }
 218                         }
 219                         return TRUE;
 220                 }
 221
 222                 case WR_INIT:
 223                 {
 224                         precache_model("models/weapons/g_laser.md3");
 225                         precache_model("models/weapons/v_laser.md3");
 226                         precache_model("models/weapons/h_laser.iqm");
 227                         precache_sound("weapons/lasergun_fire.wav");
 228                         BLASTER_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP)
 229                         return TRUE;
 230                 }
 231
 232                 case WR_SETUP:
 233                 {
 234                         self.ammo_field = ammo_none;
 235                         return TRUE;
 236                 }
 237
 238                 case WR_CHECKAMMO1:
 239                 case WR_CHECKAMMO2:
 240                 {
 241                         return TRUE; // laser has infinite ammo
 242                 }
 243
 244                 case WR_CONFIG:
 245                 {
 246                         BLASTER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 247                         return TRUE;
 248                 }
 249
 250                 case WR_SUICIDEMESSAGE:
 251                 {
 252                         return WEAPON_BLASTER_SUICIDE;
 253                 }
 254
 255                 case WR_KILLMESSAGE:
 256                 {
 257                         return WEAPON_BLASTER_MURDER;
 258                 }
 259         }
 260
 261         return TRUE;
 262 }
 263 #endif
 264 #ifdef CSQC
 265 float W_Blaster(float request)
 266 {
 267         switch(request)
 268         {
 269                 case WR_IMPACTEFFECT:
 270                 {
 271                         vector org2;
 272                         org2 = w_org + w_backoff * 6;
 273                         pointparticles(particleeffectnum("laser_impact"), org2, w_backoff * 1000, 1);
 274                         if(!w_issilent) { sound(self, CH_SHOTS, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM); }
 275                         return TRUE;
 276                 }
 277
 278                 case WR_INIT:
 279                 {
 280                         precache_sound("weapons/laserimpact.wav");
 281                         return TRUE;
 282                 }
 283                 case WR_ZOOMRETICLE:
 284                 {
 285                         // no weapon specific image for this weapon
 286                         return FALSE;
 287                 }
 288         }
 289
 290         return TRUE;
 291 }
 292 #endif
 293 #endif