qcsrc/common/weapons/w_shockwave.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ SHOTGUN,
   4 /* function */ w_shotgun,
   5 /* ammotype */ IT_SHELLS,
   6 /* impulse  */ 2,
   7 /* flags    */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN,
   8 /* rating   */ BOT_PICKUP_RATING_LOW,
   9 /* model    */ "shotgun",
  10 /* netname  */ "shotgun",
  11 /* fullname */ _("Shotgun")
  12 );
  13 #else
  14 #ifdef SVQC
  15 void spawnfunc_weapon_shotgun()
  16 {
  17         if(autocvar_sv_q3acompat_machineshotgunswap)
  18         if(self.classname != "droppedweapon")
  19         {
  20                 weapon_defaultspawnfunc(WEP_UZI);
  21                 return;
  22         }
  23         weapon_defaultspawnfunc(WEP_SHOTGUN);
  24 }
  25
  26
  27 void W_Shotgun_Attack (void)
  28 {
  29         float   sc;
  30         float   ammoamount;
  31         float   bullets;
  32         float   d;
  33         float   f;
  34         float   spread;
  35         float   bulletspeed;
  36         float   bulletconstant;
  37         entity flash;
  38
  39         ammoamount = autocvar_g_balance_shotgun_primary_ammo;
  40         bullets = autocvar_g_balance_shotgun_primary_bullets;
  41         d = autocvar_g_balance_shotgun_primary_damage;
  42         f = autocvar_g_balance_shotgun_primary_force;
  43         spread = autocvar_g_balance_shotgun_primary_spread;
  44         bulletspeed = autocvar_g_balance_shotgun_primary_speed;
  45         bulletconstant = autocvar_g_balance_shotgun_primary_bulletconstant;
  46
  47         W_DecreaseAmmo(ammo_shells, ammoamount, autocvar_g_balance_shotgun_reload_ammo);
  48
  49         W_SetupShot (self, autocvar_g_antilag_bullets && bulletspeed >= autocvar_g_antilag_bullets, 5, "weapons/shotgun_fire.wav", CH_WEAPON_A, d * bullets);
  50         for (sc = 0;sc < bullets;sc = sc + 1)
  51                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, f, WEP_SHOTGUN, 0, 1, bulletconstant);
  52         endFireBallisticBullet();
  53
  54         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, autocvar_g_balance_shotgun_primary_ammo);
  55
  56         // casing code
  57         if (autocvar_g_casings >= 1)
  58                 for (sc = 0;sc < ammoamount;sc = sc + 1)
  59                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
  60
  61         // muzzle flash for 1st person view
  62         flash = spawn();
  63         setmodel(flash, "models/uziflash.md3"); // precision set below
  64         flash.think = SUB_Remove;
  65         flash.nextthink = time + 0.06;
  66         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  67         W_AttachToShotorg(flash, '5 0 0');
  68 }
  69
  70 .float swing_prev;
  71 .entity swing_alreadyhit;
  72 void shotgun_meleethink (void)
  73 {
  74         // declarations
  75         float i, f, swing, swing_factor, swing_damage, meleetime, is_player;
  76         entity target_victim;
  77         vector targpos;
  78
  79         if(!self.cnt) // set start time of melee
  80         {
  81                 self.cnt = time;
  82                 W_PlayStrengthSound(self.realowner);
  83         }
  84
  85         makevectors(self.realowner.v_angle); // update values for v_* vectors
  86
  87         // calculate swing percentage based on time
  88         meleetime = autocvar_g_balance_shotgun_secondary_melee_time * W_WeaponRateFactor();
  89         swing = bound(0, (self.cnt + meleetime - time) / meleetime, 10);
  90         f = ((1 - swing) * autocvar_g_balance_shotgun_secondary_melee_traces);
  91
  92         // check to see if we can still continue, otherwise give up now
  93         if((self.realowner.deadflag != DEAD_NO) && autocvar_g_balance_shotgun_secondary_melee_no_doubleslap)
  94         {
  95                 remove(self);
  96                 return;
  97         }
  98
  99         // if okay, perform the traces needed for this frame
 100         for(i=self.swing_prev; i < f; ++i)
 101         {
 102                 swing_factor = ((1 - (i / autocvar_g_balance_shotgun_secondary_melee_traces)) * 2 - 1);
 103
 104                 targpos = (self.realowner.origin + self.realowner.view_ofs
 105                         + (v_forward * autocvar_g_balance_shotgun_secondary_melee_range)
 106                         + (v_up * swing_factor * autocvar_g_balance_shotgun_secondary_melee_swing_up)
 107                         + (v_right * swing_factor * autocvar_g_balance_shotgun_secondary_melee_swing_side));
 108
 109                 WarpZone_traceline_antilag(self, self.realowner.origin + self.realowner.view_ofs, targpos, FALSE, self, ANTILAG_LATENCY(self.realowner));
 110
 111                 // draw lightning beams for debugging
 112                 //te_lightning2(world, targpos, self.realowner.origin + self.realowner.view_ofs + v_forward * 5 - v_up * 5);
 113                 //te_customflash(targpos, 40,  2, '1 1 1');
 114
 115                 is_player = (IS_PLAYER(trace_ent) || trace_ent.classname == "body");
 116
 117                 if((trace_fraction < 1) // if trace is good, apply the damage and remove self
 118                         && (trace_ent.takedamage == DAMAGE_AIM)
 119                         && (trace_ent != self.swing_alreadyhit)
 120                         && (is_player || autocvar_g_balance_shotgun_secondary_melee_nonplayerdamage))
 121                 {
 122                         target_victim = trace_ent; // so it persists through other calls
 123
 124                         if(is_player) // this allows us to be able to nerf the non-player damage done in e.g. assault or onslaught.
 125                                 swing_damage = (autocvar_g_balance_shotgun_secondary_damage * min(1, swing_factor + 1));
 126                         else
 127                                 swing_damage = (autocvar_g_balance_shotgun_secondary_melee_nonplayerdamage * min(1, swing_factor + 1));
 128
 129                         //print(strcat(self.realowner.netname, " hitting ", target_victim.netname, " with ", strcat(ftos(swing_damage), " damage (factor: ", ftos(swing_factor), ") at "), ftos(time), " seconds.\n"));
 130
 131                         Damage(target_victim, self.realowner, self.realowner,
 132                                 swing_damage, WEP_SHOTGUN | HITTYPE_SECONDARY,
 133                                 self.realowner.origin + self.realowner.view_ofs,
 134                                 v_forward * autocvar_g_balance_shotgun_secondary_force);
 135
 136                         if(accuracy_isgooddamage(self.realowner, target_victim)) { accuracy_add(self.realowner, WEP_SHOTGUN, 0, swing_damage); }
 137
 138                         // draw large red flash for debugging
 139                         //te_customflash(targpos, 200, 2, '15 0 0');
 140
 141                         if(autocvar_g_balance_shotgun_secondary_melee_multihit) // allow multiple hits with one swing, but not against the same player twice.
 142                         {
 143                                 self.swing_alreadyhit = target_victim;
 144                                 continue; // move along to next trace
 145                         }
 146                         else
 147                         {
 148                                 remove(self);
 149                                 return;
 150                         }
 151                 }
 152         }
 153
 154         if(time >= self.cnt + meleetime)
 155         {
 156                 // melee is finished
 157                 remove(self);
 158                 return;
 159         }
 160         else
 161         {
 162                 // set up next frame
 163                 self.swing_prev = i;
 164                 self.nextthink = time;
 165         }
 166 }
 167
 168 void W_Shotgun_Attack2 (void)
 169 {
 170         sound (self, CH_WEAPON_A, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
 171         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_shotgun_secondary_animtime, w_ready);
 172
 173         entity meleetemp;
 174         meleetemp = spawn();
 175         meleetemp.realowner = self;
 176         meleetemp.think = shotgun_meleethink;
 177         meleetemp.nextthink = time + autocvar_g_balance_shotgun_secondary_melee_delay * W_WeaponRateFactor();
 178         W_SetupShot_Range(self, TRUE, 0, "", 0, autocvar_g_balance_shotgun_secondary_damage, autocvar_g_balance_shotgun_secondary_melee_range);
 179 }
 180
 181 void spawnfunc_weapon_shotgun(); // defined in t_items.qc
 182
 183 .float shotgun_primarytime;
 184
 185 float w_shotgun(float req)
 186 {
 187         float ammo_amount;
 188
 189         switch(req)
 190         {
 191                 case WR_AIM:
 192                 {
 193                         if(vlen(self.origin-self.enemy.origin) <= autocvar_g_balance_shotgun_secondary_melee_range)
 194                                 self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 195                         else
 196                         {
 197                                 if(autocvar_g_antilag_bullets)
 198                                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 199                                 else
 200                                         self.BUTTON_ATCK = bot_aim(autocvar_g_balance_shotgun_primary_speed, 0, 0.001, FALSE);
 201                         }
 202
 203                         return TRUE;
 204                 }
 205                 case WR_THINK:
 206                 {
 207                         if(autocvar_g_balance_shotgun_reload_ammo && self.clip_load < autocvar_g_balance_shotgun_primary_ammo) // forced reload
 208                         {
 209                                 // don't force reload an empty shotgun if its melee attack is active
 210                                 if not(autocvar_g_balance_shotgun_secondary && self.ammo_shells < autocvar_g_balance_shotgun_primary_ammo)
 211                                         WEP_ACTION(self.weapon, WR_RELOAD);
 212                         }
 213                         else
 214                         {
 215                                 if (self.BUTTON_ATCK)
 216                                 {
 217                                         if (time >= self.shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 218                                         {
 219                                                 if(weapon_prepareattack(0, autocvar_g_balance_shotgun_primary_animtime))
 220                                                 {
 221                                                         W_Shotgun_Attack();
 222                                                         self.shotgun_primarytime = time + autocvar_g_balance_shotgun_primary_refire * W_WeaponRateFactor();
 223                                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_shotgun_primary_animtime, w_ready);
 224                                                 }
 225                                         }
 226                                 }
 227                         }
 228                         if (self.clip_load >= 0) // we are not currently reloading
 229                         if (!self.crouch) // no crouchmelee please
 230                         if (self.BUTTON_ATCK2 && autocvar_g_balance_shotgun_secondary)
 231                         if (weapon_prepareattack(1, autocvar_g_balance_shotgun_secondary_refire))
 232                         {
 233                                 // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 234                                 weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 235                         }
 236
 237                         return TRUE;
 238                 }
 239                 case WR_INIT:
 240                 {
 241                         precache_model ("models/uziflash.md3");
 242                         precache_model ("models/weapons/g_shotgun.md3");
 243                         precache_model ("models/weapons/v_shotgun.md3");
 244                         precache_model ("models/weapons/h_shotgun.iqm");
 245                         precache_sound ("misc/itempickup.wav");
 246                         precache_sound ("weapons/shotgun_fire.wav");
 247                         precache_sound ("weapons/shotgun_melee.wav");
 248                         return TRUE;
 249                 }
 250                 case WR_SETUP:
 251                 {
 252                         self.current_ammo = ammo_shells;
 253                         return TRUE;
 254                 }
 255                 case WR_CHECKAMMO1:
 256                 {
 257                         ammo_amount = self.ammo_shells >= autocvar_g_balance_shotgun_primary_ammo;
 258                         ammo_amount += self.(weapon_load[WEP_SHOTGUN]) >= autocvar_g_balance_shotgun_primary_ammo;
 259                         return ammo_amount;
 260                 }
 261                 case WR_CHECKAMMO2:
 262                 {
 263                         // melee attack is always available
 264                         return TRUE;
 265                 }
 266                 case WR_RELOAD:
 267                 {
 268                         W_Reload(autocvar_g_balance_shotgun_primary_ammo, autocvar_g_balance_shotgun_reload_ammo, autocvar_g_balance_shotgun_reload_time, "weapons/reload.wav");
 269                         return TRUE;
 270                 }
 271                 case WR_SUICIDEMESSAGE:
 272                 {
 273                         return WEAPON_THINKING_WITH_PORTALS;
 274                 }
 275                 case WR_KILLMESSAGE:
 276                 {
 277                         if(w_deathtype & HITTYPE_SECONDARY)
 278                                 return WEAPON_SHOTGUN_MURDER_SLAP;
 279                         else
 280                                 return WEAPON_SHOTGUN_MURDER;
 281                 }
 282         }
 283         return TRUE;
 284 }
 285 #endif
 286 #ifdef CSQC
 287 .float prevric;
 288 float w_shotgun(float req)
 289 {
 290         switch(req)
 291         {
 292                 case WR_IMPACTEFFECT:
 293                 {
 294                         vector org2;
 295                         org2 = w_org + w_backoff * 2;
 296                         pointparticles(particleeffectnum("shotgun_impact"), org2, w_backoff * 1000, 1);
 297                         if(!w_issilent && time - self.prevric > 0.25)
 298                         {
 299                                 if(w_random < 0.0165)
 300                                         sound(self, CH_SHOTS, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 301                                 else if(w_random < 0.033)
 302                                         sound(self, CH_SHOTS, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 303                                 else if(w_random < 0.05)
 304                                         sound(self, CH_SHOTS, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 305                                 self.prevric = time;
 306                         }
 307                         return TRUE;
 308                 }
 309                 case WR_INIT:
 310                 {
 311                         precache_sound("weapons/ric1.wav");
 312                         precache_sound("weapons/ric2.wav");
 313                         precache_sound("weapons/ric3.wav");
 314                         return TRUE;
 315                 }
 316         }
 317         return TRUE;
 318 }
 319 #endif
 320 #endif