qcsrc/common/weapons/w_blaster.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ BLASTER,
   4 /* function */ W_Blaster,
   5 /* ammotype */ ammo_none,
   6 /* impulse  */ 1,
   7 /* flags    */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating   */ 0,
   9 /* model    */ "laser",
  10 /* netname  */ "laser",
  11 /* fullname */ _("Blaster")
  12 );
  13
  14 #define BLASTER_SETTINGS(w_cvar,w_prop) BLASTER_SETTINGS_LIST(w_cvar, w_prop, BLASTER, blaster)
  15 #define BLASTER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  16         w_cvar(id, sn, MO_BOTH, animtime) \
  17         w_cvar(id, sn, MO_BOTH, damage) \
  18         w_cvar(id, sn, MO_BOTH, delay) \
  19         w_cvar(id, sn, MO_BOTH, edgedamage) \
  20         w_cvar(id, sn, MO_BOTH, force) \
  21         w_cvar(id, sn, MO_BOTH, lifetime) \
  22         w_cvar(id, sn, MO_BOTH, radius) \
  23         w_cvar(id, sn, MO_BOTH, refire) \
  24         w_cvar(id, sn, MO_BOTH, shotangle) \
  25         w_cvar(id, sn, MO_BOTH, speed) \
  26         w_cvar(id, sn, MO_BOTH, spread) \
  27         w_cvar(id, sn, MO_NONE, secondary) \
  28         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  29         w_prop(id, sn, float,  reloading_time, reload_time) \
  30         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  31         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  32         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  33         w_prop(id, sn, float,  weaponstart, weaponstart) \
  34         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  35
  36 #ifdef SVQC
  37 BLASTER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  38 .float blaster_damage;
  39 .float blaster_edgedamage;
  40 .float blaster_radius;
  41 .float blaster_force;
  42 .float blaster_lifetime;
  43 #endif
  44 #else
  45 #ifdef SVQC
  46 void spawnfunc_weapon_blaster() { weapon_defaultspawnfunc(WEP_BLASTER); }
  47 void spawnfunc_weapon_laser() { spawnfunc_weapon_blaster(); }
  48
  49 void W_Blaster_Touch()
  50 {
  51         PROJECTILE_TOUCH;
  52
  53         self.event_damage = func_null;
  54
  55         RadiusDamage(
  56                 self,
  57                 self.realowner,
  58                 self.blaster_damage,
  59                 self.blaster_edgedamage,
  60                 self.blaster_radius,
  61                 world,
  62                 world,
  63                 self.blaster_force,
  64                 self.projectiledeathtype,
  65                 other
  66         );
  67
  68         remove(self);
  69 }
  70
  71 void W_Blaster_Think()
  72 {
  73         self.movetype = MOVETYPE_FLY;
  74         self.think = SUB_Remove;
  75         self.nextthink = time + self.blaster_lifetime;
  76         CSQCProjectile(self, TRUE, PROJECTILE_BLASTER, TRUE);
  77 }
  78
  79 void W_Blaster_Attack(
  80         float atk_shotangle,
  81         float atk_damage,
  82         float atk_edgedamage,
  83         float atk_radius,
  84         float atk_force,
  85         float atk_speed,
  86         float atk_spread,
  87         float atk_delay,
  88         float atk_lifetime)
  89 {
  90         vector s_forward = v_forward * cos(atk_shotangle * DEG2RAD) + v_up * sin(atk_shotangle * DEG2RAD);
  91
  92         W_SetupShot_Dir(self, s_forward, FALSE, 3, "weapons/lasergun_fire.wav", CH_WEAPON_B, atk_damage);
  93         pointparticles(particleeffectnum("laser_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  94
  95         entity missile = spawn();
  96         missile.owner = missile.realowner = self;
  97         missile.classname = "blasterbolt";
  98         missile.bot_dodge = TRUE;
  99         missile.bot_dodgerating = atk_damage;
 100         PROJECTILE_MAKETRIGGER(missile);
 101
 102         missile.blaster_damage = atk_damage;
 103         missile.blaster_edgedamage = atk_edgedamage;
 104         missile.blaster_radius = atk_radius;
 105         missile.blaster_force = atk_force;
 106         missile.blaster_lifetime = atk_lifetime;
 107
 108         setorigin(missile, w_shotorg);
 109         setsize(missile, '0 0 0', '0 0 0');
 110
 111         W_SetupProjectileVelocityEx(
 112                 missile,
 113                 w_shotdir,
 114                 v_up,
 115                 atk_speed,
 116                 0,
 117                 0,
 118                 atk_spread,
 119                 FALSE
 120         );
 121
 122         missile.angles = vectoangles(missile.velocity);
 123
 124         //missile.glow_color = 250; // 244, 250
 125         //missile.glow_size = 120;
 126
 127         missile.touch = W_Blaster_Touch;
 128         missile.flags = FL_PROJECTILE;
 129         missile.missile_flags = MIF_SPLASH;
 130         missile.projectiledeathtype = WEP_BLASTER;
 131         missile.think = W_Blaster_Think;
 132         missile.nextthink = time + atk_delay;
 133
 134         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 135
 136         if(time >= missile.nextthink)
 137         {
 138                 entity oldself;
 139                 oldself = self;
 140                 self = missile;
 141                 self.think();
 142                 self = oldself;
 143         }
 144 }
 145 float W_Blaster(float request)
 146 {
 147         switch(request)
 148         {
 149                 case WR_AIM:
 150                 {
 151                         if(WEP_CVAR(blaster, secondary))
 152                         {
 153                                 if((random() * (WEP_CVAR_PRI(blaster, damage) + WEP_CVAR_SEC(blaster, damage))) > WEP_CVAR_PRI(blaster, damage))
 154                                         { self.BUTTON_ATCK2 = bot_aim(WEP_CVAR_SEC(blaster, speed), 0, WEP_CVAR_SEC(blaster, lifetime), FALSE); }
 155                                 else
 156                                         { self.BUTTON_ATCK = bot_aim(WEP_CVAR_PRI(blaster, speed), 0, WEP_CVAR_PRI(blaster, lifetime), FALSE); }
 157                         }
 158                         else
 159                                 { self.BUTTON_ATCK = bot_aim(WEP_CVAR_PRI(blaster, speed), 0, WEP_CVAR_PRI(blaster, lifetime), FALSE); }
 160
 161                         return TRUE;
 162                 }
 163
 164                 case WR_THINK:
 165                 {
 166                         if(WEP_CVAR(blaster, reload_ammo) && self.clip_load < 1) // forced reload
 167                         {
 168                                 WEP_ACTION(self.weapon, WR_RELOAD);
 169                         }
 170                         else if(self.BUTTON_ATCK)
 171                         {
 172                                 if(weapon_prepareattack(0, WEP_CVAR_PRI(blaster, refire)))
 173                                 {
 174                                         W_DecreaseAmmo(ammo_none, 1, TRUE); // WEAPONTODO is this necessary?
 175                                         W_Blaster_Attack(
 176                                                 WEP_CVAR_PRI(blaster, shotangle),
 177                                                 WEP_CVAR_PRI(blaster, damage),
 178                                                 WEP_CVAR_PRI(blaster, edgedamage),
 179                                                 WEP_CVAR_PRI(blaster, radius),
 180                                                 WEP_CVAR_PRI(blaster, force),
 181                                                 WEP_CVAR_PRI(blaster, speed),
 182                                                 WEP_CVAR_PRI(blaster, spread),
 183                                                 WEP_CVAR_PRI(blaster, delay),
 184                                                 WEP_CVAR_PRI(blaster, lifetime)
 185                                         );
 186                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(blaster, animtime), w_ready);
 187                                 }
 188                         }
 189                         else if(self.BUTTON_ATCK2)
 190                         {
 191                                 switch(WEP_CVAR(blaster, secondary))
 192                                 {
 193                                         case 0: // switch to last used weapon
 194                                         {
 195                                                 if(self.switchweapon == WEP_BLASTER) // don't do this if already switching
 196                                                         W_LastWeapon();
 197                                                 break;
 198                                         }
 199
 200                                         case 1: // normal projectile secondary
 201                                         {
 202                                                 if(weapon_prepareattack(1, WEP_CVAR_SEC(blaster, refire)))
 203                                                 {
 204                                                         W_DecreaseAmmo(ammo_none, 1, TRUE);
 205                                                         W_Blaster_Attack(
 206                                                                 WEP_CVAR_SEC(blaster, shotangle),
 207                                                                 WEP_CVAR_SEC(blaster, damage),
 208                                                                 WEP_CVAR_SEC(blaster, edgedamage),
 209                                                                 WEP_CVAR_SEC(blaster, radius),
 210                                                                 WEP_CVAR_SEC(blaster, force),
 211                                                                 WEP_CVAR_SEC(blaster, speed),
 212                                                                 WEP_CVAR_SEC(blaster, spread),
 213                                                                 WEP_CVAR_SEC(blaster, delay),
 214                                                                 WEP_CVAR_SEC(blaster, lifetime)
 215                                                         );
 216                                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(blaster, animtime), w_ready);
 217                                                 }
 218
 219                                                 break;
 220                                         }
 221                                 }
 222                         }
 223                         return TRUE;
 224                 }
 225
 226                 case WR_INIT:
 227                 {
 228                         precache_model("models/weapons/g_laser.md3");
 229                         precache_model("models/weapons/v_laser.md3");
 230                         precache_model("models/weapons/h_laser.iqm");
 231                         precache_sound("weapons/lasergun_fire.wav");
 232                         BLASTER_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 233                         return TRUE;
 234                 }
 235
 236                 case WR_SETUP:
 237                 {
 238                         self.current_ammo = ammo_none;
 239                         return TRUE;
 240                 }
 241
 242                 case WR_CHECKAMMO1:
 243                 case WR_CHECKAMMO2:
 244                 {
 245                         return TRUE; // laser has infinite ammo
 246                 }
 247
 248                 case WR_CONFIG:
 249                 {
 250                         BLASTER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 251                         return TRUE;
 252                 }
 253
 254                 case WR_RELOAD:
 255                 {
 256                         W_Reload(0, "weapons/reload.wav");
 257                         return TRUE;
 258                 }
 259
 260                 case WR_SUICIDEMESSAGE:
 261                 {
 262                         return WEAPON_LASER_SUICIDE;
 263                 }
 264
 265                 case WR_KILLMESSAGE:
 266                 {
 267                         return WEAPON_LASER_MURDER;
 268                 }
 269         }
 270
 271         return TRUE;
 272 }
 273 #endif
 274 #ifdef CSQC
 275 float W_Blaster(float request)
 276 {
 277         switch(request)
 278         {
 279                 case WR_IMPACTEFFECT:
 280                 {
 281                         vector org2;
 282                         org2 = w_org + w_backoff * 6;
 283                         pointparticles(particleeffectnum("new_laser_impact"), org2, w_backoff * 1000, 1);
 284                         if(!w_issilent) { sound(self, CH_SHOTS, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM); }
 285                         return TRUE;
 286                 }
 287
 288                 case WR_INIT:
 289                 {
 290                         precache_sound("weapons/laserimpact.wav");
 291                         return TRUE;
 292                 }
 293         }
 294
 295         return TRUE;
 296 }
 297 #endif
 298 #endif