qcsrc/common/weapons/w_hook.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ HOOK,
   4 /* function */ w_hook,
   5 /* ammotype */ ammo_fuel,
   6 /* impulse  */ 0,
   7 /* flags    */ WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating   */ 0,
   9 /* model    */ "hookgun",
  10 /* netname  */ "hook",
  11 /* fullname */ _("Grappling Hook")
  12 );
  13
  14 #define HOOK_SETTINGS(w_cvar,w_prop) HOOK_SETTINGS_LIST(w_cvar, w_prop, HOOK, hook)
  15 #define HOOK_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  16         w_cvar(id, sn, BOTH, animtime) \
  17         w_cvar(id, sn, BOTH, ammo) \
  18         w_cvar(id, sn, BOTH, refire) \
  19         w_cvar(id, sn, PRI,  hooked_ammo) \
  20         w_cvar(id, sn, PRI,  hooked_time_free) \
  21         w_cvar(id, sn, PRI,  hooked_time_max) \
  22         w_cvar(id, sn, SEC,  damage) \
  23         w_cvar(id, sn, SEC,  duration) \
  24         w_cvar(id, sn, SEC,  edgedamage) \
  25         w_cvar(id, sn, SEC,  force) \
  26         w_cvar(id, sn, SEC,  gravity) \
  27         w_cvar(id, sn, SEC,  lifetime) \
  28         w_cvar(id, sn, SEC,  power) \
  29         w_cvar(id, sn, SEC,  radius) \
  30         w_cvar(id, sn, SEC,  speed) \
  31         w_cvar(id, sn, SEC,  health) \
  32         w_cvar(id, sn, SEC,  damageforcescale) \
  33         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  34         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  35         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  36         w_prop(id, sn, float,  weaponstart, weaponstart) \
  37         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  38
  39 #ifdef SVQC
  40 HOOK_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  41
  42 .float dmg;
  43 .float dmg_edge;
  44 .float dmg_radius;
  45 .float dmg_force;
  46 .float dmg_power;
  47 .float dmg_duration;
  48 .float dmg_last;
  49 .float hook_refire;
  50 .float hook_time_hooked;
  51 .float hook_time_fueldecrease;
  52 #endif
  53 #else
  54 #ifdef SVQC
  55
  56 void spawnfunc_weapon_hook()
  57 {
  58         if(g_grappling_hook) // offhand hook
  59         {
  60                 startitem_failed = TRUE;
  61                 remove(self);
  62                 return;
  63         }
  64         weapon_defaultspawnfunc(WEP_HOOK);
  65 }
  66
  67 void W_Hook_ExplodeThink (void)
  68 {
  69         float dt, dmg_remaining_next, f;
  70
  71         dt = time - self.teleport_time;
  72         dmg_remaining_next = pow(bound(0, 1 - dt / self.dmg_duration, 1), self.dmg_power);
  73
  74         f = self.dmg_last - dmg_remaining_next;
  75         self.dmg_last = dmg_remaining_next;
  76
  77         RadiusDamage (self, self.realowner, self.dmg * f, self.dmg_edge * f, self.dmg_radius, self.realowner, world, self.dmg_force * f, self.projectiledeathtype, world);
  78         self.projectiledeathtype |= HITTYPE_BOUNCE;
  79         //RadiusDamage (self, world, self.dmg * f, self.dmg_edge * f, self.dmg_radius, world, world, self.dmg_force * f, self.projectiledeathtype, world);
  80
  81         if(dt < self.dmg_duration)
  82                 self.nextthink = time + 0.05; // soon
  83         else
  84                 remove(self);
  85 }
  86
  87 void W_Hook_Explode2 (void)
  88 {
  89         self.event_damage = func_null;
  90         self.touch = func_null;
  91         self.effects |= EF_NODRAW;
  92
  93         self.think = W_Hook_ExplodeThink;
  94         self.nextthink = time;
  95         self.dmg = WEP_CVAR_SEC(hook, damage);
  96         self.dmg_edge = WEP_CVAR_SEC(hook, edgedamage);
  97         self.dmg_radius = WEP_CVAR_SEC(hook, radius);
  98         self.dmg_force = WEP_CVAR_SEC(hook, force);
  99         self.dmg_power = WEP_CVAR_SEC(hook, power);
 100         self.dmg_duration = WEP_CVAR_SEC(hook, duration);
 101         self.teleport_time = time;
 102         self.dmg_last = 1;
 103         self.movetype = MOVETYPE_NONE;
 104 }
 105
 106 void W_Hook_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 107 {
 108         if (self.health <= 0)
 109                 return;
 110
 111         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 112                 return; // g_projectiles_damage says to halt
 113
 114         self.health = self.health - damage;
 115
 116         if (self.health <= 0)
 117                 W_PrepareExplosionByDamage(self.realowner, W_Hook_Explode2);
 118 }
 119
 120 void W_Hook_Touch2 (void)
 121 {
 122         PROJECTILE_TOUCH;
 123         self.use();
 124 }
 125
 126 void W_Hook_Attack2()
 127 {
 128         entity gren;
 129
 130         W_DecreaseAmmo(WEP_CVAR_SEC(hook, ammo));
 131         W_SetupShot (self, FALSE, 4, "weapons/hookbomb_fire.wav", CH_WEAPON_A, WEP_CVAR_SEC(hook, damage));
 132
 133         gren = spawn ();
 134         gren.owner = gren.realowner = self;
 135         gren.classname = "hookbomb";
 136         gren.bot_dodge = TRUE;
 137         gren.bot_dodgerating = WEP_CVAR_SEC(hook, damage);
 138         gren.movetype = MOVETYPE_TOSS;
 139         PROJECTILE_MAKETRIGGER(gren);
 140         gren.projectiledeathtype = WEP_HOOK | HITTYPE_SECONDARY;
 141         setorigin(gren, w_shotorg);
 142         setsize(gren, '0 0 0', '0 0 0');
 143
 144         gren.nextthink = time + WEP_CVAR_SEC(hook, lifetime);
 145         gren.think = adaptor_think2use_hittype_splash;
 146         gren.use = W_Hook_Explode2;
 147         gren.touch = W_Hook_Touch2;
 148
 149         gren.takedamage = DAMAGE_YES;
 150         gren.health = WEP_CVAR_SEC(hook, health);
 151         gren.damageforcescale = WEP_CVAR_SEC(hook, damageforcescale);
 152         gren.event_damage = W_Hook_Damage;
 153         gren.damagedbycontents = TRUE;
 154         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 155
 156         gren.velocity = '0 0 1' * WEP_CVAR_SEC(hook, speed);
 157         if(autocvar_g_projectiles_newton_style)
 158                 gren.velocity = gren.velocity + self.velocity;
 159
 160         gren.gravity = WEP_CVAR_SEC(hook, gravity);
 161         //W_SetupProjectileVelocity(gren); // just falling down!
 162
 163         gren.angles = '0 0 0';
 164         gren.flags = FL_PROJECTILE;
 165
 166         CSQCProjectile(gren, TRUE, PROJECTILE_HOOKBOMB, TRUE);
 167
 168         other = gren; MUTATOR_CALLHOOK(EditProjectile);
 169 }
 170
 171 float w_hook(float req)
 172 {
 173         float hooked_time_max, hooked_fuel;
 174
 175         switch(req)
 176         {
 177                 case WR_AIM:
 178                 {
 179                         // no bot AI for hook (yet?)
 180                         return TRUE;
 181                 }
 182                 case WR_THINK:
 183                 {
 184                         if (self.BUTTON_ATCK || (!(self.items & IT_JETPACK) && self.BUTTON_HOOK))
 185                         {
 186                                 if(!self.hook)
 187                                 if(!(self.hook_state & HOOK_WAITING_FOR_RELEASE))
 188                                 if(!(self.hook_state & HOOK_FIRING))
 189                                 if (time > self.hook_refire)
 190                                 if (weapon_prepareattack(0, -1))
 191                                 {
 192                                         W_DecreaseAmmo(WEP_CVAR_PRI(hook, ammo));
 193                                         self.hook_state |= HOOK_FIRING;
 194                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(hook, animtime), w_ready);
 195                                 }
 196                         }
 197
 198                         if (self.BUTTON_ATCK2)
 199                         {
 200                                 if (weapon_prepareattack(1, WEP_CVAR_SEC(hook, refire)))
 201                                 {
 202                                         W_Hook_Attack2();
 203                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(hook, animtime), w_ready);
 204                                 }
 205                         }
 206
 207                         if(self.hook)
 208                         {
 209                                 // if hooked, no bombs, and increase the timer
 210                                 self.hook_refire = max(self.hook_refire, time + WEP_CVAR_PRI(hook, refire) * W_WeaponRateFactor());
 211
 212                                 // hook also inhibits health regeneration, but only for 1 second
 213                                 if(!(self.items & IT_UNLIMITED_WEAPON_AMMO))
 214                                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_fuel_regen);
 215                         }
 216
 217                         if(self.hook && self.hook.state == 1)
 218                         {
 219                                 hooked_time_max = WEP_CVAR_PRI(hook, hooked_time_max);
 220                                 if (hooked_time_max > 0)
 221                                 {
 222                                         if ( time > self.hook_time_hooked + hooked_time_max )
 223                                                 self.hook_state |= HOOK_REMOVING;
 224                                 }
 225
 226                                 hooked_fuel = WEP_CVAR_PRI(hook, hooked_ammo);
 227                                 if (hooked_fuel > 0)
 228                                 {
 229                                         if ( time > self.hook_time_fueldecrease )
 230                                         {
 231                                                 if(!(self.items & IT_UNLIMITED_WEAPON_AMMO))
 232                                                 {
 233                                                         if ( self.ammo_fuel >= (time - self.hook_time_fueldecrease) * hooked_fuel )
 234                                                         {
 235                                                                 W_DecreaseAmmo((time - self.hook_time_fueldecrease) * hooked_fuel);
 236                                                                 self.hook_time_fueldecrease = time;
 237                                                                 // decrease next frame again
 238                                                         }
 239                                                         else
 240                                                         {
 241                                                                 self.ammo_fuel = 0;
 242                                                                 self.hook_state |= HOOK_REMOVING;
 243                                                                 W_SwitchWeapon_Force(self, w_getbestweapon(self));
 244                                                         }
 245                                                 }
 246                                         }
 247                                 }
 248                         }
 249                         else
 250                         {
 251                                 self.hook_time_hooked = time;
 252                                 self.hook_time_fueldecrease = time + WEP_CVAR_PRI(hook, hooked_time_free);
 253                         }
 254
 255                         if (self.BUTTON_CROUCH)
 256                         {
 257                                 self.hook_state &= ~HOOK_PULLING;
 258                                 if (self.BUTTON_ATCK || (!(self.items & IT_JETPACK) && self.BUTTON_HOOK))
 259                                         self.hook_state &= ~HOOK_RELEASING;
 260                                 else
 261                                         self.hook_state |= HOOK_RELEASING;
 262                         }
 263                         else
 264                         {
 265                                 self.hook_state |= HOOK_PULLING;
 266                                 self.hook_state &= ~HOOK_RELEASING;
 267
 268                                 if (self.BUTTON_ATCK || (!(self.items & IT_JETPACK) && self.BUTTON_HOOK))
 269                                 {
 270                                         // already fired
 271                                         if(self.hook)
 272                                                 self.hook_state |= HOOK_WAITING_FOR_RELEASE;
 273                                 }
 274                                 else
 275                                 {
 276                                         self.hook_state |= HOOK_REMOVING;
 277                                         self.hook_state &= ~HOOK_WAITING_FOR_RELEASE;
 278                                 }
 279                         }
 280
 281                         return TRUE;
 282                 }
 283                 case WR_INIT:
 284                 {
 285                         precache_model ("models/weapons/g_hookgun.md3");
 286                         precache_model ("models/weapons/v_hookgun.md3");
 287                         precache_model ("models/weapons/h_hookgun.iqm");
 288                         precache_sound ("weapons/hook_impact.wav"); // done by g_hook.qc
 289                         precache_sound ("weapons/hook_fire.wav");
 290                         precache_sound ("weapons/hookbomb_fire.wav");
 291                         HOOK_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 292                         return TRUE;
 293                 }
 294                 case WR_SETUP:
 295                 {
 296                         self.current_ammo = ammo_fuel;
 297                         self.hook_state &= ~HOOK_WAITING_FOR_RELEASE;
 298                         return TRUE;
 299                 }
 300                 case WR_CHECKAMMO1:
 301                 {
 302                         if(self.hook)
 303                                 return self.ammo_fuel > 0;
 304                         else
 305                                 return self.ammo_fuel >= WEP_CVAR_PRI(hook, ammo);
 306                 }
 307                 case WR_CHECKAMMO2:
 308                 {
 309                         return self.ammo_cells >= WEP_CVAR_SEC(hook, ammo);
 310                 }
 311                 case WR_CONFIG:
 312                 {
 313                         HOOK_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 314                         return TRUE;
 315                 }
 316                 case WR_RESETPLAYER:
 317                 {
 318                         self.hook_refire = time;
 319                         return TRUE;
 320                 }
 321                 case WR_SUICIDEMESSAGE:
 322                 {
 323                         return FALSE;
 324                 }
 325                 case WR_KILLMESSAGE:
 326                 {
 327                         return WEAPON_HOOK_MURDER;
 328                 }
 329         }
 330         return TRUE;
 331 }
 332 #endif
 333 #ifdef CSQC
 334 float w_hook(float req)
 335 {
 336         switch(req)
 337         {
 338                 case WR_IMPACTEFFECT:
 339                 {
 340                         vector org2;
 341                         org2 = w_org + w_backoff * 2;
 342                         pointparticles(particleeffectnum("hookbomb_explode"), org2, '0 0 0', 1);
 343                         if(!w_issilent)
 344                                 sound(self, CH_SHOTS, "weapons/hookbomb_impact.wav", VOL_BASE, ATTN_NORM);
 345
 346                         return TRUE;
 347                 }
 348                 case WR_INIT:
 349                 {
 350                         precache_sound("weapons/hookbomb_impact.wav");
 351                         return TRUE;
 352                 }
 353         }
 354         return TRUE;
 355 }
 356 #endif
 357 #endif