qcsrc/common/weapons/weapon/blaster.qc

   1 #ifndef IMPLEMENTATION
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ BLASTER,
   4 /* function  */ W_Blaster,
   5 /* ammotype  */ ammo_none,
   6 /* impulse   */ 1,
   7 /* flags     */ WEP_FLAG_NORMAL | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating    */ 0,
   9 /* color     */ '1 0.5 0.5',
  10 /* modelname */ "laser",
  11 /* model     */ MDL_BLASTER_ITEM,
  12 /* simplemdl */ "foobar",
  13 /* crosshair */ "gfx/crosshairlaser 0.5",
  14 /* wepimg    */ "weaponlaser",
  15 /* refname   */ "blaster",
  16 /* wepname   */ _("Blaster")
  17 );
  18
  19 #define BLASTER_SETTINGS(w_cvar,w_prop) BLASTER_SETTINGS_LIST(w_cvar, w_prop, BLASTER, blaster)
  20 #define BLASTER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  21         w_cvar(id, sn, BOTH, animtime) \
  22         w_cvar(id, sn, BOTH, damage) \
  23         w_cvar(id, sn, BOTH, delay) \
  24         w_cvar(id, sn, BOTH, edgedamage) \
  25         w_cvar(id, sn, BOTH, force) \
  26         w_cvar(id, sn, BOTH, force_zscale) \
  27         w_cvar(id, sn, BOTH, lifetime) \
  28         w_cvar(id, sn, BOTH, radius) \
  29         w_cvar(id, sn, BOTH, refire) \
  30         w_cvar(id, sn, BOTH, shotangle) \
  31         w_cvar(id, sn, BOTH, speed) \
  32         w_cvar(id, sn, BOTH, spread) \
  33         w_cvar(id, sn, NONE, secondary) \
  34         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  35         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  36         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  37         w_prop(id, sn, float,  weaponstart, weaponstart) \
  38         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  39         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  40
  41 #ifdef SVQC
  42 BLASTER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  43 .float blaster_damage;
  44 .float blaster_edgedamage;
  45 .float blaster_radius;
  46 .float blaster_force;
  47 .float blaster_lifetime;
  48 #endif
  49 #endif
  50 #ifdef IMPLEMENTATION
  51 #ifdef SVQC
  52 void spawnfunc_weapon_blaster(void) { weapon_defaultspawnfunc(WEP_BLASTER.m_id); }
  53 void spawnfunc_weapon_laser(void) { spawnfunc_weapon_blaster(); }
  54
  55 void W_Blaster_Touch(void)
  56 {SELFPARAM();
  57         PROJECTILE_TOUCH;
  58
  59         self.event_damage = func_null;
  60
  61         RadiusDamage(
  62                 self,
  63                 self.realowner,
  64                 self.blaster_damage,
  65                 self.blaster_edgedamage,
  66                 self.blaster_radius,
  67                 world,
  68                 world,
  69                 self.blaster_force,
  70                 self.projectiledeathtype,
  71                 other
  72         );
  73
  74         remove(self);
  75 }
  76
  77 void W_Blaster_Think(void)
  78 {SELFPARAM();
  79         self.movetype = MOVETYPE_FLY;
  80         self.think = SUB_Remove;
  81         self.nextthink = time + self.blaster_lifetime;
  82         CSQCProjectile(self, true, PROJECTILE_BLASTER, true);
  83 }
  84
  85 void W_Blaster_Attack(
  86         float atk_deathtype,
  87         float atk_shotangle,
  88         float atk_damage,
  89         float atk_edgedamage,
  90         float atk_radius,
  91         float atk_force,
  92         float atk_speed,
  93         float atk_spread,
  94         float atk_delay,
  95         float atk_lifetime)
  96 {SELFPARAM();
  97         vector s_forward = v_forward * cos(atk_shotangle * DEG2RAD) + v_up * sin(atk_shotangle * DEG2RAD);
  98
  99         W_SetupShot_Dir(self, s_forward, false, 3, SND(LASERGUN_FIRE), CH_WEAPON_B, atk_damage);
 100         Send_Effect(EFFECT_BLASTER_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 101
 102         entity missile = spawn();
 103         missile.owner = missile.realowner = self;
 104         missile.classname = "blasterbolt";
 105         missile.bot_dodge = true;
 106         missile.bot_dodgerating = atk_damage;
 107         PROJECTILE_MAKETRIGGER(missile);
 108
 109         missile.blaster_damage = atk_damage;
 110         missile.blaster_edgedamage = atk_edgedamage;
 111         missile.blaster_radius = atk_radius;
 112         missile.blaster_force = atk_force;
 113         missile.blaster_lifetime = atk_lifetime;
 114
 115         setorigin(missile, w_shotorg);
 116         setsize(missile, '0 0 0', '0 0 0');
 117
 118         W_SetupProjVelocity_Explicit(
 119                 missile,
 120                 w_shotdir,
 121                 v_up,
 122                 atk_speed,
 123                 0,
 124                 0,
 125                 atk_spread,
 126                 false
 127         );
 128
 129         missile.angles = vectoangles(missile.velocity);
 130
 131         //missile.glow_color = 250; // 244, 250
 132         //missile.glow_size = 120;
 133
 134         missile.touch = W_Blaster_Touch;
 135         missile.flags = FL_PROJECTILE;
 136         missile.missile_flags = MIF_SPLASH;
 137         missile.projectiledeathtype = atk_deathtype;
 138         missile.think = W_Blaster_Think;
 139         missile.nextthink = time + atk_delay;
 140
 141         MUTATOR_CALLHOOK(EditProjectile, self, missile);
 142
 143         if(time >= missile.nextthink)
 144         {
 145                 WITH(entity, self, missile, missile.think());
 146         }
 147 }
 148 bool W_Blaster(entity thiswep, int request)
 149 {SELFPARAM();
 150         switch(request)
 151         {
 152                 case WR_AIM:
 153                 {
 154                         if(WEP_CVAR(blaster, secondary))
 155                         {
 156                                 if((random() * (WEP_CVAR_PRI(blaster, damage) + WEP_CVAR_SEC(blaster, damage))) > WEP_CVAR_PRI(blaster, damage))
 157                                         { self.BUTTON_ATCK2 = bot_aim(WEP_CVAR_SEC(blaster, speed), 0, WEP_CVAR_SEC(blaster, lifetime), false); }
 158                                 else
 159                                         { self.BUTTON_ATCK = bot_aim(WEP_CVAR_PRI(blaster, speed), 0, WEP_CVAR_PRI(blaster, lifetime), false); }
 160                         }
 161                         else
 162                                 { self.BUTTON_ATCK = bot_aim(WEP_CVAR_PRI(blaster, speed), 0, WEP_CVAR_PRI(blaster, lifetime), false); }
 163
 164                         return true;
 165                 }
 166
 167                 case WR_THINK:
 168                 {
 169                         if(self.BUTTON_ATCK)
 170                         {
 171                                 if(weapon_prepareattack(0, WEP_CVAR_PRI(blaster, refire)))
 172                                 {
 173                                         W_Blaster_Attack(
 174                                                 WEP_BLASTER.m_id,
 175                                                 WEP_CVAR_PRI(blaster, shotangle),
 176                                                 WEP_CVAR_PRI(blaster, damage),
 177                                                 WEP_CVAR_PRI(blaster, edgedamage),
 178                                                 WEP_CVAR_PRI(blaster, radius),
 179                                                 WEP_CVAR_PRI(blaster, force),
 180                                                 WEP_CVAR_PRI(blaster, speed),
 181                                                 WEP_CVAR_PRI(blaster, spread),
 182                                                 WEP_CVAR_PRI(blaster, delay),
 183                                                 WEP_CVAR_PRI(blaster, lifetime)
 184                                         );
 185                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(blaster, animtime), w_ready);
 186                                 }
 187                         }
 188                         else if(self.BUTTON_ATCK2)
 189                         {
 190                                 switch(WEP_CVAR(blaster, secondary))
 191                                 {
 192                                         case 0: // switch to last used weapon
 193                                         {
 194                                                 if(self.switchweapon == WEP_BLASTER.m_id) // don't do this if already switching
 195                                                         W_LastWeapon();
 196                                                 break;
 197                                         }
 198
 199                                         case 1: // normal projectile secondary
 200                                         {
 201                                                 if(weapon_prepareattack(1, WEP_CVAR_SEC(blaster, refire)))
 202                                                 {
 203                                                         W_Blaster_Attack(
 204                                                                 WEP_BLASTER.m_id | HITTYPE_SECONDARY,
 205                                                                 WEP_CVAR_SEC(blaster, shotangle),
 206                                                                 WEP_CVAR_SEC(blaster, damage),
 207                                                                 WEP_CVAR_SEC(blaster, edgedamage),
 208                                                                 WEP_CVAR_SEC(blaster, radius),
 209                                                                 WEP_CVAR_SEC(blaster, force),
 210                                                                 WEP_CVAR_SEC(blaster, speed),
 211                                                                 WEP_CVAR_SEC(blaster, spread),
 212                                                                 WEP_CVAR_SEC(blaster, delay),
 213                                                                 WEP_CVAR_SEC(blaster, lifetime)
 214                                                         );
 215                                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(blaster, animtime), w_ready);
 216                                                 }
 217
 218                                                 break;
 219                                         }
 220                                 }
 221                         }
 222                         return true;
 223                 }
 224
 225                 case WR_INIT:
 226                 {
 227                         BLASTER_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 228                         return true;
 229                 }
 230
 231                 case WR_SETUP:
 232                 {
 233                         self.ammo_field = ammo_none;
 234                         return true;
 235                 }
 236
 237                 case WR_CHECKAMMO1:
 238                 case WR_CHECKAMMO2:
 239                 {
 240                         return true; // laser has infinite ammo
 241                 }
 242
 243                 case WR_CONFIG:
 244                 {
 245                         BLASTER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 246                         return true;
 247                 }
 248
 249                 case WR_SUICIDEMESSAGE:
 250                 {
 251                         return WEAPON_BLASTER_SUICIDE;
 252                 }
 253
 254                 case WR_KILLMESSAGE:
 255                 {
 256                         return WEAPON_BLASTER_MURDER;
 257                 }
 258         }
 259         return false;
 260 }
 261 #endif
 262 #ifdef CSQC
 263 bool W_Blaster(entity thiswep, int request)
 264 {SELFPARAM();
 265         switch(request)
 266         {
 267                 case WR_IMPACTEFFECT:
 268                 {
 269                         vector org2;
 270                         org2 = w_org + w_backoff * 6;
 271                         pointparticles(particleeffectnum(EFFECT_BLASTER_IMPACT), org2, w_backoff * 1000, 1);
 272                         if(!w_issilent) { sound(self, CH_SHOTS, SND_LASERIMPACT, VOL_BASE, ATTN_NORM); }
 273                         return true;
 274                 }
 275
 276                 case WR_INIT:
 277                 {
 278                         return true;
 279                 }
 280                 case WR_ZOOMRETICLE:
 281                 {
 282                         // no weapon specific image for this weapon
 283                         return false;
 284                 }
 285         }
 286         return false;
 287 }
 288 #endif
 289 #endif