qcsrc/common/weapons/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ MINE_LAYER,
   4 /* function */ w_minelayer,
   5 /* ammotype */ IT_ROCKETS,
   6 /* impulse  */ 4,
   7 /* flags    */ WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH,
   8 /* rating   */ BOT_PICKUP_RATING_HIGH,
   9 /* model    */ "minelayer",
  10 /* netname  */ "minelayer",
  11 /* fullname */ _("Mine Layer")
  12 );
  13
  14 #define MINELAYER_SETTINGS(weapon) \
  15         WEP_ADD_CVAR(weapon, MO_NONE, ammo) \
  16         WEP_ADD_CVAR(weapon, MO_NONE, animtime) \
  17         WEP_ADD_CVAR(weapon, MO_NONE, damage) \
  18         WEP_ADD_CVAR(weapon, MO_NONE, damageforcescale) \
  19         WEP_ADD_CVAR(weapon, MO_NONE, detonatedelay) \
  20         WEP_ADD_CVAR(weapon, MO_NONE, edgedamage) \
  21         WEP_ADD_CVAR(weapon, MO_NONE, force) \
  22         WEP_ADD_CVAR(weapon, MO_NONE, health) \
  23         WEP_ADD_CVAR(weapon, MO_NONE, lifetime) \
  24         WEP_ADD_CVAR(weapon, MO_NONE, lifetime_countdown) \
  25         WEP_ADD_CVAR(weapon, MO_NONE, limit) \
  26         WEP_ADD_CVAR(weapon, MO_NONE, protection) \
  27         WEP_ADD_CVAR(weapon, MO_NONE, proximityradius) \
  28         WEP_ADD_CVAR(weapon, MO_NONE, radius) \
  29         WEP_ADD_CVAR(weapon, MO_NONE, refire) \
  30         WEP_ADD_CVAR(weapon, MO_NONE, remote_damage) \
  31         WEP_ADD_CVAR(weapon, MO_NONE, remote_edgedamage) \
  32         WEP_ADD_CVAR(weapon, MO_NONE, remote_force) \
  33         WEP_ADD_CVAR(weapon, MO_NONE, remote_radius) \
  34         WEP_ADD_CVAR(weapon, MO_NONE, speed) \
  35         WEP_ADD_CVAR(weapon, MO_NONE, time) \
  36         WEP_ADD_PROP(weapon, reloading_ammo, reload_ammo) \
  37         WEP_ADD_PROP(weapon, reloading_time, reload_time) \
  38         WEP_ADD_PROP(weapon, switchdelay_raise, switchdelay_raise) \
  39         WEP_ADD_PROP(weapon, switchdelay_drop, switchdelay_drop)
  40
  41 #ifdef SVQC
  42 MINELAYER_SETTINGS(minelayer)
  43 void W_Mine_Think (void);
  44 .float minelayer_detonate, mine_explodeanyway;
  45 .float mine_time;
  46 .vector mine_orientation;
  47 #endif
  48 #else
  49 #ifdef SVQC
  50 void spawnfunc_weapon_minelayer() { weapon_defaultspawnfunc(WEP_MINE_LAYER); }
  51
  52 void W_Mine_Stick (entity to)
  53 {
  54         spamsound (self, CH_SHOTS, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
  55
  56         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  57
  58         entity newmine;
  59         newmine = spawn();
  60         newmine.classname = self.classname;
  61
  62         newmine.bot_dodge = self.bot_dodge;
  63         newmine.bot_dodgerating = self.bot_dodgerating;
  64
  65         newmine.owner = self.owner;
  66         newmine.realowner = self.realowner;
  67         setsize(newmine, '-4 -4 -4', '4 4 4');
  68         setorigin(newmine, self.origin);
  69         setmodel(newmine, "models/mine.md3");
  70         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  71
  72         newmine.mine_orientation = -trace_plane_normal;
  73
  74         newmine.takedamage = self.takedamage;
  75         newmine.damageforcescale = self.damageforcescale;
  76         newmine.health = self.health;
  77         newmine.event_damage = self.event_damage;
  78         newmine.spawnshieldtime = self.spawnshieldtime;
  79         newmine.damagedbycontents = TRUE;
  80
  81         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  82         newmine.projectiledeathtype = self.projectiledeathtype;
  83
  84         newmine.mine_time = self.mine_time;
  85
  86         newmine.touch = func_null;
  87         newmine.think = W_Mine_Think;
  88         newmine.nextthink = time;
  89         newmine.cnt = self.cnt;
  90         newmine.flags = self.flags;
  91
  92         remove(self);
  93         self = newmine;
  94
  95         if(to)
  96                 SetMovetypeFollow(self, to);
  97 }
  98
  99 void W_Mine_Explode ()
 100 {
 101         if(other.takedamage == DAMAGE_AIM)
 102                 if(IS_PLAYER(other))
 103                         if(DIFF_TEAM(self.realowner, other))
 104                                 if(other.deadflag == DEAD_NO)
 105                                         if(IsFlying(other))
 106                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
 107
 108         self.event_damage = func_null;
 109         self.takedamage = DAMAGE_NO;
 110
 111         RadiusDamage (self, self.realowner, WEP_CVAR(minelayer, damage), WEP_CVAR(minelayer, edgedamage), WEP_CVAR(minelayer, radius), world, world, WEP_CVAR(minelayer, force), self.projectiledeathtype, other);
 112
 113         if (self.realowner.weapon == WEP_MINE_LAYER)
 114         {
 115                 entity oldself;
 116                 oldself = self;
 117                 self = self.realowner;
 118                 if (!WEP_ACTION(WEP_MINE_LAYER, WR_CHECKAMMO1))
 119                 {
 120                         self.cnt = WEP_MINE_LAYER;
 121                         ATTACK_FINISHED(self) = time;
 122                         self.switchweapon = w_getbestweapon(self);
 123                 }
 124                 self = oldself;
 125         }
 126         self.realowner.minelayer_mines -= 1;
 127         remove (self);
 128 }
 129
 130 void W_Mine_DoRemoteExplode ()
 131 {
 132         self.event_damage = func_null;
 133         self.takedamage = DAMAGE_NO;
 134
 135         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 136                 self.velocity = self.mine_orientation; // particle fx and decals need .velocity
 137
 138         RadiusDamage (self, self.realowner, WEP_CVAR(minelayer, remote_damage), WEP_CVAR(minelayer, remote_edgedamage), WEP_CVAR(minelayer, remote_radius), world, world, WEP_CVAR(minelayer, remote_force), self.projectiledeathtype | HITTYPE_BOUNCE, world);
 139
 140         if (self.realowner.weapon == WEP_MINE_LAYER)
 141         {
 142                 entity oldself;
 143                 oldself = self;
 144                 self = self.realowner;
 145                 if (!WEP_ACTION(WEP_MINE_LAYER, WR_CHECKAMMO1))
 146                 {
 147                         self.cnt = WEP_MINE_LAYER;
 148                         ATTACK_FINISHED(self) = time;
 149                         self.switchweapon = w_getbestweapon(self);
 150                 }
 151                 self = oldself;
 152         }
 153         self.realowner.minelayer_mines -= 1;
 154         remove (self);
 155 }
 156
 157 void W_Mine_RemoteExplode ()
 158 {
 159         if(self.realowner.deadflag == DEAD_NO)
 160                 if((self.spawnshieldtime >= 0)
 161                         ? (time >= self.spawnshieldtime) // timer
 162                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > WEP_CVAR(minelayer, remote_radius)) // safety device
 163                 )
 164                 {
 165                         W_Mine_DoRemoteExplode();
 166                 }
 167 }
 168
 169 void W_Mine_ProximityExplode ()
 170 {
 171         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 172         if(WEP_CVAR(minelayer, protection) && self.mine_explodeanyway == 0)
 173         {
 174                 entity head;
 175                 head = findradius(self.origin, WEP_CVAR(minelayer, radius));
 176                 while(head)
 177                 {
 178                         if(head == self.realowner || SAME_TEAM(head, self.realowner))
 179                                 return;
 180                         head = head.chain;
 181                 }
 182         }
 183
 184         self.mine_time = 0;
 185         W_Mine_Explode();
 186 }
 187
 188 float W_Mine_Count(entity e)
 189 {
 190         float minecount = 0;
 191         entity mine;
 192         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == e)
 193                 minecount += 1;
 194
 195         return minecount;
 196 }
 197
 198 void W_Mine_Think (void)
 199 {
 200         entity head;
 201
 202         self.nextthink = time;
 203
 204         if(self.movetype == MOVETYPE_FOLLOW)
 205         {
 206                 if(LostMovetypeFollow(self))
 207                 {
 208                         UnsetMovetypeFollow(self);
 209                         self.movetype = MOVETYPE_NONE;
 210                 }
 211         }
 212
 213         // our lifetime has expired, it's time to die - mine_time just allows us to play a sound for this
 214         // TODO: replace this mine_trigger.wav sound with a real countdown
 215         if ((time > self.cnt) && (!self.mine_time))
 216         {
 217                 if(WEP_CVAR(minelayer, lifetime_countdown) > 0)
 218                         spamsound (self, CH_SHOTS, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 219                 self.mine_time = time + WEP_CVAR(minelayer, lifetime_countdown);
 220                 self.mine_explodeanyway = 1; // make the mine super aggressive -- Samual: Rather, make it not care if a team mate is near.
 221         }
 222
 223         // a player's mines shall explode if he disconnects or dies
 224         // TODO: Do this on team change too -- Samual: But isn't a player killed when they switch teams?
 225         if(!IS_PLAYER(self.realowner) || self.realowner.deadflag != DEAD_NO)
 226         {
 227                 other = world;
 228                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 229                 W_Mine_Explode();
 230                 return;
 231         }
 232
 233         // set the mine for detonation when a foe gets close enough
 234         head = findradius(self.origin, WEP_CVAR(minelayer, proximityradius));
 235         while(head)
 236         {
 237                 if(IS_PLAYER(head) && head.deadflag == DEAD_NO)
 238                 if(head != self.realowner && DIFF_TEAM(head, self.realowner)) // don't trigger for team mates
 239                 if(!self.mine_time)
 240                 {
 241                         spamsound (self, CH_SHOTS, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 242                         self.mine_time = time + WEP_CVAR(minelayer, time);
 243                 }
 244                 head = head.chain;
 245         }
 246
 247         // explode if it's time to
 248         if(self.mine_time && time >= self.mine_time)
 249         {
 250                 W_Mine_ProximityExplode();
 251                 return;
 252         }
 253
 254         // remote detonation
 255         if (self.realowner.weapon == WEP_MINE_LAYER)
 256         if (self.realowner.deadflag == DEAD_NO)
 257         if (self.minelayer_detonate)
 258                 W_Mine_RemoteExplode();
 259 }
 260
 261 void W_Mine_Touch (void)
 262 {
 263         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 264                 return; // we're already a stuck mine, why do we get called? TODO does this even happen?
 265
 266         if(WarpZone_Projectile_Touch())
 267         {
 268                 if(wasfreed(self))
 269                         self.realowner.minelayer_mines -= 1;
 270                 return;
 271         }
 272
 273         if(other && IS_PLAYER(other) && other.deadflag == DEAD_NO)
 274         {
 275                 // hit a player
 276                 // don't stick
 277         }
 278         else
 279         {
 280                 W_Mine_Stick(other);
 281         }
 282 }
 283
 284 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 285 {
 286         if (self.health <= 0)
 287                 return;
 288
 289         float is_from_enemy = (inflictor.realowner != self.realowner);
 290
 291         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, (is_from_enemy ? 1 : -1)))
 292                 return; // g_projectiles_damage says to halt
 293
 294         self.health = self.health - damage;
 295         self.angles = vectoangles(self.velocity);
 296
 297         if (self.health <= 0)
 298                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 299 }
 300
 301 void W_Mine_Attack (void)
 302 {
 303         entity mine;
 304         entity flash;
 305
 306         // scan how many mines we placed, and return if we reached our limit
 307         if(WEP_CVAR(minelayer, limit))
 308         {
 309                 if(self.minelayer_mines >= WEP_CVAR(minelayer, limit))
 310                 {
 311                         // the refire delay keeps this message from being spammed
 312                         sprint(self, strcat("minelayer: You cannot place more than ^2", ftos(WEP_CVAR(minelayer, limit)), " ^7mines at a time\n") );
 313                         play2(self, "weapons/unavailable.wav");
 314                         return;
 315                 }
 316         }
 317
 318         W_DecreaseAmmo(ammo_rockets, WEP_CVAR(minelayer, ammo), autocvar_g_balance_minelayer_reload_ammo);
 319
 320         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", CH_WEAPON_A, WEP_CVAR(minelayer, damage));
 321         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 322
 323         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 324         mine.owner = mine.realowner = self;
 325         if(WEP_CVAR(minelayer, detonatedelay) >= 0)
 326                 mine.spawnshieldtime = time + WEP_CVAR(minelayer, detonatedelay);
 327         else
 328                 mine.spawnshieldtime = -1;
 329         mine.classname = "mine";
 330         mine.bot_dodge = TRUE;
 331         mine.bot_dodgerating = WEP_CVAR(minelayer, damage) * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 332
 333         mine.takedamage = DAMAGE_YES;
 334         mine.damageforcescale = WEP_CVAR(minelayer, damageforcescale);
 335         mine.health = WEP_CVAR(minelayer, health);
 336         mine.event_damage = W_Mine_Damage;
 337         mine.damagedbycontents = TRUE;
 338
 339         mine.movetype = MOVETYPE_TOSS;
 340         PROJECTILE_MAKETRIGGER(mine);
 341         mine.projectiledeathtype = WEP_MINE_LAYER;
 342         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 343
 344         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 345         W_SetupProjectileVelocity(mine, WEP_CVAR(minelayer, speed), 0);
 346         mine.angles = vectoangles (mine.velocity);
 347
 348         mine.touch = W_Mine_Touch;
 349         mine.think = W_Mine_Think;
 350         mine.nextthink = time;
 351         mine.cnt = time + (WEP_CVAR(minelayer, lifetime) - WEP_CVAR(minelayer, lifetime_countdown));
 352         mine.flags = FL_PROJECTILE;
 353         mine.missile_flags = MIF_SPLASH | MIF_ARC | MIF_PROXY;
 354
 355         CSQCProjectile(mine, TRUE, PROJECTILE_MINE, TRUE);
 356
 357         // muzzle flash for 1st person view
 358         flash = spawn ();
 359         setmodel (flash, "models/flash.md3"); // precision set below
 360         SUB_SetFade (flash, time, 0.1);
 361         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 362         W_AttachToShotorg(flash, '5 0 0');
 363
 364         // common properties
 365
 366         other = mine; MUTATOR_CALLHOOK(EditProjectile);
 367
 368         self.minelayer_mines = W_Mine_Count(self);
 369 }
 370
 371 float W_PlacedMines(float detonate)
 372 {
 373         entity mine;
 374         float minfound = 0;
 375
 376         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == self)
 377         {
 378                 if(detonate)
 379                 {
 380                         if(!mine.minelayer_detonate)
 381                         {
 382                                 mine.minelayer_detonate = TRUE;
 383                                 minfound = 1;
 384                         }
 385                 }
 386                 else
 387                         minfound = 1;
 388         }
 389         return minfound;
 390 }
 391
 392 float w_minelayer(float req)
 393 {
 394         entity mine;
 395         float ammo_amount;
 396         switch(req)
 397         {
 398                 case WR_AIM:
 399                 {
 400                         // aim and decide to fire if appropriate
 401                         if(self.minelayer_mines >= WEP_CVAR(minelayer, limit))
 402                                 self.BUTTON_ATCK = FALSE;
 403                         else
 404                                 self.BUTTON_ATCK = bot_aim(WEP_CVAR(minelayer, speed), 0, WEP_CVAR(minelayer, lifetime), FALSE);
 405                         if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 406                         {
 407                                 // decide whether to detonate mines
 408                                 entity targetlist, targ;
 409                                 float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 410                                 float selfdamage, teamdamage, enemydamage;
 411                                 edgedamage = WEP_CVAR(minelayer, edgedamage);
 412                                 coredamage = WEP_CVAR(minelayer, damage);
 413                                 edgeradius = WEP_CVAR(minelayer, radius);
 414                                 recipricoledgeradius = 1 / edgeradius;
 415                                 selfdamage = 0;
 416                                 teamdamage = 0;
 417                                 enemydamage = 0;
 418                                 targetlist = findchainfloat(bot_attack, TRUE);
 419                                 mine = find(world, classname, "mine");
 420                                 while (mine)
 421                                 {
 422                                         if (mine.realowner != self)
 423                                         {
 424                                                 mine = find(mine, classname, "mine");
 425                                                 continue;
 426                                         }
 427                                         targ = targetlist;
 428                                         while (targ)
 429                                         {
 430                                                 d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 431                                                 d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 432                                                 // count potential damage according to type of target
 433                                                 if (targ == self)
 434                                                         selfdamage = selfdamage + d;
 435                                                 else if (targ.team == self.team && teamplay)
 436                                                         teamdamage = teamdamage + d;
 437                                                 else if (bot_shouldattack(targ))
 438                                                         enemydamage = enemydamage + d;
 439                                                 targ = targ.chain;
 440                                         }
 441                                         mine = find(mine, classname, "mine");
 442                                 }
 443                                 float desirabledamage;
 444                                 desirabledamage = enemydamage;
 445                                 if (time > self.invincible_finished && time > self.spawnshieldtime)
 446                                         desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 447                                 if (teamplay && self.team)
 448                                         desirabledamage = desirabledamage - teamdamage;
 449
 450                                 mine = find(world, classname, "mine");
 451                                 while (mine)
 452                                 {
 453                                         if (mine.realowner != self)
 454                                         {
 455                                                 mine = find(mine, classname, "mine");
 456                                                 continue;
 457                                         }
 458                                         makevectors(mine.v_angle);
 459                                         targ = targetlist;
 460                                         if (skill > 9) // normal players only do this for the target they are tracking
 461                                         {
 462                                                 targ = targetlist;
 463                                                 while (targ)
 464                                                 {
 465                                                         if (
 466                                                                 (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 467                                                                 && desirabledamage > 0.1*coredamage
 468                                                         )self.BUTTON_ATCK2 = TRUE;
 469                                                         targ = targ.chain;
 470                                                 }
 471                                         }else{
 472                                                 float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 473                                                 //As the distance gets larger, a correct detonation gets near imposible
 474                                                 //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 475                                                 if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 476                                                         if(IS_PLAYER(self.enemy))
 477                                                                 if(desirabledamage >= 0.1*coredamage)
 478                                                                         if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 479                                                                                 self.BUTTON_ATCK2 = TRUE;
 480                                         //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 481                                         }
 482
 483                                         mine = find(mine, classname, "mine");
 484                                 }
 485                                 // if we would be doing at X percent of the core damage, detonate it
 486                                 // but don't fire a new shot at the same time!
 487                                 if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 488                                         self.BUTTON_ATCK2 = TRUE;
 489                                 if ((skill > 6.5) && (selfdamage > self.health))
 490                                         self.BUTTON_ATCK2 = FALSE;
 491                                 //if(self.BUTTON_ATCK2 == TRUE)
 492                                 //      dprint(ftos(desirabledamage),"\n");
 493                                 if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 494                         }
 495
 496                         return TRUE;
 497                 }
 498                 case WR_THINK:
 499                 {
 500                         if(autocvar_g_balance_minelayer_reload_ammo && self.clip_load < WEP_CVAR(minelayer, ammo)) // forced reload
 501                         {
 502                                 // not if we're holding the minelayer without enough ammo, but can detonate existing mines
 503                                 if not (W_PlacedMines(FALSE) && self.ammo_rockets < WEP_CVAR(minelayer, ammo))
 504                                         WEP_ACTION(self.weapon, WR_RELOAD);
 505                         }
 506                         else if (self.BUTTON_ATCK)
 507                         {
 508                                 if(weapon_prepareattack(0, WEP_CVAR(minelayer, refire)))
 509                                 {
 510                                         W_Mine_Attack();
 511                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(minelayer, animtime), w_ready);
 512                                 }
 513                         }
 514
 515                         if (self.BUTTON_ATCK2)
 516                         {
 517                                 if(W_PlacedMines(TRUE))
 518                                         sound (self, CH_WEAPON_B, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 519                         }
 520
 521                         return TRUE;
 522                 }
 523                 case WR_INIT:
 524                 {
 525                         precache_model ("models/flash.md3");
 526                         precache_model ("models/mine.md3");
 527                         precache_model ("models/weapons/g_minelayer.md3");
 528                         precache_model ("models/weapons/v_minelayer.md3");
 529                         precache_model ("models/weapons/h_minelayer.iqm");
 530                         precache_sound ("weapons/mine_det.wav");
 531                         precache_sound ("weapons/mine_fire.wav");
 532                         precache_sound ("weapons/mine_stick.wav");
 533                         precache_sound ("weapons/mine_trigger.wav");
 534                         WEP_SET_PROPS(MINELAYER_SETTINGS(minelayer), WEP_MINE_LAYER)
 535                         return TRUE;
 536                 }
 537                 case WR_SETUP:
 538                 {
 539                         self.current_ammo = ammo_rockets;
 540                         return TRUE;
 541                 }
 542                 case WR_CHECKAMMO1:
 543                 {
 544                         // don't switch while placing a mine
 545                         if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 546                         {
 547                                 ammo_amount = self.ammo_rockets >= WEP_CVAR(minelayer, ammo);
 548                                 ammo_amount += self.(weapon_load[WEP_MINE_LAYER]) >= WEP_CVAR(minelayer, ammo);
 549                                 return ammo_amount;
 550                         }
 551                         return TRUE;
 552                 }
 553                 case WR_CHECKAMMO2:
 554                 {
 555                         if (W_PlacedMines(FALSE))
 556                                 return TRUE;
 557                         else
 558                                 return FALSE;
 559                 }
 560                 case WR_CONFIG:
 561                 {
 562                         WEP_CONFIG_SETTINGS(MINELAYER_SETTINGS(minelayer))
 563                         return TRUE;
 564                 }
 565                 case WR_RESETPLAYER:
 566                 {
 567                         self.minelayer_mines = 0;
 568                         return TRUE;
 569                 }
 570                 case WR_RELOAD:
 571                 {
 572                         W_Reload(WEP_CVAR(minelayer, ammo), "weapons/reload.wav");
 573                         return TRUE;
 574                 }
 575                 case WR_SUICIDEMESSAGE:
 576                 {
 577                         return WEAPON_MINELAYER_SUICIDE;
 578                 }
 579                 case WR_KILLMESSAGE:
 580                 {
 581                         return WEAPON_MINELAYER_MURDER;
 582                 }
 583         }
 584         return TRUE;
 585 }
 586 #endif
 587 #ifdef CSQC
 588 float w_minelayer(float req)
 589 {
 590         switch(req)
 591         {
 592                 case WR_IMPACTEFFECT:
 593                 {
 594                         vector org2;
 595                         org2 = w_org + w_backoff * 12;
 596                         pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 597                         if(!w_issilent)
 598                                 sound(self, CH_SHOTS, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 599
 600                         return TRUE;
 601                 }
 602                 case WR_INIT:
 603                 {
 604                         precache_sound("weapons/mine_exp.wav");
 605                         return TRUE;
 606                 }
 607         }
 608         return TRUE;
 609 }
 610 #endif
 611 #endif