qcsrc/common/weapons/weapon/devastator.qc

   1 #ifndef IMPLEMENTATION
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ DEVASTATOR,
   4 /* function  */ W_Devastator,
   5 /* ammotype  */ ammo_rockets,
   6 /* impulse   */ 9,
   7 /* flags     */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating    */ BOT_PICKUP_RATING_HIGH,
   9 /* color     */ '1 1 0',
  10 /* modelname */ "rl",
  11 /* model     */ MDL_DEVASTATOR_ITEM,
  12 /* simplemdl */ "foobar",
  13 /* crosshair */ "gfx/crosshairrocketlauncher 0.7",
  14 /* wepimg    */ "weaponrocketlauncher",
  15 /* refname   */ "devastator",
  16 /* wepname   */ _("Devastator")
  17 );
  18
  19 #define DEVASTATOR_SETTINGS(w_cvar,w_prop) DEVASTATOR_SETTINGS_LIST(w_cvar, w_prop, DEVASTATOR, devastator)
  20 #define DEVASTATOR_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  21         w_cvar(id, sn, NONE, ammo) \
  22         w_cvar(id, sn, NONE, animtime) \
  23         w_cvar(id, sn, NONE, damage) \
  24         w_cvar(id, sn, NONE, damageforcescale) \
  25         w_cvar(id, sn, NONE, detonatedelay) \
  26         w_cvar(id, sn, NONE, edgedamage) \
  27         w_cvar(id, sn, NONE, force) \
  28         w_cvar(id, sn, NONE, guidedelay) \
  29         w_cvar(id, sn, NONE, guidegoal) \
  30         w_cvar(id, sn, NONE, guiderate) \
  31         w_cvar(id, sn, NONE, guideratedelay) \
  32         w_cvar(id, sn, NONE, guidestop) \
  33         w_cvar(id, sn, NONE, health) \
  34         w_cvar(id, sn, NONE, lifetime) \
  35         w_cvar(id, sn, NONE, radius) \
  36         w_cvar(id, sn, NONE, refire) \
  37         w_cvar(id, sn, NONE, remote_damage) \
  38         w_cvar(id, sn, NONE, remote_edgedamage) \
  39         w_cvar(id, sn, NONE, remote_force) \
  40         w_cvar(id, sn, NONE, remote_jump_damage) \
  41         w_cvar(id, sn, NONE, remote_jump_radius) \
  42         w_cvar(id, sn, NONE, remote_jump_velocity_z_add) \
  43         w_cvar(id, sn, NONE, remote_jump_velocity_z_max) \
  44         w_cvar(id, sn, NONE, remote_jump_velocity_z_min) \
  45         w_cvar(id, sn, NONE, remote_radius) \
  46         w_cvar(id, sn, NONE, speed) \
  47         w_cvar(id, sn, NONE, speedaccel) \
  48         w_cvar(id, sn, NONE, speedstart) \
  49         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  50         w_prop(id, sn, float,  reloading_time, reload_time) \
  51         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  52         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  53         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  54         w_prop(id, sn, float,  weaponstart, weaponstart) \
  55         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  56         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  57
  58 #ifdef SVQC
  59 DEVASTATOR_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  60 .float rl_release;
  61 .float rl_detonate_later;
  62 #endif
  63 #endif
  64 #ifdef IMPLEMENTATION
  65 #ifdef SVQC
  66 void spawnfunc_weapon_devastator(void) { weapon_defaultspawnfunc(WEP_DEVASTATOR.m_id); }
  67 void spawnfunc_weapon_rocketlauncher(void) { spawnfunc_weapon_devastator(); }
  68
  69 void W_Devastator_Unregister(void)
  70 {SELFPARAM();
  71         if(self.realowner && self.realowner.lastrocket == self)
  72         {
  73                 self.realowner.lastrocket = world;
  74                 // self.realowner.rl_release = 1;
  75         }
  76 }
  77
  78 void W_Devastator_Explode(void)
  79 {SELFPARAM();
  80         W_Devastator_Unregister();
  81
  82         if(other.takedamage == DAMAGE_AIM)
  83                 if(IS_PLAYER(other))
  84                         if(DIFF_TEAM(self.realowner, other))
  85                                 if(other.deadflag == DEAD_NO)
  86                                         if(IsFlying(other))
  87                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
  88
  89         self.event_damage = func_null;
  90         self.takedamage = DAMAGE_NO;
  91
  92         RadiusDamage(
  93                 self,
  94                 self.realowner,
  95                 WEP_CVAR(devastator, damage),
  96                 WEP_CVAR(devastator, edgedamage),
  97                 WEP_CVAR(devastator, radius),
  98                 world,
  99                 world,
 100                 WEP_CVAR(devastator, force),
 101                 self.projectiledeathtype,
 102                 other
 103         );
 104
 105         if(self.realowner.weapon == WEP_DEVASTATOR.m_id)
 106         {
 107                 if(self.realowner.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo))
 108                 if(!(self.realowner.items & IT_UNLIMITED_WEAPON_AMMO))
 109                 {
 110                         self.realowner.cnt = WEP_DEVASTATOR.m_id;
 111                         ATTACK_FINISHED(self.realowner) = time;
 112                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
 113                 }
 114         }
 115         remove(self);
 116 }
 117
 118 void W_Devastator_DoRemoteExplode(void)
 119 {SELFPARAM();
 120         W_Devastator_Unregister();
 121
 122         self.event_damage = func_null;
 123         self.takedamage = DAMAGE_NO;
 124
 125         float handled_as_rocketjump = false;
 126
 127         entity head = WarpZone_FindRadius(
 128                 self.origin,
 129                 WEP_CVAR(devastator, remote_jump_radius),
 130                 false
 131         );
 132
 133         while(head)
 134         {
 135                 if(head.takedamage && (head == self.realowner))
 136                 {
 137                         float distance_to_head = vlen(self.origin - head.WarpZone_findradius_nearest);
 138                         if(distance_to_head <= WEP_CVAR(devastator, remote_jump_radius))
 139                         {
 140                                 // we handled this as a rocketjump :)
 141                                 handled_as_rocketjump = true;
 142
 143                                 // modify velocity
 144                                 head.velocity_x *= 0.9;
 145                                 head.velocity_y *= 0.9;
 146                                 head.velocity_z = bound(
 147                                         WEP_CVAR(devastator, remote_jump_velocity_z_min),
 148                                         head.velocity.z + WEP_CVAR(devastator, remote_jump_velocity_z_add),
 149                                         WEP_CVAR(devastator, remote_jump_velocity_z_max)
 150                                 );
 151
 152                                 // now do the damage
 153                                 RadiusDamage(
 154                                         self,
 155                                         head,
 156                                         WEP_CVAR(devastator, remote_jump_damage),
 157                                         WEP_CVAR(devastator, remote_jump_damage),
 158                                         WEP_CVAR(devastator, remote_jump_radius),
 159                                         world,
 160                                         head,
 161                                         0,
 162                                         self.projectiledeathtype | HITTYPE_BOUNCE,
 163                                         world
 164                                 );
 165                                 break;
 166                         }
 167                 }
 168                 head = head.chain;
 169         }
 170
 171         RadiusDamage(
 172                 self,
 173                 self.realowner,
 174                 WEP_CVAR(devastator, remote_damage),
 175                 WEP_CVAR(devastator, remote_edgedamage),
 176                 WEP_CVAR(devastator, remote_radius),
 177                 (handled_as_rocketjump ? head : world),
 178                 world,
 179                 WEP_CVAR(devastator, remote_force),
 180                 self.projectiledeathtype | HITTYPE_BOUNCE,
 181                 world
 182         );
 183
 184         if(self.realowner.weapon == WEP_DEVASTATOR.m_id)
 185         {
 186                 if(self.realowner.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo))
 187                 if(!(self.realowner.items & IT_UNLIMITED_WEAPON_AMMO))
 188                 {
 189                         self.realowner.cnt = WEP_DEVASTATOR.m_id;
 190                         ATTACK_FINISHED(self.realowner) = time;
 191                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
 192                 }
 193         }
 194         remove(self);
 195 }
 196
 197 void W_Devastator_RemoteExplode(void)
 198 {SELFPARAM();
 199         if(self.realowner.deadflag == DEAD_NO)
 200         if(self.realowner.lastrocket)
 201         {
 202                 if((self.spawnshieldtime >= 0)
 203                         ? (time >= self.spawnshieldtime) // timer
 204                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > WEP_CVAR(devastator, remote_radius)) // safety device
 205                 )
 206                 {
 207                         W_Devastator_DoRemoteExplode();
 208                 }
 209         }
 210 }
 211
 212 vector W_Devastator_SteerTo(vector thisdir, vector goaldir, float maxturn_cos)
 213 {
 214         if(thisdir * goaldir > maxturn_cos)
 215                 return goaldir;
 216         if(thisdir * goaldir < -0.9998) // less than 1 degree and opposite
 217                 return thisdir; // refuse to guide (better than letting a numerical error happen)
 218         float f, m2;
 219         vector v;
 220         // solve:
 221         //   g = normalize(thisdir + goaldir * X)
 222         //   thisdir * g = maxturn
 223         //
 224         //   gg = thisdir + goaldir * X
 225         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 226         //
 227         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 228         f = thisdir * goaldir;
 229         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 230         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 231         m2 = maxturn_cos * maxturn_cos;
 232         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 233         return normalize(thisdir + goaldir * v.y); // the larger solution!
 234 }
 235 // assume thisdir == -goaldir:
 236 //   f == -1
 237 //   v = solve_qadratic(m2 - 1, -2 * (m2 - 1), m2 - 1)
 238 //   (m2 - 1) x^2 - 2 * (m2 - 1) * x + (m2 - 1) = 0
 239 //   x^2 - 2 * x + 1 = 0
 240 //   (x - 1)^2 = 0
 241 //   x = 1
 242 //   normalize(thisdir + goaldir)
 243 //   normalize(0)
 244
 245 void W_Devastator_Think(void)
 246 {SELFPARAM();
 247         vector desireddir, olddir, newdir, desiredorigin, goal;
 248         float velspeed, f;
 249         self.nextthink = time;
 250         if(time > self.cnt)
 251         {
 252                 other = world;
 253                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 254                 W_Devastator_Explode();
 255                 return;
 256         }
 257
 258         // accelerate
 259         makevectors(self.angles.x * '-1 0 0' + self.angles.y * '0 1 0');
 260         velspeed = WEP_CVAR(devastator, speed) * W_WeaponSpeedFactor() - (self.velocity * v_forward);
 261         if(velspeed > 0)
 262                 self.velocity = self.velocity + v_forward * min(WEP_CVAR(devastator, speedaccel) * W_WeaponSpeedFactor() * frametime, velspeed);
 263
 264         // laser guided, or remote detonation
 265         if(self.realowner.weapon == WEP_DEVASTATOR.m_id)
 266         {
 267                 if(self == self.realowner.lastrocket)
 268                 if(!self.realowner.rl_release)
 269                 if(!self.BUTTON_ATCK2)
 270                 if(WEP_CVAR(devastator, guiderate))
 271                 if(time > self.pushltime)
 272                 if(self.realowner.deadflag == DEAD_NO)
 273                 {
 274                         f = WEP_CVAR(devastator, guideratedelay);
 275                         if(f)
 276                                 f = bound(0, (time - self.pushltime) / f, 1);
 277                         else
 278                                 f = 1;
 279
 280                         velspeed = vlen(self.velocity);
 281
 282                         makevectors(self.realowner.v_angle);
 283                         desireddir = WarpZone_RefSys_TransformVelocity(self.realowner, self, v_forward);
 284                         desiredorigin = WarpZone_RefSys_TransformOrigin(self.realowner, self, self.realowner.origin + self.realowner.view_ofs);
 285                         olddir = normalize(self.velocity);
 286
 287                         // now it gets tricky... we want to move like some curve to approximate the target direction
 288                         // but we are limiting the rate at which we can turn!
 289                         goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + WEP_CVAR(devastator, guidegoal)) * desireddir;
 290                         newdir = W_Devastator_SteerTo(olddir, normalize(goal - self.origin), cos(WEP_CVAR(devastator, guiderate) * f * frametime * DEG2RAD));
 291
 292                         self.velocity = newdir * velspeed;
 293                         self.angles = vectoangles(self.velocity);
 294
 295                         if(!self.count)
 296                         {
 297                                 Send_Effect(EFFECT_ROCKET_GUIDE, self.origin, self.velocity, 1);
 298                                 // TODO add a better sound here
 299                                 sound(self.realowner, CH_WEAPON_B, SND_ROCKET_MODE, VOL_BASE, ATTN_NORM);
 300                                 self.count = 1;
 301                         }
 302                 }
 303
 304                 if(self.rl_detonate_later)
 305                         W_Devastator_RemoteExplode();
 306         }
 307
 308         if(self.csqcprojectile_clientanimate == 0)
 309                 UpdateCSQCProjectile(self);
 310 }
 311
 312 void W_Devastator_Touch(void)
 313 {SELFPARAM();
 314         if(WarpZone_Projectile_Touch())
 315         {
 316                 if(wasfreed(self))
 317                         W_Devastator_Unregister();
 318                 return;
 319         }
 320         W_Devastator_Unregister();
 321         W_Devastator_Explode();
 322 }
 323
 324 void W_Devastator_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 325 {SELFPARAM();
 326         if(self.health <= 0)
 327                 return;
 328
 329         if(!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 330                 return; // g_projectiles_damage says to halt
 331
 332         self.health = self.health - damage;
 333         self.angles = vectoangles(self.velocity);
 334
 335         if(self.health <= 0)
 336                 W_PrepareExplosionByDamage(attacker, W_Devastator_Explode);
 337 }
 338
 339 void W_Devastator_Attack(void)
 340 {SELFPARAM();
 341         entity missile;
 342         entity flash;
 343
 344         W_DecreaseAmmo(WEP_CVAR(devastator, ammo));
 345
 346         W_SetupShot_ProjectileSize(self, '-3 -3 -3', '3 3 3', false, 5, SND(ROCKET_FIRE), CH_WEAPON_A, WEP_CVAR(devastator, damage));
 347         Send_Effect(EFFECT_ROCKET_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 348
 349         missile = WarpZone_RefSys_SpawnSameRefSys(self);
 350         missile.owner = missile.realowner = self;
 351         self.lastrocket = missile;
 352         if(WEP_CVAR(devastator, detonatedelay) >= 0)
 353                 missile.spawnshieldtime = time + WEP_CVAR(devastator, detonatedelay);
 354         else
 355                 missile.spawnshieldtime = -1;
 356         missile.pushltime = time + WEP_CVAR(devastator, guidedelay);
 357         missile.classname = "rocket";
 358         missile.bot_dodge = true;
 359         missile.bot_dodgerating = WEP_CVAR(devastator, damage) * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 360
 361         missile.takedamage = DAMAGE_YES;
 362         missile.damageforcescale = WEP_CVAR(devastator, damageforcescale);
 363         missile.health = WEP_CVAR(devastator, health);
 364         missile.event_damage = W_Devastator_Damage;
 365         missile.damagedbycontents = true;
 366
 367         missile.movetype = MOVETYPE_FLY;
 368         PROJECTILE_MAKETRIGGER(missile);
 369         missile.projectiledeathtype = WEP_DEVASTATOR.m_id;
 370         setsize(missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 371
 372         setorigin(missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 373         W_SetupProjVelocity_Basic(missile, WEP_CVAR(devastator, speedstart), 0);
 374         missile.angles = vectoangles(missile.velocity);
 375
 376         missile.touch = W_Devastator_Touch;
 377         missile.think = W_Devastator_Think;
 378         missile.nextthink = time;
 379         missile.cnt = time + WEP_CVAR(devastator, lifetime);
 380         missile.flags = FL_PROJECTILE;
 381         missile.missile_flags = MIF_SPLASH;
 382
 383         CSQCProjectile(missile, WEP_CVAR(devastator, guiderate) == 0 && WEP_CVAR(devastator, speedaccel) == 0, PROJECTILE_ROCKET, false); // because of fly sound
 384
 385         // muzzle flash for 1st person view
 386         flash = spawn();
 387         setmodel(flash, MDL_DEVASTATOR_MUZZLEFLASH); // precision set below
 388         SUB_SetFade(flash, time, 0.1);
 389         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 390         W_AttachToShotorg(flash, '5 0 0');
 391
 392         // common properties
 393         MUTATOR_CALLHOOK(EditProjectile, self, missile);
 394 }
 395
 396 bool W_Devastator(entity thiswep, int req)
 397 {SELFPARAM();
 398         entity rock;
 399         float rockfound;
 400         float ammo_amount;
 401         switch(req)
 402         {
 403                 #if 0
 404                 case WR_AIM:
 405                 {
 406                         // aim and decide to fire if appropriate
 407                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(devastator, speed), 0, WEP_CVAR(devastator, lifetime), false);
 408                         if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 409                         {
 410                                 // decide whether to detonate rockets
 411                                 entity missile, targetlist, targ;
 412                                 targetlist = findchainfloat(bot_attack, true);
 413                                 for(missile = world; (missile = find(missile, classname, "rocket")); ) if(missile.realowner == self)
 414                                 {
 415                                         targ = targetlist;
 416                                         while(targ)
 417                                         {
 418                                                 if(targ != missile.realowner && vlen(targ.origin - missile.origin) < WEP_CVAR(devastator, radius))
 419                                                 {
 420                                                         self.BUTTON_ATCK2 = true;
 421                                                         break;
 422                                                 }
 423                                                 targ = targ.chain;
 424                                         }
 425                                 }
 426
 427                                 if(self.BUTTON_ATCK2) self.BUTTON_ATCK = false;
 428                         }
 429
 430                         return true;
 431                 }
 432                 #else
 433                 case WR_AIM:
 434                 {
 435                         // aim and decide to fire if appropriate
 436                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(devastator, speed), 0, WEP_CVAR(devastator, lifetime), false);
 437                         if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 438                         {
 439                                 // decide whether to detonate rockets
 440                                 entity missile, targetlist, targ;
 441                                 float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 442                                 float selfdamage, teamdamage, enemydamage;
 443                                 edgedamage = WEP_CVAR(devastator, edgedamage);
 444                                 coredamage = WEP_CVAR(devastator, damage);
 445                                 edgeradius = WEP_CVAR(devastator, radius);
 446                                 recipricoledgeradius = 1 / edgeradius;
 447                                 selfdamage = 0;
 448                                 teamdamage = 0;
 449                                 enemydamage = 0;
 450                                 targetlist = findchainfloat(bot_attack, true);
 451                                 missile = find(world, classname, "rocket");
 452                                 while(missile)
 453                                 {
 454                                         if(missile.realowner != self)
 455                                         {
 456                                                 missile = find(missile, classname, "rocket");
 457                                                 continue;
 458                                         }
 459                                         targ = targetlist;
 460                                         while(targ)
 461                                         {
 462                                                 d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 463                                                 d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 464                                                 // count potential damage according to type of target
 465                                                 if(targ == self)
 466                                                         selfdamage = selfdamage + d;
 467                                                 else if(targ.team == self.team && teamplay)
 468                                                         teamdamage = teamdamage + d;
 469                                                 else if(bot_shouldattack(targ))
 470                                                         enemydamage = enemydamage + d;
 471                                                 targ = targ.chain;
 472                                         }
 473                                         missile = find(missile, classname, "rocket");
 474                                 }
 475                                 float desirabledamage;
 476                                 desirabledamage = enemydamage;
 477                                 if(time > self.invincible_finished && time > self.spawnshieldtime)
 478                                         desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 479                                 if(teamplay && self.team)
 480                                         desirabledamage = desirabledamage - teamdamage;
 481
 482                                 missile = find(world, classname, "rocket");
 483                                 while(missile)
 484                                 {
 485                                         if(missile.realowner != self)
 486                                         {
 487                                                 missile = find(missile, classname, "rocket");
 488                                                 continue;
 489                                         }
 490                                         makevectors(missile.v_angle);
 491                                         targ = targetlist;
 492                                         if(skill > 9) // normal players only do this for the target they are tracking
 493                                         {
 494                                                 targ = targetlist;
 495                                                 while(targ)
 496                                                 {
 497                                                         if(
 498                                                                 (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 499                                                                 && desirabledamage > 0.1*coredamage
 500                                                         )self.BUTTON_ATCK2 = true;
 501                                                         targ = targ.chain;
 502                                                 }
 503                                         }else{
 504                                                 float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 505                                                 //As the distance gets larger, a correct detonation gets near imposible
 506                                                 //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 507                                                 if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 508                                                         if(IS_PLAYER(self.enemy))
 509                                                                 if(desirabledamage >= 0.1*coredamage)
 510                                                                         if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 511                                                                                 self.BUTTON_ATCK2 = true;
 512                                         //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 513                                         }
 514
 515                                         missile = find(missile, classname, "rocket");
 516                                 }
 517                                 // if we would be doing at X percent of the core damage, detonate it
 518                                 // but don't fire a new shot at the same time!
 519                                 if(desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 520                                         self.BUTTON_ATCK2 = true;
 521                                 if((skill > 6.5) && (selfdamage > self.health))
 522                                         self.BUTTON_ATCK2 = false;
 523                                 //if(self.BUTTON_ATCK2 == true)
 524                                 //      dprint(ftos(desirabledamage),"\n");
 525                                 if(self.BUTTON_ATCK2 == true) self.BUTTON_ATCK = false;
 526                         }
 527
 528                         return true;
 529                 }
 530                 #endif
 531                 case WR_THINK:
 532                 {
 533                         if(WEP_CVAR(devastator, reload_ammo) && self.clip_load < WEP_CVAR(devastator, ammo)) // forced reload
 534                                 _WEP_ACTION(self.weapon, WR_RELOAD);
 535                         else
 536                         {
 537                                 if(self.BUTTON_ATCK)
 538                                 {
 539                                         if(self.rl_release || WEP_CVAR(devastator, guidestop))
 540                                         if(weapon_prepareattack(0, WEP_CVAR(devastator, refire)))
 541                                         {
 542                                                 W_Devastator_Attack();
 543                                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(devastator, animtime), w_ready);
 544                                                 self.rl_release = 0;
 545                                         }
 546                                 }
 547                                 else
 548                                         self.rl_release = 1;
 549
 550                                 if(self.BUTTON_ATCK2)
 551                                 if(self.switchweapon == WEP_DEVASTATOR.m_id)
 552                                 {
 553                                         rockfound = 0;
 554                                         for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.realowner == self)
 555                                         {
 556                                                 if(!rock.rl_detonate_later)
 557                                                 {
 558                                                         rock.rl_detonate_later = true;
 559                                                         rockfound = 1;
 560                                                 }
 561                                         }
 562                                         if(rockfound)
 563                                                 sound(self, CH_WEAPON_B, SND_ROCKET_DET, VOL_BASE, ATTN_NORM);
 564                                 }
 565                         }
 566
 567                         return true;
 568                 }
 569                 case WR_INIT:
 570                 {
 571                         DEVASTATOR_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 572                         return true;
 573                 }
 574                 case WR_SETUP:
 575                 {
 576                         self.rl_release = 1;
 577                         return true;
 578                 }
 579                 case WR_CHECKAMMO1:
 580                 {
 581                         #if 0
 582                         // don't switch while guiding a missile
 583                         if(ATTACK_FINISHED(self) <= time || self.weapon != WEP_DEVASTATOR.m_id)
 584                         {
 585                                 ammo_amount = false;
 586                                 if(WEP_CVAR(devastator, reload_ammo))
 587                                 {
 588                                         if(self.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo) && self.(weapon_load[WEP_DEVASTATOR.m_id]) < WEP_CVAR(devastator, ammo))
 589                                                 ammo_amount = true;
 590                                 }
 591                                 else if(self.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo))
 592                                         ammo_amount = true;
 593                                 return !ammo_amount;
 594                         }
 595                         #endif
 596                         #if 0
 597                         if(self.rl_release == 0)
 598                         {
 599                                 LOG_INFOF("W_Devastator(WR_CHECKAMMO1): %d, %.2f, %d: TRUE\n", self.rl_release, self.WEP_AMMO(DEVASTATOR), WEP_CVAR(devastator, ammo));
 600                                 return true;
 601                         }
 602                         else
 603                         {
 604                                 ammo_amount = self.WEP_AMMO(DEVASTATOR) >= WEP_CVAR(devastator, ammo);
 605                                 ammo_amount += self.(weapon_load[WEP_DEVASTATOR.m_id]) >= WEP_CVAR(devastator, ammo);
 606                                 LOG_INFOF("W_Devastator(WR_CHECKAMMO1): %d, %.2f, %d: %s\n", self.rl_release, self.WEP_AMMO(DEVASTATOR), WEP_CVAR(devastator, ammo), (ammo_amount ? "TRUE" : "FALSE"));
 607                                 return ammo_amount;
 608                         }
 609                         #else
 610                         ammo_amount = self.WEP_AMMO(DEVASTATOR) >= WEP_CVAR(devastator, ammo);
 611                         ammo_amount += self.(weapon_load[WEP_DEVASTATOR.m_id]) >= WEP_CVAR(devastator, ammo);
 612                         return ammo_amount;
 613                         #endif
 614                 }
 615                 case WR_CHECKAMMO2:
 616                 {
 617                         return false;
 618                 }
 619                 case WR_CONFIG:
 620                 {
 621                         DEVASTATOR_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 622                         return true;
 623                 }
 624                 case WR_RESETPLAYER:
 625                 {
 626                         self.rl_release = 0;
 627                         return true;
 628                 }
 629                 case WR_RELOAD:
 630                 {
 631                         W_Reload(WEP_CVAR(devastator, ammo), SND(RELOAD));
 632                         return true;
 633                 }
 634                 case WR_SUICIDEMESSAGE:
 635                 {
 636                         return WEAPON_DEVASTATOR_SUICIDE;
 637                 }
 638                 case WR_KILLMESSAGE:
 639                 {
 640                         if((w_deathtype & HITTYPE_BOUNCE) || (w_deathtype & HITTYPE_SPLASH))
 641                                 return WEAPON_DEVASTATOR_MURDER_SPLASH;
 642                         else
 643                                 return WEAPON_DEVASTATOR_MURDER_DIRECT;
 644                 }
 645         }
 646         return false;
 647 }
 648 #endif
 649 #ifdef CSQC
 650 bool W_Devastator(entity thiswep, int req)
 651 {SELFPARAM();
 652         switch(req)
 653         {
 654                 case WR_IMPACTEFFECT:
 655                 {
 656                         vector org2;
 657                         org2 = w_org + w_backoff * 12;
 658                         pointparticles(particleeffectnum(EFFECT_ROCKET_EXPLODE), org2, '0 0 0', 1);
 659                         if(!w_issilent)
 660                                 sound(self, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTN_NORM);
 661
 662                         return true;
 663                 }
 664                 case WR_INIT:
 665                 {
 666                         return true;
 667                 }
 668                 case WR_ZOOMRETICLE:
 669                 {
 670                         // no weapon specific image for this weapon
 671                         return false;
 672                 }
 673         }
 674         return false;
 675 }
 676 #endif
 677 #endif