qcsrc/common/weapons/w_rifle.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ RIFLE,
   4 /* function */ W_Rifle,
   5 /* ammotype */ ammo_nails,
   6 /* impulse  */ 7,
   7 /* flags    */ WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN,
   8 /* rating   */ BOT_PICKUP_RATING_MID,
   9 /* model    */ "campingrifle",
  10 /* netname  */ "rifle",
  11 /* fullname */ _("Rifle")
  12 );
  13
  14 #define RIFLE_SETTINGS(w_cvar,w_prop) RIFLE_SETTINGS_LIST(w_cvar, w_prop, RIFLE, rifle)
  15 #define RIFLE_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  16         w_cvar(id, sn, BOTH, ammo) \
  17         w_cvar(id, sn, BOTH, animtime) \
  18         w_cvar(id, sn, BOTH, bullethail) \
  19         w_cvar(id, sn, BOTH, burstcost) \
  20         w_cvar(id, sn, BOTH, damage) \
  21         w_cvar(id, sn, BOTH, force) \
  22         w_cvar(id, sn, BOTH, refire) \
  23         w_cvar(id, sn, BOTH, shots) \
  24         w_cvar(id, sn, BOTH, solidpenetration) \
  25         w_cvar(id, sn, BOTH, spread) \
  26         w_cvar(id, sn, BOTH, tracer) \
  27         w_cvar(id, sn, NONE, bursttime) \
  28         w_cvar(id, sn, NONE, secondary) \
  29         w_cvar(id, sn, SEC,  reload) \
  30         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  31         w_prop(id, sn, float,  reloading_time, reload_time) \
  32         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  33         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  34         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  35         w_prop(id, sn, float,  weaponstart, weaponstart) \
  36         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  37
  38 #ifdef SVQC
  39 RIFLE_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  40 .float rifle_accumulator;
  41 #endif
  42 #else
  43 #ifdef SVQC
  44 void spawnfunc_weapon_rifle (void) { weapon_defaultspawnfunc(WEP_RIFLE); }
  45 void spawnfunc_weapon_campingrifle (void) { spawnfunc_weapon_rifle(); }
  46 void spawnfunc_weapon_sniperrifle (void) { spawnfunc_weapon_rifle(); }
  47
  48 void W_Rifle_FireBullet(float pSpread, float pDamage, float pForce, float pSolidPenetration, float pAmmo, float deathtype, float pTracer, float pShots, string pSound)
  49 {
  50         float i;
  51
  52         W_DecreaseAmmo(pAmmo);
  53
  54         W_SetupShot (self, TRUE, 2, pSound, CH_WEAPON_A, pDamage * pShots);
  55
  56         pointparticles(particleeffectnum("rifle_muzzleflash"), w_shotorg, w_shotdir * 2000, 1);
  57
  58         if(self.BUTTON_ZOOM | self.BUTTON_ZOOMSCRIPT) // if zoomed, shoot from the eye
  59         {
  60                 w_shotdir = v_forward;
  61                 w_shotorg = self.origin + self.view_ofs + ((w_shotorg - self.origin - self.view_ofs) * v_forward) * v_forward;
  62         }
  63
  64         for(i = 0; i < pShots; ++i)
  65                 fireBullet(w_shotorg, w_shotdir, pSpread, pSolidPenetration, pDamage, pForce, deathtype, (pTracer ? EF_RED : EF_BLUE));
  66
  67         if (autocvar_g_casings >= 2)
  68                 SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, self);
  69 }
  70
  71 void W_Rifle_Attack()
  72 {
  73         W_Rifle_FireBullet(WEP_CVAR_PRI(rifle, spread), WEP_CVAR_PRI(rifle, damage), WEP_CVAR_PRI(rifle, force), WEP_CVAR_PRI(rifle, solidpenetration), WEP_CVAR_PRI(rifle, ammo), WEP_RIFLE, WEP_CVAR_PRI(rifle, tracer), WEP_CVAR_PRI(rifle, shots), "weapons/campingrifle_fire.wav");
  74 }
  75
  76 void W_Rifle_Attack2()
  77 {
  78         W_Rifle_FireBullet(WEP_CVAR_SEC(rifle, spread), WEP_CVAR_SEC(rifle, damage), WEP_CVAR_SEC(rifle, force), WEP_CVAR_SEC(rifle, solidpenetration), WEP_CVAR_SEC(rifle, ammo), WEP_RIFLE | HITTYPE_SECONDARY, WEP_CVAR_SEC(rifle, tracer), WEP_CVAR_SEC(rifle, shots), "weapons/campingrifle_fire2.wav");
  79 }
  80
  81 .void(void) rifle_bullethail_attackfunc;
  82 .float rifle_bullethail_frame;
  83 .float rifle_bullethail_animtime;
  84 .float rifle_bullethail_refire;
  85 void W_Rifle_BulletHail_Continue()
  86 {
  87         float r, sw, af;
  88
  89         sw = self.switchweapon; // make it not detect weapon changes as reason to abort firing
  90         af = ATTACK_FINISHED(self);
  91         self.switchweapon = self.weapon;
  92         ATTACK_FINISHED(self) = time;
  93         print(ftos(self.AMMO_VAL(WEP_RIFLE)), "\n");
  94         r = weapon_prepareattack(self.rifle_bullethail_frame == WFRAME_FIRE2, self.rifle_bullethail_refire);
  95         if(self.switchweapon == self.weapon)
  96                 self.switchweapon = sw;
  97         if(r)
  98         {
  99                 self.rifle_bullethail_attackfunc();
 100                 weapon_thinkf(self.rifle_bullethail_frame, self.rifle_bullethail_animtime, W_Rifle_BulletHail_Continue);
 101                 print("thinkf set\n");
 102         }
 103         else
 104         {
 105                 ATTACK_FINISHED(self) = af; // reset attack_finished if we didn't fire, so the last shot enforces the refire time
 106                 print("out of ammo... ", ftos(self.weaponentity.state), "\n");
 107         }
 108 }
 109
 110 void W_Rifle_BulletHail(float mode, void(void) AttackFunc, float fr, float animtime, float refire)
 111 {
 112         // if we get here, we have at least one bullet to fire
 113         AttackFunc();
 114         if(mode)
 115         {
 116                 // continue hail
 117                 self.rifle_bullethail_attackfunc = AttackFunc;
 118                 self.rifle_bullethail_frame = fr;
 119                 self.rifle_bullethail_animtime = animtime;
 120                 self.rifle_bullethail_refire = refire;
 121                 weapon_thinkf(fr, animtime, W_Rifle_BulletHail_Continue);
 122         }
 123         else
 124         {
 125                 // just one shot
 126                 weapon_thinkf(fr, animtime, w_ready);
 127         }
 128 }
 129
 130 .float bot_secondary_riflemooth;
 131 float W_Rifle(float req)
 132 {
 133         float ammo_amount;
 134
 135         switch(req)
 136         {
 137                 case WR_AIM:
 138                 {
 139                         self.BUTTON_ATCK=FALSE;
 140                         self.BUTTON_ATCK2=FALSE;
 141                         if(vlen(self.origin-self.enemy.origin) > 1000)
 142                                 self.bot_secondary_riflemooth = 0;
 143                         if(self.bot_secondary_riflemooth == 0)
 144                         {
 145                                 if(bot_aim(1000000, 0, 0.001, FALSE))
 146                                 {
 147                                         self.BUTTON_ATCK = TRUE;
 148                                         if(random() < 0.01) self.bot_secondary_riflemooth = 1;
 149                                 }
 150                         }
 151                         else
 152                         {
 153                                 if(bot_aim(1000000, 0, 0.001, FALSE))
 154                                 {
 155                                         self.BUTTON_ATCK2 = TRUE;
 156                                         if(random() < 0.03) self.bot_secondary_riflemooth = 0;
 157                                 }
 158                         }
 159
 160                         return TRUE;
 161                 }
 162                 case WR_THINK:
 163                 {
 164                         if(autocvar_g_balance_rifle_reload_ammo && self.clip_load < min(WEP_CVAR_PRI(rifle, ammo), WEP_CVAR_SEC(rifle, ammo))) // forced reload
 165                                 WEP_ACTION(self.weapon, WR_RELOAD);
 166                         else
 167                         {
 168                                 self.rifle_accumulator = bound(time - WEP_CVAR(rifle, bursttime), self.rifle_accumulator, time);
 169                                 if (self.BUTTON_ATCK)
 170                                 if (weapon_prepareattack_check(0, WEP_CVAR_PRI(rifle, refire)))
 171                                 if (time >= self.rifle_accumulator + WEP_CVAR_PRI(rifle, burstcost))
 172                                 {
 173                                         weapon_prepareattack_do(0, WEP_CVAR_PRI(rifle, refire));
 174                                         W_Rifle_BulletHail(WEP_CVAR_PRI(rifle, bullethail), W_Rifle_Attack, WFRAME_FIRE1, WEP_CVAR_PRI(rifle, animtime), WEP_CVAR_PRI(rifle, refire));
 175                                         self.rifle_accumulator += WEP_CVAR_PRI(rifle, burstcost);
 176                                 }
 177                                 if (self.BUTTON_ATCK2)
 178                                 {
 179                                         if (WEP_CVAR(rifle, secondary))
 180                                         {
 181                                                 if(WEP_CVAR_SEC(rifle, reload))
 182                                                         WEP_ACTION(self.weapon, WR_RELOAD);
 183                                                 else
 184                                                 {
 185                                                         if (weapon_prepareattack_check(1, WEP_CVAR_SEC(rifle, refire)))
 186                                                         if (time >= self.rifle_accumulator + WEP_CVAR_SEC(rifle, burstcost))
 187                                                         {
 188                                                                 weapon_prepareattack_do(1, WEP_CVAR_SEC(rifle, refire));
 189                                                                 W_Rifle_BulletHail(WEP_CVAR_SEC(rifle, bullethail), W_Rifle_Attack2, WFRAME_FIRE2, WEP_CVAR_SEC(rifle, animtime), WEP_CVAR_PRI(rifle, refire));
 190                                                                 self.rifle_accumulator += WEP_CVAR_SEC(rifle, burstcost);
 191                                                         }
 192                                                 }
 193                                         }
 194                                 }
 195                         }
 196
 197                         return TRUE;
 198                 }
 199                 case WR_INIT:
 200                 {
 201                         precache_model ("models/weapons/g_campingrifle.md3");
 202                         precache_model ("models/weapons/v_campingrifle.md3");
 203                         precache_model ("models/weapons/h_campingrifle.iqm");
 204                         precache_sound ("weapons/campingrifle_fire.wav");
 205                         precache_sound ("weapons/campingrifle_fire2.wav");
 206                         RIFLE_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 207                         return TRUE;
 208                 }
 209                 case WR_CHECKAMMO1:
 210                 {
 211                         ammo_amount = self.AMMO_VAL(WEP_RIFLE) >= WEP_CVAR_PRI(rifle, ammo);
 212                         ammo_amount += self.(weapon_load[WEP_RIFLE]) >= WEP_CVAR_PRI(rifle, ammo);
 213                         return ammo_amount;
 214                 }
 215                 case WR_CHECKAMMO2:
 216                 {
 217                         ammo_amount = self.AMMO_VAL(WEP_RIFLE) >= WEP_CVAR_SEC(rifle, ammo);
 218                         ammo_amount += self.(weapon_load[WEP_RIFLE]) >= WEP_CVAR_SEC(rifle, ammo);
 219                         return ammo_amount;
 220                 }
 221                 case WR_CONFIG:
 222                 {
 223                         RIFLE_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 224                         return TRUE;
 225                 }
 226                 case WR_RESETPLAYER:
 227                 {
 228                         self.rifle_accumulator = time - WEP_CVAR(rifle, bursttime);
 229                         return TRUE;
 230                 }
 231                 case WR_RELOAD:
 232                 {
 233                         W_Reload(min(WEP_CVAR_PRI(rifle, ammo), WEP_CVAR_SEC(rifle, ammo)), "weapons/reload.wav");
 234                         return TRUE;
 235                 }
 236                 case WR_SUICIDEMESSAGE:
 237                 {
 238                         return WEAPON_THINKING_WITH_PORTALS;
 239                 }
 240                 case WR_KILLMESSAGE:
 241                 {
 242                         if(w_deathtype & HITTYPE_SECONDARY)
 243                         {
 244                                 if(w_deathtype & HITTYPE_BOUNCE)
 245                                         return WEAPON_RIFLE_MURDER_HAIL_PIERCING;
 246                                 else
 247                                         return WEAPON_RIFLE_MURDER_HAIL;
 248                         }
 249                         else
 250                         {
 251                                 if(w_deathtype & HITTYPE_BOUNCE)
 252                                         return WEAPON_RIFLE_MURDER_PIERCING;
 253                                 else
 254                                         return WEAPON_RIFLE_MURDER;
 255                         }
 256                 }
 257         }
 258         return TRUE;
 259 }
 260 #endif
 261 #ifdef CSQC
 262 float W_Rifle(float req)
 263 {
 264         switch(req)
 265         {
 266                 case WR_IMPACTEFFECT:
 267                 {
 268                         vector org2;
 269                         org2 = w_org + w_backoff * 2;
 270                         pointparticles(particleeffectnum("machinegun_impact"), org2, w_backoff * 1000, 1);
 271                         if(!w_issilent)
 272                         {
 273                                 if(w_random < 0.2)
 274                                         sound(self, CH_SHOTS, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 275                                 else if(w_random < 0.4)
 276                                         sound(self, CH_SHOTS, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 277                                 else if(w_random < 0.5)
 278                                         sound(self, CH_SHOTS, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 279                         }
 280
 281                         return TRUE;
 282                 }
 283                 case WR_INIT:
 284                 {
 285                         precache_sound("weapons/ric1.wav");
 286                         precache_sound("weapons/ric2.wav");
 287                         precache_sound("weapons/ric3.wav");
 288                         return TRUE;
 289                 }
 290         }
 291
 292         return TRUE;
 293 }
 294 #endif
 295 #endif