qcsrc/common/weapons/w_electro.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ ELECTRO,
   4 /* function */ W_Electro,
   5 /* ammotype */ IT_CELLS,
   6 /* impulse  */ 5,
   7 /* flags    */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH,
   8 /* rating   */ BOT_PICKUP_RATING_MID,
   9 /* model    */ "electro",
  10 /* netname  */ "electro",
  11 /* fullname */ _("Electro")
  12 );
  13
  14 #define ELECTRO_SETTINGS(w_cvar,w_prop) \
  15         w_cvar(WEP_ELECTRO, electro, MO_BOTH, ammo) \
  16         w_cvar(WEP_ELECTRO, electro, MO_BOTH, animtime) \
  17         w_cvar(WEP_ELECTRO, electro, MO_BOTH, damage) \
  18         w_cvar(WEP_ELECTRO, electro, MO_BOTH, edgedamage) \
  19         w_cvar(WEP_ELECTRO, electro, MO_BOTH, force) \
  20         w_cvar(WEP_ELECTRO, electro, MO_BOTH, radius) \
  21         w_cvar(WEP_ELECTRO, electro, MO_BOTH, refire) \
  22         w_cvar(WEP_ELECTRO, electro, MO_BOTH, speed) \
  23         w_cvar(WEP_ELECTRO, electro, MO_BOTH, spread) \
  24         w_cvar(WEP_ELECTRO, electro, MO_BOTH, lifetime) \
  25         w_cvar(WEP_ELECTRO, electro, MO_PRI,  comboradius) \
  26         w_cvar(WEP_ELECTRO, electro, MO_PRI,  midaircombo_interval) \
  27         w_cvar(WEP_ELECTRO, electro, MO_PRI,  midaircombo_radius) \
  28         w_cvar(WEP_ELECTRO, electro, MO_SEC,  bouncefactor) \
  29         w_cvar(WEP_ELECTRO, electro, MO_SEC,  bouncestop) \
  30         w_cvar(WEP_ELECTRO, electro, MO_SEC,  count) \
  31         w_cvar(WEP_ELECTRO, electro, MO_SEC,  damageforcescale) \
  32         w_cvar(WEP_ELECTRO, electro, MO_SEC,  damagedbycontents) \
  33         w_cvar(WEP_ELECTRO, electro, MO_SEC,  takedamageexplode) \
  34         w_cvar(WEP_ELECTRO, electro, MO_SEC,  health) \
  35         w_cvar(WEP_ELECTRO, electro, MO_SEC,  refire2) \
  36         w_cvar(WEP_ELECTRO, electro, MO_SEC,  speed_up) \
  37         w_cvar(WEP_ELECTRO, electro, MO_SEC,  speed_z) \
  38         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_comboradius) \
  39         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_comboradius_thruwall) \
  40         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_damage) \
  41         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_edgedamage) \
  42         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_force) \
  43         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_radius) \
  44         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_speed) \
  45         w_cvar(WEP_ELECTRO, electro, MO_NONE, combo_safeammocheck) \
  46         w_prop(WEP_ELECTRO, electro, reloading_ammo, reload_ammo) \
  47         w_prop(WEP_ELECTRO, electro, reloading_time, reload_time) \
  48         w_prop(WEP_ELECTRO, electro, switchdelay_raise, switchdelay_raise) \
  49         w_prop(WEP_ELECTRO, electro, switchdelay_drop, switchdelay_drop)
  50
  51 #ifdef SVQC
  52 ELECTRO_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  53 .float electro_count;
  54 .float electro_secondarytime;
  55 void W_Plasma_Explode_Combo(void);
  56 #endif
  57 #else
  58 #ifdef SVQC
  59 void spawnfunc_weapon_electro() { weapon_defaultspawnfunc(WEP_ELECTRO); }
  60
  61 void W_Plasma_TriggerCombo(vector org, float rad, entity own)
  62 {
  63         entity e = WarpZone_FindRadius(org, rad, !WEP_CVAR(electro, combo_comboradius_thruwall));
  64         while(e)
  65         {
  66                 if(e.classname == "plasma")
  67                 {
  68                         // change owner to whoever caused the combo explosion
  69                         WarpZone_TraceLine(org, e.origin, MOVE_NOMONSTERS, e);
  70
  71                         if(
  72                                 (trace_fraction == 1)
  73                                 ||
  74                                 (WEP_CVAR(electro, combo_comboradius_thruwall) >= vlen(e.WarpZone_findradius_dist))
  75                         )
  76                         {
  77                                 e.realowner = own;
  78                                 e.takedamage = DAMAGE_NO;
  79                                 e.classname = "plasma_chain";
  80                                 e.think = W_Plasma_Explode_Combo;
  81                                 e.nextthink = time + vlen(e.WarpZone_findradius_dist) / WEP_CVAR(electro, combo_speed); // delay combo chains, looks cooler
  82                         }
  83                 }
  84                 e = e.chain;
  85         }
  86 }
  87
  88 void W_Plasma_Explode(void)
  89 {
  90         if(other.takedamage == DAMAGE_AIM)
  91                 if(IS_PLAYER(other))
  92                         if(DIFF_TEAM(self.realowner, other))
  93                                 if(other.deadflag == DEAD_NO)
  94                                         if(IsFlying(other))
  95                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_ELECTROBITCH);
  96
  97         self.event_damage = func_null;
  98         self.takedamage = DAMAGE_NO;
  99
 100         if(self.movetype == MOVETYPE_BOUNCE)
 101         {
 102                 RadiusDamage(
 103                         self,
 104                         self.realowner,
 105                         WEP_CVAR_SEC(electro, damage),
 106                         WEP_CVAR_SEC(electro, edgedamage),
 107                         WEP_CVAR_SEC(electro, radius),
 108                         world,
 109                         world,
 110                         WEP_CVAR_SEC(electro, force),
 111                         self.projectiledeathtype,
 112                         other
 113                 );
 114         }
 115         else
 116         {
 117                 W_Plasma_TriggerCombo(self.origin, WEP_CVAR_PRI(electro, comboradius), self.realowner);
 118                 RadiusDamage(
 119                         self,
 120                         self.realowner,
 121                         WEP_CVAR_PRI(electro, damage),
 122                         WEP_CVAR_PRI(electro, edgedamage),
 123                         WEP_CVAR_PRI(electro, radius),
 124                         world,
 125                         world,
 126                         WEP_CVAR_PRI(electro, force),
 127                         self.projectiledeathtype,
 128                         other
 129                 );
 130         }
 131
 132         remove(self);
 133 }
 134
 135 void W_Plasma_Explode_Combo(void)
 136 {
 137         W_Plasma_TriggerCombo(self.origin, WEP_CVAR(electro, combo_comboradius), self.realowner);
 138
 139         self.event_damage = func_null;
 140
 141         RadiusDamage(
 142                 self,
 143                 self.realowner,
 144                 WEP_CVAR(electro, combo_damage),
 145                 WEP_CVAR(electro, combo_edgedamage),
 146                 WEP_CVAR(electro, combo_radius),
 147                 world,
 148                 world,
 149                 WEP_CVAR(electro, combo_force),
 150                 WEP_ELECTRO | HITTYPE_BOUNCE, // use THIS type for a combo because primary can't bounce
 151                 world
 152         );
 153
 154         remove (self);
 155 }
 156
 157 void W_Plasma_Touch(void)
 158 {
 159         PROJECTILE_TOUCH;
 160         if(other.takedamage == DAMAGE_AIM)
 161                 { if(WEP_CVAR_SEC(electro, takedamageexplode)) { W_Plasma_Explode(); } }
 162         else
 163         {
 164                 //UpdateCSQCProjectile(self);
 165                 spamsound(self, CH_SHOTS, "weapons/electro_bounce.wav", VOL_BASE, ATTEN_NORM);
 166                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 167         }
 168 }
 169
 170 void W_Plasma_TouchExplode(void)
 171 {
 172         PROJECTILE_TOUCH;
 173         W_Plasma_Explode();
 174 }
 175
 176 void W_Plasma_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 177 {
 178         if(self.health <= 0)
 179                 return;
 180
 181         // note: combos are usually triggered by W_Plasma_TriggerCombo, not damage
 182         float is_combo = (inflictor.classname == "plasma_chain" || inflictor.classname == "plasma_prim");
 183
 184         if(!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, (is_combo ? 1 : -1)))
 185                 return; // g_projectiles_damage says to halt
 186
 187         self.health = self.health - damage;
 188         if(self.health <= 0)
 189         {
 190                 self.takedamage = DAMAGE_NO;
 191                 self.nextthink = time;
 192                 if(is_combo)
 193                 {
 194                         // change owner to whoever caused the combo explosion
 195                         self.realowner = inflictor.realowner;
 196                         self.classname = "plasma_chain";
 197                         self.think = W_Plasma_Explode_Combo;
 198                         self.nextthink = time +
 199                                 (
 200                                         // bound the length, inflictor may be in a galaxy far far away (warpzones)
 201                                         min(
 202                                                 WEP_CVAR(electro, combo_radius),
 203                                                 vlen(self.origin - inflictor.origin)
 204                                         )
 205                                         /
 206                                         // delay combo chains, looks cooler
 207                                         WEP_CVAR(electro, combo_speed)
 208                                 );
 209                 }
 210                 else
 211                 {
 212                         self.use = W_Plasma_Explode;
 213                         self.think = adaptor_think2use; // not _hittype_splash, as this runs "immediately"
 214                 }
 215         }
 216 }
 217
 218 void W_Plasma_Think()
 219 {
 220         self.nextthink = min(time + WEP_CVAR_PRI(electro, midaircombo_interval), self.ltime);
 221
 222         if(time >= self.ltime)
 223         {
 224                 self.use();
 225                 return;
 226         }
 227
 228         W_Plasma_TriggerCombo(self.origin, WEP_CVAR_PRI(electro, midaircombo_radius), self.realowner);
 229 }
 230
 231 void W_Electro_Attack_Bolt(void)
 232 {
 233         entity proj;
 234
 235         W_DecreaseAmmo(ammo_cells, WEP_CVAR_PRI(electro, ammo), autocvar_g_balance_electro_reload_ammo);//weapontodo
 236
 237         W_SetupShot_ProjectileSize(self, '0 0 -3', '0 0 -3', FALSE, 2, "weapons/electro_fire.wav", CH_WEAPON_A, WEP_CVAR_PRI(electro, damage));
 238
 239         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 240
 241         proj = spawn ();
 242         proj.classname = "plasma_prim";
 243         proj.owner = proj.realowner = self;
 244         proj.bot_dodge = TRUE;
 245         proj.bot_dodgerating = WEP_CVAR_PRI(electro, damage);
 246         proj.use = W_Plasma_Explode;
 247         proj.think = W_Plasma_Think;
 248         proj.nextthink = time;
 249         proj.ltime = time + WEP_CVAR_PRI(electro, lifetime);
 250         PROJECTILE_MAKETRIGGER(proj);
 251         proj.projectiledeathtype = WEP_ELECTRO;
 252         setorigin(proj, w_shotorg);
 253
 254         proj.movetype = MOVETYPE_FLY;
 255         WEP_SETUPPROJVELOCITY_PRI(proj, electro);
 256         proj.angles = vectoangles(proj.velocity);
 257         proj.touch = W_Plasma_TouchExplode;
 258         setsize(proj, '0 0 -3', '0 0 -3');
 259         proj.flags = FL_PROJECTILE;
 260         proj.missile_flags = MIF_SPLASH;
 261
 262         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO_BEAM, TRUE);
 263
 264         other = proj; MUTATOR_CALLHOOK(EditProjectile);
 265 }
 266
 267 void W_Electro_Attack_Orbs(void)
 268 {
 269         W_DecreaseAmmo(ammo_cells, WEP_CVAR_SEC(electro, ammo), autocvar_g_balance_electro_reload_ammo);//weapontodo
 270
 271         W_SetupShot_ProjectileSize(self, '0 0 -4', '0 0 -4', FALSE, 2, "weapons/electro_fire2.wav", CH_WEAPON_A, WEP_CVAR_SEC(electro, damage));
 272
 273         w_shotdir = v_forward; // no TrueAim for grenades please
 274
 275         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 276
 277         entity proj = spawn();
 278         proj.classname = "plasma";
 279         proj.owner = proj.realowner = self;
 280         proj.use = W_Plasma_Explode;
 281         proj.think = adaptor_think2use_hittype_splash;
 282         proj.bot_dodge = TRUE;
 283         proj.bot_dodgerating = WEP_CVAR_SEC(electro, damage);
 284         proj.nextthink = time + WEP_CVAR_SEC(electro, lifetime);
 285         PROJECTILE_MAKETRIGGER(proj);
 286         proj.projectiledeathtype = WEP_ELECTRO | HITTYPE_SECONDARY;
 287         setorigin(proj, w_shotorg);
 288
 289         //proj.glow_size = 50;
 290         //proj.glow_color = 45;
 291         proj.movetype = MOVETYPE_BOUNCE;
 292         WEP_SETUPPROJVELOCITY_UP_SEC(proj, electro);
 293         proj.touch = W_Plasma_Touch;
 294         setsize(proj, '0 0 -4', '0 0 -4');
 295         proj.takedamage = DAMAGE_YES;
 296         proj.damageforcescale = WEP_CVAR_SEC(electro, damageforcescale);
 297         proj.health = WEP_CVAR_SEC(electro, health);
 298         proj.event_damage = W_Plasma_Damage;
 299         proj.flags = FL_PROJECTILE;
 300         proj.damagedbycontents = (WEP_CVAR_SEC(electro, damagedbycontents));
 301
 302         proj.bouncefactor = WEP_CVAR_SEC(electro, bouncefactor);
 303         proj.bouncestop = WEP_CVAR_SEC(electro, bouncestop);
 304         proj.missile_flags = MIF_SPLASH | MIF_ARC;
 305
 306 #if 0
 307         entity p2;
 308         p2 = spawn();
 309         copyentity(proj, p2);
 310         setmodel(p2, "models/ebomb.mdl");
 311         setsize(p2, proj.mins, proj.maxs);
 312 #endif
 313
 314         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO, FALSE); // no culling, it has sound
 315
 316         other = proj; MUTATOR_CALLHOOK(EditProjectile);
 317 }
 318
 319 void W_Electro_CheckAttack()
 320 {
 321         if(self.electro_count > 1)
 322         if(self.BUTTON_ATCK2)
 323         if(weapon_prepareattack(1, -1))
 324         {
 325                 W_Electro_Attack_Orbs();
 326                 self.electro_count -= 1;
 327                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(electro, animtime), W_Electro_CheckAttack);
 328                 return;
 329         }
 330         w_ready();
 331 }
 332
 333 .float bot_secondary_electromooth;
 334 float W_Electro(float req)
 335 {
 336         float ammo_amount;
 337         switch(req)
 338         {
 339                 case WR_AIM:
 340                 {
 341                         self.BUTTON_ATCK = self.BUTTON_ATCK2 = FALSE;
 342                         if(vlen(self.origin-self.enemy.origin) > 1000) { self.bot_secondary_electromooth = 0; }
 343                         if(self.bot_secondary_electromooth == 0)
 344                         {
 345                                 float shoot;
 346
 347                                 if(WEP_CVAR_PRI(electro, speed))
 348                                         shoot = bot_aim(WEP_CVAR_PRI(electro, speed), 0, WEP_CVAR_PRI(electro, lifetime), FALSE);
 349                                 else
 350                                         shoot = bot_aim(1000000, 0, 0.001, FALSE);
 351
 352                                 if(shoot)
 353                                 {
 354                                         self.BUTTON_ATCK = TRUE;
 355                                         if(random() < 0.01) self.bot_secondary_electromooth = 1;
 356                                 }
 357                         }
 358                         else
 359                         {
 360                                 if(bot_aim(WEP_CVAR_SEC(electro, speed), WEP_CVAR_SEC(electro, speed_up), WEP_CVAR_SEC(electro, lifetime), TRUE))
 361                                 {
 362                                         self.BUTTON_ATCK2 = TRUE;
 363                                         if(random() < 0.03) self.bot_secondary_electromooth = 0;
 364                                 }
 365                         }
 366
 367                         return TRUE;
 368                 }
 369                 case WR_THINK:
 370                 {
 371                         if(autocvar_g_balance_electro_reload_ammo) // forced reload // WEAPONTODO
 372                         {
 373                                 ammo_amount = 0;
 374                                 if(self.clip_load >= WEP_CVAR_PRI(electro, ammo))
 375                                         ammo_amount = 1;
 376                                 if(self.clip_load >= WEP_CVAR_SEC(electro, ammo))
 377                                         ammo_amount += 1;
 378
 379                                 if(!ammo_amount)
 380                                 {
 381                                         WEP_ACTION(self.weapon, WR_RELOAD);
 382                                         return FALSE;
 383                                 }
 384
 385                                 return TRUE;
 386                         }
 387
 388                         if(self.BUTTON_ATCK)
 389                         {
 390                                 if(weapon_prepareattack(0, WEP_CVAR_PRI(electro, refire)))
 391                                 {
 392                                                 W_Electro_Attack_Bolt();
 393                                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(electro, animtime), w_ready);
 394                                 }
 395                         }
 396                         else if(self.BUTTON_ATCK2)
 397                         {
 398                                 if(time >= self.electro_secondarytime)
 399                                 if(weapon_prepareattack(1, WEP_CVAR_SEC(electro, refire)))
 400                                 {
 401                                         W_Electro_Attack_Orbs();
 402                                         self.electro_count = WEP_CVAR_SEC(electro, count);
 403                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(electro, animtime), W_Electro_CheckAttack);
 404                                         self.electro_secondarytime = time + WEP_CVAR_SEC(electro, refire2) * W_WeaponRateFactor();
 405                                 }
 406                         }
 407
 408                         return TRUE;
 409                 }
 410                 case WR_INIT:
 411                 {
 412                         precache_model("models/weapons/g_electro.md3");
 413                         precache_model("models/weapons/v_electro.md3");
 414                         precache_model("models/weapons/h_electro.iqm");
 415                         precache_sound("weapons/electro_bounce.wav");
 416                         precache_sound("weapons/electro_fire.wav");
 417                         precache_sound("weapons/electro_fire2.wav");
 418                         precache_sound("weapons/electro_impact.wav");
 419                         precache_sound("weapons/electro_impact_combo.wav");
 420                         ELECTRO_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 421                         return TRUE;
 422                 }
 423                 case WR_SETUP:
 424                 {
 425                         self.current_ammo = ammo_cells;
 426                         return TRUE;
 427                 }
 428                 case WR_CHECKAMMO1:
 429                 {
 430                         ammo_amount = self.ammo_cells >= WEP_CVAR_PRI(electro, ammo);
 431                         ammo_amount += self.(weapon_load[WEP_ELECTRO]) >= WEP_CVAR_PRI(electro, ammo);
 432                         return ammo_amount;
 433                 }
 434                 case WR_CHECKAMMO2:
 435                 {
 436                         if(WEP_CVAR(electro, combo_safeammocheck)) // true if you can fire at least one secondary blob AND one primary shot after it, otherwise false.
 437                         {
 438                                 ammo_amount = self.ammo_cells >= WEP_CVAR_SEC(electro, ammo) + WEP_CVAR_PRI(electro, ammo);
 439                                 ammo_amount += self.(weapon_load[WEP_ELECTRO]) >= WEP_CVAR_SEC(electro, ammo) + WEP_CVAR_PRI(electro, ammo);
 440                         }
 441                         else
 442                         {
 443                                 ammo_amount = self.ammo_cells >= WEP_CVAR_SEC(electro, ammo);
 444                                 ammo_amount += self.(weapon_load[WEP_ELECTRO]) >= WEP_CVAR_SEC(electro, ammo);
 445                         }
 446                         return ammo_amount;
 447                 }
 448                 case WR_CONFIG:
 449                 {
 450                         ELECTRO_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 451                         return TRUE;
 452                 }
 453                 case WR_RESETPLAYER:
 454                 {
 455                         self.electro_secondarytime = time;
 456                         return TRUE;
 457                 }
 458                 case WR_RELOAD:
 459                 {
 460                         W_Reload(min(WEP_CVAR_PRI(electro, ammo), WEP_CVAR_SEC(electro, ammo)), "weapons/reload.wav");
 461                         return TRUE;
 462                 }
 463                 case WR_SUICIDEMESSAGE:
 464                 {
 465                         if(w_deathtype & HITTYPE_SECONDARY)
 466                                 return WEAPON_ELECTRO_SUICIDE_ORBS;
 467                         else
 468                                 return WEAPON_ELECTRO_SUICIDE_BOLT;
 469                 }
 470                 case WR_KILLMESSAGE:
 471                 {
 472                         if(w_deathtype & HITTYPE_SECONDARY)
 473                         {
 474                                 return WEAPON_ELECTRO_MURDER_ORBS;
 475                         }
 476                         else
 477                         {
 478                                 if(w_deathtype & HITTYPE_BOUNCE)
 479                                         return WEAPON_ELECTRO_MURDER_COMBO;
 480                                 else
 481                                         return WEAPON_ELECTRO_MURDER_BOLT;
 482                         }
 483                 }
 484         }
 485         return TRUE;
 486 }
 487 #endif
 488 #ifdef CSQC
 489 float W_Electro(float req)
 490 {
 491         switch(req)
 492         {
 493                 case WR_IMPACTEFFECT:
 494                 {
 495                         vector org2;
 496                         org2 = w_org + w_backoff * 6;
 497                         if(w_deathtype & HITTYPE_SECONDARY)
 498                         {
 499                                 pointparticles(particleeffectnum("electro_ballexplode"), org2, '0 0 0', 1);
 500                                 if(!w_issilent)
 501                                         sound(self, CH_SHOTS, "weapons/electro_impact.wav", VOL_BASE, ATTEN_NORM);
 502                         }
 503                         else
 504                         {
 505                                 if(w_deathtype & HITTYPE_BOUNCE)
 506                                 {
 507                                         // this is sent as "primary (w_deathtype & HITTYPE_BOUNCE)" to distinguish it from (w_deathtype & HITTYPE_SECONDARY) bounced balls
 508                                         pointparticles(particleeffectnum("electro_combo"), org2, '0 0 0', 1);
 509                                         if(!w_issilent)
 510                                                 sound(self, CH_SHOTS, "weapons/electro_impact_combo.wav", VOL_BASE, ATTEN_NORM);
 511                                 }
 512                                 else
 513                                 {
 514                                         pointparticles(particleeffectnum("electro_impact"), org2, '0 0 0', 1);
 515                                         if(!w_issilent)
 516                                                 sound(self, CH_SHOTS, "weapons/electro_impact.wav", VOL_BASE, ATTEN_NORM);
 517                                 }
 518                         }
 519
 520                         return TRUE;
 521                 }
 522                 case WR_INIT:
 523                 {
 524                         precache_sound("weapons/electro_impact.wav");
 525                         precache_sound("weapons/electro_impact_combo.wav");
 526                         return TRUE;
 527                 }
 528         }
 529         return TRUE;
 530 }
 531 #endif
 532 #endif