qcsrc/common/weapons/weapon/machinegun.qc

   1 #ifndef IMPLEMENTATION
   2 CLASS(MachineGun, Weapon)
   3 /* ammotype  */ ATTRIB(MachineGun, ammo_field, .int, ammo_nails)
   4 /* impulse   */ ATTRIB(MachineGun, impulse, int, 3)
   5 /* flags     */ ATTRIB(MachineGun, spawnflags, int, WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN);
   6 /* rating    */ ATTRIB(MachineGun, bot_pickupbasevalue, float, BOT_PICKUP_RATING_MID);
   7 /* color     */ ATTRIB(MachineGun, wpcolor, vector, '1 1 0');
   8 /* modelname */ ATTRIB(MachineGun, mdl, string, "uzi");
   9 #ifndef MENUQC
  10 /* model     */ ATTRIB(MachineGun, m_model, Model, MDL_MACHINEGUN_ITEM);
  11 #endif
  12 /* crosshair */ ATTRIB(MachineGun, w_crosshair, string, "gfx/crosshairuzi");
  13 /* crosshair */ ATTRIB(MachineGun, w_crosshair_size, float, 0.6);
  14 /* wepimg    */ ATTRIB(MachineGun, model2, string, "weaponuzi");
  15 /* refname   */ ATTRIB(MachineGun, netname, string, "machinegun");
  16 /* wepname   */ ATTRIB(MachineGun, m_name, string, _("MachineGun"));
  17 ENDCLASS(MachineGun)
  18 REGISTER_WEAPON(MACHINEGUN, NEW(MachineGun));
  19
  20 #define MACHINEGUN_SETTINGS(w_cvar,w_prop) MACHINEGUN_SETTINGS_LIST(w_cvar, w_prop, MACHINEGUN, machinegun)
  21 #define MACHINEGUN_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  22         w_cvar(id, sn, NONE, spread_min) \
  23         w_cvar(id, sn, NONE, spread_max) \
  24         w_cvar(id, sn, NONE, spread_add) \
  25         w_cvar(id, sn, NONE, mode) \
  26         w_cvar(id, sn, NONE, first) \
  27         w_cvar(id, sn, NONE, first_damage) \
  28         w_cvar(id, sn, NONE, first_force) \
  29         w_cvar(id, sn, NONE, first_refire) \
  30         w_cvar(id, sn, NONE, first_spread) \
  31         w_cvar(id, sn, NONE, first_ammo) \
  32         w_cvar(id, sn, NONE, solidpenetration) \
  33         w_cvar(id, sn, NONE, sustained_damage) \
  34         w_cvar(id, sn, NONE, sustained_force) \
  35         w_cvar(id, sn, NONE, sustained_refire) \
  36         w_cvar(id, sn, NONE, sustained_spread) \
  37         w_cvar(id, sn, NONE, sustained_ammo) \
  38         w_cvar(id, sn, NONE, burst) \
  39         w_cvar(id, sn, NONE, burst_refire) \
  40         w_cvar(id, sn, NONE, burst_refire2) \
  41         w_cvar(id, sn, NONE, burst_animtime) \
  42         w_cvar(id, sn, NONE, burst_speed) \
  43         w_cvar(id, sn, NONE, burst_ammo) \
  44         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  45         w_prop(id, sn, float,  reloading_time, reload_time) \
  46         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  47         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  48         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  49         w_prop(id, sn, float,  weaponstart, weaponstart) \
  50         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  51         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  52
  53 #ifdef SVQC
  54 MACHINEGUN_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  55 #endif
  56 #endif
  57 #ifdef IMPLEMENTATION
  58 #ifdef SVQC
  59
  60 spawnfunc(weapon_machinegun)
  61 {
  62         if(autocvar_sv_q3acompat_machineshotgunswap)
  63         if(self.classname != "droppedweapon")
  64         {
  65                 weapon_defaultspawnfunc(this, WEP_SHOCKWAVE);
  66                 return;
  67         }
  68         weapon_defaultspawnfunc(this, WEP_MACHINEGUN);
  69 }
  70 spawnfunc(weapon_uzi) { spawnfunc_weapon_machinegun(this); }
  71
  72 void W_MachineGun_MuzzleFlash_Think()
  73 {SELFPARAM();
  74         this.frame += 2;
  75         this.scale *= 0.5;
  76         this.alpha -= 0.25;
  77         this.nextthink = time + 0.05;
  78
  79         if(this.alpha <= 0)
  80         {
  81                 this.think = SUB_Remove_self;
  82                 this.nextthink = time;
  83                 this.realowner.muzzle_flash = world;
  84                 return;
  85         }
  86
  87 }
  88
  89 void W_MachineGun_MuzzleFlash()
  90 {SELFPARAM();
  91         if(self.muzzle_flash == world)
  92                 self.muzzle_flash = spawn();
  93
  94         // muzzle flash for 1st person view
  95         setmodel(self.muzzle_flash, MDL_MACHINEGUN_MUZZLEFLASH); // precision set below
  96
  97         self.muzzle_flash.scale = 0.75;
  98         self.muzzle_flash.think = W_MachineGun_MuzzleFlash_Think;
  99         self.muzzle_flash.nextthink = time + 0.02;
 100         self.muzzle_flash.frame = 2;
 101         self.muzzle_flash.alpha = 0.75;
 102         self.muzzle_flash.angles_z = random() * 180;
 103         self.muzzle_flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 104         self.muzzle_flash.owner = self.muzzle_flash.realowner = self;
 105 }
 106
 107 void W_MachineGun_Attack(Weapon thiswep, int deathtype, .entity weaponentity)
 108 {SELFPARAM();
 109         W_SetupShot(self, true, 0, SND(UZI_FIRE), CH_WEAPON_A, ((self.misc_bulletcounter == 1) ? WEP_CVAR(machinegun, first_damage) : WEP_CVAR(machinegun, sustained_damage)));
 110         if(!autocvar_g_norecoil)
 111         {
 112                 self.punchangle_x = random() - 0.5;
 113                 self.punchangle_y = random() - 0.5;
 114         }
 115         int slot = weaponslot(weaponentity);
 116         // this attack_finished just enforces a cooldown at the end of a burst
 117         ATTACK_FINISHED(self, slot) = time + WEP_CVAR(machinegun, first_refire) * W_WeaponRateFactor();
 118
 119         if(self.misc_bulletcounter == 1)
 120                 fireBullet(w_shotorg, w_shotdir, WEP_CVAR(machinegun, first_spread), WEP_CVAR(machinegun, solidpenetration), WEP_CVAR(machinegun, first_damage), WEP_CVAR(machinegun, first_force), deathtype, 0);
 121         else
 122                 fireBullet(w_shotorg, w_shotdir, WEP_CVAR(machinegun, sustained_spread), WEP_CVAR(machinegun, solidpenetration), WEP_CVAR(machinegun, sustained_damage), WEP_CVAR(machinegun, sustained_force), deathtype, 0);
 123
 124         Send_Effect(EFFECT_MACHINEGUN_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 125
 126         W_MachineGun_MuzzleFlash();
 127         W_AttachToShotorg(self, self.muzzle_flash, '5 0 0');
 128
 129         // casing code
 130         if(autocvar_g_casings >= 2)
 131                 SpawnCasing(((random() * 50 + 50) * v_right) - (v_forward * (random() * 25 + 25)) - ((random() * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, self);
 132
 133         if(self.misc_bulletcounter == 1)
 134                 W_DecreaseAmmo(thiswep, self, WEP_CVAR(machinegun, first_ammo));
 135         else
 136                 W_DecreaseAmmo(thiswep, self, WEP_CVAR(machinegun, sustained_ammo));
 137 }
 138
 139 // weapon frames
 140 void W_MachineGun_Attack_Frame(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 141 {
 142         if(actor.weapon != actor.switchweapon) // abort immediately if switching
 143         {
 144                 w_ready(thiswep, actor, weaponentity, fire);
 145                 return;
 146         }
 147         if(actor.BUTTON_ATCK)
 148         {
 149                 if(!thiswep.wr_checkammo2(thiswep))
 150                 if(!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 151                 {
 152                         W_SwitchWeapon_Force(actor, Weapons_from(w_getbestweapon(actor)));
 153                         w_ready(thiswep, actor, weaponentity, fire);
 154                         return;
 155                 }
 156                 actor.misc_bulletcounter = actor.misc_bulletcounter + 1;
 157                 W_MachineGun_Attack(WEP_MACHINEGUN, WEP_MACHINEGUN.m_id, weaponentity);
 158                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(machinegun, sustained_refire), W_MachineGun_Attack_Frame);
 159         }
 160         else
 161                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(machinegun, sustained_refire), w_ready);
 162 }
 163
 164
 165 void W_MachineGun_Attack_Auto(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 166 {
 167         float machinegun_spread;
 168
 169         if(!(fire & 1))
 170         {
 171                 w_ready(thiswep, actor, weaponentity, fire);
 172                 return;
 173         }
 174
 175         if(!thiswep.wr_checkammo1(thiswep))
 176         if(!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 177         {
 178                 W_SwitchWeapon_Force(actor, Weapons_from(w_getbestweapon(actor)));
 179                 w_ready(thiswep, actor, weaponentity, fire);
 180                 return;
 181         }
 182
 183         W_DecreaseAmmo(WEP_MACHINEGUN, actor, WEP_CVAR(machinegun, sustained_ammo));
 184
 185         W_SetupShot(actor, true, 0, SND(UZI_FIRE), CH_WEAPON_A, WEP_CVAR(machinegun, sustained_damage));
 186         if(!autocvar_g_norecoil)
 187         {
 188                 actor.punchangle_x = random() - 0.5;
 189                 actor.punchangle_y = random() - 0.5;
 190         }
 191
 192         machinegun_spread = bound(WEP_CVAR(machinegun, spread_min), WEP_CVAR(machinegun, spread_min) + (WEP_CVAR(machinegun, spread_add) * actor.misc_bulletcounter), WEP_CVAR(machinegun, spread_max));
 193         fireBullet(w_shotorg, w_shotdir, machinegun_spread, WEP_CVAR(machinegun, solidpenetration), WEP_CVAR(machinegun, sustained_damage), WEP_CVAR(machinegun, sustained_force), WEP_MACHINEGUN.m_id, 0);
 194
 195         actor.misc_bulletcounter = actor.misc_bulletcounter + 1;
 196
 197         Send_Effect(EFFECT_MACHINEGUN_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 198
 199         W_MachineGun_MuzzleFlash();
 200         W_AttachToShotorg(actor, actor.muzzle_flash, '5 0 0');
 201
 202         if(autocvar_g_casings >= 2) // casing code
 203                 SpawnCasing(((random() * 50 + 50) * v_right) - (v_forward * (random() * 25 + 25)) - ((random() * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, actor);
 204
 205         int slot = weaponslot(weaponentity);
 206         ATTACK_FINISHED(actor, slot) = time + WEP_CVAR(machinegun, first_refire) * W_WeaponRateFactor();
 207         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(machinegun, sustained_refire), W_MachineGun_Attack_Auto);
 208 }
 209
 210 void W_MachineGun_Attack_Burst(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 211 {
 212         W_SetupShot(actor, true, 0, SND(UZI_FIRE), CH_WEAPON_A, WEP_CVAR(machinegun, sustained_damage));
 213         if(!autocvar_g_norecoil)
 214         {
 215                 actor.punchangle_x = random() - 0.5;
 216                 actor.punchangle_y = random() - 0.5;
 217         }
 218
 219         fireBullet(w_shotorg, w_shotdir, WEP_CVAR(machinegun, burst_speed), WEP_CVAR(machinegun, solidpenetration), WEP_CVAR(machinegun, sustained_damage), WEP_CVAR(machinegun, sustained_force), WEP_MACHINEGUN.m_id, 0);
 220
 221         Send_Effect(EFFECT_MACHINEGUN_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 222
 223         W_MachineGun_MuzzleFlash();
 224         W_AttachToShotorg(actor, actor.muzzle_flash, '5 0 0');
 225
 226         if(autocvar_g_casings >= 2) // casing code
 227                 SpawnCasing(((random() * 50 + 50) * v_right) - (v_forward * (random() * 25 + 25)) - ((random() * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, actor);
 228
 229         actor.misc_bulletcounter = actor.misc_bulletcounter + 1;
 230         if(actor.misc_bulletcounter == 0)
 231         {
 232                 int slot = weaponslot(weaponentity);
 233                 ATTACK_FINISHED(actor, slot) = time + WEP_CVAR(machinegun, burst_refire2) * W_WeaponRateFactor();
 234                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(machinegun, burst_animtime), w_ready);
 235         }
 236         else
 237         {
 238                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(machinegun, burst_refire), W_MachineGun_Attack_Burst);
 239         }
 240
 241 }
 242
 243                 METHOD(MachineGun, wr_aim, void(entity thiswep))
 244                 {
 245                         if(vlen(self.origin-self.enemy.origin) < 3000 - bound(0, skill, 10) * 200)
 246                                 self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, false);
 247                         else
 248                                 self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, false);
 249                 }
 250                 METHOD(MachineGun, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 251                 {
 252                         if(WEP_CVAR(machinegun, reload_ammo) && actor.clip_load < min(max(WEP_CVAR(machinegun, sustained_ammo), WEP_CVAR(machinegun, first_ammo)), WEP_CVAR(machinegun, burst_ammo))) { // forced reload
 253                                 thiswep.wr_reload(thiswep);
 254                         } else
 255                         if(WEP_CVAR(machinegun, mode) == 1)
 256                         {
 257                                 if(fire & 1)
 258                                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, 0))
 259                                 {
 260                                         actor.misc_bulletcounter = 0;
 261                                         W_MachineGun_Attack_Auto(thiswep, actor, weaponentity, fire);
 262                                 }
 263
 264                                 if(fire & 2)
 265                                 if(weapon_prepareattack(thiswep, actor, weaponentity, true, 0))
 266                                 {
 267                                         if(!thiswep.wr_checkammo2(thiswep))
 268                                         if(!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 269                                         {
 270                                                 W_SwitchWeapon_Force(actor, Weapons_from(w_getbestweapon(actor)));
 271                                                 w_ready(thiswep, actor, weaponentity, fire);
 272                                                 return;
 273                                         }
 274
 275                                         W_DecreaseAmmo(thiswep, actor, WEP_CVAR(machinegun, burst_ammo));
 276
 277                                         actor.misc_bulletcounter = WEP_CVAR(machinegun, burst) * -1;
 278                                         W_MachineGun_Attack_Burst(thiswep, actor, weaponentity, fire);
 279                                 }
 280                         }
 281                         else
 282                         {
 283
 284                                 if(fire & 1)
 285                                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, 0))
 286                                 {
 287                                         actor.misc_bulletcounter = 1;
 288                                         W_MachineGun_Attack(WEP_MACHINEGUN, WEP_MACHINEGUN.m_id, weaponentity); // sets attack_finished
 289                                         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(machinegun, sustained_refire), W_MachineGun_Attack_Frame);
 290                                 }
 291
 292                                 if((fire & 2) && WEP_CVAR(machinegun, first))
 293                                 if(weapon_prepareattack(thiswep, actor, weaponentity, true, 0))
 294                                 {
 295                                         actor.misc_bulletcounter = 1;
 296                                         W_MachineGun_Attack(WEP_MACHINEGUN, WEP_MACHINEGUN.m_id | HITTYPE_SECONDARY, weaponentity); // sets attack_finished
 297                                         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(machinegun, first_refire), w_ready);
 298                                 }
 299                         }
 300                 }
 301                 METHOD(MachineGun, wr_init, void(entity thiswep))
 302                 {
 303                         MACHINEGUN_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 304                 }
 305                 METHOD(MachineGun, wr_checkammo1, bool(entity thiswep))
 306                 {
 307                         float ammo_amount;
 308                         if(WEP_CVAR(machinegun, mode) == 1)
 309                                 ammo_amount = self.WEP_AMMO(MACHINEGUN) >= WEP_CVAR(machinegun, sustained_ammo);
 310                         else
 311                                 ammo_amount = self.WEP_AMMO(MACHINEGUN) >= WEP_CVAR(machinegun, first_ammo);
 312
 313                         if(WEP_CVAR(machinegun, reload_ammo))
 314                         {
 315                                 if(WEP_CVAR(machinegun, mode) == 1)
 316                                         ammo_amount += self.(weapon_load[WEP_MACHINEGUN.m_id]) >= WEP_CVAR(machinegun, sustained_ammo);
 317                                 else
 318                                         ammo_amount += self.(weapon_load[WEP_MACHINEGUN.m_id]) >= WEP_CVAR(machinegun, first_ammo);
 319                         }
 320                         return ammo_amount;
 321                 }
 322                 METHOD(MachineGun, wr_checkammo2, bool(entity thiswep))
 323                 {
 324                         float ammo_amount;
 325                         if(WEP_CVAR(machinegun, mode) == 1)
 326                                 ammo_amount = self.WEP_AMMO(MACHINEGUN) >= WEP_CVAR(machinegun, burst_ammo);
 327                         else
 328                                 ammo_amount = self.WEP_AMMO(MACHINEGUN) >= WEP_CVAR(machinegun, first_ammo);
 329
 330                         if(WEP_CVAR(machinegun, reload_ammo))
 331                         {
 332                                 if(WEP_CVAR(machinegun, mode) == 1)
 333                                         ammo_amount += self.(weapon_load[WEP_MACHINEGUN.m_id]) >= WEP_CVAR(machinegun, burst_ammo);
 334                                 else
 335                                         ammo_amount += self.(weapon_load[WEP_MACHINEGUN.m_id]) >= WEP_CVAR(machinegun, first_ammo);
 336                         }
 337                         return ammo_amount;
 338                 }
 339                 METHOD(MachineGun, wr_config, void(entity thiswep))
 340                 {
 341                         MACHINEGUN_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 342                 }
 343                 METHOD(MachineGun, wr_reload, void(entity thiswep))
 344                 {
 345                         W_Reload(self, min(max(WEP_CVAR(machinegun, sustained_ammo), WEP_CVAR(machinegun, first_ammo)), WEP_CVAR(machinegun, burst_ammo)), SND(RELOAD));
 346                 }
 347                 METHOD(MachineGun, wr_suicidemessage, int(entity thiswep))
 348                 {
 349                         return WEAPON_THINKING_WITH_PORTALS;
 350                 }
 351                 METHOD(MachineGun, wr_killmessage, int(entity thiswep))
 352                 {
 353                         if(w_deathtype & HITTYPE_SECONDARY)
 354                                 return WEAPON_MACHINEGUN_MURDER_SNIPE;
 355                         else
 356                                 return WEAPON_MACHINEGUN_MURDER_SPRAY;
 357                 }
 358
 359 #endif
 360 #ifdef CSQC
 361
 362                 METHOD(MachineGun, wr_impacteffect, void(entity thiswep))
 363                 {
 364                         vector org2;
 365                         org2 = w_org + w_backoff * 2;
 366                         pointparticles(EFFECT_MACHINEGUN_IMPACT, org2, w_backoff * 1000, 1);
 367                         if(!w_issilent)
 368                                 sound(self, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTN_NORM);
 369                 }
 370
 371 #endif
 372 #endif