qcsrc/common/weapons/w_machinegun.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ UZI,
   4 /* function */ w_uzi,
   5 /* ammotype */ IT_NAILS,
   6 /* impulse  */ 3,
   7 /* flags    */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN,
   8 /* rating   */ BOT_PICKUP_RATING_MID,
   9 /* model    */ "uzi",
  10 /* netname  */ "uzi",
  11 /* fullname */ _("Machine Gun")
  12 );
  13
  14 #define UZI_SETTINGS(weapon) \
  15         WEP_ADD_CVAR(weapon, MO_NONE, speed) \
  16         WEP_ADD_CVAR(weapon, MO_NONE, spread_min) \
  17         WEP_ADD_CVAR(weapon, MO_NONE, spread_max) \
  18         WEP_ADD_CVAR(weapon, MO_NONE, spread_add) \
  19         WEP_ADD_CVAR(weapon, MO_NONE, mode) \
  20         WEP_ADD_CVAR(weapon, MO_NONE, bulletconstant) \
  21         WEP_ADD_CVAR(weapon, MO_NONE, first) \
  22         WEP_ADD_CVAR(weapon, MO_NONE, first_damage) \
  23         WEP_ADD_CVAR(weapon, MO_NONE, first_force) \
  24         WEP_ADD_CVAR(weapon, MO_NONE, first_refire) \
  25         WEP_ADD_CVAR(weapon, MO_NONE, first_spread) \
  26         WEP_ADD_CVAR(weapon, MO_NONE, first_ammo) \
  27         WEP_ADD_CVAR(weapon, MO_NONE, sustained_damage) \
  28         WEP_ADD_CVAR(weapon, MO_NONE, sustained_force) \
  29         WEP_ADD_CVAR(weapon, MO_NONE, sustained_refire) \
  30         WEP_ADD_CVAR(weapon, MO_NONE, sustained_spread) \
  31         WEP_ADD_CVAR(weapon, MO_NONE, sustained_ammo) \
  32         WEP_ADD_CVAR(weapon, MO_NONE, burst) \
  33         WEP_ADD_CVAR(weapon, MO_NONE, burst_refire) \
  34         WEP_ADD_CVAR(weapon, MO_NONE, burst_refire2) \
  35         WEP_ADD_CVAR(weapon, MO_NONE, burst_animtime) \
  36         WEP_ADD_CVAR(weapon, MO_NONE, burst_speed) \
  37         WEP_ADD_CVAR(weapon, MO_NONE, burst_ammo) \
  38         WEP_ADD_PROP(weapon, reloading_ammo, reload_ammo) \
  39         WEP_ADD_PROP(weapon, reloading_time, reload_time) \
  40         WEP_ADD_PROP(weapon, switchdelay_raise, switchdelay_raise) \
  41         WEP_ADD_PROP(weapon, switchdelay_drop, switchdelay_drop)
  42
  43 #ifdef SVQC
  44 UZI_SETTINGS(uzi)
  45 #endif
  46 #else
  47 #ifdef SVQC
  48
  49 void spawnfunc_weapon_uzi()
  50 {
  51         if(autocvar_sv_q3acompat_machineshotgunswap)
  52         if(self.classname != "droppedweapon")
  53         {
  54                 weapon_defaultspawnfunc(WEP_SHOTGUN);
  55                 return;
  56         }
  57         weapon_defaultspawnfunc(WEP_UZI);
  58 }
  59
  60 // leilei's fancy muzzleflash stuff
  61 void UZI_Flash_Go()
  62 {
  63         self.frame = self.frame + 2;
  64         self.scale = self.scale * 0.5;
  65         self.alpha = self.alpha - 0.25;
  66         self.nextthink = time + 0.05;
  67
  68         if (self.alpha <= 0)
  69         {
  70                 self.think = SUB_Remove;
  71                 self.nextthink = time;
  72                 self.realowner.muzzle_flash = world;
  73                 return;
  74         }
  75
  76 }
  77
  78 void UziFlash()
  79 {
  80         if (self.muzzle_flash == world)
  81                 self.muzzle_flash = spawn();
  82
  83         // muzzle flash for 1st person view
  84         setmodel(self.muzzle_flash, "models/uziflash.md3"); // precision set below
  85
  86         self.muzzle_flash.scale = 0.75;
  87         self.muzzle_flash.think = UZI_Flash_Go;
  88         self.muzzle_flash.nextthink = time + 0.02;
  89         self.muzzle_flash.frame = 2;
  90         self.muzzle_flash.alpha = 0.75;
  91         self.muzzle_flash.angles_z = random() * 180;
  92         self.muzzle_flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  93         self.muzzle_flash.owner = self.muzzle_flash.realowner = self;
  94 }
  95
  96 void W_UZI_Attack (float deathtype)
  97 {
  98         W_SetupShot (self, autocvar_g_antilag_bullets && WEP_CVAR(uzi, speed) >= autocvar_g_antilag_bullets, 0, "weapons/uzi_fire.wav", CH_WEAPON_A, ((self.misc_bulletcounter == 1) ? WEP_CVAR(uzi, first_damage) : WEP_CVAR(uzi, sustained_damage)));
  99         if (!g_norecoil)
 100         {
 101                 self.punchangle_x = random () - 0.5;
 102                 self.punchangle_y = random () - 0.5;
 103         }
 104
 105         // this attack_finished just enforces a cooldown at the end of a burst
 106         ATTACK_FINISHED(self) = time + WEP_CVAR(uzi, first_refire) * W_WeaponRateFactor();
 107
 108         if (self.misc_bulletcounter == 1)
 109                 fireBallisticBullet(w_shotorg, w_shotdir, WEP_CVAR(uzi, first_spread), WEP_CVAR(uzi, speed), 5, WEP_CVAR(uzi, first_damage), WEP_CVAR(uzi, first_force), deathtype, 0, 1, WEP_CVAR(uzi, bulletconstant));
 110         else
 111                 fireBallisticBullet(w_shotorg, w_shotdir, WEP_CVAR(uzi, sustained_spread), WEP_CVAR(uzi, speed), 5, WEP_CVAR(uzi, sustained_damage), WEP_CVAR(uzi, sustained_force), deathtype, 0, 1, WEP_CVAR(uzi, bulletconstant));
 112         endFireBallisticBullet();
 113
 114         pointparticles(particleeffectnum("uzi_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 115
 116         UziFlash();
 117         W_AttachToShotorg(self.muzzle_flash, '5 0 0');
 118
 119         // casing code
 120         if (autocvar_g_casings >= 2)
 121                 SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, self);
 122
 123         if (self.misc_bulletcounter == 1)
 124                 W_DecreaseAmmo(ammo_nails, WEP_CVAR(uzi, first_ammo), autocvar_g_balance_uzi_reload_ammo);
 125         else
 126                 W_DecreaseAmmo(ammo_nails, WEP_CVAR(uzi, sustained_ammo), autocvar_g_balance_uzi_reload_ammo);
 127 }
 128
 129 // weapon frames
 130 void uzi_fire1_02()
 131 {
 132         if(self.weapon != self.switchweapon) // abort immediately if switching
 133         {
 134                 w_ready();
 135                 return;
 136         }
 137         if (self.BUTTON_ATCK)
 138         {
 139                 if (!WEP_ACTION(self.weapon, WR_CHECKAMMO2))
 140                 if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 141                 {
 142                         W_SwitchWeapon_Force(self, w_getbestweapon(self));
 143                         w_ready();
 144                         return;
 145                 }
 146                 self.misc_bulletcounter = self.misc_bulletcounter + 1;
 147                 W_UZI_Attack(WEP_UZI);
 148                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(uzi, sustained_refire), uzi_fire1_02);
 149         }
 150         else
 151                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(uzi, sustained_refire), w_ready);
 152 }
 153
 154
 155 void uzi_mode1_fire_auto()
 156 {
 157         float uzi_spread;
 158
 159         if (!self.BUTTON_ATCK)
 160         {
 161                 w_ready();
 162                 return;
 163         }
 164
 165         if (!WEP_ACTION(self.weapon, WR_CHECKAMMO1))
 166         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 167         {
 168                 W_SwitchWeapon_Force(self, w_getbestweapon(self));
 169                 w_ready();
 170                 return;
 171         }
 172
 173         W_DecreaseAmmo(ammo_nails, WEP_CVAR(uzi, sustained_ammo), autocvar_g_balance_uzi_reload_ammo);
 174
 175         W_SetupShot (self, autocvar_g_antilag_bullets && WEP_CVAR(uzi, speed) >= autocvar_g_antilag_bullets, 0, "weapons/uzi_fire.wav", CH_WEAPON_A, WEP_CVAR(uzi, sustained_damage));
 176         if (!g_norecoil)
 177         {
 178                 self.punchangle_x = random () - 0.5;
 179                 self.punchangle_y = random () - 0.5;
 180         }
 181
 182         uzi_spread = bound(WEP_CVAR(uzi, spread_min), WEP_CVAR(uzi, spread_min) + (WEP_CVAR(uzi, spread_add) * self.misc_bulletcounter), WEP_CVAR(uzi, spread_max));
 183         fireBallisticBullet(w_shotorg, w_shotdir, uzi_spread, WEP_CVAR(uzi, speed), 5, WEP_CVAR(uzi, sustained_damage), WEP_CVAR(uzi, sustained_force), WEP_UZI, 0, 1, WEP_CVAR(uzi, bulletconstant));
 184         endFireBallisticBullet();
 185
 186         self.misc_bulletcounter = self.misc_bulletcounter + 1;
 187
 188         pointparticles(particleeffectnum("uzi_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 189
 190         UziFlash();
 191         W_AttachToShotorg(self.muzzle_flash, '5 0 0');
 192
 193         if (autocvar_g_casings >= 2) // casing code
 194                 SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, self);
 195
 196         ATTACK_FINISHED(self) = time + WEP_CVAR(uzi, first_refire) * W_WeaponRateFactor();
 197         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(uzi, sustained_refire), uzi_mode1_fire_auto);
 198 }
 199
 200 void uzi_mode1_fire_burst()
 201 {
 202         W_SetupShot (self, autocvar_g_antilag_bullets && WEP_CVAR(uzi, speed) >= autocvar_g_antilag_bullets, 0, "weapons/uzi_fire.wav", CH_WEAPON_A, WEP_CVAR(uzi, sustained_damage));
 203         if (!g_norecoil)
 204         {
 205                 self.punchangle_x = random () - 0.5;
 206                 self.punchangle_y = random () - 0.5;
 207         }
 208
 209         fireBallisticBullet(w_shotorg, w_shotdir, WEP_CVAR(uzi, burst_speed), WEP_CVAR(uzi, speed), 5, WEP_CVAR(uzi, sustained_damage), WEP_CVAR(uzi, sustained_force), WEP_UZI, 0, 1, WEP_CVAR(uzi, bulletconstant));
 210         endFireBallisticBullet();
 211
 212
 213         pointparticles(particleeffectnum("uzi_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 214
 215         UziFlash();
 216         W_AttachToShotorg(self.muzzle_flash, '5 0 0');
 217
 218         if (autocvar_g_casings >= 2) // casing code
 219                 SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, self);
 220
 221         self.misc_bulletcounter = self.misc_bulletcounter + 1;
 222         if (self.misc_bulletcounter == 0)
 223         {
 224                 ATTACK_FINISHED(self) = time + WEP_CVAR(uzi, burst_refire2) * W_WeaponRateFactor();
 225                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(uzi, burst_animtime), w_ready);
 226         }
 227         else
 228         {
 229                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(uzi, burst_refire), uzi_mode1_fire_burst);
 230         }
 231
 232 }
 233
 234 float w_uzi(float req)
 235 {
 236         float ammo_amount;
 237         switch(req)
 238         {
 239                 case WR_AIM:
 240                 {
 241                         if(vlen(self.origin-self.enemy.origin) < 3000 - bound(0, skill, 10) * 200)
 242                                 self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 243                         else
 244                                 self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 245
 246                         return TRUE;
 247                 }
 248                 case WR_THINK:
 249                 {
 250                         if(autocvar_g_balance_uzi_reload_ammo && self.clip_load < min(max(WEP_CVAR(uzi, sustained_ammo), WEP_CVAR(uzi, first_ammo)), WEP_CVAR(uzi, burst_ammo))) // forced reload
 251                                 WEP_ACTION(self.weapon, WR_RELOAD);
 252                         else if(WEP_CVAR(uzi, mode) == 1)
 253                         {
 254                                 if (self.BUTTON_ATCK)
 255                                 if (weapon_prepareattack(0, 0))
 256                                 {
 257                                         self.misc_bulletcounter = 0;
 258                                         uzi_mode1_fire_auto();
 259                                 }
 260
 261                                 if(self.BUTTON_ATCK2)
 262                                 if(weapon_prepareattack(1, 0))
 263                                 {
 264                                         if (!WEP_ACTION(self.weapon, WR_CHECKAMMO2))
 265                                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 266                                         {
 267                                                 W_SwitchWeapon_Force(self, w_getbestweapon(self));
 268                                                 w_ready();
 269                                                 return FALSE;
 270                                         }
 271
 272                                         W_DecreaseAmmo(ammo_nails, WEP_CVAR(uzi, burst_ammo), autocvar_g_balance_uzi_reload_ammo);
 273
 274                                         self.misc_bulletcounter = WEP_CVAR(uzi, burst) * -1;
 275                                         uzi_mode1_fire_burst();
 276                                 }
 277                         }
 278                         else
 279                         {
 280
 281                                 if (self.BUTTON_ATCK)
 282                                 if (weapon_prepareattack(0, 0))
 283                                 {
 284                                         self.misc_bulletcounter = 1;
 285                                         W_UZI_Attack(WEP_UZI); // sets attack_finished
 286                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(uzi, sustained_refire), uzi_fire1_02);
 287                                 }
 288
 289                                 if (self.BUTTON_ATCK2 && WEP_CVAR(uzi, first))
 290                                 if (weapon_prepareattack(1, 0))
 291                                 {
 292                                         self.misc_bulletcounter = 1;
 293                                         W_UZI_Attack(WEP_UZI | HITTYPE_SECONDARY); // sets attack_finished
 294                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(uzi, first_refire), w_ready);
 295                                 }
 296                         }
 297
 298                         return TRUE;
 299                 }
 300                 case WR_INIT:
 301                 {
 302                         precache_model ("models/uziflash.md3");
 303                         precache_model ("models/weapons/g_uzi.md3");
 304                         precache_model ("models/weapons/v_uzi.md3");
 305                         precache_model ("models/weapons/h_uzi.iqm");
 306                         precache_sound ("weapons/uzi_fire.wav");
 307                         WEP_SET_PROPS(UZI_SETTINGS(uzi), WEP_UZI)
 308                         return TRUE;
 309                 }
 310                 case WR_SETUP:
 311                 {
 312                         self.current_ammo = ammo_nails;
 313                         return TRUE;
 314                 }
 315                 case WR_CHECKAMMO1:
 316                 {
 317                         if(WEP_CVAR(uzi, mode) == 1)
 318                                 ammo_amount = self.ammo_nails >= WEP_CVAR(uzi, sustained_ammo);
 319                         else
 320                                 ammo_amount = self.ammo_nails >= WEP_CVAR(uzi, first_ammo);
 321
 322                         if(autocvar_g_balance_uzi_reload_ammo)
 323                         {
 324                                 if(WEP_CVAR(uzi, mode) == 1)
 325                                         ammo_amount += self.(weapon_load[WEP_UZI]) >= WEP_CVAR(uzi, sustained_ammo);
 326                                 else
 327                                         ammo_amount += self.(weapon_load[WEP_UZI]) >= WEP_CVAR(uzi, first_ammo);
 328                         }
 329                         return ammo_amount;
 330                 }
 331                 case WR_CHECKAMMO2:
 332                 {
 333                         if(WEP_CVAR(uzi, mode) == 1)
 334                                 ammo_amount = self.ammo_nails >= WEP_CVAR(uzi, burst_ammo);
 335                         else
 336                                 ammo_amount = self.ammo_nails >= WEP_CVAR(uzi, first_ammo);
 337
 338                         if(autocvar_g_balance_uzi_reload_ammo)
 339                         {
 340                                 if(WEP_CVAR(uzi, mode) == 1)
 341                                         ammo_amount += self.(weapon_load[WEP_UZI]) >= WEP_CVAR(uzi, burst_ammo);
 342                                 else
 343                                         ammo_amount += self.(weapon_load[WEP_UZI]) >= WEP_CVAR(uzi, first_ammo);
 344                         }
 345                         return ammo_amount;
 346                 }
 347                 case WR_CONFIG:
 348                 {
 349                         WEP_CONFIG_SETTINGS(UZI_SETTINGS(uzi))
 350                         return TRUE;
 351                 }
 352                 case WR_RELOAD:
 353                 {
 354                         W_Reload(min(max(WEP_CVAR(uzi, sustained_ammo), WEP_CVAR(uzi, first_ammo)), WEP_CVAR(uzi, burst_ammo)), autocvar_g_balance_uzi_reload_ammo, autocvar_g_balance_uzi_reload_time, "weapons/reload.wav");
 355                         return TRUE;
 356                 }
 357                 case WR_SUICIDEMESSAGE:
 358                 {
 359                         return WEAPON_THINKING_WITH_PORTALS;
 360                 }
 361                 case WR_KILLMESSAGE:
 362                 {
 363                         if(w_deathtype & HITTYPE_SECONDARY)
 364                                 return WEAPON_UZI_MURDER_SNIPE;
 365                         else
 366                                 return WEAPON_UZI_MURDER_SPRAY;
 367                 }
 368         }
 369         return TRUE;
 370 }
 371 #endif
 372 #ifdef CSQC
 373 float w_uzi(float req)
 374 {
 375         switch(req)
 376         {
 377                 case WR_IMPACTEFFECT:
 378                 {
 379                         vector org2;
 380                         org2 = w_org + w_backoff * 2;
 381                         pointparticles(particleeffectnum("machinegun_impact"), org2, w_backoff * 1000, 1);
 382                         if(!w_issilent)
 383                                 if(w_random < 0.05)
 384                                         sound(self, CH_SHOTS, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 385                                 else if(w_random < 0.1)
 386                                         sound(self, CH_SHOTS, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 387                                 else if(w_random < 0.2)
 388                                         sound(self, CH_SHOTS, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 389
 390                         return TRUE;
 391                 }
 392                 case WR_INIT:
 393                 {
 394                         precache_sound("weapons/ric1.wav");
 395                         precache_sound("weapons/ric2.wav");
 396                         precache_sound("weapons/ric3.wav");
 397                         return TRUE;
 398                 }
 399         }
 400         return TRUE;
 401 }
 402 #endif
 403 #endif