qcsrc/common/weapons/weapon/devastator.qc

   1 #ifndef IMPLEMENTATION
   2 CLASS(Devastator, Weapon)
   3 /* ammotype  */ ATTRIB(Devastator, ammo_field, .int, ammo_rockets)
   4 /* impulse   */ ATTRIB(Devastator, impulse, int, 9)
   5 /* flags     */ ATTRIB(Devastator, spawnflags, int, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH);
   6 /* rating    */ ATTRIB(Devastator, bot_pickupbasevalue, float, BOT_PICKUP_RATING_HIGH);
   7 /* color     */ ATTRIB(Devastator, wpcolor, vector, '1 1 0');
   8 /* modelname */ ATTRIB(Devastator, mdl, string, "rl");
   9 #ifndef MENUQC
  10 /* model     */ ATTRIB(Devastator, m_model, Model, MDL_DEVASTATOR_ITEM);
  11 #endif
  12 /* crosshair */ ATTRIB(Devastator, w_crosshair, string, "gfx/crosshairrocketlauncher");
  13 /* crosshair */ ATTRIB(Devastator, w_crosshair_size, float, 0.7);
  14 /* wepimg    */ ATTRIB(Devastator, model2, string, "weaponrocketlauncher");
  15 /* refname   */ ATTRIB(Devastator, netname, string, "devastator");
  16 /* wepname   */ ATTRIB(Devastator, m_name, string, _("Devastator"));
  17
  18 #define X(BEGIN, P, END, class, prefix) \
  19         BEGIN(class) \
  20                 P(class, prefix, ammo, float, NONE) \
  21         P(class, prefix, animtime, float, NONE) \
  22         P(class, prefix, damageforcescale, float, NONE) \
  23         P(class, prefix, damage, float, NONE) \
  24         P(class, prefix, detonatedelay, float, NONE) \
  25         P(class, prefix, edgedamage, float, NONE) \
  26         P(class, prefix, force, float, NONE) \
  27         P(class, prefix, guidedelay, float, NONE) \
  28         P(class, prefix, guidegoal, float, NONE) \
  29         P(class, prefix, guideratedelay, float, NONE) \
  30         P(class, prefix, guiderate, float, NONE) \
  31         P(class, prefix, guidestop, float, NONE) \
  32         P(class, prefix, health, float, NONE) \
  33         P(class, prefix, lifetime, float, NONE) \
  34         P(class, prefix, radius, float, NONE) \
  35         P(class, prefix, refire, float, NONE) \
  36                 P(class, prefix, reload_ammo, float, NONE) \
  37                 P(class, prefix, reload_time, float, NONE) \
  38         P(class, prefix, remote_damage, float, NONE) \
  39         P(class, prefix, remote_edgedamage, float, NONE) \
  40         P(class, prefix, remote_force, float, NONE) \
  41         P(class, prefix, remote_jump_damage, float, NONE) \
  42         P(class, prefix, remote_jump_radius, float, NONE) \
  43         P(class, prefix, remote_jump_velocity_z_add, float, NONE) \
  44         P(class, prefix, remote_jump_velocity_z_max, float, NONE) \
  45         P(class, prefix, remote_jump_velocity_z_min, float, NONE) \
  46         P(class, prefix, remote_radius, float, NONE) \
  47         P(class, prefix, speedaccel, float, NONE) \
  48         P(class, prefix, speedstart, float, NONE) \
  49         P(class, prefix, speed, float, NONE) \
  50                 P(class, prefix, switchdelay_drop, float, NONE) \
  51                 P(class, prefix, switchdelay_raise, float, NONE) \
  52                 P(class, prefix, weaponreplace, string,NONE) \
  53                 P(class, prefix, weaponstartoverride, float, NONE) \
  54                 P(class, prefix, weaponstart, float, NONE) \
  55                 P(class, prefix, weaponthrowable, float, NONE) \
  56         END()
  57         W_PROPS(X, Devastator, devastator)
  58 #undef X
  59
  60 ENDCLASS(Devastator)
  61 REGISTER_WEAPON(DEVASTATOR, devastator, NEW(Devastator));
  62
  63 #ifdef SVQC
  64 .float rl_release;
  65 .float rl_detonate_later;
  66 #endif
  67 #endif
  68 #ifdef IMPLEMENTATION
  69 #ifdef SVQC
  70 spawnfunc(weapon_devastator) { weapon_defaultspawnfunc(this, WEP_DEVASTATOR); }
  71 spawnfunc(weapon_rocketlauncher) { spawnfunc_weapon_devastator(this); }
  72
  73 .entity lastrocket;
  74
  75 void W_Devastator_Unregister()
  76 {SELFPARAM();
  77         if(self.realowner && self.realowner.lastrocket == self)
  78         {
  79                 self.realowner.lastrocket = world;
  80                 // self.realowner.rl_release = 1;
  81         }
  82 }
  83
  84 void W_Devastator_Explode()
  85 {SELFPARAM();
  86         W_Devastator_Unregister();
  87
  88         if(other.takedamage == DAMAGE_AIM)
  89                 if(IS_PLAYER(other))
  90                         if(DIFF_TEAM(self.realowner, other))
  91                                 if(other.deadflag == DEAD_NO)
  92                                         if(IsFlying(other))
  93                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
  94
  95         self.event_damage = func_null;
  96         self.takedamage = DAMAGE_NO;
  97
  98         RadiusDamage(
  99                 self,
 100                 self.realowner,
 101                 WEP_CVAR(devastator, damage),
 102                 WEP_CVAR(devastator, edgedamage),
 103                 WEP_CVAR(devastator, radius),
 104                 world,
 105                 world,
 106                 WEP_CVAR(devastator, force),
 107                 self.projectiledeathtype,
 108                 other
 109         );
 110
 111         if(self.realowner.weapon == WEP_DEVASTATOR.m_id)
 112         {
 113                 if(self.realowner.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo))
 114                 if(!(self.realowner.items & IT_UNLIMITED_WEAPON_AMMO))
 115                 {
 116                         self.realowner.cnt = WEP_DEVASTATOR.m_id;
 117                         int slot = 0; // TODO: unhardcode
 118                         ATTACK_FINISHED(self.realowner, slot) = time;
 119                         PS(self.realowner).m_switchweapon = w_getbestweapon(self.realowner);
 120                 }
 121         }
 122         remove(self);
 123 }
 124
 125 void W_Devastator_DoRemoteExplode(.entity weaponentity)
 126 {SELFPARAM();
 127         W_Devastator_Unregister();
 128
 129         self.event_damage = func_null;
 130         self.takedamage = DAMAGE_NO;
 131
 132         float handled_as_rocketjump = false;
 133
 134         entity head = WarpZone_FindRadius(
 135                 self.origin,
 136                 WEP_CVAR(devastator, remote_jump_radius),
 137                 false
 138         );
 139
 140         while(head)
 141         {
 142                 if(head.takedamage && (head == self.realowner))
 143                 {
 144                         float distance_to_head = vlen(self.origin - head.WarpZone_findradius_nearest);
 145                         if(distance_to_head <= WEP_CVAR(devastator, remote_jump_radius))
 146                         {
 147                                 // we handled this as a rocketjump :)
 148                                 handled_as_rocketjump = true;
 149
 150                                 // modify velocity
 151                                 head.velocity_x *= 0.9;
 152                                 head.velocity_y *= 0.9;
 153                                 head.velocity_z = bound(
 154                                         WEP_CVAR(devastator, remote_jump_velocity_z_min),
 155                                         head.velocity.z + WEP_CVAR(devastator, remote_jump_velocity_z_add),
 156                                         WEP_CVAR(devastator, remote_jump_velocity_z_max)
 157                                 );
 158
 159                                 // now do the damage
 160                                 RadiusDamage(
 161                                         self,
 162                                         head,
 163                                         WEP_CVAR(devastator, remote_jump_damage),
 164                                         WEP_CVAR(devastator, remote_jump_damage),
 165                                         WEP_CVAR(devastator, remote_jump_radius),
 166                                         world,
 167                                         head,
 168                                         0,
 169                                         self.projectiledeathtype | HITTYPE_BOUNCE,
 170                                         world
 171                                 );
 172                                 break;
 173                         }
 174                 }
 175                 head = head.chain;
 176         }
 177
 178         RadiusDamage(
 179                 self,
 180                 self.realowner,
 181                 WEP_CVAR(devastator, remote_damage),
 182                 WEP_CVAR(devastator, remote_edgedamage),
 183                 WEP_CVAR(devastator, remote_radius),
 184                 (handled_as_rocketjump ? head : world),
 185                 world,
 186                 WEP_CVAR(devastator, remote_force),
 187                 self.projectiledeathtype | HITTYPE_BOUNCE,
 188                 world
 189         );
 190
 191         if(self.realowner.weapon == WEP_DEVASTATOR.m_id)
 192         {
 193                 if(self.realowner.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo))
 194                 if(!(self.realowner.items & IT_UNLIMITED_WEAPON_AMMO))
 195                 {
 196                         self.realowner.cnt = WEP_DEVASTATOR.m_id;
 197                         int slot = weaponslot(weaponentity);
 198                         ATTACK_FINISHED(self.realowner, slot) = time;
 199                         PS(self.realowner).m_switchweapon = w_getbestweapon(self.realowner);
 200                 }
 201         }
 202         remove(self);
 203 }
 204
 205 void W_Devastator_RemoteExplode(.entity weaponentity)
 206 {SELFPARAM();
 207         if(self.realowner.deadflag == DEAD_NO)
 208         if(self.realowner.lastrocket)
 209         {
 210                 if((self.spawnshieldtime >= 0)
 211                         ? (time >= self.spawnshieldtime) // timer
 212                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > WEP_CVAR(devastator, remote_radius)) // safety device
 213                 )
 214                 {
 215                         W_Devastator_DoRemoteExplode(weaponentity);
 216                 }
 217         }
 218 }
 219
 220 vector W_Devastator_SteerTo(vector thisdir, vector goaldir, float maxturn_cos)
 221 {
 222         if(thisdir * goaldir > maxturn_cos)
 223                 return goaldir;
 224         if(thisdir * goaldir < -0.9998) // less than 1 degree and opposite
 225                 return thisdir; // refuse to guide (better than letting a numerical error happen)
 226         float f, m2;
 227         vector v;
 228         // solve:
 229         //   g = normalize(thisdir + goaldir * X)
 230         //   thisdir * g = maxturn
 231         //
 232         //   gg = thisdir + goaldir * X
 233         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 234         //
 235         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 236         f = thisdir * goaldir;
 237         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 238         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 239         m2 = maxturn_cos * maxturn_cos;
 240         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 241         return normalize(thisdir + goaldir * v.y); // the larger solution!
 242 }
 243 // assume thisdir == -goaldir:
 244 //   f == -1
 245 //   v = solve_qadratic(m2 - 1, -2 * (m2 - 1), m2 - 1)
 246 //   (m2 - 1) x^2 - 2 * (m2 - 1) * x + (m2 - 1) = 0
 247 //   x^2 - 2 * x + 1 = 0
 248 //   (x - 1)^2 = 0
 249 //   x = 1
 250 //   normalize(thisdir + goaldir)
 251 //   normalize(0)
 252
 253 void W_Devastator_Think()
 254 {SELFPARAM();
 255         vector desireddir, olddir, newdir, desiredorigin, goal;
 256         float velspeed, f;
 257         self.nextthink = time;
 258         if(time > self.cnt)
 259         {
 260                 other = world;
 261                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 262                 W_Devastator_Explode();
 263                 return;
 264         }
 265
 266         // accelerate
 267         makevectors(self.angles.x * '-1 0 0' + self.angles.y * '0 1 0');
 268         velspeed = WEP_CVAR(devastator, speed) * W_WeaponSpeedFactor() - (self.velocity * v_forward);
 269         if(velspeed > 0)
 270                 self.velocity = self.velocity + v_forward * min(WEP_CVAR(devastator, speedaccel) * W_WeaponSpeedFactor() * frametime, velspeed);
 271
 272         // laser guided, or remote detonation
 273         if(self.realowner.weapon == WEP_DEVASTATOR.m_id)
 274         {
 275                 if(self == self.realowner.lastrocket)
 276                 if(!self.realowner.rl_release)
 277                 if(!self.BUTTON_ATCK2)
 278                 if(WEP_CVAR(devastator, guiderate))
 279                 if(time > self.pushltime)
 280                 if(self.realowner.deadflag == DEAD_NO)
 281                 {
 282                         f = WEP_CVAR(devastator, guideratedelay);
 283                         if(f)
 284                                 f = bound(0, (time - self.pushltime) / f, 1);
 285                         else
 286                                 f = 1;
 287
 288                         velspeed = vlen(self.velocity);
 289
 290                         makevectors(self.realowner.v_angle);
 291                         desireddir = WarpZone_RefSys_TransformVelocity(self.realowner, self, v_forward);
 292                         desiredorigin = WarpZone_RefSys_TransformOrigin(self.realowner, self, self.realowner.origin + self.realowner.view_ofs);
 293                         olddir = normalize(self.velocity);
 294
 295                         // now it gets tricky... we want to move like some curve to approximate the target direction
 296                         // but we are limiting the rate at which we can turn!
 297                         goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + WEP_CVAR(devastator, guidegoal)) * desireddir;
 298                         newdir = W_Devastator_SteerTo(olddir, normalize(goal - self.origin), cos(WEP_CVAR(devastator, guiderate) * f * frametime * DEG2RAD));
 299
 300                         self.velocity = newdir * velspeed;
 301                         self.angles = vectoangles(self.velocity);
 302
 303                         if(!self.count)
 304                         {
 305                                 Send_Effect(EFFECT_ROCKET_GUIDE, self.origin, self.velocity, 1);
 306                                 // TODO add a better sound here
 307                                 sound(self.realowner, CH_WEAPON_B, SND_ROCKET_MODE, VOL_BASE, ATTN_NORM);
 308                                 self.count = 1;
 309                         }
 310                 }
 311
 312                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 313                 if(self.rl_detonate_later)
 314                         W_Devastator_RemoteExplode(weaponentity);
 315         }
 316
 317         if(self.csqcprojectile_clientanimate == 0)
 318                 UpdateCSQCProjectile(self);
 319 }
 320
 321 void W_Devastator_Touch()
 322 {SELFPARAM();
 323         if(WarpZone_Projectile_Touch())
 324         {
 325                 if(wasfreed(self))
 326                         W_Devastator_Unregister();
 327                 return;
 328         }
 329         W_Devastator_Unregister();
 330         W_Devastator_Explode();
 331 }
 332
 333 void W_Devastator_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 334 {SELFPARAM();
 335         if(self.health <= 0)
 336                 return;
 337
 338         if(!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 339                 return; // g_projectiles_damage says to halt
 340
 341         self.health = self.health - damage;
 342         self.angles = vectoangles(self.velocity);
 343
 344         if(self.health <= 0)
 345                 W_PrepareExplosionByDamage(attacker, W_Devastator_Explode);
 346 }
 347
 348 void W_Devastator_Attack(Weapon thiswep)
 349 {SELFPARAM();
 350         entity missile;
 351         entity flash;
 352
 353         W_DecreaseAmmo(thiswep, self, WEP_CVAR(devastator, ammo));
 354
 355         W_SetupShot_ProjectileSize(self, '-3 -3 -3', '3 3 3', false, 5, SND(ROCKET_FIRE), CH_WEAPON_A, WEP_CVAR(devastator, damage));
 356         Send_Effect(EFFECT_ROCKET_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 357
 358         missile = WarpZone_RefSys_SpawnSameRefSys(self);
 359         missile.owner = missile.realowner = self;
 360         self.lastrocket = missile;
 361         if(WEP_CVAR(devastator, detonatedelay) >= 0)
 362                 missile.spawnshieldtime = time + WEP_CVAR(devastator, detonatedelay);
 363         else
 364                 missile.spawnshieldtime = -1;
 365         missile.pushltime = time + WEP_CVAR(devastator, guidedelay);
 366         missile.classname = "rocket";
 367         missile.bot_dodge = true;
 368         missile.bot_dodgerating = WEP_CVAR(devastator, damage) * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 369
 370         missile.takedamage = DAMAGE_YES;
 371         missile.damageforcescale = WEP_CVAR(devastator, damageforcescale);
 372         missile.health = WEP_CVAR(devastator, health);
 373         missile.event_damage = W_Devastator_Damage;
 374         missile.damagedbycontents = true;
 375
 376         missile.movetype = MOVETYPE_FLY;
 377         PROJECTILE_MAKETRIGGER(missile);
 378         missile.projectiledeathtype = WEP_DEVASTATOR.m_id;
 379         setsize(missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 380
 381         setorigin(missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 382         W_SetupProjVelocity_Basic(missile, WEP_CVAR(devastator, speedstart), 0);
 383         missile.angles = vectoangles(missile.velocity);
 384
 385         missile.touch = W_Devastator_Touch;
 386         missile.think = W_Devastator_Think;
 387         missile.nextthink = time;
 388         missile.cnt = time + WEP_CVAR(devastator, lifetime);
 389         missile.flags = FL_PROJECTILE;
 390         missile.missile_flags = MIF_SPLASH;
 391
 392         CSQCProjectile(missile, WEP_CVAR(devastator, guiderate) == 0 && WEP_CVAR(devastator, speedaccel) == 0, PROJECTILE_ROCKET, false); // because of fly sound
 393
 394         // muzzle flash for 1st person view
 395         flash = spawn();
 396         setmodel(flash, MDL_DEVASTATOR_MUZZLEFLASH); // precision set below
 397         SUB_SetFade(flash, time, 0.1);
 398         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 399         W_AttachToShotorg(self, flash, '5 0 0');
 400
 401         // common properties
 402         MUTATOR_CALLHOOK(EditProjectile, self, missile);
 403 }
 404
 405                 #if 0
 406                 METHOD(Devastator, wr_aim, void(entity thiswep))
 407                 {
 408                         // aim and decide to fire if appropriate
 409                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(devastator, speed), 0, WEP_CVAR(devastator, lifetime), false);
 410                         if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 411                         {
 412                                 // decide whether to detonate rockets
 413                                 entity missile, targetlist, targ;
 414                                 targetlist = findchainfloat(bot_attack, true);
 415                                 for(missile = world; (missile = find(missile, classname, "rocket")); ) if(missile.realowner == self)
 416                                 {
 417                                         targ = targetlist;
 418                                         while(targ)
 419                                         {
 420                                                 if(targ != missile.realowner && vlen(targ.origin - missile.origin) < WEP_CVAR(devastator, radius))
 421                                                 {
 422                                                         self.BUTTON_ATCK2 = true;
 423                                                         break;
 424                                                 }
 425                                                 targ = targ.chain;
 426                                         }
 427                                 }
 428
 429                                 if(self.BUTTON_ATCK2) self.BUTTON_ATCK = false;
 430                         }
 431                 }
 432                 #else
 433                 METHOD(Devastator, wr_aim, void(entity thiswep))
 434                 {
 435                         // aim and decide to fire if appropriate
 436                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(devastator, speed), 0, WEP_CVAR(devastator, lifetime), false);
 437                         if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 438                         {
 439                                 // decide whether to detonate rockets
 440                                 entity missile, targetlist, targ;
 441                                 float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 442                                 float selfdamage, teamdamage, enemydamage;
 443                                 edgedamage = WEP_CVAR(devastator, edgedamage);
 444                                 coredamage = WEP_CVAR(devastator, damage);
 445                                 edgeradius = WEP_CVAR(devastator, radius);
 446                                 recipricoledgeradius = 1 / edgeradius;
 447                                 selfdamage = 0;
 448                                 teamdamage = 0;
 449                                 enemydamage = 0;
 450                                 targetlist = findchainfloat(bot_attack, true);
 451                                 missile = find(world, classname, "rocket");
 452                                 while(missile)
 453                                 {
 454                                         if(missile.realowner != self)
 455                                         {
 456                                                 missile = find(missile, classname, "rocket");
 457                                                 continue;
 458                                         }
 459                                         targ = targetlist;
 460                                         while(targ)
 461                                         {
 462                                                 d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 463                                                 d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 464                                                 // count potential damage according to type of target
 465                                                 if(targ == self)
 466                                                         selfdamage = selfdamage + d;
 467                                                 else if(targ.team == self.team && teamplay)
 468                                                         teamdamage = teamdamage + d;
 469                                                 else if(bot_shouldattack(targ))
 470                                                         enemydamage = enemydamage + d;
 471                                                 targ = targ.chain;
 472                                         }
 473                                         missile = find(missile, classname, "rocket");
 474                                 }
 475                                 float desirabledamage;
 476                                 desirabledamage = enemydamage;
 477                                 if(time > self.invincible_finished && time > self.spawnshieldtime)
 478                                         desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 479                                 if(teamplay && self.team)
 480                                         desirabledamage = desirabledamage - teamdamage;
 481
 482                                 missile = find(world, classname, "rocket");
 483                                 while(missile)
 484                                 {
 485                                         if(missile.realowner != self)
 486                                         {
 487                                                 missile = find(missile, classname, "rocket");
 488                                                 continue;
 489                                         }
 490                                         makevectors(missile.v_angle);
 491                                         targ = targetlist;
 492                                         if(skill > 9) // normal players only do this for the target they are tracking
 493                                         {
 494                                                 targ = targetlist;
 495                                                 while(targ)
 496                                                 {
 497                                                         if(
 498                                                                 (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 499                                                                 && desirabledamage > 0.1*coredamage
 500                                                         )self.BUTTON_ATCK2 = true;
 501                                                         targ = targ.chain;
 502                                                 }
 503                                         }else{
 504                                                 float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 505                                                 //As the distance gets larger, a correct detonation gets near imposible
 506                                                 //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 507                                                 if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 508                                                         if(IS_PLAYER(self.enemy))
 509                                                                 if(desirabledamage >= 0.1*coredamage)
 510                                                                         if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 511                                                                                 self.BUTTON_ATCK2 = true;
 512                                         //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 513                                         }
 514
 515                                         missile = find(missile, classname, "rocket");
 516                                 }
 517                                 // if we would be doing at X percent of the core damage, detonate it
 518                                 // but don't fire a new shot at the same time!
 519                                 if(desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 520                                         self.BUTTON_ATCK2 = true;
 521                                 if((skill > 6.5) && (selfdamage > self.health))
 522                                         self.BUTTON_ATCK2 = false;
 523                                 //if(self.BUTTON_ATCK2 == true)
 524                                 //      dprint(ftos(desirabledamage),"\n");
 525                                 if(self.BUTTON_ATCK2 == true) self.BUTTON_ATCK = false;
 526                         }
 527                 }
 528                 #endif
 529                 METHOD(Devastator, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 530                 {
 531                         if(WEP_CVAR(devastator, reload_ammo) && actor.clip_load < WEP_CVAR(devastator, ammo)) { // forced reload
 532                                 thiswep.wr_reload(thiswep);
 533                         } else {
 534                                 if(fire & 1)
 535                                 {
 536                                         if(actor.rl_release || WEP_CVAR(devastator, guidestop))
 537                                         if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(devastator, refire)))
 538                                         {
 539                                                 W_Devastator_Attack(thiswep);
 540                                                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(devastator, animtime), w_ready);
 541                                                 actor.rl_release = 0;
 542                                         }
 543                                 }
 544                                 else
 545                                         actor.rl_release = 1;
 546
 547                                 if(fire & 2)
 548                                 if(PS(actor).m_switchweapon == WEP_DEVASTATOR)
 549                                 {
 550                                         entity rock;
 551                                         bool rockfound = false;
 552                                         for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.realowner == actor)
 553                                         {
 554                                                 if(!rock.rl_detonate_later)
 555                                                 {
 556                                                         rock.rl_detonate_later = true;
 557                                                         rockfound = true;
 558                                                 }
 559                                         }
 560                                         if(rockfound)
 561                                                 sound(actor, CH_WEAPON_B, SND_ROCKET_DET, VOL_BASE, ATTN_NORM);
 562                                 }
 563                         }
 564                 }
 565                 METHOD(Devastator, wr_setup, void(entity thiswep))
 566                 {
 567                         self.rl_release = 1;
 568                 }
 569                 METHOD(Devastator, wr_checkammo1, bool(entity thiswep))
 570                 {
 571                         #if 0
 572                         // don't switch while guiding a missile
 573                         if(ATTACK_FINISHED(self, slot) <= time || self.weapon != WEP_DEVASTATOR.m_id)
 574                         {
 575                                 ammo_amount = false;
 576                                 if(WEP_CVAR(devastator, reload_ammo))
 577                                 {
 578                                         if(self.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo) && self.(weapon_load[WEP_DEVASTATOR.m_id]) < WEP_CVAR(devastator, ammo))
 579                                                 ammo_amount = true;
 580                                 }
 581                                 else if(self.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo))
 582                                         ammo_amount = true;
 583                                 return !ammo_amount;
 584                         }
 585                         #endif
 586                         #if 0
 587                         if(self.rl_release == 0)
 588                         {
 589                                 LOG_INFOF("W_Devastator(WR_CHECKAMMO1): %d, %.2f, %d: TRUE\n", self.rl_release, self.WEP_AMMO(DEVASTATOR), WEP_CVAR(devastator, ammo));
 590                                 return true;
 591                         }
 592                         else
 593                         {
 594                                 ammo_amount = self.WEP_AMMO(DEVASTATOR) >= WEP_CVAR(devastator, ammo);
 595                                 ammo_amount += self.(weapon_load[WEP_DEVASTATOR.m_id]) >= WEP_CVAR(devastator, ammo);
 596                                 LOG_INFOF("W_Devastator(WR_CHECKAMMO1): %d, %.2f, %d: %s\n", self.rl_release, self.WEP_AMMO(DEVASTATOR), WEP_CVAR(devastator, ammo), (ammo_amount ? "TRUE" : "FALSE"));
 597                                 return ammo_amount;
 598                         }
 599                         #else
 600                         float ammo_amount = self.WEP_AMMO(DEVASTATOR) >= WEP_CVAR(devastator, ammo);
 601                         ammo_amount += self.(weapon_load[WEP_DEVASTATOR.m_id]) >= WEP_CVAR(devastator, ammo);
 602                         return ammo_amount;
 603                         #endif
 604                 }
 605                 METHOD(Devastator, wr_checkammo2, bool(entity thiswep))
 606                 {
 607                         return false;
 608                 }
 609                 METHOD(Devastator, wr_resetplayer, void(entity thiswep))
 610                 {
 611                         self.lastrocket = NULL; // stop rocket guiding, no revenge from the grave!
 612                         self.rl_release = 0;
 613                 }
 614                 METHOD(Devastator, wr_reload, void(entity thiswep))
 615                 {
 616                         W_Reload(self, WEP_CVAR(devastator, ammo), SND(RELOAD));
 617                 }
 618                 METHOD(Devastator, wr_suicidemessage, int(entity thiswep))
 619                 {
 620                         return WEAPON_DEVASTATOR_SUICIDE;
 621                 }
 622                 METHOD(Devastator, wr_killmessage, int(entity thiswep))
 623                 {
 624                         if((w_deathtype & HITTYPE_BOUNCE) || (w_deathtype & HITTYPE_SPLASH))
 625                                 return WEAPON_DEVASTATOR_MURDER_SPLASH;
 626                         else
 627                                 return WEAPON_DEVASTATOR_MURDER_DIRECT;
 628                 }
 629
 630 #endif
 631 #ifdef CSQC
 632
 633                 METHOD(Devastator, wr_impacteffect, void(entity thiswep))
 634                 {
 635                         vector org2;
 636                         org2 = w_org + w_backoff * 12;
 637                         pointparticles(EFFECT_ROCKET_EXPLODE, org2, '0 0 0', 1);
 638                         if(!w_issilent)
 639                                 sound(self, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTN_NORM);
 640                 }
 641
 642 #endif
 643 #endif