qcsrc/common/weapons/w_blaster.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ BLASTER,
   4 /* function */ W_Blaster,
   5 /* ammotype */ 0,
   6 /* impulse  */ 1,
   7 /* flags    */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating   */ 0,
   9 /* model    */ "laser",
  10 /* netname  */ "laser",
  11 /* fullname */ _("Blaster")
  12 );
  13
  14 #define BLASTER_SETTINGS(w_cvar,w_prop) \
  15         w_cvar(WEP_BLASTER, blaster, MO_BOTH, animtime) \
  16         w_cvar(WEP_BLASTER, blaster, MO_BOTH, damage) \
  17         w_cvar(WEP_BLASTER, blaster, MO_BOTH, delay) \
  18         w_cvar(WEP_BLASTER, blaster, MO_BOTH, edgedamage) \
  19         w_cvar(WEP_BLASTER, blaster, MO_BOTH, force) \
  20         w_cvar(WEP_BLASTER, blaster, MO_BOTH, lifetime) \
  21         w_cvar(WEP_BLASTER, blaster, MO_BOTH, radius) \
  22         w_cvar(WEP_BLASTER, blaster, MO_BOTH, refire) \
  23         w_cvar(WEP_BLASTER, blaster, MO_BOTH, shotangle) \
  24         w_cvar(WEP_BLASTER, blaster, MO_BOTH, speed) \
  25         w_cvar(WEP_BLASTER, blaster, MO_BOTH, spread) \
  26         w_cvar(WEP_BLASTER, blaster, MO_NONE, secondary) \
  27         w_prop(WEP_BLASTER, blaster, float,  reloading_ammo, reload_ammo) \
  28         w_prop(WEP_BLASTER, blaster, float,  reloading_time, reload_time) \
  29         w_prop(WEP_BLASTER, blaster, float,  switchdelay_raise, switchdelay_raise) \
  30         w_prop(WEP_BLASTER, blaster, float,  switchdelay_drop, switchdelay_drop) \
  31         w_prop(WEP_BLASTER, blaster, string, weaponreplace, weaponreplace) \
  32         w_prop(WEP_BLASTER, blaster, float,  weaponstart, weaponstart) \
  33         w_prop(WEP_BLASTER, blaster, float,  weaponstartoverride, weaponstartoverride)
  34
  35 #ifdef SVQC
  36 BLASTER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  37 .float blaster_damage;
  38 .float blaster_edgedamage;
  39 .float blaster_radius;
  40 .float blaster_force;
  41 .float blaster_lifetime;
  42 #endif
  43 #else
  44 #ifdef SVQC
  45 void spawnfunc_weapon_blaster() { weapon_defaultspawnfunc(WEP_BLASTER); }
  46 void spawnfunc_weapon_laser() { spawnfunc_weapon_blaster(); }
  47
  48 void W_Blaster_Touch()
  49 {
  50         PROJECTILE_TOUCH;
  51
  52         self.event_damage = func_null;
  53
  54         RadiusDamage(
  55                 self,
  56                 self.realowner,
  57                 self.blaster_damage,
  58                 self.blaster_edgedamage,
  59                 self.blaster_radius,
  60                 world,
  61                 world,
  62                 self.blaster_force,
  63                 self.projectiledeathtype,
  64                 other
  65         );
  66
  67         remove(self);
  68 }
  69
  70 void W_Blaster_Think()
  71 {
  72         self.movetype = MOVETYPE_FLY;
  73         self.think = SUB_Remove;
  74         self.nextthink = time + self.blaster_lifetime;
  75         CSQCProjectile(self, TRUE, PROJECTILE_BLASTER, TRUE);
  76 }
  77
  78 void W_Blaster_Attack(
  79         float atk_shotangle,
  80         float atk_damage,
  81         float atk_edgedamage,
  82         float atk_radius,
  83         float atk_force,
  84         float atk_speed,
  85         float atk_spread,
  86         float atk_delay,
  87         float atk_lifetime)
  88 {
  89         vector s_forward = v_forward * cos(atk_shotangle * DEG2RAD) + v_up * sin(atk_shotangle * DEG2RAD);
  90
  91         W_SetupShot_Dir(self, s_forward, FALSE, 3, "weapons/lasergun_fire.wav", CH_WEAPON_B, atk_damage);
  92         pointparticles(particleeffectnum("laser_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  93
  94         entity missile = spawn();
  95         missile.owner = missile.realowner = self;
  96         missile.classname = "blasterbolt";
  97         missile.bot_dodge = TRUE;
  98         missile.bot_dodgerating = atk_damage;
  99         PROJECTILE_MAKETRIGGER(missile);
 100
 101         missile.blaster_damage = atk_damage;
 102         missile.blaster_edgedamage = atk_edgedamage;
 103         missile.blaster_radius = atk_radius;
 104         missile.blaster_force = atk_force;
 105         missile.blaster_lifetime = atk_lifetime;
 106
 107         setorigin(missile, w_shotorg);
 108         setsize(missile, '0 0 0', '0 0 0');
 109
 110         W_SetupProjectileVelocityEx(
 111                 missile,
 112                 w_shotdir,
 113                 v_up,
 114                 atk_speed,
 115                 0,
 116                 0,
 117                 atk_spread,
 118                 FALSE
 119         );
 120
 121         missile.angles = vectoangles(missile.velocity);
 122
 123         //missile.glow_color = 250; // 244, 250
 124         //missile.glow_size = 120;
 125
 126         missile.touch = W_Blaster_Touch;
 127         missile.flags = FL_PROJECTILE;
 128         missile.missile_flags = MIF_SPLASH;
 129         missile.projectiledeathtype = WEP_BLASTER;
 130         missile.think = W_Blaster_Think;
 131         missile.nextthink = time + atk_delay;
 132
 133         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 134
 135         if(time >= missile.nextthink)
 136         {
 137                 entity oldself;
 138                 oldself = self;
 139                 self = missile;
 140                 self.think();
 141                 self = oldself;
 142         }
 143 }
 144 float W_Blaster(float request)
 145 {
 146         switch(request)
 147         {
 148                 case WR_AIM:
 149                 {
 150                         if(WEP_CVAR(blaster, secondary))
 151                         {
 152                                 if((random() * (WEP_CVAR_PRI(blaster, damage) + WEP_CVAR_SEC(blaster, damage))) > WEP_CVAR_PRI(blaster, damage))
 153                                         { self.BUTTON_ATCK2 = bot_aim(WEP_CVAR_SEC(blaster, speed), 0, WEP_CVAR_SEC(blaster, lifetime), FALSE); }
 154                                 else
 155                                         { self.BUTTON_ATCK = bot_aim(WEP_CVAR_PRI(blaster, speed), 0, WEP_CVAR_PRI(blaster, lifetime), FALSE); }
 156                         }
 157                         else
 158                                 { self.BUTTON_ATCK = bot_aim(WEP_CVAR_PRI(blaster, speed), 0, WEP_CVAR_PRI(blaster, lifetime), FALSE); }
 159
 160                         return TRUE;
 161                 }
 162
 163                 case WR_THINK:
 164                 {
 165                         if(WEP_CVAR(blaster, reload_ammo) && self.clip_load < 1) // forced reload
 166                         {
 167                                 WEP_ACTION(self.weapon, WR_RELOAD);
 168                         }
 169                         else if(self.BUTTON_ATCK)
 170                         {
 171                                 if(weapon_prepareattack(0, WEP_CVAR_PRI(blaster, refire)))
 172                                 {
 173                                         W_DecreaseAmmo(ammo_none, 1, TRUE); // WEAPONTODO is this necessary?
 174                                         W_Blaster_Attack(
 175                                                 WEP_CVAR_PRI(blaster, shotangle),
 176                                                 WEP_CVAR_PRI(blaster, damage),
 177                                                 WEP_CVAR_PRI(blaster, edgedamage),
 178                                                 WEP_CVAR_PRI(blaster, radius),
 179                                                 WEP_CVAR_PRI(blaster, force),
 180                                                 WEP_CVAR_PRI(blaster, speed),
 181                                                 WEP_CVAR_PRI(blaster, spread),
 182                                                 WEP_CVAR_PRI(blaster, delay),
 183                                                 WEP_CVAR_PRI(blaster, lifetime)
 184                                         );
 185                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(blaster, animtime), w_ready);
 186                                 }
 187                         }
 188                         else if(self.BUTTON_ATCK2)
 189                         {
 190                                 switch(WEP_CVAR(blaster, secondary))
 191                                 {
 192                                         case 0: // switch to last used weapon
 193                                         {
 194                                                 if(self.switchweapon == WEP_BLASTER) // don't do this if already switching
 195                                                         W_LastWeapon();
 196                                                 break;
 197                                         }
 198
 199                                         case 1: // normal projectile secondary
 200                                         {
 201                                                 if(weapon_prepareattack(1, WEP_CVAR_SEC(blaster, refire)))
 202                                                 {
 203                                                         W_DecreaseAmmo(ammo_none, 1, TRUE);
 204                                                         W_Blaster_Attack(
 205                                                                 WEP_CVAR_SEC(blaster, shotangle),
 206                                                                 WEP_CVAR_SEC(blaster, damage),
 207                                                                 WEP_CVAR_SEC(blaster, edgedamage),
 208                                                                 WEP_CVAR_SEC(blaster, radius),
 209                                                                 WEP_CVAR_SEC(blaster, force),
 210                                                                 WEP_CVAR_SEC(blaster, speed),
 211                                                                 WEP_CVAR_SEC(blaster, spread),
 212                                                                 WEP_CVAR_SEC(blaster, delay),
 213                                                                 WEP_CVAR_SEC(blaster, lifetime)
 214                                                         );
 215                                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(blaster, animtime), w_ready);
 216                                                 }
 217
 218                                                 break;
 219                                         }
 220                                 }
 221                         }
 222                         return TRUE;
 223                 }
 224
 225                 case WR_INIT:
 226                 {
 227                         precache_model("models/weapons/g_laser.md3");
 228                         precache_model("models/weapons/v_laser.md3");
 229                         precache_model("models/weapons/h_laser.iqm");
 230                         precache_sound("weapons/lasergun_fire.wav");
 231                         BLASTER_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 232                         return TRUE;
 233                 }
 234
 235                 case WR_SETUP:
 236                 {
 237                         self.current_ammo = ammo_none;
 238                         return TRUE;
 239                 }
 240
 241                 case WR_CHECKAMMO1:
 242                 case WR_CHECKAMMO2:
 243                 {
 244                         return TRUE; // laser has infinite ammo
 245                 }
 246
 247                 case WR_CONFIG:
 248                 {
 249                         BLASTER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 250                         return TRUE;
 251                 }
 252
 253                 case WR_RELOAD:
 254                 {
 255                         W_Reload(0, "weapons/reload.wav");
 256                         return TRUE;
 257                 }
 258
 259                 case WR_SUICIDEMESSAGE:
 260                 {
 261                         return WEAPON_LASER_SUICIDE;
 262                 }
 263
 264                 case WR_KILLMESSAGE:
 265                 {
 266                         return WEAPON_LASER_MURDER;
 267                 }
 268         }
 269
 270         return TRUE;
 271 }
 272 #endif
 273 #ifdef CSQC
 274 float W_Blaster(float request)
 275 {
 276         switch(request)
 277         {
 278                 case WR_IMPACTEFFECT:
 279                 {
 280                         vector org2;
 281                         org2 = w_org + w_backoff * 6;
 282                         pointparticles(particleeffectnum("new_laser_impact"), org2, w_backoff * 1000, 1);
 283                         if(!w_issilent) { sound(self, CH_SHOTS, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM); }
 284                         return TRUE;
 285                 }
 286
 287                 case WR_INIT:
 288                 {
 289                         precache_sound("weapons/laserimpact.wav");
 290                         return TRUE;
 291                 }
 292         }
 293
 294         return TRUE;
 295 }
 296 #endif
 297 #endif