qcsrc/common/weapons/w_shockwave.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ SHOTGUN,
   4 /* function  */ w_shotgun,
   5 /* ammotype  */ IT_SHELLS,
   6 /* impulse   */ 2,
   7 /* flags     */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN,
   8 /* rating    */ BOT_PICKUP_RATING_LOW,
   9 /* model     */ "shotgun",
  10 /* shortname */ "shotgun",
  11 /* fullname  */ _("Shotgun")
  12 );
  13 #else
  14 #ifdef SVQC
  15
  16 void W_Shotgun_Attack (void)
  17 {
  18         float   sc;
  19         float   ammoamount;
  20         float   bullets;
  21         float   d;
  22         float   f;
  23         float   spread;
  24         float   bulletspeed;
  25         float   bulletconstant;
  26         entity flash;
  27
  28         ammoamount = autocvar_g_balance_shotgun_primary_ammo;
  29         bullets = autocvar_g_balance_shotgun_primary_bullets;
  30         d = autocvar_g_balance_shotgun_primary_damage;
  31         f = autocvar_g_balance_shotgun_primary_force;
  32         spread = autocvar_g_balance_shotgun_primary_spread;
  33         bulletspeed = autocvar_g_balance_shotgun_primary_speed;
  34         bulletconstant = autocvar_g_balance_shotgun_primary_bulletconstant;
  35
  36         W_DecreaseAmmo(ammo_shells, ammoamount, autocvar_g_balance_shotgun_reload_ammo);
  37
  38         W_SetupShot (self, autocvar_g_antilag_bullets && bulletspeed >= autocvar_g_antilag_bullets, 5, "weapons/shotgun_fire.wav", CH_WEAPON_A, d * bullets);
  39         for (sc = 0;sc < bullets;sc = sc + 1)
  40                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, f, WEP_SHOTGUN, 0, 1, bulletconstant);
  41         endFireBallisticBullet();
  42
  43         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, autocvar_g_balance_shotgun_primary_ammo);
  44
  45         // casing code
  46         if (autocvar_g_casings >= 1)
  47                 for (sc = 0;sc < ammoamount;sc = sc + 1)
  48                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
  49
  50         // muzzle flash for 1st person view
  51         flash = spawn();
  52         setmodel(flash, "models/uziflash.md3"); // precision set below
  53         flash.think = SUB_Remove;
  54         flash.nextthink = time + 0.06;
  55         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  56         W_AttachToShotorg(flash, '5 0 0');
  57 }
  58
  59 .float swing_prev;
  60 .entity swing_alreadyhit;
  61 void shotgun_meleethink (void)
  62 {
  63         // declarations
  64         float i, f, swing, swing_factor, swing_damage, meleetime, is_player;
  65         entity target_victim;
  66         vector targpos;
  67
  68         if(!self.cnt) // set start time of melee
  69         {
  70                 self.cnt = time;
  71                 W_PlayStrengthSound(self.realowner);
  72         }
  73
  74         makevectors(self.realowner.v_angle); // update values for v_* vectors
  75
  76         // calculate swing percentage based on time
  77         meleetime = autocvar_g_balance_shotgun_secondary_melee_time * W_WeaponRateFactor();
  78         swing = bound(0, (self.cnt + meleetime - time) / meleetime, 10);
  79         f = ((1 - swing) * autocvar_g_balance_shotgun_secondary_melee_traces);
  80
  81         // check to see if we can still continue, otherwise give up now
  82         if((self.realowner.deadflag != DEAD_NO) && autocvar_g_balance_shotgun_secondary_melee_no_doubleslap)
  83         {
  84                 remove(self);
  85                 return;
  86         }
  87
  88         // if okay, perform the traces needed for this frame
  89         for(i=self.swing_prev; i < f; ++i)
  90         {
  91                 swing_factor = ((1 - (i / autocvar_g_balance_shotgun_secondary_melee_traces)) * 2 - 1);
  92
  93                 targpos = (self.realowner.origin + self.realowner.view_ofs
  94                         + (v_forward * autocvar_g_balance_shotgun_secondary_melee_range)
  95                         + (v_up * swing_factor * autocvar_g_balance_shotgun_secondary_melee_swing_up)
  96                         + (v_right * swing_factor * autocvar_g_balance_shotgun_secondary_melee_swing_side));
  97
  98                 WarpZone_traceline_antilag(self, self.realowner.origin + self.realowner.view_ofs, targpos, FALSE, self, ANTILAG_LATENCY(self.realowner));
  99
 100                 // draw lightning beams for debugging
 101                 //te_lightning2(world, targpos, self.realowner.origin + self.realowner.view_ofs + v_forward * 5 - v_up * 5);
 102                 //te_customflash(targpos, 40,  2, '1 1 1');
 103
 104                 is_player = (IS_PLAYER(trace_ent) || trace_ent.classname == "body");
 105
 106                 if((trace_fraction < 1) // if trace is good, apply the damage and remove self
 107                         && (trace_ent.takedamage == DAMAGE_AIM)
 108                         && (trace_ent != self.swing_alreadyhit)
 109                         && (is_player || autocvar_g_balance_shotgun_secondary_melee_nonplayerdamage))
 110                 {
 111                         target_victim = trace_ent; // so it persists through other calls
 112
 113                         if(is_player) // this allows us to be able to nerf the non-player damage done in e.g. assault or onslaught.
 114                                 swing_damage = (autocvar_g_balance_shotgun_secondary_damage * min(1, swing_factor + 1));
 115                         else
 116                                 swing_damage = (autocvar_g_balance_shotgun_secondary_melee_nonplayerdamage * min(1, swing_factor + 1));
 117
 118                         //print(strcat(self.realowner.netname, " hitting ", target_victim.netname, " with ", strcat(ftos(swing_damage), " damage (factor: ", ftos(swing_factor), ") at "), ftos(time), " seconds.\n"));
 119
 120                         Damage(target_victim, self.realowner, self.realowner,
 121                                 swing_damage, WEP_SHOTGUN | HITTYPE_SECONDARY,
 122                                 self.realowner.origin + self.realowner.view_ofs,
 123                                 v_forward * autocvar_g_balance_shotgun_secondary_force);
 124
 125                         if(accuracy_isgooddamage(self.realowner, target_victim)) { accuracy_add(self.realowner, WEP_SHOTGUN, 0, swing_damage); }
 126
 127                         // draw large red flash for debugging
 128                         //te_customflash(targpos, 200, 2, '15 0 0');
 129
 130                         if(autocvar_g_balance_shotgun_secondary_melee_multihit) // allow multiple hits with one swing, but not against the same player twice.
 131                         {
 132                                 self.swing_alreadyhit = target_victim;
 133                                 continue; // move along to next trace
 134                         }
 135                         else
 136                         {
 137                                 remove(self);
 138                                 return;
 139                         }
 140                 }
 141         }
 142
 143         if(time >= self.cnt + meleetime)
 144         {
 145                 // melee is finished
 146                 remove(self);
 147                 return;
 148         }
 149         else
 150         {
 151                 // set up next frame
 152                 self.swing_prev = i;
 153                 self.nextthink = time;
 154         }
 155 }
 156
 157 void W_Shotgun_Attack2 (void)
 158 {
 159         sound (self, CH_WEAPON_A, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
 160         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_shotgun_secondary_animtime, w_ready);
 161
 162         entity meleetemp;
 163         meleetemp = spawn();
 164         meleetemp.realowner = self;
 165         meleetemp.think = shotgun_meleethink;
 166         meleetemp.nextthink = time + autocvar_g_balance_shotgun_secondary_melee_delay * W_WeaponRateFactor();
 167         W_SetupShot_Range(self, TRUE, 0, "", 0, autocvar_g_balance_shotgun_secondary_damage, autocvar_g_balance_shotgun_secondary_melee_range);
 168 }
 169
 170 void spawnfunc_weapon_shotgun(); // defined in t_items.qc
 171
 172 .float shotgun_primarytime;
 173
 174 float w_shotgun(float req)
 175 {
 176         float ammo_amount;
 177
 178         switch(req)
 179         {
 180                 case WR_AIM:
 181                 {
 182                         if(vlen(self.origin-self.enemy.origin) <= autocvar_g_balance_shotgun_secondary_melee_range)
 183                                 self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 184                         else
 185                         {
 186                                 if(autocvar_g_antilag_bullets)
 187                                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 188                                 else
 189                                         self.BUTTON_ATCK = bot_aim(autocvar_g_balance_shotgun_primary_speed, 0, 0.001, FALSE);
 190                         }
 191
 192                         return TRUE;
 193                 }
 194                 case WR_THINK:
 195                 {
 196                         if(autocvar_g_balance_shotgun_reload_ammo && self.clip_load < autocvar_g_balance_shotgun_primary_ammo) // forced reload
 197                         {
 198                                 // don't force reload an empty shotgun if its melee attack is active
 199                                 if not(autocvar_g_balance_shotgun_secondary && self.ammo_shells < autocvar_g_balance_shotgun_primary_ammo)
 200                                         weapon_action(self.weapon, WR_RELOAD);
 201                         }
 202                         else
 203                         {
 204                                 if (self.BUTTON_ATCK)
 205                                 {
 206                                         if (time >= self.shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 207                                         {
 208                                                 if(weapon_prepareattack(0, autocvar_g_balance_shotgun_primary_animtime))
 209                                                 {
 210                                                         W_Shotgun_Attack();
 211                                                         self.shotgun_primarytime = time + autocvar_g_balance_shotgun_primary_refire * W_WeaponRateFactor();
 212                                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_shotgun_primary_animtime, w_ready);
 213                                                 }
 214                                         }
 215                                 }
 216                         }
 217                         if (self.clip_load >= 0) // we are not currently reloading
 218                         if (!self.crouch) // no crouchmelee please
 219                         if (self.BUTTON_ATCK2 && autocvar_g_balance_shotgun_secondary)
 220                         if (weapon_prepareattack(1, autocvar_g_balance_shotgun_secondary_refire))
 221                         {
 222                                 // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 223                                 weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 224                         }
 225
 226                         return TRUE;
 227                 }
 228                 case WR_PRECACHE:
 229                 {
 230                         precache_model ("models/uziflash.md3");
 231                         precache_model ("models/weapons/g_shotgun.md3");
 232                         precache_model ("models/weapons/v_shotgun.md3");
 233                         precache_model ("models/weapons/h_shotgun.iqm");
 234                         precache_sound ("misc/itempickup.wav");
 235                         precache_sound ("weapons/shotgun_fire.wav");
 236                         precache_sound ("weapons/shotgun_melee.wav");
 237                         return TRUE;
 238                 }
 239                 case WR_SETUP:
 240                 {
 241                         weapon_setup(WEP_SHOTGUN);
 242                         self.current_ammo = ammo_shells;
 243                         return TRUE;
 244                 }
 245                 case WR_CHECKAMMO1:
 246                 {
 247                         ammo_amount = self.ammo_shells >= autocvar_g_balance_shotgun_primary_ammo;
 248                         ammo_amount += self.(weapon_load[WEP_SHOTGUN]) >= autocvar_g_balance_shotgun_primary_ammo;
 249                         return ammo_amount;
 250                 }
 251                 case WR_CHECKAMMO2:
 252                 {
 253                         // melee attack is always available
 254                         return TRUE;
 255                 }
 256                 case WR_RELOAD:
 257                 {
 258                         W_Reload(autocvar_g_balance_shotgun_primary_ammo, autocvar_g_balance_shotgun_reload_ammo, autocvar_g_balance_shotgun_reload_time, "weapons/reload.wav");
 259                         return TRUE;
 260                 }
 261                 case WR_SUICIDEMESSAGE:
 262                 {
 263                         return WEAPON_THINKING_WITH_PORTALS;
 264                 }
 265                 case WR_KILLMESSAGE:
 266                 {
 267                         if(w_deathtype & HITTYPE_SECONDARY)
 268                                 return WEAPON_SHOTGUN_MURDER_SLAP;
 269                         else
 270                                 return WEAPON_SHOTGUN_MURDER;
 271                 }
 272         }
 273         return TRUE;
 274 }
 275 #endif
 276 #ifdef CSQC
 277 .float prevric;
 278 float w_shotgun(float req)
 279 {
 280         switch(req)
 281         {
 282                 case WR_IMPACTEFFECT:
 283                 {
 284                         vector org2;
 285                         org2 = w_org + w_backoff * 2;
 286                         pointparticles(particleeffectnum("shotgun_impact"), org2, w_backoff * 1000, 1);
 287                         if(!w_issilent && time - self.prevric > 0.25)
 288                         {
 289                                 if(w_random < 0.0165)
 290                                         sound(self, CH_SHOTS, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 291                                 else if(w_random < 0.033)
 292                                         sound(self, CH_SHOTS, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 293                                 else if(w_random < 0.05)
 294                                         sound(self, CH_SHOTS, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 295                                 self.prevric = time;
 296                         }
 297                         return TRUE;
 298                 }
 299                 case WR_PRECACHE:
 300                 {
 301                         precache_sound("weapons/ric1.wav");
 302                         precache_sound("weapons/ric2.wav");
 303                         precache_sound("weapons/ric3.wav");
 304                         return TRUE;
 305                 }
 306         }
 307         return TRUE;
 308 }
 309 #endif
 310 #endif