qcsrc/common/weapons/w_devastator.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ DEVASTATOR,
   4 /* function */ W_Devastator,
   5 /* ammotype */ ammo_rockets,
   6 /* impulse  */ 9,
   7 /* flags    */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating   */ BOT_PICKUP_RATING_HIGH,
   9 /* model    */ "rl",
  10 /* netname  */ "devastator",
  11 /* fullname */ _("Devastator")
  12 );
  13
  14 #define DEVASTATOR_SETTINGS(w_cvar,w_prop) DEVASTATOR_SETTINGS_LIST(w_cvar, w_prop, DEVASTATOR, devastator)
  15 #define DEVASTATOR_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  16         w_cvar(id, sn, NONE, ammo) \
  17         w_cvar(id, sn, NONE, animtime) \
  18         w_cvar(id, sn, NONE, damage) \
  19         w_cvar(id, sn, NONE, damageforcescale) \
  20         w_cvar(id, sn, NONE, detonatedelay) \
  21         w_cvar(id, sn, NONE, edgedamage) \
  22         w_cvar(id, sn, NONE, force) \
  23         w_cvar(id, sn, NONE, guidedelay) \
  24         w_cvar(id, sn, NONE, guidegoal) \
  25         w_cvar(id, sn, NONE, guiderate) \
  26         w_cvar(id, sn, NONE, guideratedelay) \
  27         w_cvar(id, sn, NONE, guidestop) \
  28         w_cvar(id, sn, NONE, health) \
  29         w_cvar(id, sn, NONE, lifetime) \
  30         w_cvar(id, sn, NONE, radius) \
  31         w_cvar(id, sn, NONE, refire) \
  32         w_cvar(id, sn, NONE, remote_damage) \
  33         w_cvar(id, sn, NONE, remote_edgedamage) \
  34         w_cvar(id, sn, NONE, remote_force) \
  35         w_cvar(id, sn, NONE, remote_radius) \
  36         w_cvar(id, sn, NONE, speed) \
  37         w_cvar(id, sn, NONE, speedaccel) \
  38         w_cvar(id, sn, NONE, speedstart) \
  39         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  40         w_prop(id, sn, float,  reloading_time, reload_time) \
  41         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  42         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  43         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  44         w_prop(id, sn, float,  weaponstart, weaponstart) \
  45         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  46
  47 #ifdef SVQC
  48 DEVASTATOR_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  49 .float rl_release;
  50 .float rl_detonate_later;
  51 #endif
  52 #else
  53 #ifdef SVQC
  54 void spawnfunc_weapon_devastator() { weapon_defaultspawnfunc(WEP_DEVASTATOR); }
  55 void spawnfunc_weapon_rocketlauncher() { spawnfunc_weapon_devastator(); }
  56
  57 void W_Devastator_Unregister()
  58 {
  59         if(self.realowner && self.realowner.lastrocket == self)
  60         {
  61                 self.realowner.lastrocket = world;
  62                 // self.realowner.rl_release = 1;
  63         }
  64 }
  65
  66 void W_Devastator_Explode()
  67 {
  68         W_Devastator_Unregister();
  69
  70         if(other.takedamage == DAMAGE_AIM)
  71                 if(IS_PLAYER(other))
  72                         if(DIFF_TEAM(self.realowner, other))
  73                                 if(other.deadflag == DEAD_NO)
  74                                         if(IsFlying(other))
  75                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
  76
  77         self.event_damage = func_null;
  78         self.takedamage = DAMAGE_NO;
  79
  80         RadiusDamage (self, self.realowner, WEP_CVAR(devastator, damage), WEP_CVAR(devastator, edgedamage), WEP_CVAR(devastator, radius), world, world, WEP_CVAR(devastator, force), self.projectiledeathtype, other);
  81
  82         if (self.realowner.weapon == WEP_DEVASTATOR)
  83         {
  84                 if(self.realowner.ammo_rockets < WEP_CVAR(devastator, ammo))
  85                 {
  86                         self.realowner.cnt = WEP_DEVASTATOR;
  87                         ATTACK_FINISHED(self.realowner) = time;
  88                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
  89                 }
  90         }
  91         remove (self);
  92 }
  93
  94 void W_Devastator_DoRemoteExplode()
  95 {
  96         W_Devastator_Unregister();
  97
  98         self.event_damage = func_null;
  99         self.takedamage = DAMAGE_NO;
 100
 101         RadiusDamage (self, self.realowner, WEP_CVAR(devastator, remote_damage), WEP_CVAR(devastator, remote_edgedamage), WEP_CVAR(devastator, remote_radius), world, world, WEP_CVAR(devastator, remote_force), self.projectiledeathtype | HITTYPE_BOUNCE, world);
 102
 103         if (self.realowner.weapon == WEP_DEVASTATOR)
 104         {
 105                 if(self.realowner.ammo_rockets < WEP_CVAR(devastator, ammo))
 106                 {
 107                         self.realowner.cnt = WEP_DEVASTATOR;
 108                         ATTACK_FINISHED(self.realowner) = time;
 109                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
 110                 }
 111         }
 112         remove (self);
 113 }
 114
 115 void W_Devastator_RemoteExplode()
 116 {
 117         if(self.realowner.deadflag == DEAD_NO)
 118         if(self.realowner.lastrocket)
 119         {
 120                 if((self.spawnshieldtime >= 0)
 121                         ? (time >= self.spawnshieldtime) // timer
 122                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > WEP_CVAR(devastator, remote_radius)) // safety device
 123                 )
 124                 {
 125                         W_Devastator_DoRemoteExplode();
 126                 }
 127         }
 128 }
 129
 130 vector W_Devastator_SteerTo(vector thisdir, vector goaldir, float maxturn_cos)
 131 {
 132         if(thisdir * goaldir > maxturn_cos)
 133                 return goaldir;
 134         if(thisdir * goaldir < -0.9998) // less than 1 degree and opposite
 135                 return thisdir; // refuse to guide (better than letting a numerical error happen)
 136         float f, m2;
 137         vector v;
 138         // solve:
 139         //   g = normalize(thisdir + goaldir * X)
 140         //   thisdir * g = maxturn
 141         //
 142         //   gg = thisdir + goaldir * X
 143         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 144         //
 145         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 146         f = thisdir * goaldir;
 147         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 148         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 149         m2 = maxturn_cos * maxturn_cos;
 150         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 151         return normalize(thisdir + goaldir * v_y); // the larger solution!
 152 }
 153 // assume thisdir == -goaldir:
 154 //   f == -1
 155 //   v = solve_qadratic(m2 - 1, -2 * (m2 - 1), m2 - 1)
 156 //   (m2 - 1) x^2 - 2 * (m2 - 1) * x + (m2 - 1) = 0
 157 //   x^2 - 2 * x + 1 = 0
 158 //   (x - 1)^2 = 0
 159 //   x = 1
 160 //   normalize(thisdir + goaldir)
 161 //   normalize(0)
 162
 163 void W_Devastator_Think (void)
 164 {
 165         vector desireddir, olddir, newdir, desiredorigin, goal;
 166 #if 0
 167         float cosminang, cosmaxang, cosang;
 168 #endif
 169         float velspeed, f;
 170         self.nextthink = time;
 171         if (time > self.cnt)
 172         {
 173                 other = world;
 174                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 175                 W_Devastator_Explode ();
 176                 return;
 177         }
 178
 179         // accelerate
 180         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 181         velspeed = WEP_CVAR(devastator, speed) * g_weaponspeedfactor - (self.velocity * v_forward);
 182         if (velspeed > 0)
 183                 self.velocity = self.velocity + v_forward * min(WEP_CVAR(devastator, speedaccel) * g_weaponspeedfactor * frametime, velspeed);
 184
 185         // laser guided, or remote detonation
 186         if (self.realowner.weapon == WEP_DEVASTATOR)
 187         {
 188                 if(self == self.realowner.lastrocket)
 189                 if(!self.realowner.rl_release)
 190                 if(!self.BUTTON_ATCK2)
 191                 if(WEP_CVAR(devastator, guiderate))
 192                 if(time > self.pushltime)
 193                 if(self.realowner.deadflag == DEAD_NO)
 194                 {
 195                         f = WEP_CVAR(devastator, guideratedelay);
 196                         if(f)
 197                                 f = bound(0, (time - self.pushltime) / f, 1);
 198                         else
 199                                 f = 1;
 200
 201                         velspeed = vlen(self.velocity);
 202
 203                         makevectors(self.realowner.v_angle);
 204                         desireddir = WarpZone_RefSys_TransformVelocity(self.realowner, self, v_forward);
 205                         desiredorigin = WarpZone_RefSys_TransformOrigin(self.realowner, self, self.realowner.origin + self.realowner.view_ofs);
 206                         olddir = normalize(self.velocity);
 207
 208                         // now it gets tricky... we want to move like some curve to approximate the target direction
 209                         // but we are limiting the rate at which we can turn!
 210                         goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + WEP_CVAR(devastator, guidegoal)) * desireddir;
 211                         newdir = W_Devastator_SteerTo(olddir, normalize(goal - self.origin), cos(WEP_CVAR(devastator, guiderate) * f * frametime * DEG2RAD));
 212
 213                         self.velocity = newdir * velspeed;
 214                         self.angles = vectoangles(self.velocity);
 215
 216                         if(!self.count)
 217                         {
 218                                 pointparticles(particleeffectnum("rocket_guide"), self.origin, self.velocity, 1);
 219                                 // TODO add a better sound here
 220                                 sound (self.realowner, CH_WEAPON_B, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 221                                 self.count = 1;
 222                         }
 223                 }
 224
 225                 if(self.rl_detonate_later)
 226                         W_Devastator_RemoteExplode();
 227         }
 228
 229         if(self.csqcprojectile_clientanimate == 0)
 230                 UpdateCSQCProjectile(self);
 231 }
 232
 233 void W_Devastator_Touch (void)
 234 {
 235         if(WarpZone_Projectile_Touch())
 236         {
 237                 if(wasfreed(self))
 238                         W_Devastator_Unregister();
 239                 return;
 240         }
 241         W_Devastator_Unregister();
 242         W_Devastator_Explode ();
 243 }
 244
 245 void W_Devastator_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 246 {
 247         if (self.health <= 0)
 248                 return;
 249
 250         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 251                 return; // g_projectiles_damage says to halt
 252
 253         self.health = self.health - damage;
 254         self.angles = vectoangles(self.velocity);
 255
 256         if (self.health <= 0)
 257                 W_PrepareExplosionByDamage(attacker, W_Devastator_Explode);
 258 }
 259
 260 void W_Devastator_Attack (void)
 261 {
 262         entity missile;
 263         entity flash;
 264
 265         W_DecreaseAmmo(WEP_CVAR(devastator, ammo));
 266
 267         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav", CH_WEAPON_A, WEP_CVAR(devastator, damage));
 268         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 269
 270         missile = WarpZone_RefSys_SpawnSameRefSys(self);
 271         missile.owner = missile.realowner = self;
 272         self.lastrocket = missile;
 273         if(WEP_CVAR(devastator, detonatedelay) >= 0)
 274                 missile.spawnshieldtime = time + WEP_CVAR(devastator, detonatedelay);
 275         else
 276                 missile.spawnshieldtime = -1;
 277         missile.pushltime = time + WEP_CVAR(devastator, guidedelay);
 278         missile.classname = "rocket";
 279         missile.bot_dodge = TRUE;
 280         missile.bot_dodgerating = WEP_CVAR(devastator, damage) * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 281
 282         missile.takedamage = DAMAGE_YES;
 283         missile.damageforcescale = WEP_CVAR(devastator, damageforcescale);
 284         missile.health = WEP_CVAR(devastator, health);
 285         missile.event_damage = W_Devastator_Damage;
 286         missile.damagedbycontents = TRUE;
 287
 288         missile.movetype = MOVETYPE_FLY;
 289         PROJECTILE_MAKETRIGGER(missile);
 290         missile.projectiledeathtype = WEP_DEVASTATOR;
 291         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 292
 293         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 294         W_SetupProjectileVelocity(missile, WEP_CVAR(devastator, speedstart), 0);
 295         missile.angles = vectoangles (missile.velocity);
 296
 297         missile.touch = W_Devastator_Touch;
 298         missile.think = W_Devastator_Think;
 299         missile.nextthink = time;
 300         missile.cnt = time + WEP_CVAR(devastator, lifetime);
 301         missile.flags = FL_PROJECTILE;
 302         missile.missile_flags = MIF_SPLASH;
 303
 304         CSQCProjectile(missile, WEP_CVAR(devastator, guiderate) == 0 && WEP_CVAR(devastator, speedaccel) == 0, PROJECTILE_ROCKET, FALSE); // because of fly sound
 305
 306         // muzzle flash for 1st person view
 307         flash = spawn ();
 308         setmodel (flash, "models/flash.md3"); // precision set below
 309         SUB_SetFade (flash, time, 0.1);
 310         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 311         W_AttachToShotorg(flash, '5 0 0');
 312
 313         // common properties
 314         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 315 }
 316
 317 float W_Devastator(float req)
 318 {
 319         entity rock;
 320         float rockfound;
 321         float ammo_amount;
 322         switch(req)
 323         {
 324                 case WR_AIM: // WEAPONTODO: rewrite this, it's WAY too complicated for what it should be
 325                 {
 326                         // aim and decide to fire if appropriate
 327                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(devastator, speed), 0, WEP_CVAR(devastator, lifetime), FALSE);
 328                         if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 329                         {
 330                                 // decide whether to detonate rockets
 331                                 entity missile, targetlist, targ;
 332                                 targetlist = findchainfloat(bot_attack, TRUE);
 333                                 for(missile = world; (missile = find(missile, classname, "rocket")); ) if(missile.realowner == self)
 334                                 {
 335                                         targ = targetlist;
 336                                         while(targ)
 337                                         {
 338                                                 if(targ != missile.realowner && vlen(targ.origin - missile.origin) < WEP_CVAR(devastator, radius))
 339                                                 {
 340                                                         self.BUTTON_ATCK2 = TRUE;
 341                                                         break;
 342                                                 }
 343                                                 targ = targ.chain;
 344                                         }
 345                                 }
 346
 347                                 if(self.BUTTON_ATCK2) self.BUTTON_ATCK = FALSE;
 348                         }
 349
 350                         return TRUE;
 351                 }
 352                 case WR_THINK:
 353                 {
 354                         if(WEP_CVAR(devastator, reload_ammo) && self.clip_load < WEP_CVAR(devastator, ammo)) // forced reload
 355                                 WEP_ACTION(self.weapon, WR_RELOAD);
 356                         else
 357                         {
 358                                 if(self.BUTTON_ATCK)
 359                                 {
 360                                         if(self.rl_release || WEP_CVAR(devastator, guidestop))
 361                                         if(weapon_prepareattack(0, WEP_CVAR(devastator, refire)))
 362                                         {
 363                                                 W_Devastator_Attack();
 364                                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(devastator, animtime), w_ready);
 365                                                 self.rl_release = 0;
 366                                         }
 367                                 }
 368                                 else
 369                                         self.rl_release = 1;
 370
 371                                 if(self.BUTTON_ATCK2)
 372                                 {
 373                                         rockfound = 0;
 374                                         for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.realowner == self)
 375                                         {
 376                                                 if(!rock.rl_detonate_later)
 377                                                 {
 378                                                         rock.rl_detonate_later = TRUE;
 379                                                         rockfound = 1;
 380                                                 }
 381                                         }
 382                                         if(rockfound)
 383                                                 sound (self, CH_WEAPON_B, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 384                                 }
 385                         }
 386
 387                         return TRUE;
 388                 }
 389                 case WR_INIT:
 390                 {
 391                         if(autocvar_sv_precacheweapons)
 392                         {
 393                                 precache_model("models/flash.md3");
 394                                 precache_model("models/weapons/g_rl.md3");
 395                                 precache_model("models/weapons/v_rl.md3");
 396                                 precache_model("models/weapons/h_rl.iqm");
 397                                 precache_sound("weapons/rocket_det.wav");
 398                                 precache_sound("weapons/rocket_fire.wav");
 399                                 precache_sound("weapons/rocket_mode.wav");
 400                         }
 401                         DEVASTATOR_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 402                         return TRUE;
 403                 }
 404                 case WR_SETUP:
 405                 {
 406                         self.current_ammo = ammo_rockets;
 407                         self.rl_release = 1;
 408                         return TRUE;
 409                 }
 410                 case WR_CHECKAMMO1:
 411                 {
 412                         // don't switch while guiding a missile
 413                         if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_DEVASTATOR)
 414                         {
 415                                 ammo_amount = FALSE;
 416                                 if(WEP_CVAR(devastator, reload_ammo))
 417                                 {
 418                                         if(self.ammo_rockets < WEP_CVAR(devastator, ammo) && self.(weapon_load[WEP_DEVASTATOR]) < WEP_CVAR(devastator, ammo))
 419                                                 ammo_amount = TRUE;
 420                                 }
 421                                 else if(self.ammo_rockets < WEP_CVAR(devastator, ammo))
 422                                         ammo_amount = TRUE;
 423                                 return !ammo_amount;
 424                         }
 425
 426                         return TRUE;
 427                 }
 428                 case WR_CHECKAMMO2:
 429                 {
 430                         return FALSE;
 431                 }
 432                 case WR_CONFIG:
 433                 {
 434                         DEVASTATOR_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 435                         return TRUE;
 436                 }
 437                 case WR_RESETPLAYER:
 438                 {
 439                         self.rl_release = 0;
 440                         return TRUE;
 441                 }
 442                 case WR_RELOAD:
 443                 {
 444                         W_Reload(WEP_CVAR(devastator, ammo), "weapons/reload.wav");
 445                         return TRUE;
 446                 }
 447                 case WR_SUICIDEMESSAGE:
 448                 {
 449                         return WEAPON_ROCKETLAUNCHER_SUICIDE;
 450                 }
 451                 case WR_KILLMESSAGE:
 452                 {
 453                         if((w_deathtype & HITTYPE_BOUNCE) || (w_deathtype & HITTYPE_SPLASH))
 454                                 return WEAPON_ROCKETLAUNCHER_MURDER_SPLASH;
 455                         else
 456                                 return WEAPON_ROCKETLAUNCHER_MURDER_DIRECT;
 457                 }
 458         }
 459         return TRUE;
 460 }
 461 #endif
 462 #ifdef CSQC
 463 float W_Devastator(float req)
 464 {
 465         switch(req)
 466         {
 467                 case WR_IMPACTEFFECT:
 468                 {
 469                         vector org2;
 470                         org2 = w_org + w_backoff * 12;
 471                         pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 472                         if(!w_issilent)
 473                                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 474
 475                         return TRUE;
 476                 }
 477                 case WR_INIT:
 478                 {
 479                         precache_sound("weapons/rocket_impact.wav");
 480                         return TRUE;
 481                 }
 482         }
 483         return TRUE;
 484 }
 485 #endif
 486 #endif