qcsrc/common/weapons/weapon/arc.qc

   1 #ifndef IMPLEMENTATION
   2 CLASS(Arc, Weapon)
   3 /* ammotype  */ ATTRIB(Arc, ammo_field, .int, ammo_cells)
   4 /* impulse   */ ATTRIB(Arc, impulse, int, 3)
   5 /* flags     */ ATTRIB(Arc, spawnflags, int, WEP_FLAG_NORMAL);
   6 /* rating    */ ATTRIB(Arc, bot_pickupbasevalue, float, BOT_PICKUP_RATING_HIGH);
   7 /* color     */ ATTRIB(Arc, wpcolor, vector, '1 1 1');
   8 /* modelname */ ATTRIB(Arc, mdl, string, "arc");
   9 #ifndef MENUQC
  10 /* model     */ ATTRIB(Arc, m_model, Model, MDL_ARC_ITEM);
  11 #endif
  12 /* crosshair */ ATTRIB(Arc, w_crosshair, string, "gfx/crosshairhlac");
  13 /* crosshair */ ATTRIB(Arc, w_crosshair_size, float, 0.7);
  14 /* wepimg    */ ATTRIB(Arc, model2, string, "weaponarc");
  15 /* refname   */ ATTRIB(Arc, netname, string, "arc");
  16 /* wepname   */ ATTRIB(Arc, m_name, string, _("Arc"));
  17
  18 #define X(BEGIN, P, END, class, prefix) \
  19         BEGIN(class) \
  20                 P(class, prefix, bolt, float, NONE) \
  21                 P(class, prefix, bolt_ammo, float, NONE) \
  22         P(class, prefix, bolt_damageforcescale, float, NONE) \
  23         P(class, prefix, bolt_damage, float, NONE) \
  24         P(class, prefix, bolt_edgedamage, float, NONE) \
  25         P(class, prefix, bolt_force, float, NONE) \
  26         P(class, prefix, bolt_health, float, NONE) \
  27         P(class, prefix, bolt_lifetime, float, NONE) \
  28         P(class, prefix, bolt_radius, float, NONE) \
  29         P(class, prefix, bolt_refire, float, NONE) \
  30         P(class, prefix, bolt_speed, float, NONE) \
  31         P(class, prefix, bolt_spread, float, NONE) \
  32                 P(class, prefix, beam_ammo, float, NONE) \
  33         P(class, prefix, beam_animtime, float, NONE) \
  34         P(class, prefix, beam_botaimlifetime, float, NONE) \
  35         P(class, prefix, beam_botaimspeed, float, NONE) \
  36         P(class, prefix, beam_damage, float, NONE) \
  37         P(class, prefix, beam_degreespersegment, float, NONE) \
  38         P(class, prefix, beam_distancepersegment, float, NONE) \
  39         P(class, prefix, beam_falloff_halflifedist, float, NONE) \
  40         P(class, prefix, beam_falloff_maxdist, float, NONE) \
  41         P(class, prefix, beam_falloff_mindist, float, NONE) \
  42         P(class, prefix, beam_force, float, NONE) \
  43         P(class, prefix, beam_healing_amax, float, NONE) \
  44         P(class, prefix, beam_healing_aps, float, NONE) \
  45         P(class, prefix, beam_healing_hmax, float, NONE) \
  46         P(class, prefix, beam_healing_hps, float, NONE) \
  47         P(class, prefix, beam_heat, float, NONE) /* heat increase per second (primary) */ \
  48         P(class, prefix, beam_maxangle, float, NONE) \
  49         P(class, prefix, beam_nonplayerdamage, float, NONE) \
  50         P(class, prefix, beam_range, float, NONE) \
  51         P(class, prefix, beam_refire, float, NONE) \
  52         P(class, prefix, beam_returnspeed, float, NONE) \
  53         P(class, prefix, beam_tightness, float, NONE) \
  54         P(class, prefix, burst_ammo, float, NONE) \
  55         P(class, prefix, burst_damage, float, NONE) \
  56         P(class, prefix, burst_healing_aps, float, NONE) \
  57         P(class, prefix, burst_healing_hps, float, NONE) \
  58         P(class, prefix, burst_heat, float, NONE) /* heat increase per second (secondary) */ \
  59         P(class, prefix, cooldown, float, NONE) /* heat decrease per second when resting */ \
  60         P(class, prefix, cooldown_release, float, NONE) /* delay weapon re-use when releasing button */ \
  61         P(class, prefix, overheat_max, float, NONE) /* maximum heat before jamming */ \
  62         P(class, prefix, overheat_min, float, NONE) /* minimum heat to wait for cooldown */ \
  63         P(class, prefix, switchdelay_drop, float, NONE) \
  64         P(class, prefix, switchdelay_raise, float, NONE) \
  65         P(class, prefix, weaponreplace, string, NONE) \
  66         P(class, prefix, weaponstartoverride, float, NONE) \
  67         P(class, prefix, weaponstart, float, NONE) \
  68         P(class, prefix, weaponthrowable, float, NONE) \
  69     END()
  70     W_PROPS(X, Arc, arc)
  71 #undef X
  72
  73 ENDCLASS(Arc)
  74 REGISTER_WEAPON(ARC, arc, NEW(Arc));
  75
  76
  77 #ifndef MENUQC
  78 const float ARC_MAX_SEGMENTS = 20;
  79 vector arc_shotorigin[4];
  80 .vector beam_start;
  81 .vector beam_dir;
  82 .vector beam_wantdir;
  83 .int beam_type;
  84
  85 const int ARC_BT_MISS =        0x00;
  86 const int ARC_BT_WALL =        0x01;
  87 const int ARC_BT_HEAL =        0x02;
  88 const int ARC_BT_HIT =         0x03;
  89 const int ARC_BT_BURST_MISS =  0x10;
  90 const int ARC_BT_BURST_WALL =  0x11;
  91 const int ARC_BT_BURST_HEAL =  0x12;
  92 const int ARC_BT_BURST_HIT =   0x13;
  93 const int ARC_BT_BURSTMASK =   0x10;
  94
  95 const int ARC_SF_SETTINGS =    BIT(0);
  96 const int ARC_SF_START =       BIT(1);
  97 const int ARC_SF_WANTDIR =     BIT(2);
  98 const int ARC_SF_BEAMDIR =     BIT(3);
  99 const int ARC_SF_BEAMTYPE =    BIT(4);
 100 const int ARC_SF_LOCALMASK =   ARC_SF_START | ARC_SF_WANTDIR | ARC_SF_BEAMDIR;
 101 #endif
 102 #ifdef SVQC
 103 .entity arc_beam;
 104 .bool arc_BUTTON_ATCK_prev; // for better animation control
 105 .float beam_prev;
 106 .float beam_initialized;
 107 .float beam_bursting;
 108 .float beam_teleporttime;
 109 .float beam_heat; // (beam) amount of heat produced
 110 .float arc_overheat; // (dropped arc/player) time during which it's too hot
 111 .float arc_cooldown; // (dropped arc/player) cooling speed
 112 .float arc_heat_percent = _STAT(ARC_HEAT);
 113 .float arc_smoke_sound;
 114 #endif
 115 #ifdef CSQC
 116
 117 .vector beam_color;
 118 .float beam_alpha;
 119 .float beam_thickness;
 120 .entity beam_traileffect;
 121 .entity beam_hiteffect;
 122 .float beam_hitlight[4]; // 0: radius, 123: rgb
 123 .entity beam_muzzleeffect;
 124 .float beam_muzzlelight[4]; // 0: radius, 123: rgb
 125 .string beam_image;
 126
 127 .entity beam_muzzleentity;
 128
 129 .float beam_degreespersegment;
 130 .float beam_distancepersegment;
 131 .float beam_usevieworigin;
 132 .float beam_initialized;
 133 .float beam_maxangle;
 134 .float beam_range;
 135 .float beam_returnspeed;
 136 .float beam_tightness;
 137 .vector beam_shotorigin;
 138
 139 entity Draw_ArcBeam_callback_entity;
 140 float Draw_ArcBeam_callback_last_thickness;
 141 vector Draw_ArcBeam_callback_last_top; // NOTE: in same coordinate system as player.
 142 vector Draw_ArcBeam_callback_last_bottom; // NOTE: in same coordinate system as player.
 143 #endif
 144 #endif
 145 #ifdef IMPLEMENTATION
 146 #ifdef SVQC
 147 spawnfunc(weapon_arc) { weapon_defaultspawnfunc(this, WEP_ARC); }
 148
 149 bool W_Arc_Beam_Send(entity this, entity to, int sf)
 150 {
 151         WriteHeader(MSG_ENTITY, ENT_CLIENT_ARC_BEAM);
 152
 153         // Truncate information when this beam is displayed to the owner client
 154         // - The owner client has no use for beam start position or directions,
 155         //    it always figures this information out for itself with csqc code.
 156         // - Spectating the owner also truncates this information.
 157         float drawlocal = ((to == this.owner) || ((to.enemy == this.owner) && IS_SPEC(to)));
 158         if(drawlocal) { sf &= ~ARC_SF_LOCALMASK; }
 159
 160         WriteByte(MSG_ENTITY, sf);
 161
 162         if(sf & ARC_SF_SETTINGS) // settings information
 163         {
 164                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_degreespersegment));
 165                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_distancepersegment));
 166                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_maxangle));
 167                 WriteCoord(MSG_ENTITY, WEP_CVAR(arc, beam_range));
 168                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_returnspeed));
 169                 WriteByte(MSG_ENTITY, WEP_CVAR(arc, beam_tightness) * 10);
 170
 171                 WriteByte(MSG_ENTITY, drawlocal);
 172                 WriteByte(MSG_ENTITY, etof(this.owner));
 173         }
 174         if(sf & ARC_SF_START) // starting location
 175         {
 176                 WriteCoord(MSG_ENTITY, this.beam_start.x);
 177                 WriteCoord(MSG_ENTITY, this.beam_start.y);
 178                 WriteCoord(MSG_ENTITY, this.beam_start.z);
 179         }
 180         if(sf & ARC_SF_WANTDIR) // want/aim direction
 181         {
 182                 WriteCoord(MSG_ENTITY, this.beam_wantdir.x);
 183                 WriteCoord(MSG_ENTITY, this.beam_wantdir.y);
 184                 WriteCoord(MSG_ENTITY, this.beam_wantdir.z);
 185         }
 186         if(sf & ARC_SF_BEAMDIR) // beam direction
 187         {
 188                 WriteCoord(MSG_ENTITY, this.beam_dir.x);
 189                 WriteCoord(MSG_ENTITY, this.beam_dir.y);
 190                 WriteCoord(MSG_ENTITY, this.beam_dir.z);
 191         }
 192         if(sf & ARC_SF_BEAMTYPE) // beam type
 193         {
 194                 WriteByte(MSG_ENTITY, this.beam_type);
 195         }
 196
 197         return true;
 198 }
 199
 200 void Reset_ArcBeam(entity player, vector forward)
 201 {
 202         if (!player.arc_beam) {
 203                 return;
 204         }
 205         player.arc_beam.beam_dir = forward;
 206         player.arc_beam.beam_teleporttime = time;
 207 }
 208
 209 float Arc_GetHeat_Percent(entity player)
 210 {
 211         if ( WEP_CVAR(arc, overheat_max) <= 0 ||  WEP_CVAR(arc, overheat_max) <= 0 )
 212         {
 213                 player.arc_overheat = 0;
 214                 return 0;
 215         }
 216
 217         if ( player.arc_beam )
 218                 return player.arc_beam.beam_heat/WEP_CVAR(arc, overheat_max);
 219
 220         if ( player.arc_overheat > time )
 221         {
 222                 return (player.arc_overheat-time) / WEP_CVAR(arc, overheat_max)
 223                         * player.arc_cooldown;
 224         }
 225
 226         return 0;
 227 }
 228 void Arc_Player_SetHeat(entity player)
 229 {
 230         player.arc_heat_percent = Arc_GetHeat_Percent(player);
 231         //dprint("Heat: ",ftos(player.arc_heat_percent*100),"%\n");
 232 }
 233
 234 void W_Arc_Bolt_Explode(entity this, entity directhitentity)
 235 {
 236         this.event_damage = func_null;
 237         RadiusDamage(this, this.realowner, WEP_CVAR(arc, bolt_damage), WEP_CVAR(arc, bolt_edgedamage), WEP_CVAR(arc, bolt_radius), NULL, NULL, WEP_CVAR(arc, bolt_force), this.projectiledeathtype, directhitentity);
 238
 239         remove(this);
 240 }
 241
 242 void W_Arc_Bolt_Explode_use(entity this, entity actor, entity trigger)
 243 {
 244         W_Arc_Bolt_Explode(this, trigger);
 245 }
 246
 247 void W_Arc_Bolt_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 248 {
 249         if(this.health <= 0)
 250                 return;
 251
 252         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1))
 253                 return; // g_projectiles_damage says to halt
 254
 255         this.health = this.health - damage;
 256         this.angles = vectoangles(this.velocity);
 257
 258         if(this.health <= 0)
 259                 W_PrepareExplosionByDamage(this, attacker, getthink(this));
 260 }
 261
 262 void W_Arc_Bolt_Touch(entity this, entity toucher)
 263 {
 264         PROJECTILE_TOUCH(this, toucher);
 265         this.use(this, NULL, toucher);
 266 }
 267
 268 void W_Arc_Attack_Bolt(Weapon thiswep, entity actor)
 269 {
 270         entity missile;
 271
 272         W_DecreaseAmmo(thiswep, actor, WEP_CVAR(arc, bolt_ammo));
 273
 274         W_SetupShot(actor, false, 2, SND_LASERGUN_FIRE, CH_WEAPON_A, WEP_CVAR(arc, bolt_damage));
 275
 276         Send_Effect(EFFECT_ARC_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 277
 278         missile = new(missile);
 279         missile.owner = missile.realowner = actor;
 280         missile.bot_dodge = true;
 281         missile.bot_dodgerating = WEP_CVAR(arc, bolt_damage);
 282
 283         missile.takedamage = DAMAGE_YES;
 284         missile.health = WEP_CVAR(arc, bolt_health);
 285         missile.damageforcescale = WEP_CVAR(arc, bolt_damageforcescale);
 286         missile.event_damage = W_Arc_Bolt_Damage;
 287         missile.damagedbycontents = true;
 288
 289         settouch(missile, W_Arc_Bolt_Touch);
 290         missile.use = W_Arc_Bolt_Explode_use;
 291         setthink(missile, adaptor_think2use_hittype_splash);
 292         missile.nextthink = time + WEP_CVAR(arc, bolt_lifetime);
 293         PROJECTILE_MAKETRIGGER(missile);
 294         missile.projectiledeathtype = WEP_ARC.m_id | HITTYPE_SECONDARY;
 295         setorigin(missile, w_shotorg);
 296         setsize(missile, '0 0 0', '0 0 0');
 297
 298         set_movetype(missile, MOVETYPE_FLY);
 299         W_SetupProjVelocity_PRE(missile, arc, bolt_);
 300
 301         missile.angles = vectoangles(missile.velocity);
 302         missile.flags = FL_PROJECTILE;
 303         missile.missile_flags = MIF_SPLASH;
 304
 305         CSQCProjectile(missile, true, PROJECTILE_ARC_BOLT, true);
 306
 307         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 308 }
 309
 310 void W_Arc_Beam_Think(entity this)
 311 {
 312         if(this != this.owner.arc_beam)
 313         {
 314                 remove(this);
 315                 return;
 316         }
 317
 318
 319         float burst = 0;
 320         if( (PHYS_INPUT_BUTTON_ATCK2(this.owner) && !WEP_CVAR(arc, bolt)) || this.beam_bursting)
 321         {
 322                 if(!this.beam_bursting)
 323                         this.beam_bursting = true;
 324                 burst = ARC_BT_BURSTMASK;
 325         }
 326
 327         Weapon thiswep = WEP_ARC;
 328
 329         if(
 330                 !IS_PLAYER(this.owner)
 331                 ||
 332                 (this.owner.(thiswep.ammo_field) <= 0 && !(this.owner.items & IT_UNLIMITED_WEAPON_AMMO))
 333                 ||
 334                 IS_DEAD(this.owner)
 335                 ||
 336                 gameover
 337                 ||
 338                 (!PHYS_INPUT_BUTTON_ATCK(this.owner) && !burst )
 339                 ||
 340                 STAT(FROZEN, this.owner)
 341                 ||
 342                 this.owner.vehicle
 343                 ||
 344                 (WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max))
 345         )
 346         {
 347                 if ( WEP_CVAR(arc, cooldown) > 0 )
 348                 {
 349                         float cooldown_speed = 0;
 350                         if ( this.beam_heat > WEP_CVAR(arc, overheat_min) && WEP_CVAR(arc, cooldown) > 0 )
 351                         {
 352                                 cooldown_speed = WEP_CVAR(arc, cooldown);
 353                         }
 354                         else if ( !burst )
 355                         {
 356                                 cooldown_speed = this.beam_heat / WEP_CVAR(arc, beam_refire);
 357                         }
 358
 359                         if ( cooldown_speed )
 360                         {
 361                                 if ( WEP_CVAR(arc, cooldown_release) || (WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max)) )
 362                                         this.owner.arc_overheat = time + this.beam_heat / cooldown_speed;
 363                                 this.owner.arc_cooldown = cooldown_speed;
 364                         }
 365
 366                         if ( WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max) )
 367                         {
 368                                 Send_Effect(EFFECT_ARC_OVERHEAT,
 369                                         this.beam_start, this.beam_wantdir, 1 );
 370                                 sound(this, CH_WEAPON_A, SND_ARC_STOP, VOL_BASE, ATTN_NORM);
 371                         }
 372                 }
 373
 374                 if(this == this.owner.arc_beam) { this.owner.arc_beam = NULL; }
 375                 entity own = this.owner;
 376                 Weapon w = WEP_ARC;
 377                 if(!w.wr_checkammo1(w, own) && !w.wr_checkammo2(w, own))
 378                 if(!(own.items & IT_UNLIMITED_WEAPON_AMMO))
 379                 {
 380                         // note: this doesn't force the switch
 381                         W_SwitchToOtherWeapon(own);
 382                 }
 383                 remove(this);
 384                 return;
 385         }
 386
 387         // decrease ammo
 388         float coefficient = frametime;
 389         if(!(this.owner.items & IT_UNLIMITED_WEAPON_AMMO))
 390         {
 391                 float rootammo;
 392                 if(burst)
 393                         { rootammo = WEP_CVAR(arc, burst_ammo); }
 394                 else
 395                         { rootammo = WEP_CVAR(arc, beam_ammo); }
 396
 397                 if(rootammo)
 398                 {
 399                         coefficient = min(coefficient, this.owner.(thiswep.ammo_field) / rootammo);
 400                         this.owner.(thiswep.ammo_field) = max(0, this.owner.(thiswep.ammo_field) - (rootammo * frametime));
 401                 }
 402         }
 403         float heat_speed = burst ? WEP_CVAR(arc, burst_heat) : WEP_CVAR(arc, beam_heat);
 404         this.beam_heat = min( WEP_CVAR(arc, overheat_max), this.beam_heat + heat_speed*frametime );
 405
 406         makevectors(this.owner.v_angle);
 407
 408         W_SetupShot_Range(
 409                 this.owner,
 410                 true,
 411                 0,
 412                 SND_Null,
 413                 0,
 414                 WEP_CVAR(arc, beam_damage) * coefficient,
 415                 WEP_CVAR(arc, beam_range)
 416         );
 417
 418         // After teleport, "lock" the beam until the teleport is confirmed.
 419         if (time < this.beam_teleporttime + ANTILAG_LATENCY(this.owner)) {
 420                 w_shotdir = this.beam_dir;
 421         }
 422
 423         // network information: shot origin and want/aim direction
 424         if(this.beam_start != w_shotorg)
 425         {
 426                 this.SendFlags |= ARC_SF_START;
 427                 this.beam_start = w_shotorg;
 428         }
 429         if(this.beam_wantdir != w_shotdir)
 430         {
 431                 this.SendFlags |= ARC_SF_WANTDIR;
 432                 this.beam_wantdir = w_shotdir;
 433         }
 434
 435         if(!this.beam_initialized)
 436         {
 437                 this.beam_dir = w_shotdir;
 438                 this.beam_initialized = true;
 439         }
 440
 441         // WEAPONTODO: Detect player velocity so that the beam curves when moving too
 442         // idea: blend together this.beam_dir with the inverted direction the player is moving in
 443         // might have to make some special accomodation so that it only uses view_right and view_up
 444
 445         // note that if we do this, it'll always be corrected to a maximum angle by beam_maxangle handling
 446
 447         float segments;
 448         if(this.beam_dir != w_shotdir)
 449         {
 450                 // calculate how much we're going to move the end of the beam to the want position
 451                 // WEAPONTODO (server and client):
 452                 // blendfactor never actually becomes 0 in this situation, which is a problem
 453                 // regarding precision... this means that this.beam_dir and w_shotdir approach
 454                 // eachother, however they never actually become the same value with this method.
 455                 // Perhaps we should do some form of rounding/snapping?
 456                 float angle = vlen(w_shotdir - this.beam_dir) * RAD2DEG;
 457                 if(angle && (angle > WEP_CVAR(arc, beam_maxangle)))
 458                 {
 459                         // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
 460                         float blendfactor = bound(
 461                                 0,
 462                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 463                                 min(WEP_CVAR(arc, beam_maxangle) / angle, 1)
 464                         );
 465                         this.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 466                 }
 467                 else
 468                 {
 469                         // the radius is not too far yet, no worries :D
 470                         float blendfactor = bound(
 471                                 0,
 472                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 473                                 1
 474                         );
 475                         this.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 476                 }
 477
 478                 // network information: beam direction
 479                 this.SendFlags |= ARC_SF_BEAMDIR;
 480
 481                 // calculate how many segments are needed
 482                 float max_allowed_segments;
 483
 484                 if(WEP_CVAR(arc, beam_distancepersegment))
 485                 {
 486                         max_allowed_segments = min(
 487                                 ARC_MAX_SEGMENTS,
 488                                 1 + (vlen(w_shotdir / WEP_CVAR(arc, beam_distancepersegment)))
 489                         );
 490                 }
 491                 else { max_allowed_segments = ARC_MAX_SEGMENTS; }
 492
 493                 if(WEP_CVAR(arc, beam_degreespersegment))
 494                 {
 495                         segments = bound(
 496                                 1,
 497                                 (
 498                                         min(
 499                                                 angle,
 500                                                 WEP_CVAR(arc, beam_maxangle)
 501                                         )
 502                                         /
 503                                         WEP_CVAR(arc, beam_degreespersegment)
 504                                 ),
 505                                 max_allowed_segments
 506                         );
 507                 }
 508                 else { segments = 1; }
 509         }
 510         else { segments = 1; }
 511
 512         vector beam_endpos = (w_shotorg + (this.beam_dir * WEP_CVAR(arc, beam_range)));
 513         vector beam_controlpoint = w_shotorg + w_shotdir * (WEP_CVAR(arc, beam_range) * (1 - WEP_CVAR(arc, beam_tightness)));
 514
 515         float i;
 516         float new_beam_type = 0;
 517         vector last_origin = w_shotorg;
 518         for(i = 1; i <= segments; ++i)
 519         {
 520                 // WEAPONTODO (client):
 521                 // In order to do nice fading and pointing on the starting segment, we must always
 522                 // have that drawn as a separate triangle... However, that is difficult to do when
 523                 // keeping in mind the above problems and also optimizing the amount of segments
 524                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
 525
 526                 vector new_origin = bezier_quadratic_getpoint(
 527                         w_shotorg,
 528                         beam_controlpoint,
 529                         beam_endpos,
 530                         i / segments);
 531                 vector new_dir = normalize(new_origin - last_origin);
 532
 533                 WarpZone_traceline_antilag(
 534                         this.owner,
 535                         last_origin,
 536                         new_origin,
 537                         MOVE_NORMAL,
 538                         this.owner,
 539                         ANTILAG_LATENCY(this.owner)
 540                 );
 541
 542                 // Do all the transforms for warpzones right now, as we already
 543                 // "are" in the post-trace system (if we hit a player, that's
 544                 // always BEHIND the last passed wz).
 545                 last_origin = trace_endpos;
 546                 w_shotorg = WarpZone_TransformOrigin(WarpZone_trace_transform, w_shotorg);
 547                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
 548                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
 549                 new_dir = WarpZone_TransformVelocity(WarpZone_trace_transform, new_dir);
 550
 551                 float is_player = (
 552                         IS_PLAYER(trace_ent)
 553                         ||
 554                         trace_ent.classname == "body"
 555                         ||
 556                         IS_MONSTER(trace_ent)
 557                 );
 558
 559                 if(trace_ent && trace_ent.takedamage && (is_player || WEP_CVAR(arc, beam_nonplayerdamage)))
 560                 {
 561                         // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 562                         // NO. trace_endpos should be just fine. If not,
 563                         // that's an engine bug that needs proper debugging.
 564                         vector hitorigin = trace_endpos;
 565
 566                         float falloff = ExponentialFalloff(
 567                                 WEP_CVAR(arc, beam_falloff_mindist),
 568                                 WEP_CVAR(arc, beam_falloff_maxdist),
 569                                 WEP_CVAR(arc, beam_falloff_halflifedist),
 570                                 vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, hitorigin) - w_shotorg)
 571                         );
 572
 573                         if(is_player && SAME_TEAM(this.owner, trace_ent))
 574                         {
 575                                 float roothealth, rootarmor;
 576                                 if(burst)
 577                                 {
 578                                         roothealth = WEP_CVAR(arc, burst_healing_hps);
 579                                         rootarmor = WEP_CVAR(arc, burst_healing_aps);
 580                                 }
 581                                 else
 582                                 {
 583                                         roothealth = WEP_CVAR(arc, beam_healing_hps);
 584                                         rootarmor = WEP_CVAR(arc, beam_healing_aps);
 585                                 }
 586
 587                                 if(trace_ent.health <= WEP_CVAR(arc, beam_healing_hmax) && roothealth)
 588                                 {
 589                                         trace_ent.health = min(
 590                                                 trace_ent.health + (roothealth * coefficient),
 591                                                 WEP_CVAR(arc, beam_healing_hmax)
 592                                         );
 593                                 }
 594                                 if(trace_ent.armorvalue <= WEP_CVAR(arc, beam_healing_amax) && rootarmor)
 595                                 {
 596                                         trace_ent.armorvalue = min(
 597                                                 trace_ent.armorvalue + (rootarmor * coefficient),
 598                                                 WEP_CVAR(arc, beam_healing_amax)
 599                                         );
 600                                 }
 601
 602                                 // stop rot, set visual effect
 603                                 if(roothealth || rootarmor)
 604                                 {
 605                                         trace_ent.pauserothealth_finished = max(
 606                                                 trace_ent.pauserothealth_finished,
 607                                                 time + autocvar_g_balance_pause_health_rot
 608                                         );
 609                                         trace_ent.pauserotarmor_finished = max(
 610                                                 trace_ent.pauserotarmor_finished,
 611                                                 time + autocvar_g_balance_pause_armor_rot
 612                                         );
 613                                         new_beam_type = ARC_BT_HEAL;
 614                                 }
 615                         }
 616                         else
 617                         {
 618                                 float rootdamage;
 619                                 if(is_player)
 620                                 {
 621                                         if(burst)
 622                                                 { rootdamage = WEP_CVAR(arc, burst_damage); }
 623                                         else
 624                                                 { rootdamage = WEP_CVAR(arc, beam_damage); }
 625                                 }
 626                                 else
 627                                         { rootdamage = WEP_CVAR(arc, beam_nonplayerdamage); }
 628
 629                                 if(accuracy_isgooddamage(this.owner, trace_ent))
 630                                 {
 631                                         accuracy_add(
 632                                                 this.owner,
 633                                                 WEP_ARC.m_id,
 634                                                 0,
 635                                                 rootdamage * coefficient * falloff
 636                                         );
 637                                 }
 638
 639                                 Damage(
 640                                         trace_ent,
 641                                         this.owner,
 642                                         this.owner,
 643                                         rootdamage * coefficient * falloff,
 644                                         WEP_ARC.m_id,
 645                                         hitorigin,
 646                                         WEP_CVAR(arc, beam_force) * new_dir * coefficient * falloff
 647                                 );
 648
 649                                 new_beam_type = ARC_BT_HIT;
 650                         }
 651                         break;
 652                 }
 653                 else if(trace_fraction != 1)
 654                 {
 655                         // we collided with geometry
 656                         new_beam_type = ARC_BT_WALL;
 657                         break;
 658                 }
 659         }
 660
 661         // te_explosion(trace_endpos);
 662
 663         // if we're bursting, use burst visual effects
 664         new_beam_type |= burst;
 665
 666         // network information: beam type
 667         if(new_beam_type != this.beam_type)
 668         {
 669                 this.SendFlags |= ARC_SF_BEAMTYPE;
 670                 this.beam_type = new_beam_type;
 671         }
 672
 673         this.owner.beam_prev = time;
 674         this.nextthink = time;
 675 }
 676
 677 void W_Arc_Beam(float burst, entity actor)
 678 {
 679
 680         // only play fire sound if 1 sec has passed since player let go the fire button
 681         if(time - actor.beam_prev > 1)
 682                 sound(actor, CH_WEAPON_A, SND_ARC_FIRE, VOL_BASE, ATTN_NORM);
 683
 684         entity beam = actor.arc_beam = new(W_Arc_Beam);
 685         beam.solid = SOLID_NOT;
 686         setthink(beam, W_Arc_Beam_Think);
 687         beam.owner = actor;
 688         set_movetype(beam, MOVETYPE_NONE);
 689         beam.bot_dodge = true;
 690         beam.bot_dodgerating = WEP_CVAR(arc, beam_damage);
 691         beam.beam_bursting = burst;
 692         Net_LinkEntity(beam, false, 0, W_Arc_Beam_Send);
 693
 694         getthink(beam)(beam);
 695 }
 696 void Arc_Smoke(entity actor)
 697 {
 698         makevectors(actor.v_angle);
 699         W_SetupShot_Range(actor,true,0,SND_Null,0,0,0);
 700
 701         vector smoke_origin = w_shotorg + actor.velocity*frametime;
 702         if ( actor.arc_overheat > time )
 703         {
 704                 if ( random() < actor.arc_heat_percent )
 705                         Send_Effect(EFFECT_ARC_SMOKE, smoke_origin, '0 0 0', 1 );
 706                 if ( PHYS_INPUT_BUTTON_ATCK(actor) || PHYS_INPUT_BUTTON_ATCK2(actor) )
 707                 {
 708                         Send_Effect(EFFECT_ARC_OVERHEAT_FIRE, smoke_origin, w_shotdir, 1 );
 709                         if ( !actor.arc_smoke_sound )
 710                         {
 711                                 actor.arc_smoke_sound = 1;
 712                                 sound(actor, CH_SHOTS_SINGLE, SND_ARC_LOOP_OVERHEAT, VOL_BASE, ATTN_NORM);
 713                         }
 714                 }
 715         }
 716         else if ( actor.arc_beam && WEP_CVAR(arc, overheat_max) > 0 &&
 717                         actor.arc_beam.beam_heat > WEP_CVAR(arc, overheat_min) )
 718         {
 719                 if ( random() < (actor.arc_beam.beam_heat-WEP_CVAR(arc, overheat_min)) /
 720                                 ( WEP_CVAR(arc, overheat_max)-WEP_CVAR(arc, overheat_min) ) )
 721                         Send_Effect(EFFECT_ARC_SMOKE, smoke_origin, '0 0 0', 1 );
 722         }
 723
 724         if (  actor.arc_smoke_sound && ( actor.arc_overheat <= time ||
 725                 !( PHYS_INPUT_BUTTON_ATCK(actor) || PHYS_INPUT_BUTTON_ATCK2(actor) ) ) || PS(actor).m_switchweapon != WEP_ARC )
 726         {
 727                 actor.arc_smoke_sound = 0;
 728                 sound(actor, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
 729         }
 730 }
 731
 732 METHOD(Arc, wr_aim, void(entity thiswep, entity actor))
 733 {
 734     if(WEP_CVAR(arc, beam_botaimspeed))
 735     {
 736         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(
 737                 actor,
 738             WEP_CVAR(arc, beam_botaimspeed),
 739             0,
 740             WEP_CVAR(arc, beam_botaimlifetime),
 741             false
 742         );
 743     }
 744     else
 745     {
 746         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(
 747                 actor,
 748             1000000,
 749             0,
 750             0.001,
 751             false
 752         );
 753     }
 754 }
 755 METHOD(Arc, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 756 {
 757     Arc_Player_SetHeat(actor);
 758     Arc_Smoke(actor);
 759
 760     bool beam_fire2 = ((fire & 2) && !WEP_CVAR(arc, bolt));
 761
 762     if (time >= actor.arc_overheat)
 763     if ((fire & 1) || beam_fire2 || actor.arc_beam.beam_bursting)
 764     {
 765
 766         if(actor.arc_BUTTON_ATCK_prev)
 767         {
 768             #if 0
 769             if(actor.animstate_startframe == actor.anim_shoot.x && actor.animstate_numframes == actor.anim_shoot.y)
 770                 weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, autocvar_g_balance_arc_primary_animtime, w_ready);
 771             else
 772             #endif
 773                 weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, WEP_CVAR(arc, beam_animtime), w_ready);
 774         }
 775
 776         if((!actor.arc_beam) || wasfreed(actor.arc_beam))
 777         {
 778             if(weapon_prepareattack(thiswep, actor, weaponentity, boolean(beam_fire2), 0))
 779             {
 780                 W_Arc_Beam(boolean(beam_fire2), actor);
 781
 782                 if(!actor.arc_BUTTON_ATCK_prev)
 783                 {
 784                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 785                     actor.arc_BUTTON_ATCK_prev = true;
 786                 }
 787             }
 788         }
 789
 790         return;
 791     }
 792     else if(fire & 2)
 793     {
 794         if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(arc, bolt_refire)))
 795         {
 796             W_Arc_Attack_Bolt(thiswep, actor);
 797             weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, bolt_refire), w_ready);
 798         }
 799     }
 800
 801     if(actor.arc_BUTTON_ATCK_prev)
 802     {
 803         sound(actor, CH_WEAPON_A, SND_ARC_STOP, VOL_BASE, ATTN_NORM);
 804         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 805         int slot = weaponslot(weaponentity);
 806         ATTACK_FINISHED(actor, slot) = time + WEP_CVAR(arc, beam_refire) * W_WeaponRateFactor(actor);
 807     }
 808     actor.arc_BUTTON_ATCK_prev = false;
 809
 810     #if 0
 811     if(fire & 2)
 812     if(weapon_prepareattack(thiswep, actor, weaponentity, true, autocvar_g_balance_arc_secondary_refire))
 813     {
 814         W_Arc_Attack2();
 815         actor.arc_count = autocvar_g_balance_arc_secondary_count;
 816         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, autocvar_g_balance_arc_secondary_animtime, w_arc_checkattack);
 817         actor.arc_secondarytime = time + autocvar_g_balance_arc_secondary_refire2 * W_WeaponRateFactor(actor);
 818     }
 819     #endif
 820 }
 821 METHOD(Arc, wr_init, void(entity thiswep))
 822 {
 823     if(!arc_shotorigin[0])
 824     {
 825         arc_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 1);
 826         arc_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 2);
 827         arc_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 3);
 828         arc_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 4);
 829     }
 830 }
 831 METHOD(Arc, wr_checkammo1, bool(entity thiswep, entity actor))
 832 {
 833     return ((!WEP_CVAR(arc, beam_ammo)) || (actor.(thiswep.ammo_field) > 0));
 834 }
 835 METHOD(Arc, wr_checkammo2, bool(entity thiswep, entity actor))
 836 {
 837     if(WEP_CVAR(arc, bolt))
 838     {
 839         float ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR(arc, bolt_ammo);
 840         ammo_amount += actor.(weapon_load[WEP_ARC.m_id]) >= WEP_CVAR(arc, bolt_ammo);
 841         return ammo_amount;
 842     }
 843     else
 844         return WEP_CVAR(arc, overheat_max) > 0 &&
 845             ((!WEP_CVAR(arc, burst_ammo)) || (actor.(thiswep.ammo_field) > 0));
 846 }
 847 METHOD(Arc, wr_killmessage, Notification(entity thiswep))
 848 {
 849     if(w_deathtype & HITTYPE_SECONDARY)
 850         return WEAPON_ARC_MURDER_SPRAY;
 851     else
 852         return WEAPON_ARC_MURDER;
 853 }
 854 METHOD(Arc, wr_drop, void(entity thiswep, entity actor))
 855 {
 856     weapon_dropevent_item.arc_overheat = actor.arc_overheat;
 857     weapon_dropevent_item.arc_cooldown = actor.arc_cooldown;
 858     actor.arc_overheat = 0;
 859     actor.arc_cooldown = 0;
 860     actor.arc_BUTTON_ATCK_prev = false;
 861 }
 862 METHOD(Arc, wr_pickup, void(entity thiswep, entity actor))
 863 {
 864     if ( !client_hasweapon(actor, thiswep, false, false) &&
 865         weapon_dropevent_item.arc_overheat > time )
 866     {
 867         actor.arc_overheat = weapon_dropevent_item.arc_overheat;
 868         actor.arc_cooldown = weapon_dropevent_item.arc_cooldown;
 869     }
 870 }
 871 METHOD(Arc, wr_resetplayer, void(entity thiswep, entity actor))
 872 {
 873     actor.arc_overheat = 0;
 874     actor.arc_cooldown = 0;
 875     actor.arc_BUTTON_ATCK_prev = false;
 876 }
 877 METHOD(Arc, wr_playerdeath, void(entity thiswep, entity actor))
 878 {
 879     actor.arc_overheat = 0;
 880     actor.arc_cooldown = 0;
 881     actor.arc_BUTTON_ATCK_prev = false;
 882 }
 883 #endif
 884 #ifdef CSQC
 885 bool autocvar_cl_arcbeam_teamcolor = true;
 886
 887 METHOD(Arc, wr_impacteffect, void(entity thiswep, entity actor))
 888 {
 889     if(w_deathtype & HITTYPE_SECONDARY)
 890     {
 891         vector org2;
 892         org2 = w_org + w_backoff * 6;
 893         pointparticles(EFFECT_ARC_BOLT_EXPLODE, org2, w_backoff * 1000, 1);
 894         if(!w_issilent) { sound(actor, CH_SHOTS, SND_LASERIMPACT, VOL_BASE, ATTN_NORM); }
 895     }
 896 }
 897
 898 void Draw_ArcBeam_callback(vector start, vector hit, vector end)
 899 {
 900         entity beam = Draw_ArcBeam_callback_entity;
 901         vector transformed_view_org;
 902         transformed_view_org = WarpZone_TransformOrigin(WarpZone_trace_transform, view_origin);
 903
 904         // Thickdir shall be perpendicular to the beam and to the view-to-beam direction (WEAPONTODO: WHY)
 905         // WEAPONTODO: Wouldn't it be better to be perpendicular to the beam and to the view FORWARD direction?
 906         vector thickdir = normalize(cross(normalize(start - hit), transformed_view_org - start));
 907
 908         vector hitorigin;
 909
 910         // draw segment
 911         #if 0
 912         if(trace_fraction != 1)
 913         {
 914                 // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 915                 hitorigin = start + (Draw_ArcBeam_callback_new_dir * Draw_ArcBeam_callback_segmentdist * trace_fraction);
 916                 hitorigin = WarpZone_TransformOrigin(WarpZone_trace_transform, hitorigin);
 917         }
 918         else
 919         {
 920                 hitorigin = hit;
 921         }
 922         #else
 923         hitorigin = hit;
 924         #endif
 925
 926         // decide upon thickness
 927         float thickness = beam.beam_thickness;
 928
 929         // draw primary beam render
 930         vector top    = hitorigin + (thickdir * thickness);
 931         vector bottom = hitorigin - (thickdir * thickness);
 932
 933         vector last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
 934         vector last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
 935
 936         R_BeginPolygon(beam.beam_image, DRAWFLAG_NORMAL); // DRAWFLAG_ADDITIVE
 937         R_PolygonVertex(
 938                 top,
 939                 '0 0.5 0' + ('0 0.5 0' * (thickness / beam.beam_thickness)),
 940                 beam.beam_color,
 941                 beam.beam_alpha
 942         );
 943         R_PolygonVertex(
 944                 last_top,
 945                 '0 0.5 0' + ('0 0.5 0' * (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 946                 beam.beam_color,
 947                 beam.beam_alpha
 948         );
 949         R_PolygonVertex(
 950                 last_bottom,
 951                 '0 0.5 0' * (1 - (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 952                 beam.beam_color,
 953                 beam.beam_alpha
 954         );
 955         R_PolygonVertex(
 956                 bottom,
 957                 '0 0.5 0' * (1 - (thickness / beam.beam_thickness)),
 958                 beam.beam_color,
 959                 beam.beam_alpha
 960         );
 961         R_EndPolygon();
 962
 963         // draw trailing particles
 964         // NOTES:
 965         //  - Don't use spammy particle counts here, use a FEW small particles around the beam
 966         //  - We're not using WarpZone_TrailParticles here because we will handle warpzones ourselves.
 967         if(beam.beam_traileffect)
 968         {
 969                 trailparticles(beam, beam.beam_traileffect, start, hitorigin);
 970         }
 971
 972         // set up for the next
 973         Draw_ArcBeam_callback_last_thickness = thickness;
 974         Draw_ArcBeam_callback_last_top = WarpZone_UnTransformOrigin(WarpZone_trace_transform, top);
 975         Draw_ArcBeam_callback_last_bottom = WarpZone_UnTransformOrigin(WarpZone_trace_transform, bottom);
 976 }
 977
 978 void Reset_ArcBeam()
 979 {
 980         entity e;
 981         for (e = NULL; (e = findfloat(e, beam_usevieworigin, 1)); ) {
 982                 e.beam_initialized = false;
 983         }
 984         for (e = NULL; (e = findfloat(e, beam_usevieworigin, 2)); ) {
 985                 e.beam_initialized = false;
 986         }
 987 }
 988
 989 void Draw_ArcBeam(entity this)
 990 {
 991         float dt = time - this.move_time;
 992         this.move_time = time;
 993         if(dt <= 0) { return; }
 994
 995         if(!this.beam_usevieworigin)
 996         {
 997                 InterpolateOrigin_Do(this);
 998         }
 999
1000         // origin = beam starting origin
1001         // v_angle = wanted/aim direction
1002         // angles = current direction of beam
1003
1004         vector start_pos;
1005         vector wantdir; //= view_forward;
1006         vector beamdir; //= this.beam_dir;
1007
1008         float segments;
1009         if(this.beam_usevieworigin)
1010         {
1011                 // WEAPONTODO:
1012                 // Currently we have to replicate nearly the same method of figuring
1013                 // out the shotdir that the server does... Ideally in the future we
1014                 // should be able to acquire this from a generalized function built
1015                 // into a weapon system for client code.
1016
1017                 // find where we are aiming
1018                 makevectors(warpzone_save_view_angles);
1019                 vector forward = v_forward;
1020                 vector right = v_right;
1021                 vector up = v_up;
1022
1023                 // decide upon start position
1024                 if(this.beam_usevieworigin == 2)
1025                         { start_pos = warpzone_save_view_origin; }
1026                 else
1027                         { start_pos = this.origin; }
1028
1029                 // trace forward with an estimation
1030                 WarpZone_TraceLine(
1031                         start_pos,
1032                         start_pos + forward * this.beam_range,
1033                         MOVE_NOMONSTERS,
1034                         this
1035                 );
1036
1037                 // untransform in case our trace went through a warpzone
1038                 vector end_pos = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
1039
1040                 // un-adjust trueaim if shotend is too close
1041                 if(vdist(end_pos - start_pos, <, g_trueaim_minrange))
1042                         end_pos = start_pos + (forward * g_trueaim_minrange);
1043
1044                 // move shot origin to the actual gun muzzle origin
1045                 vector origin_offset =
1046                           right * -this.beam_shotorigin.y
1047                         + up * this.beam_shotorigin.z;
1048
1049                 start_pos = start_pos + origin_offset;
1050
1051                 // Move it also forward, but only as far as possible without hitting anything. Don't poke into walls!
1052                 traceline(start_pos, start_pos + forward * this.beam_shotorigin.x, MOVE_NORMAL, this);
1053                 start_pos = trace_endpos;
1054
1055                 // calculate the aim direction now
1056                 wantdir = normalize(end_pos - start_pos);
1057
1058                 if(!this.beam_initialized)
1059                 {
1060                         this.beam_dir = wantdir;
1061                         this.beam_initialized = true;
1062                 }
1063
1064                 if(this.beam_dir != wantdir)
1065                 {
1066                         // calculate how much we're going to move the end of the beam to the want position
1067                         // WEAPONTODO (server and client):
1068                         // blendfactor never actually becomes 0 in this situation, which is a problem
1069                         // regarding precision... this means that this.beam_dir and w_shotdir approach
1070                         // eachother, however they never actually become the same value with this method.
1071                         // Perhaps we should do some form of rounding/snapping?
1072                         float angle = vlen(wantdir - this.beam_dir) * RAD2DEG;
1073                         if(angle && (angle > this.beam_maxangle))
1074                         {
1075                                 // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
1076                                 float blendfactor = bound(
1077                                         0,
1078                                         (1 - (this.beam_returnspeed * frametime)),
1079                                         min(this.beam_maxangle / angle, 1)
1080                                 );
1081                                 this.beam_dir = normalize((wantdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
1082                         }
1083                         else
1084                         {
1085                                 // the radius is not too far yet, no worries :D
1086                                 float blendfactor = bound(
1087                                         0,
1088                                         (1 - (this.beam_returnspeed * frametime)),
1089                                         1
1090                                 );
1091                                 this.beam_dir = normalize((wantdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
1092                         }
1093
1094                         // calculate how many segments are needed
1095                         float max_allowed_segments;
1096
1097                         if(this.beam_distancepersegment)
1098                         {
1099                                 max_allowed_segments = min(
1100                                         ARC_MAX_SEGMENTS,
1101                                         1 + (vlen(wantdir / this.beam_distancepersegment))
1102                                 );
1103                         }
1104                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
1105
1106                         if(this.beam_degreespersegment)
1107                         {
1108                                 segments = bound(
1109                                         1,
1110                                         (
1111                                                 min(
1112                                                         angle,
1113                                                         this.beam_maxangle
1114                                                 )
1115                                                 /
1116                                                 this.beam_degreespersegment
1117                                         ),
1118                                         max_allowed_segments
1119                                 );
1120                         }
1121                         else { segments = 1; }
1122                 }
1123                 else { segments = 1; }
1124
1125                 // set the beam direction which the rest of the code will refer to
1126                 beamdir = this.beam_dir;
1127
1128                 // finally, set this.angles to the proper direction so that muzzle attachment points in proper direction
1129                 this.angles = fixedvectoangles2(forward, up); // TODO(Samual): is this == warpzone_save_view_angles?
1130         }
1131         else
1132         {
1133                 // set the values from the provided info from the networked entity
1134                 start_pos = this.origin;
1135                 wantdir = this.v_angle;
1136                 beamdir = this.angles;
1137
1138                 if(beamdir != wantdir)
1139                 {
1140                         float angle = vlen(wantdir - beamdir) * RAD2DEG;
1141
1142                         // calculate how many segments are needed
1143                         float max_allowed_segments;
1144
1145                         if(this.beam_distancepersegment)
1146                         {
1147                                 max_allowed_segments = min(
1148                                         ARC_MAX_SEGMENTS,
1149                                         1 + (vlen(wantdir / this.beam_distancepersegment))
1150                                 );
1151                         }
1152                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
1153
1154                         if(this.beam_degreespersegment)
1155                         {
1156                                 segments = bound(
1157                                         1,
1158                                         (
1159                                                 min(
1160                                                         angle,
1161                                                         this.beam_maxangle
1162                                                 )
1163                                                 /
1164                                                 this.beam_degreespersegment
1165                                         ),
1166                                         max_allowed_segments
1167                                 );
1168                         }
1169                         else { segments = 1; }
1170                 }
1171                 else { segments = 1; }
1172         }
1173
1174         setorigin(this, start_pos);
1175         this.beam_muzzleentity.angles_z = random() * 360; // WEAPONTODO: use avelocity instead?
1176
1177         vector beam_endpos = (start_pos + (beamdir * this.beam_range));
1178         vector beam_controlpoint = start_pos + wantdir * (this.beam_range * (1 - this.beam_tightness));
1179
1180         Draw_ArcBeam_callback_entity = this;
1181         Draw_ArcBeam_callback_last_thickness = 0;
1182         Draw_ArcBeam_callback_last_top = start_pos;
1183         Draw_ArcBeam_callback_last_bottom = start_pos;
1184
1185         vector last_origin = start_pos;
1186         vector original_start_pos = start_pos;
1187
1188         float i;
1189         for(i = 1; i <= segments; ++i)
1190         {
1191                 // WEAPONTODO (client):
1192                 // In order to do nice fading and pointing on the starting segment, we must always
1193                 // have that drawn as a separate triangle... However, that is difficult to do when
1194                 // keeping in mind the above problems and also optimizing the amount of segments
1195                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
1196
1197                 vector new_origin = bezier_quadratic_getpoint(
1198                         start_pos,
1199                         beam_controlpoint,
1200                         beam_endpos,
1201                         i / segments);
1202
1203                 WarpZone_TraceBox_ThroughZone(
1204                         last_origin,
1205                         '0 0 0',
1206                         '0 0 0',
1207                         new_origin,
1208                         MOVE_NORMAL,
1209                         NULL,
1210                         NULL,
1211                         Draw_ArcBeam_callback
1212                 );
1213
1214                 // Do all the transforms for warpzones right now, as we already "are" in the post-trace
1215                 // system (if we hit a player, that's always BEHIND the last passed wz).
1216                 last_origin = trace_endpos;
1217                 start_pos = WarpZone_TransformOrigin(WarpZone_trace_transform, start_pos);
1218                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
1219                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
1220                 beamdir = WarpZone_TransformVelocity(WarpZone_trace_transform, beamdir);
1221                 Draw_ArcBeam_callback_last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
1222                 Draw_ArcBeam_callback_last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
1223
1224                 if(trace_fraction < 1) { break; }
1225         }
1226
1227         // visual effects for startpoint and endpoint
1228         if(this.beam_hiteffect)
1229         {
1230                 // FIXME we really should do this on the server so it actually
1231                 // matches gameplay. What this client side stuff is doing is no
1232                 // more than guesswork.
1233                 if((trace_ent || trace_fraction < 1) && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
1234                 pointparticles(
1235                         this.beam_hiteffect,
1236                         last_origin,
1237                         beamdir * -1,
1238                         frametime * 2
1239                 );
1240         }
1241         if(this.beam_hitlight[0])
1242         {
1243                 adddynamiclight(
1244                         last_origin,
1245                         this.beam_hitlight[0],
1246                         vec3(
1247                                 this.beam_hitlight[1],
1248                                 this.beam_hitlight[2],
1249                                 this.beam_hitlight[3]
1250                         )
1251                 );
1252         }
1253         if(this.beam_muzzleeffect)
1254         {
1255                 pointparticles(
1256                         this.beam_muzzleeffect,
1257                         original_start_pos + wantdir * 20,
1258                         wantdir * 1000,
1259                         frametime * 0.1
1260                 );
1261         }
1262         if(this.beam_muzzlelight[0])
1263         {
1264                 adddynamiclight(
1265                         original_start_pos + wantdir * 20,
1266                         this.beam_muzzlelight[0],
1267                         vec3(
1268                                 this.beam_muzzlelight[1],
1269                                 this.beam_muzzlelight[2],
1270                                 this.beam_muzzlelight[3]
1271                         )
1272                 );
1273         }
1274
1275         // cleanup
1276         Draw_ArcBeam_callback_entity = NULL;
1277         Draw_ArcBeam_callback_last_thickness = 0;
1278         Draw_ArcBeam_callback_last_top = '0 0 0';
1279         Draw_ArcBeam_callback_last_bottom = '0 0 0';
1280 }
1281
1282 void Remove_ArcBeam(entity this)
1283 {
1284         remove(this.beam_muzzleentity);
1285         sound(this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
1286 }
1287
1288 NET_HANDLE(ENT_CLIENT_ARC_BEAM, bool isnew)
1289 {
1290         int sf = ReadByte();
1291         entity flash;
1292
1293         if(isnew)
1294         {
1295                 int gunalign = W_GetGunAlignment(NULL);
1296
1297                 this.beam_shotorigin = arc_shotorigin[gunalign];
1298
1299                 // set other main attributes of the beam
1300                 this.draw = Draw_ArcBeam;
1301                 this.entremove = Remove_ArcBeam;
1302                 this.move_time = time;
1303                 loopsound(this, CH_SHOTS_SINGLE, SND(ARC_LOOP), VOL_BASE, ATTEN_NORM);
1304
1305                 flash = spawn();
1306                 flash.owner = this;
1307                 flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
1308                 flash.drawmask = MASK_NORMAL;
1309                 flash.solid = SOLID_NOT;
1310                 flash.avelocity_z = 5000;
1311                 setattachment(flash, this, "");
1312                 setorigin(flash, '0 0 0');
1313
1314                 this.beam_muzzleentity = flash;
1315         }
1316         else
1317         {
1318                 flash = this.beam_muzzleentity;
1319         }
1320
1321         if(sf & ARC_SF_SETTINGS) // settings information
1322         {
1323                 this.beam_degreespersegment = ReadShort();
1324                 this.beam_distancepersegment = ReadShort();
1325                 this.beam_maxangle = ReadShort();
1326                 this.beam_range = ReadCoord();
1327                 this.beam_returnspeed = ReadShort();
1328                 this.beam_tightness = (ReadByte() / 10);
1329
1330                 if(ReadByte())
1331                 {
1332                         if(autocvar_chase_active)
1333                                 { this.beam_usevieworigin = 1; }
1334                         else // use view origin
1335                                 { this.beam_usevieworigin = 2; }
1336                 }
1337                 else
1338                 {
1339                         this.beam_usevieworigin = 0;
1340                 }
1341
1342                 this.sv_entnum = ReadByte();
1343         }
1344
1345         if(!this.beam_usevieworigin)
1346         {
1347                 // this.iflags = IFLAG_ORIGIN | IFLAG_ANGLES | IFLAG_V_ANGLE; // why doesn't this work?
1348                 this.iflags = IFLAG_ORIGIN;
1349
1350                 InterpolateOrigin_Undo(this);
1351         }
1352
1353         if(sf & ARC_SF_START) // starting location
1354         {
1355                 this.origin_x = ReadCoord();
1356                 this.origin_y = ReadCoord();
1357                 this.origin_z = ReadCoord();
1358         }
1359         else if(this.beam_usevieworigin) // infer the location from player location
1360         {
1361                 if(this.beam_usevieworigin == 2)
1362                 {
1363                         // use view origin
1364                         this.origin = view_origin;
1365                 }
1366                 else
1367                 {
1368                         // use player origin so that third person display still works
1369                         this.origin = entcs_receiver(player_localnum).origin + ('0 0 1' * STAT(VIEWHEIGHT));
1370                 }
1371         }
1372
1373         setorigin(this, this.origin);
1374
1375         if(sf & ARC_SF_WANTDIR) // want/aim direction
1376         {
1377                 this.v_angle_x = ReadCoord();
1378                 this.v_angle_y = ReadCoord();
1379                 this.v_angle_z = ReadCoord();
1380         }
1381
1382         if(sf & ARC_SF_BEAMDIR) // beam direction
1383         {
1384                 this.angles_x = ReadCoord();
1385                 this.angles_y = ReadCoord();
1386                 this.angles_z = ReadCoord();
1387         }
1388
1389         if(sf & ARC_SF_BEAMTYPE) // beam type
1390         {
1391                 this.beam_type = ReadByte();
1392
1393                 vector beamcolor = ((autocvar_cl_arcbeam_teamcolor) ? colormapPaletteColor(stof(getplayerkeyvalue(this.sv_entnum - 1, "colors")) & 0x0F, true) : '1 1 1');
1394                 switch(this.beam_type)
1395                 {
1396                         case ARC_BT_MISS:
1397                         {
1398                                 this.beam_color = beamcolor;
1399                                 this.beam_alpha = 0.5;
1400                                 this.beam_thickness = 8;
1401                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1402                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1403                                 this.beam_hitlight[0] = 0;
1404                                 this.beam_hitlight[1] = 1;
1405                                 this.beam_hitlight[2] = 1;
1406                                 this.beam_hitlight[3] = 1;
1407                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1408                                 this.beam_muzzlelight[0] = 0;
1409                                 this.beam_muzzlelight[1] = 1;
1410                                 this.beam_muzzlelight[2] = 1;
1411                                 this.beam_muzzlelight[3] = 1;
1412                                 if(this.beam_muzzleeffect)
1413                                 {
1414                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1415                                         flash.alpha = this.beam_alpha;
1416                                         flash.colormod = this.beam_color;
1417                                         flash.scale = 0.5;
1418                                 }
1419                                 break;
1420                         }
1421                         case ARC_BT_WALL: // grenadelauncher_muzzleflash healray_muzzleflash
1422                         {
1423                                 this.beam_color = beamcolor;
1424                                 this.beam_alpha = 0.5;
1425                                 this.beam_thickness = 8;
1426                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1427                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1428                                 this.beam_hitlight[0] = 0;
1429                                 this.beam_hitlight[1] = 1;
1430                                 this.beam_hitlight[2] = 1;
1431                                 this.beam_hitlight[3] = 1;
1432                                 this.beam_muzzleeffect = NULL; // (EFFECT_GRENADE_MUZZLEFLASH);
1433                                 this.beam_muzzlelight[0] = 0;
1434                                 this.beam_muzzlelight[1] = 1;
1435                                 this.beam_muzzlelight[2] = 1;
1436                                 this.beam_muzzlelight[3] = 1;
1437                                 this.beam_image = "particles/lgbeam";
1438                                 if(this.beam_muzzleeffect)
1439                                 {
1440                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1441                                         flash.alpha = this.beam_alpha;
1442                                         flash.colormod = this.beam_color;
1443                                         flash.scale = 0.5;
1444                                 }
1445                                 break;
1446                         }
1447                         case ARC_BT_HEAL:
1448                         {
1449                                 this.beam_color = beamcolor;
1450                                 this.beam_alpha = 0.5;
1451                                 this.beam_thickness = 8;
1452                                 this.beam_traileffect = (EFFECT_ARC_BEAM_HEAL);
1453                                 this.beam_hiteffect = (EFFECT_ARC_BEAM_HEAL_IMPACT);
1454                                 this.beam_hitlight[0] = 0;
1455                                 this.beam_hitlight[1] = 1;
1456                                 this.beam_hitlight[2] = 1;
1457                                 this.beam_hitlight[3] = 1;
1458                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1459                                 this.beam_muzzlelight[0] = 0;
1460                                 this.beam_muzzlelight[1] = 1;
1461                                 this.beam_muzzlelight[2] = 1;
1462                                 this.beam_muzzlelight[3] = 1;
1463                                 this.beam_image = "particles/lgbeam";
1464                                 if(this.beam_muzzleeffect)
1465                                 {
1466                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1467                                         flash.alpha = this.beam_alpha;
1468                                         flash.colormod = this.beam_color;
1469                                         flash.scale = 0.5;
1470                                 }
1471                                 break;
1472                         }
1473                         case ARC_BT_HIT:
1474                         {
1475                                 this.beam_color = beamcolor;
1476                                 this.beam_alpha = 0.5;
1477                                 this.beam_thickness = 8;
1478                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1479                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1480                                 this.beam_hitlight[0] = 20;
1481                                 this.beam_hitlight[1] = 1;
1482                                 this.beam_hitlight[2] = 0;
1483                                 this.beam_hitlight[3] = 0;
1484                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1485                                 this.beam_muzzlelight[0] = 50;
1486                                 this.beam_muzzlelight[1] = 1;
1487                                 this.beam_muzzlelight[2] = 0;
1488                                 this.beam_muzzlelight[3] = 0;
1489                                 this.beam_image = "particles/lgbeam";
1490                                 if(this.beam_muzzleeffect)
1491                                 {
1492                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1493                                         flash.alpha = this.beam_alpha;
1494                                         flash.colormod = this.beam_color;
1495                                         flash.scale = 0.5;
1496                                 }
1497                                 break;
1498                         }
1499                         case ARC_BT_BURST_MISS:
1500                         {
1501                                 this.beam_color = beamcolor;
1502                                 this.beam_alpha = 0.5;
1503                                 this.beam_thickness = 14;
1504                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1505                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1506                                 this.beam_hitlight[0] = 0;
1507                                 this.beam_hitlight[1] = 1;
1508                                 this.beam_hitlight[2] = 1;
1509                                 this.beam_hitlight[3] = 1;
1510                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1511                                 this.beam_muzzlelight[0] = 0;
1512                                 this.beam_muzzlelight[1] = 1;
1513                                 this.beam_muzzlelight[2] = 1;
1514                                 this.beam_muzzlelight[3] = 1;
1515                                 this.beam_image = "particles/lgbeam";
1516                                 if(this.beam_muzzleeffect)
1517                                 {
1518                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1519                                         flash.alpha = this.beam_alpha;
1520                                         flash.colormod = this.beam_color;
1521                                         flash.scale = 0.5;
1522                                 }
1523                                 break;
1524                         }
1525                         case ARC_BT_BURST_WALL:
1526                         {
1527                                 this.beam_color = beamcolor;
1528                                 this.beam_alpha = 0.5;
1529                                 this.beam_thickness = 14;
1530                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1531                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1532                                 this.beam_hitlight[0] = 0;
1533                                 this.beam_hitlight[1] = 1;
1534                                 this.beam_hitlight[2] = 1;
1535                                 this.beam_hitlight[3] = 1;
1536                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1537                                 this.beam_muzzlelight[0] = 0;
1538                                 this.beam_muzzlelight[1] = 1;
1539                                 this.beam_muzzlelight[2] = 1;
1540                                 this.beam_muzzlelight[3] = 1;
1541                                 this.beam_image = "particles/lgbeam";
1542                                 if(this.beam_muzzleeffect)
1543                                 {
1544                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1545                                         flash.alpha = this.beam_alpha;
1546                                         flash.colormod = this.beam_color;
1547                                         flash.scale = 0.5;
1548                                 }
1549                                 break;
1550                         }
1551                         case ARC_BT_BURST_HEAL:
1552                         {
1553                                 this.beam_color = beamcolor;
1554                                 this.beam_alpha = 0.5;
1555                                 this.beam_thickness = 14;
1556                                 this.beam_traileffect = (EFFECT_ARC_BEAM_HEAL);
1557                                 this.beam_hiteffect = (EFFECT_ARC_BEAM_HEAL_IMPACT2);
1558                                 this.beam_hitlight[0] = 0;
1559                                 this.beam_hitlight[1] = 1;
1560                                 this.beam_hitlight[2] = 1;
1561                                 this.beam_hitlight[3] = 1;
1562                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1563                                 this.beam_muzzlelight[0] = 0;
1564                                 this.beam_muzzlelight[1] = 1;
1565                                 this.beam_muzzlelight[2] = 1;
1566                                 this.beam_muzzlelight[3] = 1;
1567                                 this.beam_image = "particles/lgbeam";
1568                                 if(this.beam_muzzleeffect)
1569                                 {
1570                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1571                                         flash.alpha = this.beam_alpha;
1572                                         flash.colormod = this.beam_color;
1573                                         flash.scale = 0.5;
1574                                 }
1575                                 break;
1576                         }
1577                         case ARC_BT_BURST_HIT:
1578                         {
1579                                 this.beam_color = beamcolor;
1580                                 this.beam_alpha = 0.5;
1581                                 this.beam_thickness = 14;
1582                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1583                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1584                                 this.beam_hitlight[0] = 0;
1585                                 this.beam_hitlight[1] = 1;
1586                                 this.beam_hitlight[2] = 1;
1587                                 this.beam_hitlight[3] = 1;
1588                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1589                                 this.beam_muzzlelight[0] = 0;
1590                                 this.beam_muzzlelight[1] = 1;
1591                                 this.beam_muzzlelight[2] = 1;
1592                                 this.beam_muzzlelight[3] = 1;
1593                                 this.beam_image = "particles/lgbeam";
1594                                 if(this.beam_muzzleeffect)
1595                                 {
1596                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1597                                         flash.alpha = this.beam_alpha;
1598                                         flash.colormod = this.beam_color;
1599                                         flash.scale = 0.5;
1600                                 }
1601                                 break;
1602                         }
1603
1604                         // shouldn't be possible, but lets make it colorful if it does :D
1605                         default:
1606                         {
1607                                 this.beam_color = randomvec();
1608                                 this.beam_alpha = 1;
1609                                 this.beam_thickness = 8;
1610                                 this.beam_traileffect = NULL;
1611                                 this.beam_hiteffect = NULL;
1612                                 this.beam_hitlight[0] = 0;
1613                                 this.beam_hitlight[1] = 1;
1614                                 this.beam_hitlight[2] = 1;
1615                                 this.beam_hitlight[3] = 1;
1616                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1617                                 this.beam_muzzlelight[0] = 0;
1618                                 this.beam_muzzlelight[1] = 1;
1619                                 this.beam_muzzlelight[2] = 1;
1620                                 this.beam_muzzlelight[3] = 1;
1621                                 this.beam_image = "particles/lgbeam";
1622                                 if(this.beam_muzzleeffect)
1623                                 {
1624                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1625                                         flash.alpha = this.beam_alpha;
1626                                         flash.colormod = this.beam_color;
1627                                         flash.scale = 0.5;
1628                                 }
1629                                 break;
1630                         }
1631                 }
1632         }
1633
1634         if(!this.beam_usevieworigin)
1635         {
1636                 InterpolateOrigin_Note(this);
1637         }
1638         return true;
1639 }
1640
1641 #endif
1642 #endif