qcsrc/common/weapons/w_vaporizer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ VAPORIZER,
   4 /* function */ W_Vaporizer,
   5 /* ammotype */ ammo_cells,
   6 /* impulse  */ 7,
   7 /* flags    */ WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_FLAG_SUPERWEAPON | WEP_TYPE_HITSCAN,
   8 /* rating   */ BOT_PICKUP_RATING_HIGH,
   9 /* color        */ '0.5 1 1',
  10 /* model    */ "minstanex",
  11 /* netname  */ "minstanex",
  12 /* fullname */ _("Vaporizer")
  13 );
  14
  15 #define VAPORIZER_SETTINGS(w_cvar,w_prop) VAPORIZER_SETTINGS_LIST(w_cvar, w_prop, VAPORIZER, vaporizer)
  16 #define VAPORIZER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  17         w_cvar(id, sn, PRI, ammo) \
  18         w_cvar(id, sn, PRI, animtime) \
  19         w_cvar(id, sn, PRI, refire) \
  20         w_cvar(id, sn, SEC, ammo) \
  21         w_cvar(id, sn, SEC, animtime) \
  22         w_cvar(id, sn, SEC, damage) \
  23         w_cvar(id, sn, SEC, delay) \
  24         w_cvar(id, sn, SEC, edgedamage) \
  25         w_cvar(id, sn, SEC, force) \
  26         w_cvar(id, sn, SEC, lifetime) \
  27         w_cvar(id, sn, SEC, radius) \
  28         w_cvar(id, sn, SEC, refire) \
  29         w_cvar(id, sn, SEC, shotangle) \
  30         w_cvar(id, sn, SEC, speed) \
  31         w_cvar(id, sn, SEC, spread) \
  32         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  33         w_prop(id, sn, float,  reloading_time, reload_time) \
  34         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  35         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  36         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  37         w_prop(id, sn, float,  weaponstart, weaponstart) \
  38         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  39
  40 #ifdef SVQC
  41 VAPORIZER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  42 .float vaporizer_lasthit;
  43 .float jump_interval;
  44 #endif
  45 #else
  46 #ifdef SVQC
  47 void spawnfunc_weapon_vaporizer (void) { weapon_defaultspawnfunc(WEP_VAPORIZER); }
  48 void spawnfunc_weapon_minstanex () { spawnfunc_weapon_vaporizer(); }
  49
  50 void W_Vaporizer_Attack (void)
  51 {
  52         float flying;
  53         flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
  54
  55         W_SetupShot (self, TRUE, 0, "weapons/minstanexfire.wav", CH_WEAPON_A, 10000);
  56
  57         yoda = 0;
  58         damage_goodhits = 0;
  59         FireRailgunBullet (w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, 10000, 800, 0, 0, 0, 0, WEP_VAPORIZER);
  60
  61         if(yoda && flying)
  62                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_ACHIEVEMENT_YODA);
  63         if(damage_goodhits && self.vaporizer_lasthit)
  64         {
  65                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_ACHIEVEMENT_IMPRESSIVE);
  66                 damage_goodhits = 0; // only every second time
  67         }
  68
  69         self.vaporizer_lasthit = damage_goodhits;
  70
  71         pointparticles(particleeffectnum("nex_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  72
  73         // teamcolor / hit beam effect
  74         vector v;
  75         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
  76         switch(self.team)
  77         {
  78                 case NUM_TEAM_1:   // Red
  79                         if(damage_goodhits)
  80                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3RED_HIT"), w_shotorg, v);
  81                         else
  82                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3RED"), w_shotorg, v);
  83                         break;
  84                 case NUM_TEAM_2:   // Blue
  85                         if(damage_goodhits)
  86                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3BLUE_HIT"), w_shotorg, v);
  87                         else
  88                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3BLUE"), w_shotorg, v);
  89                         break;
  90                 case NUM_TEAM_3:   // Yellow
  91                         if(damage_goodhits)
  92                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3YELLOW_HIT"), w_shotorg, v);
  93                         else
  94                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3YELLOW"), w_shotorg, v);
  95                         break;
  96                 case NUM_TEAM_4:   // Pink
  97                         if(damage_goodhits)
  98                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3PINK_HIT"), w_shotorg, v);
  99                         else
 100                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3PINK"), w_shotorg, v);
 101                         break;
 102                 default:
 103                         if(damage_goodhits)
 104                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3_HIT"), w_shotorg, v);
 105                         else
 106                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3"), w_shotorg, v);
 107                         break;
 108         }
 109
 110         W_DecreaseAmmo(((g_minstagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo)));
 111 }
 112
 113 float W_Vaporizer(float req)
 114 {
 115         float ammo_amount;
 116         float vaporizer_ammo;
 117
 118         // now multiple WR_s use this
 119         vaporizer_ammo = ((g_minstagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo));
 120
 121         switch(req)
 122         {
 123                 case WR_AIM:
 124                 {
 125                         if(self.AMMO_VAL(WEP_VAPORIZER) > 0)
 126                                 self.BUTTON_ATCK = bot_aim(1000000, 0, 1, FALSE);
 127                         else
 128                                 self.BUTTON_ATCK2 = bot_aim(WEP_CVAR_SEC(vaporizer, speed), 0, WEP_CVAR_SEC(vaporizer, lifetime), FALSE); // WEAPONTODO: replace with proper vaporizer cvars
 129
 130                         return TRUE;
 131                 }
 132                 case WR_THINK:
 133                 {
 134                         // if the laser uses load, we also consider its ammo for reloading
 135                         if(WEP_CVAR(vaporizer, reload_ammo) && WEP_CVAR_SEC(vaporizer, ammo) && self.clip_load < min(vaporizer_ammo, WEP_CVAR_SEC(vaporizer, ammo))) // forced reload
 136                                 WEP_ACTION(self.weapon, WR_RELOAD);
 137                         else if(WEP_CVAR(vaporizer, reload_ammo) && self.clip_load < vaporizer_ammo) // forced reload
 138                                 WEP_ACTION(self.weapon, WR_RELOAD);
 139                         else if (self.BUTTON_ATCK)
 140                         {
 141                                 if (weapon_prepareattack(0, WEP_CVAR_PRI(vaporizer, refire)))
 142                                 {
 143                                         W_Vaporizer_Attack();
 144                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(vaporizer, animtime), w_ready);
 145                                 }
 146                         }
 147                         else if (self.BUTTON_ATCK2)
 148                         {
 149                                 if (self.jump_interval <= time)
 150                                 if (weapon_prepareattack(1, -1))
 151                                 {
 152                                         // handle refire manually, so that primary and secondary can be fired without conflictions (important for minstagib)
 153                                         self.jump_interval = time + WEP_CVAR_SEC(vaporizer, refire) * W_WeaponRateFactor();
 154
 155                                         // decrease ammo for the laser?
 156                                         if(WEP_CVAR_SEC(vaporizer, ammo))
 157                                                 W_DecreaseAmmo(WEP_CVAR_SEC(vaporizer, ammo));
 158
 159                                         // ugly minstagib hack to reuse the fire mode of the laser
 160                                         float w;
 161                                         w = self.weapon;
 162                                         self.weapon = WEP_BLASTER;
 163                                         W_Blaster_Attack(
 164                                                 WEP_CVAR_SEC(vaporizer, shotangle),
 165                                                 WEP_CVAR_SEC(vaporizer, damage),
 166                                                 WEP_CVAR_SEC(vaporizer, edgedamage),
 167                                                 WEP_CVAR_SEC(vaporizer, radius),
 168                                                 WEP_CVAR_SEC(vaporizer, force),
 169                                                 WEP_CVAR_SEC(vaporizer, speed),
 170                                                 WEP_CVAR_SEC(vaporizer, spread),
 171                                                 WEP_CVAR_SEC(vaporizer, delay),
 172                                                 WEP_CVAR_SEC(vaporizer, lifetime)
 173                                         );
 174                                         self.weapon = w;
 175
 176                                         // now do normal refire
 177                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(vaporizer, animtime), w_ready);
 178                                 }
 179                         }
 180
 181                         return TRUE;
 182                 }
 183                 case WR_INIT:
 184                 {
 185                         precache_model("models/nexflash.md3");
 186                         precache_model("models/weapons/g_minstanex.md3");
 187                         precache_model("models/weapons/v_minstanex.md3");
 188                         precache_model("models/weapons/h_minstanex.iqm");
 189                         precache_sound("weapons/minstanexfire.wav");
 190                         precache_sound("weapons/nexwhoosh1.wav");
 191                         precache_sound("weapons/nexwhoosh2.wav");
 192                         precache_sound("weapons/nexwhoosh3.wav");
 193                         //W_Blaster(WR_INIT); // Samual: Is this really the proper thing to do? Didn't we already run this previously?
 194                         VAPORIZER_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 195                         return TRUE;
 196                 }
 197                 case WR_SETUP:
 198                 {
 199                         self.current_ammo = AMMO_VAL(WEP_VAPORIZER);
 200                         self.vaporizer_lasthit = 0;
 201                         return TRUE;
 202                 }
 203                 case WR_CHECKAMMO1:
 204                 {
 205                         ammo_amount = self.AMMO_VAL(WEP_VAPORIZER) >= vaporizer_ammo;
 206                         ammo_amount += self.(weapon_load[WEP_VAPORIZER]) >= vaporizer_ammo;
 207                         return ammo_amount;
 208                 }
 209                 case WR_CHECKAMMO2:
 210                 {
 211                         if(!WEP_CVAR_SEC(vaporizer, ammo))
 212                                 return TRUE;
 213                         ammo_amount = self.AMMO_VAL(WEP_VAPORIZER) >= WEP_CVAR_SEC(vaporizer, ammo);
 214                         ammo_amount += self.(weapon_load[WEP_VAPORIZER]) >= WEP_CVAR_SEC(vaporizer, ammo);
 215                         return ammo_amount;
 216                 }
 217                 case WR_CONFIG:
 218                 {
 219                         VAPORIZER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 220                         return TRUE;
 221                 }
 222                 case WR_RESETPLAYER:
 223                 {
 224                         self.vaporizer_lasthit = 0;
 225                         return TRUE;
 226                 }
 227                 case WR_RELOAD:
 228                 {
 229                         float used_ammo;
 230                         if(WEP_CVAR_SEC(vaporizer, ammo))
 231                                 used_ammo = min(vaporizer_ammo, WEP_CVAR_SEC(vaporizer, ammo));
 232                         else
 233                                 used_ammo = vaporizer_ammo;
 234
 235                         W_Reload(used_ammo, "weapons/reload.wav");
 236                         return TRUE;
 237                 }
 238                 case WR_SUICIDEMESSAGE:
 239                 {
 240                         return WEAPON_THINKING_WITH_PORTALS;
 241                 }
 242                 case WR_KILLMESSAGE:
 243                 {
 244                         return WEAPON_VAPORIZER_MURDER;
 245                 }
 246         }
 247         return TRUE;
 248 }
 249 #endif
 250 #ifdef CSQC
 251 float W_Vaporizer(float req)
 252 {
 253         switch(req)
 254         {
 255                 case WR_IMPACTEFFECT:
 256                 {
 257                         vector org2;
 258                         org2 = w_org + w_backoff * 6;
 259                         pointparticles(particleeffectnum("nex_impact"), org2, '0 0 0', 1);
 260                         if(!w_issilent)
 261                                 sound(self, CH_SHOTS, "weapons/neximpact.wav", VOL_BASE, ATTN_NORM);
 262
 263                         return TRUE;
 264                 }
 265                 case WR_INIT:
 266                 {
 267                         precache_sound("weapons/neximpact.wav");
 268                         return TRUE;
 269                 }
 270         }
 271         return TRUE;
 272 }
 273 #endif
 274 #endif