qcsrc/common/weapons/w_nex.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ NEX,
   4 /* function  */ w_nex,
   5 /* ammotype  */ IT_CELLS,
   6 /* impulse   */ 7,
   7 /* flags     */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN,
   8 /* rating    */ BOT_PICKUP_RATING_HIGH,
   9 /* model     */ "nex",
  10 /* shortname */ "nex",
  11 /* fullname  */ _("Nex")
  12 );
  13
  14 #define NEX_SETTINGS(weapon) \
  15         WEP_ADD_CVAR(weapon, MO_BOTH, ammo) \
  16         WEP_ADD_CVAR(weapon, MO_BOTH, animtime) \
  17         WEP_ADD_CVAR(weapon, MO_BOTH, damage) \
  18         WEP_ADD_CVAR(weapon, MO_BOTH, force) \
  19         WEP_ADD_CVAR(weapon, MO_BOTH, damagefalloff_mindist) \
  20         WEP_ADD_CVAR(weapon, MO_BOTH, damagefalloff_maxdist) \
  21         WEP_ADD_CVAR(weapon, MO_BOTH, damagefalloff_halflife) \
  22         WEP_ADD_CVAR(weapon, MO_BOTH, damagefalloff_forcehalflife) \
  23         WEP_ADD_CVAR(weapon, MO_BOTH, ammo) \
  24         WEP_ADD_CVAR(weapon, MO_BOTH, refire) \
  25         WEP_ADD_CVAR(weapon, MO_NONE, charge) \
  26         WEP_ADD_CVAR(weapon, MO_NONE, charge_mindmg) \
  27         WEP_ADD_CVAR(weapon, MO_NONE, charge_shot_multiplier) \
  28         WEP_ADD_CVAR(weapon, MO_NONE, charge_animlimit) \
  29         WEP_ADD_CVAR(weapon, MO_NONE, charge_limit) \
  30         WEP_ADD_CVAR(weapon, MO_NONE, charge_rate) \
  31         WEP_ADD_CVAR(weapon, MO_NONE, charge_rot_rate) \
  32         WEP_ADD_CVAR(weapon, MO_NONE, charge_rot_pause) \
  33         WEP_ADD_CVAR(weapon, MO_NONE, charge_start) \
  34         WEP_ADD_CVAR(weapon, MO_NONE, charge_minspeed) \
  35         WEP_ADD_CVAR(weapon, MO_NONE, charge_maxspeed) \
  36         WEP_ADD_CVAR(weapon, MO_NONE, charge_velocity_rate) \
  37         WEP_ADD_CVAR(weapon, MO_SEC,  chargepool) \
  38         WEP_ADD_CVAR(weapon, MO_SEC,  chargepool_regen) \
  39         WEP_ADD_CVAR(weapon, MO_SEC,  chargepool_pause_regen) \
  40         WEP_ADD_PROP(weapon, reloading_ammo, reload_ammo) \
  41         WEP_ADD_PROP(weapon, reloading_time, reload_time) \
  42         WEP_ADD_PROP(weapon, switchdelay_raise, switchdelay_raise) \
  43         WEP_ADD_PROP(weapon, switchdelay_drop, switchdelay_drop)
  44
  45 #ifdef SVQC
  46 NEX_SETTINGS(nex)
  47 void spawnfunc_weapon_nex (void) { weapon_defaultspawnfunc(WEP_NEX); }
  48 #endif
  49 #else
  50 #ifdef SVQC
  51
  52 void SendCSQCNexBeamParticle(float charge) {
  53         vector v;
  54         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
  55         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  56         WriteByte(MSG_BROADCAST, TE_CSQC_NEXGUNBEAMPARTICLE);
  57         WriteCoord(MSG_BROADCAST, w_shotorg_x);
  58         WriteCoord(MSG_BROADCAST, w_shotorg_y);
  59         WriteCoord(MSG_BROADCAST, w_shotorg_z);
  60         WriteCoord(MSG_BROADCAST, v_x);
  61         WriteCoord(MSG_BROADCAST, v_y);
  62         WriteCoord(MSG_BROADCAST, v_z);
  63         WriteByte(MSG_BROADCAST, bound(0, 255 * charge, 255));
  64 }
  65
  66 void W_Nex_Attack (float issecondary)
  67 {
  68         float mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, myammo, charge;
  69
  70         mydmg = WEP_CVAR_BOTH(nex, !issecondary, damage);
  71         myforce = WEP_CVAR_BOTH(nex, !issecondary, force);
  72         mymindist = WEP_CVAR_BOTH(nex, !issecondary, damagefalloff_mindist);
  73         mymaxdist = WEP_CVAR_BOTH(nex, !issecondary, damagefalloff_maxdist);
  74         myhalflife = WEP_CVAR_BOTH(nex, !issecondary, damagefalloff_halflife);
  75         myforcehalflife = WEP_CVAR_BOTH(nex, !issecondary, damagefalloff_forcehalflife);
  76         myammo = WEP_CVAR_BOTH(nex, !issecondary, ammo);
  77
  78         float flying;
  79         flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
  80
  81         if(WEP_CVAR(nex, charge))
  82         {
  83                 charge = WEP_CVAR(nex, charge_mindmg) / mydmg + (1 - WEP_CVAR(nex, charge_mindmg) / mydmg) * self.nex_charge;
  84                 self.nex_charge *= WEP_CVAR(nex, charge_shot_multiplier); // do this AFTER setting mydmg/myforce
  85                 // O RLY? -- divVerent
  86                 // YA RLY -- FruitieX
  87         }
  88         else
  89                 charge = 1;
  90         mydmg *= charge;
  91         myforce *= charge;
  92
  93         W_SetupShot (self, TRUE, 5, "weapons/nexfire.wav", CH_WEAPON_A, mydmg);
  94         if(charge > WEP_CVAR(nex, charge_animlimit) && WEP_CVAR(nex, charge_animlimit)) // if the Nex is overcharged, we play an extra sound
  95         {
  96                 sound (self, CH_WEAPON_B, "weapons/nexcharge.wav", VOL_BASE * (charge - 0.5 * WEP_CVAR(nex, charge_animlimit)) / (1 - 0.5 * WEP_CVAR(nex, charge_animlimit)), ATTN_NORM);
  97         }
  98
  99         yoda = 0;
 100         FireRailgunBullet (w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, WEP_NEX);
 101
 102         if(yoda && flying)
 103                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_ACHIEVEMENT_YODA);
 104
 105         //beam and muzzle flash done on client
 106         SendCSQCNexBeamParticle(charge);
 107
 108         W_DecreaseAmmo(ammo_cells, myammo, autocvar_g_balance_nex_reload_ammo);
 109 }
 110
 111 void spawnfunc_weapon_nex (void); // defined in t_items.qc
 112
 113 .float nex_chargepool_pauseregen_finished;
 114 float w_nex(float req)
 115 {
 116         float dt;
 117         float ammo_amount;
 118         switch(req)
 119         {
 120                 case WR_AIM:
 121                 {
 122                         if(bot_aim(1000000, 0, 1, FALSE))
 123                                 self.BUTTON_ATCK = TRUE;
 124                         else
 125                         {
 126                                 if(WEP_CVAR(nex, charge))
 127                                         self.BUTTON_ATCK2 = TRUE;
 128                         }
 129                         return TRUE;
 130                 }
 131                 case WR_THINK:
 132                 {
 133                         if(WEP_CVAR(nex, charge) && self.nex_charge < WEP_CVAR(nex, charge_limit))
 134                                 self.nex_charge = min(1, self.nex_charge + WEP_CVAR(nex, charge_rate) * frametime / W_TICSPERFRAME);
 135
 136                         if(WEP_CVAR_SEC(nex, chargepool))
 137                                 if(self.nex_chargepool_ammo < 1)
 138                                 {
 139                                         if(self.nex_chargepool_pauseregen_finished < time)
 140                                                 self.nex_chargepool_ammo = min(1, self.nex_chargepool_ammo + WEP_CVAR_SEC(nex, chargepool_regen) * frametime / W_TICSPERFRAME);
 141                                         self.pauseregen_finished = max(self.pauseregen_finished, time + WEP_CVAR_SEC(nex, chargepool_pause_regen));
 142                                 }
 143
 144                         if(autocvar_g_balance_nex_reload_ammo && self.clip_load < min(autocvar_g_balance_nex_primary_ammo, autocvar_g_balance_nex_secondary_ammo)) // forced reload
 145                                 WEP_ACTION(self.weapon, WR_RELOAD);
 146                         else
 147                         {
 148                                 if (self.BUTTON_ATCK)
 149                                 {
 150                                         if (weapon_prepareattack(0, WEP_CVAR_PRI(nex, refire)))
 151                                         {
 152                                                 W_Nex_Attack(0);
 153                                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(nex, animtime), w_ready);
 154                                         }
 155                                 }
 156                                 if ((WEP_CVAR(nex, charge) && !autocvar_g_balance_nex_secondary) ? (self.BUTTON_ZOOM | self.BUTTON_ZOOMSCRIPT) : self.BUTTON_ATCK2)
 157                                 {
 158                                         if(WEP_CVAR(nex, charge))
 159                                         {
 160                                                 self.nex_charge_rottime = time + WEP_CVAR(nex, charge_rot_pause);
 161                                                 dt = frametime / W_TICSPERFRAME;
 162
 163                                                 if(self.nex_charge < 1)
 164                                                 {
 165                                                         if(WEP_CVAR_SEC(nex, chargepool))
 166                                                         {
 167                                                                 if(WEP_CVAR_SEC(nex, ammo))
 168                                                                 {
 169                                                                         // always deplete if secondary is held
 170                                                                         self.nex_chargepool_ammo = max(0, self.nex_chargepool_ammo - WEP_CVAR_SEC(nex, ammo) * dt);
 171
 172                                                                         dt = min(dt, (1 - self.nex_charge) / WEP_CVAR(nex, charge_rate));
 173                                                                         self.nex_chargepool_pauseregen_finished = time + WEP_CVAR_SEC(nex, chargepool_pause_regen);
 174                                                                         dt = min(dt, self.nex_chargepool_ammo);
 175                                                                         dt = max(0, dt);
 176
 177                                                                         self.nex_charge += dt * WEP_CVAR(nex, charge_rate);
 178                                                                 }
 179                                                         }
 180
 181                                                         else if(WEP_CVAR_SEC(nex, ammo))
 182                                                         {
 183                                                                 if(self.BUTTON_ATCK2) // only eat ammo when the button is pressed
 184                                                                 {
 185                                                                         dt = min(dt, (1 - self.nex_charge) / WEP_CVAR(nex, charge_rate));
 186                                                                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 187                                                                         {
 188                                                                                 // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 189                                                                                 if(autocvar_g_balance_nex_reload_ammo)
 190                                                                                 {
 191                                                                                         dt = min(dt, (self.clip_load - WEP_CVAR_PRI(nex, ammo)) / WEP_CVAR_SEC(nex, ammo));
 192                                                                                         dt = max(0, dt);
 193                                                                                         if(dt > 0)
 194                                                                                         {
 195                                                                                                 self.clip_load = max(WEP_CVAR_SEC(nex, ammo), self.clip_load - WEP_CVAR_SEC(nex, ammo) * dt);
 196                                                                                         }
 197                                                                                         self.(weapon_load[WEP_NEX]) = self.clip_load;
 198                                                                                 }
 199                                                                                 else
 200                                                                                 {
 201                                                                                         dt = min(dt, (self.ammo_cells - WEP_CVAR_PRI(nex, ammo)) / WEP_CVAR_SEC(nex, ammo));
 202                                                                                         dt = max(0, dt);
 203                                                                                         if(dt > 0)
 204                                                                                         {
 205                                                                                                 self.ammo_cells = max(WEP_CVAR_SEC(nex, ammo), self.ammo_cells - WEP_CVAR_SEC(nex, ammo) * dt);
 206                                                                                         }
 207                                                                                 }
 208                                                                         }
 209                                                                         self.nex_charge += dt * WEP_CVAR(nex, charge_rate);
 210                                                                 }
 211                                                         }
 212
 213                                                         else
 214                                                         {
 215                                                                 dt = min(dt, (1 - self.nex_charge) / WEP_CVAR(nex, charge_rate));
 216                                                                 self.nex_charge += dt * WEP_CVAR(nex, charge_rate);
 217                                                         }
 218                                                 }
 219                                         }
 220                                         else if(autocvar_g_balance_nex_secondary)
 221                                         {
 222                                                 if (weapon_prepareattack(0, WEP_CVAR_SEC(nex, refire)))
 223                                                 {
 224                                                         W_Nex_Attack(1);
 225                                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_SEC(nex, animtime), w_ready);
 226                                                 }
 227                                         }
 228                                 }
 229                         }
 230
 231                         return TRUE;
 232                 }
 233                 case WR_PRECACHE:
 234                 {
 235                         precache_model ("models/nexflash.md3");
 236                         precache_model ("models/weapons/g_nex.md3");
 237                         precache_model ("models/weapons/v_nex.md3");
 238                         precache_model ("models/weapons/h_nex.iqm");
 239                         precache_sound ("weapons/nexfire.wav");
 240                         precache_sound ("weapons/nexcharge.wav");
 241                         precache_sound ("weapons/nexwhoosh1.wav");
 242                         precache_sound ("weapons/nexwhoosh2.wav");
 243                         precache_sound ("weapons/nexwhoosh3.wav");
 244                         #define WEP_ADD_CVAR(weapon,mode,name) /*nothing*/
 245                         #define WEP_ADD_PROP(weapon,prop,name) WEP_SET_PROP(WEP_NEX,weapon,prop,name)
 246                         NEX_SETTINGS(nex)
 247                         #undef WEP_ADD_CVAR
 248                         #undef WEP_ADD_PROP
 249                         return TRUE;
 250                 }
 251                 case WR_SETUP:
 252                 {
 253                         weapon_setup(WEP_NEX);
 254                         self.current_ammo = ammo_cells;
 255                         return TRUE;
 256                 }
 257                 case WR_CHECKAMMO1:
 258                 {
 259                         ammo_amount = self.ammo_cells >= WEP_CVAR_PRI(nex, ammo);
 260                         ammo_amount += (autocvar_g_balance_nex_reload_ammo && self.(weapon_load[WEP_NEX]) >= WEP_CVAR_PRI(nex, ammo));
 261                         return ammo_amount;
 262                 }
 263                 case WR_CHECKAMMO2:
 264                 {
 265                         if(autocvar_g_balance_nex_secondary)
 266                         {
 267                                 // don't allow charging if we don't have enough ammo
 268                                 ammo_amount = self.ammo_cells >= WEP_CVAR_SEC(nex, ammo);
 269                                 ammo_amount += self.(weapon_load[WEP_NEX]) >= WEP_CVAR_SEC(nex, ammo);
 270                                 return ammo_amount;
 271                         }
 272                         else
 273                         {
 274                                 return FALSE; // zoom is not a fire mode
 275                         }
 276                 }
 277                 case WR_RELOAD:
 278                 {
 279                         W_Reload(min(WEP_CVAR_PRI(nex, ammo), WEP_CVAR_SEC(nex, ammo)), autocvar_g_balance_nex_reload_ammo, autocvar_g_balance_nex_reload_time, "weapons/reload.wav");
 280                         return TRUE;
 281                 }
 282                 case WR_SUICIDEMESSAGE:
 283                 {
 284                         return WEAPON_THINKING_WITH_PORTALS;
 285                 }
 286                 case WR_KILLMESSAGE:
 287                 {
 288                         return WEAPON_NEX_MURDER;
 289                 }
 290         }
 291         return TRUE;
 292 }
 293 #endif
 294 #ifdef CSQC
 295 float w_nex(float req)
 296 {
 297         switch(req)
 298         {
 299                 case WR_IMPACTEFFECT:
 300                 {
 301                         vector org2;
 302                         org2 = w_org + w_backoff * 6;
 303                         pointparticles(particleeffectnum("nex_impact"), org2, '0 0 0', 1);
 304                         if(!w_issilent)
 305                                 sound(self, CH_SHOTS, "weapons/neximpact.wav", VOL_BASE, ATTN_NORM);
 306
 307                         return TRUE;
 308                 }
 309                 case WR_PRECACHE:
 310                 {
 311                         precache_sound("weapons/neximpact.wav");
 312                         return TRUE;
 313                 }
 314         }
 315         return TRUE;
 316 }
 317 #endif
 318 #endif