qcsrc/common/weapons/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ MINE_LAYER,
   4 /* function */ w_minelayer,
   5 /* ammotype */ IT_ROCKETS,
   6 /* impulse  */ 4,
   7 /* flags    */ WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH,
   8 /* rating   */ BOT_PICKUP_RATING_HIGH,
   9 /* model    */ "minelayer",
  10 /* netname  */ "minelayer",
  11 /* fullname */ _("Mine Layer")
  12 );
  13 #define MINELAYER_SETTINGS(w_cvar,w_prop) MINELAYER_SETTINGS_LIST(w_cvar, w_prop, WEP_MINE_LAYER, minelayer)
  14 #define MINELAYER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  15         w_cvar(id, sn, MO_NONE, ammo) \
  16         w_cvar(id, sn, MO_NONE, animtime) \
  17         w_cvar(id, sn, MO_NONE, damage) \
  18         w_cvar(id, sn, MO_NONE, damageforcescale) \
  19         w_cvar(id, sn, MO_NONE, detonatedelay) \
  20         w_cvar(id, sn, MO_NONE, edgedamage) \
  21         w_cvar(id, sn, MO_NONE, force) \
  22         w_cvar(id, sn, MO_NONE, health) \
  23         w_cvar(id, sn, MO_NONE, lifetime) \
  24         w_cvar(id, sn, MO_NONE, lifetime_countdown) \
  25         w_cvar(id, sn, MO_NONE, limit) \
  26         w_cvar(id, sn, MO_NONE, protection) \
  27         w_cvar(id, sn, MO_NONE, proximityradius) \
  28         w_cvar(id, sn, MO_NONE, radius) \
  29         w_cvar(id, sn, MO_NONE, refire) \
  30         w_cvar(id, sn, MO_NONE, remote_damage) \
  31         w_cvar(id, sn, MO_NONE, remote_edgedamage) \
  32         w_cvar(id, sn, MO_NONE, remote_force) \
  33         w_cvar(id, sn, MO_NONE, remote_radius) \
  34         w_cvar(id, sn, MO_NONE, speed) \
  35         w_cvar(id, sn, MO_NONE, time) \
  36         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  37         w_prop(id, sn, float,  reloading_time, reload_time) \
  38         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  39         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  40         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  41         w_prop(id, sn, float,  weaponstart, weaponstart) \
  42         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  43
  44 #ifdef SVQC
  45 MINELAYER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  46 void W_Mine_Think (void);
  47 .float minelayer_detonate, mine_explodeanyway;
  48 .float mine_time;
  49 .vector mine_orientation;
  50 #endif
  51 #else
  52 #ifdef SVQC
  53 void spawnfunc_weapon_minelayer() { weapon_defaultspawnfunc(WEP_MINE_LAYER); }
  54
  55 void W_Mine_Stick (entity to)
  56 {
  57         spamsound (self, CH_SHOTS, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
  58
  59         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  60
  61         entity newmine;
  62         newmine = spawn();
  63         newmine.classname = self.classname;
  64
  65         newmine.bot_dodge = self.bot_dodge;
  66         newmine.bot_dodgerating = self.bot_dodgerating;
  67
  68         newmine.owner = self.owner;
  69         newmine.realowner = self.realowner;
  70         setsize(newmine, '-4 -4 -4', '4 4 4');
  71         setorigin(newmine, self.origin);
  72         setmodel(newmine, "models/mine.md3");
  73         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  74
  75         newmine.mine_orientation = -trace_plane_normal;
  76
  77         newmine.takedamage = self.takedamage;
  78         newmine.damageforcescale = self.damageforcescale;
  79         newmine.health = self.health;
  80         newmine.event_damage = self.event_damage;
  81         newmine.spawnshieldtime = self.spawnshieldtime;
  82         newmine.damagedbycontents = TRUE;
  83
  84         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  85         newmine.projectiledeathtype = self.projectiledeathtype;
  86
  87         newmine.mine_time = self.mine_time;
  88
  89         newmine.touch = func_null;
  90         newmine.think = W_Mine_Think;
  91         newmine.nextthink = time;
  92         newmine.cnt = self.cnt;
  93         newmine.flags = self.flags;
  94
  95         remove(self);
  96         self = newmine;
  97
  98         if(to)
  99                 SetMovetypeFollow(self, to);
 100 }
 101
 102 void W_Mine_Explode ()
 103 {
 104         if(other.takedamage == DAMAGE_AIM)
 105                 if(IS_PLAYER(other))
 106                         if(DIFF_TEAM(self.realowner, other))
 107                                 if(other.deadflag == DEAD_NO)
 108                                         if(IsFlying(other))
 109                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
 110
 111         self.event_damage = func_null;
 112         self.takedamage = DAMAGE_NO;
 113
 114         RadiusDamage (self, self.realowner, WEP_CVAR(minelayer, damage), WEP_CVAR(minelayer, edgedamage), WEP_CVAR(minelayer, radius), world, world, WEP_CVAR(minelayer, force), self.projectiledeathtype, other);
 115
 116         if (self.realowner.weapon == WEP_MINE_LAYER)
 117         {
 118                 entity oldself;
 119                 oldself = self;
 120                 self = self.realowner;
 121                 if (!WEP_ACTION(WEP_MINE_LAYER, WR_CHECKAMMO1))
 122                 {
 123                         self.cnt = WEP_MINE_LAYER;
 124                         ATTACK_FINISHED(self) = time;
 125                         self.switchweapon = w_getbestweapon(self);
 126                 }
 127                 self = oldself;
 128         }
 129         self.realowner.minelayer_mines -= 1;
 130         remove (self);
 131 }
 132
 133 void W_Mine_DoRemoteExplode ()
 134 {
 135         self.event_damage = func_null;
 136         self.takedamage = DAMAGE_NO;
 137
 138         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 139                 self.velocity = self.mine_orientation; // particle fx and decals need .velocity
 140
 141         RadiusDamage (self, self.realowner, WEP_CVAR(minelayer, remote_damage), WEP_CVAR(minelayer, remote_edgedamage), WEP_CVAR(minelayer, remote_radius), world, world, WEP_CVAR(minelayer, remote_force), self.projectiledeathtype | HITTYPE_BOUNCE, world);
 142
 143         if (self.realowner.weapon == WEP_MINE_LAYER)
 144         {
 145                 entity oldself;
 146                 oldself = self;
 147                 self = self.realowner;
 148                 if (!WEP_ACTION(WEP_MINE_LAYER, WR_CHECKAMMO1))
 149                 {
 150                         self.cnt = WEP_MINE_LAYER;
 151                         ATTACK_FINISHED(self) = time;
 152                         self.switchweapon = w_getbestweapon(self);
 153                 }
 154                 self = oldself;
 155         }
 156         self.realowner.minelayer_mines -= 1;
 157         remove (self);
 158 }
 159
 160 void W_Mine_RemoteExplode ()
 161 {
 162         if(self.realowner.deadflag == DEAD_NO)
 163                 if((self.spawnshieldtime >= 0)
 164                         ? (time >= self.spawnshieldtime) // timer
 165                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > WEP_CVAR(minelayer, remote_radius)) // safety device
 166                 )
 167                 {
 168                         W_Mine_DoRemoteExplode();
 169                 }
 170 }
 171
 172 void W_Mine_ProximityExplode ()
 173 {
 174         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 175         if(WEP_CVAR(minelayer, protection) && self.mine_explodeanyway == 0)
 176         {
 177                 entity head;
 178                 head = findradius(self.origin, WEP_CVAR(minelayer, radius));
 179                 while(head)
 180                 {
 181                         if(head == self.realowner || SAME_TEAM(head, self.realowner))
 182                                 return;
 183                         head = head.chain;
 184                 }
 185         }
 186
 187         self.mine_time = 0;
 188         W_Mine_Explode();
 189 }
 190
 191 float W_Mine_Count(entity e)
 192 {
 193         float minecount = 0;
 194         entity mine;
 195         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == e)
 196                 minecount += 1;
 197
 198         return minecount;
 199 }
 200
 201 void W_Mine_Think (void)
 202 {
 203         entity head;
 204
 205         self.nextthink = time;
 206
 207         if(self.movetype == MOVETYPE_FOLLOW)
 208         {
 209                 if(LostMovetypeFollow(self))
 210                 {
 211                         UnsetMovetypeFollow(self);
 212                         self.movetype = MOVETYPE_NONE;
 213                 }
 214         }
 215
 216         // our lifetime has expired, it's time to die - mine_time just allows us to play a sound for this
 217         // TODO: replace this mine_trigger.wav sound with a real countdown
 218         if ((time > self.cnt) && (!self.mine_time))
 219         {
 220                 if(WEP_CVAR(minelayer, lifetime_countdown) > 0)
 221                         spamsound (self, CH_SHOTS, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 222                 self.mine_time = time + WEP_CVAR(minelayer, lifetime_countdown);
 223                 self.mine_explodeanyway = 1; // make the mine super aggressive -- Samual: Rather, make it not care if a team mate is near.
 224         }
 225
 226         // a player's mines shall explode if he disconnects or dies
 227         // TODO: Do this on team change too -- Samual: But isn't a player killed when they switch teams?
 228         if(!IS_PLAYER(self.realowner) || self.realowner.deadflag != DEAD_NO)
 229         {
 230                 other = world;
 231                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 232                 W_Mine_Explode();
 233                 return;
 234         }
 235
 236         // set the mine for detonation when a foe gets close enough
 237         head = findradius(self.origin, WEP_CVAR(minelayer, proximityradius));
 238         while(head)
 239         {
 240                 if(IS_PLAYER(head) && head.deadflag == DEAD_NO)
 241                 if(head != self.realowner && DIFF_TEAM(head, self.realowner)) // don't trigger for team mates
 242                 if(!self.mine_time)
 243                 {
 244                         spamsound (self, CH_SHOTS, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 245                         self.mine_time = time + WEP_CVAR(minelayer, time);
 246                 }
 247                 head = head.chain;
 248         }
 249
 250         // explode if it's time to
 251         if(self.mine_time && time >= self.mine_time)
 252         {
 253                 W_Mine_ProximityExplode();
 254                 return;
 255         }
 256
 257         // remote detonation
 258         if (self.realowner.weapon == WEP_MINE_LAYER)
 259         if (self.realowner.deadflag == DEAD_NO)
 260         if (self.minelayer_detonate)
 261                 W_Mine_RemoteExplode();
 262 }
 263
 264 void W_Mine_Touch (void)
 265 {
 266         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 267                 return; // we're already a stuck mine, why do we get called? TODO does this even happen?
 268
 269         if(WarpZone_Projectile_Touch())
 270         {
 271                 if(wasfreed(self))
 272                         self.realowner.minelayer_mines -= 1;
 273                 return;
 274         }
 275
 276         if(other && IS_PLAYER(other) && other.deadflag == DEAD_NO)
 277         {
 278                 // hit a player
 279                 // don't stick
 280         }
 281         else
 282         {
 283                 W_Mine_Stick(other);
 284         }
 285 }
 286
 287 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 288 {
 289         if (self.health <= 0)
 290                 return;
 291
 292         float is_from_enemy = (inflictor.realowner != self.realowner);
 293
 294         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, (is_from_enemy ? 1 : -1)))
 295                 return; // g_projectiles_damage says to halt
 296
 297         self.health = self.health - damage;
 298         self.angles = vectoangles(self.velocity);
 299
 300         if (self.health <= 0)
 301                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 302 }
 303
 304 void W_Mine_Attack (void)
 305 {
 306         entity mine;
 307         entity flash;
 308
 309         // scan how many mines we placed, and return if we reached our limit
 310         if(WEP_CVAR(minelayer, limit))
 311         {
 312                 if(self.minelayer_mines >= WEP_CVAR(minelayer, limit))
 313                 {
 314                         // the refire delay keeps this message from being spammed
 315                         sprint(self, strcat("minelayer: You cannot place more than ^2", ftos(WEP_CVAR(minelayer, limit)), " ^7mines at a time\n") );
 316                         play2(self, "weapons/unavailable.wav");
 317                         return;
 318                 }
 319         }
 320
 321         W_DecreaseAmmo(ammo_rockets, WEP_CVAR(minelayer, ammo), autocvar_g_balance_minelayer_reload_ammo);
 322
 323         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", CH_WEAPON_A, WEP_CVAR(minelayer, damage));
 324         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 325
 326         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 327         mine.owner = mine.realowner = self;
 328         if(WEP_CVAR(minelayer, detonatedelay) >= 0)
 329                 mine.spawnshieldtime = time + WEP_CVAR(minelayer, detonatedelay);
 330         else
 331                 mine.spawnshieldtime = -1;
 332         mine.classname = "mine";
 333         mine.bot_dodge = TRUE;
 334         mine.bot_dodgerating = WEP_CVAR(minelayer, damage) * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 335
 336         mine.takedamage = DAMAGE_YES;
 337         mine.damageforcescale = WEP_CVAR(minelayer, damageforcescale);
 338         mine.health = WEP_CVAR(minelayer, health);
 339         mine.event_damage = W_Mine_Damage;
 340         mine.damagedbycontents = TRUE;
 341
 342         mine.movetype = MOVETYPE_TOSS;
 343         PROJECTILE_MAKETRIGGER(mine);
 344         mine.projectiledeathtype = WEP_MINE_LAYER;
 345         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 346
 347         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 348         W_SetupProjectileVelocity(mine, WEP_CVAR(minelayer, speed), 0);
 349         mine.angles = vectoangles (mine.velocity);
 350
 351         mine.touch = W_Mine_Touch;
 352         mine.think = W_Mine_Think;
 353         mine.nextthink = time;
 354         mine.cnt = time + (WEP_CVAR(minelayer, lifetime) - WEP_CVAR(minelayer, lifetime_countdown));
 355         mine.flags = FL_PROJECTILE;
 356         mine.missile_flags = MIF_SPLASH | MIF_ARC | MIF_PROXY;
 357
 358         CSQCProjectile(mine, TRUE, PROJECTILE_MINE, TRUE);
 359
 360         // muzzle flash for 1st person view
 361         flash = spawn ();
 362         setmodel (flash, "models/flash.md3"); // precision set below
 363         SUB_SetFade (flash, time, 0.1);
 364         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 365         W_AttachToShotorg(flash, '5 0 0');
 366
 367         // common properties
 368
 369         other = mine; MUTATOR_CALLHOOK(EditProjectile);
 370
 371         self.minelayer_mines = W_Mine_Count(self);
 372 }
 373
 374 float W_PlacedMines(float detonate)
 375 {
 376         entity mine;
 377         float minfound = 0;
 378
 379         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == self)
 380         {
 381                 if(detonate)
 382                 {
 383                         if(!mine.minelayer_detonate)
 384                         {
 385                                 mine.minelayer_detonate = TRUE;
 386                                 minfound = 1;
 387                         }
 388                 }
 389                 else
 390                         minfound = 1;
 391         }
 392         return minfound;
 393 }
 394
 395 float w_minelayer(float req)
 396 {
 397         entity mine;
 398         float ammo_amount;
 399         switch(req)
 400         {
 401                 case WR_AIM:
 402                 {
 403                         // aim and decide to fire if appropriate
 404                         if(self.minelayer_mines >= WEP_CVAR(minelayer, limit))
 405                                 self.BUTTON_ATCK = FALSE;
 406                         else
 407                                 self.BUTTON_ATCK = bot_aim(WEP_CVAR(minelayer, speed), 0, WEP_CVAR(minelayer, lifetime), FALSE);
 408                         if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 409                         {
 410                                 // decide whether to detonate mines
 411                                 entity targetlist, targ;
 412                                 float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 413                                 float selfdamage, teamdamage, enemydamage;
 414                                 edgedamage = WEP_CVAR(minelayer, edgedamage);
 415                                 coredamage = WEP_CVAR(minelayer, damage);
 416                                 edgeradius = WEP_CVAR(minelayer, radius);
 417                                 recipricoledgeradius = 1 / edgeradius;
 418                                 selfdamage = 0;
 419                                 teamdamage = 0;
 420                                 enemydamage = 0;
 421                                 targetlist = findchainfloat(bot_attack, TRUE);
 422                                 mine = find(world, classname, "mine");
 423                                 while (mine)
 424                                 {
 425                                         if (mine.realowner != self)
 426                                         {
 427                                                 mine = find(mine, classname, "mine");
 428                                                 continue;
 429                                         }
 430                                         targ = targetlist;
 431                                         while (targ)
 432                                         {
 433                                                 d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 434                                                 d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 435                                                 // count potential damage according to type of target
 436                                                 if (targ == self)
 437                                                         selfdamage = selfdamage + d;
 438                                                 else if (targ.team == self.team && teamplay)
 439                                                         teamdamage = teamdamage + d;
 440                                                 else if (bot_shouldattack(targ))
 441                                                         enemydamage = enemydamage + d;
 442                                                 targ = targ.chain;
 443                                         }
 444                                         mine = find(mine, classname, "mine");
 445                                 }
 446                                 float desirabledamage;
 447                                 desirabledamage = enemydamage;
 448                                 if (time > self.invincible_finished && time > self.spawnshieldtime)
 449                                         desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 450                                 if (teamplay && self.team)
 451                                         desirabledamage = desirabledamage - teamdamage;
 452
 453                                 mine = find(world, classname, "mine");
 454                                 while (mine)
 455                                 {
 456                                         if (mine.realowner != self)
 457                                         {
 458                                                 mine = find(mine, classname, "mine");
 459                                                 continue;
 460                                         }
 461                                         makevectors(mine.v_angle);
 462                                         targ = targetlist;
 463                                         if (skill > 9) // normal players only do this for the target they are tracking
 464                                         {
 465                                                 targ = targetlist;
 466                                                 while (targ)
 467                                                 {
 468                                                         if (
 469                                                                 (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 470                                                                 && desirabledamage > 0.1*coredamage
 471                                                         )self.BUTTON_ATCK2 = TRUE;
 472                                                         targ = targ.chain;
 473                                                 }
 474                                         }else{
 475                                                 float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 476                                                 //As the distance gets larger, a correct detonation gets near imposible
 477                                                 //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 478                                                 if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 479                                                         if(IS_PLAYER(self.enemy))
 480                                                                 if(desirabledamage >= 0.1*coredamage)
 481                                                                         if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 482                                                                                 self.BUTTON_ATCK2 = TRUE;
 483                                         //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 484                                         }
 485
 486                                         mine = find(mine, classname, "mine");
 487                                 }
 488                                 // if we would be doing at X percent of the core damage, detonate it
 489                                 // but don't fire a new shot at the same time!
 490                                 if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 491                                         self.BUTTON_ATCK2 = TRUE;
 492                                 if ((skill > 6.5) && (selfdamage > self.health))
 493                                         self.BUTTON_ATCK2 = FALSE;
 494                                 //if(self.BUTTON_ATCK2 == TRUE)
 495                                 //      dprint(ftos(desirabledamage),"\n");
 496                                 if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 497                         }
 498
 499                         return TRUE;
 500                 }
 501                 case WR_THINK:
 502                 {
 503                         if(autocvar_g_balance_minelayer_reload_ammo && self.clip_load < WEP_CVAR(minelayer, ammo)) // forced reload
 504                         {
 505                                 // not if we're holding the minelayer without enough ammo, but can detonate existing mines
 506                                 if(!(W_PlacedMines(FALSE) && self.ammo_rockets < WEP_CVAR(minelayer, ammo)))
 507                                         WEP_ACTION(self.weapon, WR_RELOAD);
 508                         }
 509                         else if (self.BUTTON_ATCK)
 510                         {
 511                                 if(weapon_prepareattack(0, WEP_CVAR(minelayer, refire)))
 512                                 {
 513                                         W_Mine_Attack();
 514                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(minelayer, animtime), w_ready);
 515                                 }
 516                         }
 517
 518                         if (self.BUTTON_ATCK2)
 519                         {
 520                                 if(W_PlacedMines(TRUE))
 521                                         sound (self, CH_WEAPON_B, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 522                         }
 523
 524                         return TRUE;
 525                 }
 526                 case WR_INIT:
 527                 {
 528                         precache_model ("models/flash.md3");
 529                         precache_model ("models/mine.md3");
 530                         precache_model ("models/weapons/g_minelayer.md3");
 531                         precache_model ("models/weapons/v_minelayer.md3");
 532                         precache_model ("models/weapons/h_minelayer.iqm");
 533                         precache_sound ("weapons/mine_det.wav");
 534                         precache_sound ("weapons/mine_fire.wav");
 535                         precache_sound ("weapons/mine_stick.wav");
 536                         precache_sound ("weapons/mine_trigger.wav");
 537                         MINELAYER_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 538                         return TRUE;
 539                 }
 540                 case WR_SETUP:
 541                 {
 542                         self.current_ammo = ammo_rockets;
 543                         return TRUE;
 544                 }
 545                 case WR_CHECKAMMO1:
 546                 {
 547                         // don't switch while placing a mine
 548                         if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 549                         {
 550                                 ammo_amount = self.ammo_rockets >= WEP_CVAR(minelayer, ammo);
 551                                 ammo_amount += self.(weapon_load[WEP_MINE_LAYER]) >= WEP_CVAR(minelayer, ammo);
 552                                 return ammo_amount;
 553                         }
 554                         return TRUE;
 555                 }
 556                 case WR_CHECKAMMO2:
 557                 {
 558                         if (W_PlacedMines(FALSE))
 559                                 return TRUE;
 560                         else
 561                                 return FALSE;
 562                 }
 563                 case WR_CONFIG:
 564                 {
 565                         MINELAYER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 566                         return TRUE;
 567                 }
 568                 case WR_RESETPLAYER:
 569                 {
 570                         self.minelayer_mines = 0;
 571                         return TRUE;
 572                 }
 573                 case WR_RELOAD:
 574                 {
 575                         W_Reload(WEP_CVAR(minelayer, ammo), "weapons/reload.wav");
 576                         return TRUE;
 577                 }
 578                 case WR_SUICIDEMESSAGE:
 579                 {
 580                         return WEAPON_MINELAYER_SUICIDE;
 581                 }
 582                 case WR_KILLMESSAGE:
 583                 {
 584                         return WEAPON_MINELAYER_MURDER;
 585                 }
 586         }
 587         return TRUE;
 588 }
 589 #endif
 590 #ifdef CSQC
 591 float w_minelayer(float req)
 592 {
 593         switch(req)
 594         {
 595                 case WR_IMPACTEFFECT:
 596                 {
 597                         vector org2;
 598                         org2 = w_org + w_backoff * 12;
 599                         pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 600                         if(!w_issilent)
 601                                 sound(self, CH_SHOTS, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 602
 603                         return TRUE;
 604                 }
 605                 case WR_INIT:
 606                 {
 607                         precache_sound("weapons/mine_exp.wav");
 608                         return TRUE;
 609                 }
 610         }
 611         return TRUE;
 612 }
 613 #endif
 614 #endif