qcsrc/common/weapons/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ MINE_LAYER,
   4 /* function */ w_minelayer,
   5 /* ammotype */ ammo_rockets,
   6 /* impulse  */ 4,
   7 /* flags    */ WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH,
   8 /* rating   */ BOT_PICKUP_RATING_HIGH,
   9 /* model    */ "minelayer",
  10 /* netname  */ "minelayer",
  11 /* fullname */ _("Mine Layer")
  12 );
  13
  14 #define MINELAYER_SETTINGS(w_cvar,w_prop) MINELAYER_SETTINGS_LIST(w_cvar, w_prop, MINE_LAYER, minelayer)
  15 #define MINELAYER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  16         w_cvar(id, sn, NONE, ammo) \
  17         w_cvar(id, sn, NONE, animtime) \
  18         w_cvar(id, sn, NONE, damage) \
  19         w_cvar(id, sn, NONE, damageforcescale) \
  20         w_cvar(id, sn, NONE, detonatedelay) \
  21         w_cvar(id, sn, NONE, edgedamage) \
  22         w_cvar(id, sn, NONE, force) \
  23         w_cvar(id, sn, NONE, health) \
  24         w_cvar(id, sn, NONE, lifetime) \
  25         w_cvar(id, sn, NONE, lifetime_countdown) \
  26         w_cvar(id, sn, NONE, limit) \
  27         w_cvar(id, sn, NONE, protection) \
  28         w_cvar(id, sn, NONE, proximityradius) \
  29         w_cvar(id, sn, NONE, radius) \
  30         w_cvar(id, sn, NONE, refire) \
  31         w_cvar(id, sn, NONE, remote_damage) \
  32         w_cvar(id, sn, NONE, remote_edgedamage) \
  33         w_cvar(id, sn, NONE, remote_force) \
  34         w_cvar(id, sn, NONE, remote_radius) \
  35         w_cvar(id, sn, NONE, speed) \
  36         w_cvar(id, sn, NONE, time) \
  37         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  38         w_prop(id, sn, float,  reloading_time, reload_time) \
  39         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  40         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  41         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  42         w_prop(id, sn, float,  weaponstart, weaponstart) \
  43         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  44
  45 #ifdef SVQC
  46 MINELAYER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  47 void W_Mine_Think (void);
  48 .float minelayer_detonate, mine_explodeanyway;
  49 .float mine_time;
  50 .vector mine_orientation;
  51 #endif
  52 #else
  53 #ifdef SVQC
  54 void spawnfunc_weapon_minelayer() { weapon_defaultspawnfunc(WEP_MINE_LAYER); }
  55
  56 void W_Mine_Stick (entity to)
  57 {
  58         spamsound (self, CH_SHOTS, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
  59
  60         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  61
  62         entity newmine;
  63         newmine = spawn();
  64         newmine.classname = self.classname;
  65
  66         newmine.bot_dodge = self.bot_dodge;
  67         newmine.bot_dodgerating = self.bot_dodgerating;
  68
  69         newmine.owner = self.owner;
  70         newmine.realowner = self.realowner;
  71         setsize(newmine, '-4 -4 -4', '4 4 4');
  72         setorigin(newmine, self.origin);
  73         setmodel(newmine, "models/mine.md3");
  74         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  75
  76         newmine.mine_orientation = -trace_plane_normal;
  77
  78         newmine.takedamage = self.takedamage;
  79         newmine.damageforcescale = self.damageforcescale;
  80         newmine.health = self.health;
  81         newmine.event_damage = self.event_damage;
  82         newmine.spawnshieldtime = self.spawnshieldtime;
  83         newmine.damagedbycontents = TRUE;
  84
  85         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  86         newmine.projectiledeathtype = self.projectiledeathtype;
  87
  88         newmine.mine_time = self.mine_time;
  89
  90         newmine.touch = func_null;
  91         newmine.think = W_Mine_Think;
  92         newmine.nextthink = time;
  93         newmine.cnt = self.cnt;
  94         newmine.flags = self.flags;
  95
  96         remove(self);
  97         self = newmine;
  98
  99         if(to)
 100                 SetMovetypeFollow(self, to);
 101 }
 102
 103 void W_Mine_Explode ()
 104 {
 105         if(other.takedamage == DAMAGE_AIM)
 106                 if(IS_PLAYER(other))
 107                         if(DIFF_TEAM(self.realowner, other))
 108                                 if(other.deadflag == DEAD_NO)
 109                                         if(IsFlying(other))
 110                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
 111
 112         self.event_damage = func_null;
 113         self.takedamage = DAMAGE_NO;
 114
 115         RadiusDamage (self, self.realowner, WEP_CVAR(minelayer, damage), WEP_CVAR(minelayer, edgedamage), WEP_CVAR(minelayer, radius), world, world, WEP_CVAR(minelayer, force), self.projectiledeathtype, other);
 116
 117         if (self.realowner.weapon == WEP_MINE_LAYER)
 118         {
 119                 entity oldself;
 120                 oldself = self;
 121                 self = self.realowner;
 122                 if (!WEP_ACTION(WEP_MINE_LAYER, WR_CHECKAMMO1))
 123                 {
 124                         self.cnt = WEP_MINE_LAYER;
 125                         ATTACK_FINISHED(self) = time;
 126                         self.switchweapon = w_getbestweapon(self);
 127                 }
 128                 self = oldself;
 129         }
 130         self.realowner.minelayer_mines -= 1;
 131         remove (self);
 132 }
 133
 134 void W_Mine_DoRemoteExplode ()
 135 {
 136         self.event_damage = func_null;
 137         self.takedamage = DAMAGE_NO;
 138
 139         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 140                 self.velocity = self.mine_orientation; // particle fx and decals need .velocity
 141
 142         RadiusDamage (self, self.realowner, WEP_CVAR(minelayer, remote_damage), WEP_CVAR(minelayer, remote_edgedamage), WEP_CVAR(minelayer, remote_radius), world, world, WEP_CVAR(minelayer, remote_force), self.projectiledeathtype | HITTYPE_BOUNCE, world);
 143
 144         if (self.realowner.weapon == WEP_MINE_LAYER)
 145         {
 146                 entity oldself;
 147                 oldself = self;
 148                 self = self.realowner;
 149                 if (!WEP_ACTION(WEP_MINE_LAYER, WR_CHECKAMMO1))
 150                 {
 151                         self.cnt = WEP_MINE_LAYER;
 152                         ATTACK_FINISHED(self) = time;
 153                         self.switchweapon = w_getbestweapon(self);
 154                 }
 155                 self = oldself;
 156         }
 157         self.realowner.minelayer_mines -= 1;
 158         remove (self);
 159 }
 160
 161 void W_Mine_RemoteExplode ()
 162 {
 163         if(self.realowner.deadflag == DEAD_NO)
 164                 if((self.spawnshieldtime >= 0)
 165                         ? (time >= self.spawnshieldtime) // timer
 166                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > WEP_CVAR(minelayer, remote_radius)) // safety device
 167                 )
 168                 {
 169                         W_Mine_DoRemoteExplode();
 170                 }
 171 }
 172
 173 void W_Mine_ProximityExplode ()
 174 {
 175         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 176         if(WEP_CVAR(minelayer, protection) && self.mine_explodeanyway == 0)
 177         {
 178                 entity head;
 179                 head = findradius(self.origin, WEP_CVAR(minelayer, radius));
 180                 while(head)
 181                 {
 182                         if(head == self.realowner || SAME_TEAM(head, self.realowner))
 183                                 return;
 184                         head = head.chain;
 185                 }
 186         }
 187
 188         self.mine_time = 0;
 189         W_Mine_Explode();
 190 }
 191
 192 float W_Mine_Count(entity e)
 193 {
 194         float minecount = 0;
 195         entity mine;
 196         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == e)
 197                 minecount += 1;
 198
 199         return minecount;
 200 }
 201
 202 void W_Mine_Think (void)
 203 {
 204         entity head;
 205
 206         self.nextthink = time;
 207
 208         if(self.movetype == MOVETYPE_FOLLOW)
 209         {
 210                 if(LostMovetypeFollow(self))
 211                 {
 212                         UnsetMovetypeFollow(self);
 213                         self.movetype = MOVETYPE_NONE;
 214                 }
 215         }
 216
 217         // our lifetime has expired, it's time to die - mine_time just allows us to play a sound for this
 218         // TODO: replace this mine_trigger.wav sound with a real countdown
 219         if ((time > self.cnt) && (!self.mine_time))
 220         {
 221                 if(WEP_CVAR(minelayer, lifetime_countdown) > 0)
 222                         spamsound (self, CH_SHOTS, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 223                 self.mine_time = time + WEP_CVAR(minelayer, lifetime_countdown);
 224                 self.mine_explodeanyway = 1; // make the mine super aggressive -- Samual: Rather, make it not care if a team mate is near.
 225         }
 226
 227         // a player's mines shall explode if he disconnects or dies
 228         // TODO: Do this on team change too -- Samual: But isn't a player killed when they switch teams?
 229         if(!IS_PLAYER(self.realowner) || self.realowner.deadflag != DEAD_NO)
 230         {
 231                 other = world;
 232                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 233                 W_Mine_Explode();
 234                 return;
 235         }
 236
 237         // set the mine for detonation when a foe gets close enough
 238         head = findradius(self.origin, WEP_CVAR(minelayer, proximityradius));
 239         while(head)
 240         {
 241                 if(IS_PLAYER(head) && head.deadflag == DEAD_NO)
 242                 if(head != self.realowner && DIFF_TEAM(head, self.realowner)) // don't trigger for team mates
 243                 if(!self.mine_time)
 244                 {
 245                         spamsound (self, CH_SHOTS, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 246                         self.mine_time = time + WEP_CVAR(minelayer, time);
 247                 }
 248                 head = head.chain;
 249         }
 250
 251         // explode if it's time to
 252         if(self.mine_time && time >= self.mine_time)
 253         {
 254                 W_Mine_ProximityExplode();
 255                 return;
 256         }
 257
 258         // remote detonation
 259         if (self.realowner.weapon == WEP_MINE_LAYER)
 260         if (self.realowner.deadflag == DEAD_NO)
 261         if (self.minelayer_detonate)
 262                 W_Mine_RemoteExplode();
 263 }
 264
 265 void W_Mine_Touch (void)
 266 {
 267         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 268                 return; // we're already a stuck mine, why do we get called? TODO does this even happen?
 269
 270         if(WarpZone_Projectile_Touch())
 271         {
 272                 if(wasfreed(self))
 273                         self.realowner.minelayer_mines -= 1;
 274                 return;
 275         }
 276
 277         if(other && IS_PLAYER(other) && other.deadflag == DEAD_NO)
 278         {
 279                 // hit a player
 280                 // don't stick
 281         }
 282         else
 283         {
 284                 W_Mine_Stick(other);
 285         }
 286 }
 287
 288 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 289 {
 290         if (self.health <= 0)
 291                 return;
 292
 293         float is_from_enemy = (inflictor.realowner != self.realowner);
 294
 295         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, (is_from_enemy ? 1 : -1)))
 296                 return; // g_projectiles_damage says to halt
 297
 298         self.health = self.health - damage;
 299         self.angles = vectoangles(self.velocity);
 300
 301         if (self.health <= 0)
 302                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 303 }
 304
 305 void W_Mine_Attack (void)
 306 {
 307         entity mine;
 308         entity flash;
 309
 310         // scan how many mines we placed, and return if we reached our limit
 311         if(WEP_CVAR(minelayer, limit))
 312         {
 313                 if(self.minelayer_mines >= WEP_CVAR(minelayer, limit))
 314                 {
 315                         // the refire delay keeps this message from being spammed
 316                         sprint(self, strcat("minelayer: You cannot place more than ^2", ftos(WEP_CVAR(minelayer, limit)), " ^7mines at a time\n") );
 317                         play2(self, "weapons/unavailable.wav");
 318                         return;
 319                 }
 320         }
 321
 322         W_DecreaseAmmo(WEP_CVAR(minelayer, ammo));
 323
 324         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", CH_WEAPON_A, WEP_CVAR(minelayer, damage));
 325         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 326
 327         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 328         mine.owner = mine.realowner = self;
 329         if(WEP_CVAR(minelayer, detonatedelay) >= 0)
 330                 mine.spawnshieldtime = time + WEP_CVAR(minelayer, detonatedelay);
 331         else
 332                 mine.spawnshieldtime = -1;
 333         mine.classname = "mine";
 334         mine.bot_dodge = TRUE;
 335         mine.bot_dodgerating = WEP_CVAR(minelayer, damage) * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 336
 337         mine.takedamage = DAMAGE_YES;
 338         mine.damageforcescale = WEP_CVAR(minelayer, damageforcescale);
 339         mine.health = WEP_CVAR(minelayer, health);
 340         mine.event_damage = W_Mine_Damage;
 341         mine.damagedbycontents = TRUE;
 342
 343         mine.movetype = MOVETYPE_TOSS;
 344         PROJECTILE_MAKETRIGGER(mine);
 345         mine.projectiledeathtype = WEP_MINE_LAYER;
 346         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 347
 348         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 349         W_SetupProjectileVelocity(mine, WEP_CVAR(minelayer, speed), 0);
 350         mine.angles = vectoangles (mine.velocity);
 351
 352         mine.touch = W_Mine_Touch;
 353         mine.think = W_Mine_Think;
 354         mine.nextthink = time;
 355         mine.cnt = time + (WEP_CVAR(minelayer, lifetime) - WEP_CVAR(minelayer, lifetime_countdown));
 356         mine.flags = FL_PROJECTILE;
 357         mine.missile_flags = MIF_SPLASH | MIF_ARC | MIF_PROXY;
 358
 359         CSQCProjectile(mine, TRUE, PROJECTILE_MINE, TRUE);
 360
 361         // muzzle flash for 1st person view
 362         flash = spawn ();
 363         setmodel (flash, "models/flash.md3"); // precision set below
 364         SUB_SetFade (flash, time, 0.1);
 365         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 366         W_AttachToShotorg(flash, '5 0 0');
 367
 368         // common properties
 369
 370         other = mine; MUTATOR_CALLHOOK(EditProjectile);
 371
 372         self.minelayer_mines = W_Mine_Count(self);
 373 }
 374
 375 float W_PlacedMines(float detonate)
 376 {
 377         entity mine;
 378         float minfound = 0;
 379
 380         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == self)
 381         {
 382                 if(detonate)
 383                 {
 384                         if(!mine.minelayer_detonate)
 385                         {
 386                                 mine.minelayer_detonate = TRUE;
 387                                 minfound = 1;
 388                         }
 389                 }
 390                 else
 391                         minfound = 1;
 392         }
 393         return minfound;
 394 }
 395
 396 float w_minelayer(float req)
 397 {
 398         entity mine;
 399         float ammo_amount;
 400         switch(req)
 401         {
 402                 case WR_AIM:
 403                 {
 404                         // aim and decide to fire if appropriate
 405                         if(self.minelayer_mines >= WEP_CVAR(minelayer, limit))
 406                                 self.BUTTON_ATCK = FALSE;
 407                         else
 408                                 self.BUTTON_ATCK = bot_aim(WEP_CVAR(minelayer, speed), 0, WEP_CVAR(minelayer, lifetime), FALSE);
 409                         if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 410                         {
 411                                 // decide whether to detonate mines
 412                                 entity targetlist, targ;
 413                                 float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 414                                 float selfdamage, teamdamage, enemydamage;
 415                                 edgedamage = WEP_CVAR(minelayer, edgedamage);
 416                                 coredamage = WEP_CVAR(minelayer, damage);
 417                                 edgeradius = WEP_CVAR(minelayer, radius);
 418                                 recipricoledgeradius = 1 / edgeradius;
 419                                 selfdamage = 0;
 420                                 teamdamage = 0;
 421                                 enemydamage = 0;
 422                                 targetlist = findchainfloat(bot_attack, TRUE);
 423                                 mine = find(world, classname, "mine");
 424                                 while (mine)
 425                                 {
 426                                         if (mine.realowner != self)
 427                                         {
 428                                                 mine = find(mine, classname, "mine");
 429                                                 continue;
 430                                         }
 431                                         targ = targetlist;
 432                                         while (targ)
 433                                         {
 434                                                 d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 435                                                 d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 436                                                 // count potential damage according to type of target
 437                                                 if (targ == self)
 438                                                         selfdamage = selfdamage + d;
 439                                                 else if (targ.team == self.team && teamplay)
 440                                                         teamdamage = teamdamage + d;
 441                                                 else if (bot_shouldattack(targ))
 442                                                         enemydamage = enemydamage + d;
 443                                                 targ = targ.chain;
 444                                         }
 445                                         mine = find(mine, classname, "mine");
 446                                 }
 447                                 float desirabledamage;
 448                                 desirabledamage = enemydamage;
 449                                 if (time > self.invincible_finished && time > self.spawnshieldtime)
 450                                         desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 451                                 if (teamplay && self.team)
 452                                         desirabledamage = desirabledamage - teamdamage;
 453
 454                                 mine = find(world, classname, "mine");
 455                                 while (mine)
 456                                 {
 457                                         if (mine.realowner != self)
 458                                         {
 459                                                 mine = find(mine, classname, "mine");
 460                                                 continue;
 461                                         }
 462                                         makevectors(mine.v_angle);
 463                                         targ = targetlist;
 464                                         if (skill > 9) // normal players only do this for the target they are tracking
 465                                         {
 466                                                 targ = targetlist;
 467                                                 while (targ)
 468                                                 {
 469                                                         if (
 470                                                                 (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 471                                                                 && desirabledamage > 0.1*coredamage
 472                                                         )self.BUTTON_ATCK2 = TRUE;
 473                                                         targ = targ.chain;
 474                                                 }
 475                                         }else{
 476                                                 float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 477                                                 //As the distance gets larger, a correct detonation gets near imposible
 478                                                 //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 479                                                 if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 480                                                         if(IS_PLAYER(self.enemy))
 481                                                                 if(desirabledamage >= 0.1*coredamage)
 482                                                                         if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 483                                                                                 self.BUTTON_ATCK2 = TRUE;
 484                                         //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 485                                         }
 486
 487                                         mine = find(mine, classname, "mine");
 488                                 }
 489                                 // if we would be doing at X percent of the core damage, detonate it
 490                                 // but don't fire a new shot at the same time!
 491                                 if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 492                                         self.BUTTON_ATCK2 = TRUE;
 493                                 if ((skill > 6.5) && (selfdamage > self.health))
 494                                         self.BUTTON_ATCK2 = FALSE;
 495                                 //if(self.BUTTON_ATCK2 == TRUE)
 496                                 //      dprint(ftos(desirabledamage),"\n");
 497                                 if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 498                         }
 499
 500                         return TRUE;
 501                 }
 502                 case WR_THINK:
 503                 {
 504                         if(autocvar_g_balance_minelayer_reload_ammo && self.clip_load < WEP_CVAR(minelayer, ammo)) // forced reload
 505                         {
 506                                 // not if we're holding the minelayer without enough ammo, but can detonate existing mines
 507                                 if(!(W_PlacedMines(FALSE) && self.ammo_rockets < WEP_CVAR(minelayer, ammo)))
 508                                         WEP_ACTION(self.weapon, WR_RELOAD);
 509                         }
 510                         else if (self.BUTTON_ATCK)
 511                         {
 512                                 if(weapon_prepareattack(0, WEP_CVAR(minelayer, refire)))
 513                                 {
 514                                         W_Mine_Attack();
 515                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(minelayer, animtime), w_ready);
 516                                 }
 517                         }
 518
 519                         if (self.BUTTON_ATCK2)
 520                         {
 521                                 if(W_PlacedMines(TRUE))
 522                                         sound (self, CH_WEAPON_B, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 523                         }
 524
 525                         return TRUE;
 526                 }
 527                 case WR_INIT:
 528                 {
 529                         precache_model ("models/flash.md3");
 530                         precache_model ("models/mine.md3");
 531                         precache_model ("models/weapons/g_minelayer.md3");
 532                         precache_model ("models/weapons/v_minelayer.md3");
 533                         precache_model ("models/weapons/h_minelayer.iqm");
 534                         precache_sound ("weapons/mine_det.wav");
 535                         precache_sound ("weapons/mine_fire.wav");
 536                         precache_sound ("weapons/mine_stick.wav");
 537                         precache_sound ("weapons/mine_trigger.wav");
 538                         MINELAYER_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 539                         return TRUE;
 540                 }
 541                 case WR_SETUP:
 542                 {
 543                         self.current_ammo = ammo_rockets;
 544                         return TRUE;
 545                 }
 546                 case WR_CHECKAMMO1:
 547                 {
 548                         // don't switch while placing a mine
 549                         if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 550                         {
 551                                 ammo_amount = self.ammo_rockets >= WEP_CVAR(minelayer, ammo);
 552                                 ammo_amount += self.(weapon_load[WEP_MINE_LAYER]) >= WEP_CVAR(minelayer, ammo);
 553                                 return ammo_amount;
 554                         }
 555                         return TRUE;
 556                 }
 557                 case WR_CHECKAMMO2:
 558                 {
 559                         if (W_PlacedMines(FALSE))
 560                                 return TRUE;
 561                         else
 562                                 return FALSE;
 563                 }
 564                 case WR_CONFIG:
 565                 {
 566                         MINELAYER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 567                         return TRUE;
 568                 }
 569                 case WR_RESETPLAYER:
 570                 {
 571                         self.minelayer_mines = 0;
 572                         return TRUE;
 573                 }
 574                 case WR_RELOAD:
 575                 {
 576                         W_Reload(WEP_CVAR(minelayer, ammo), "weapons/reload.wav");
 577                         return TRUE;
 578                 }
 579                 case WR_SUICIDEMESSAGE:
 580                 {
 581                         return WEAPON_MINELAYER_SUICIDE;
 582                 }
 583                 case WR_KILLMESSAGE:
 584                 {
 585                         return WEAPON_MINELAYER_MURDER;
 586                 }
 587         }
 588         return TRUE;
 589 }
 590 #endif
 591 #ifdef CSQC
 592 float w_minelayer(float req)
 593 {
 594         switch(req)
 595         {
 596                 case WR_IMPACTEFFECT:
 597                 {
 598                         vector org2;
 599                         org2 = w_org + w_backoff * 12;
 600                         pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 601                         if(!w_issilent)
 602                                 sound(self, CH_SHOTS, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 603
 604                         return TRUE;
 605                 }
 606                 case WR_INIT:
 607                 {
 608                         precache_sound("weapons/mine_exp.wav");
 609                         return TRUE;
 610                 }
 611         }
 612         return TRUE;
 613 }
 614 #endif
 615 #endif