qcsrc/common/weapons/weapon/minelayer.qc

   1 #ifndef IMPLEMENTATION
   2 CLASS(MineLayer, Weapon)
   3 /* ammotype  */ ATTRIB(MineLayer, ammo_field, .int, ammo_rockets)
   4 /* impulse   */ ATTRIB(MineLayer, impulse, int, 4)
   5 /* flags     */ ATTRIB(MineLayer, spawnflags, int, WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH);
   6 /* rating    */ ATTRIB(MineLayer, bot_pickupbasevalue, float, BOT_PICKUP_RATING_HIGH);
   7 /* color     */ ATTRIB(MineLayer, wpcolor, vector, '0.75 1 0');
   8 /* modelname */ ATTRIB(MineLayer, mdl, string, "minelayer");
   9 #ifndef MENUQC
  10 /* model     */ ATTRIB(MineLayer, m_model, Model, MDL_MINELAYER_ITEM);
  11 #endif
  12 /* crosshair */ ATTRIB(MineLayer, w_crosshair, string, "gfx/crosshairminelayer");
  13 /* crosshair */ ATTRIB(MineLayer, w_crosshair_size, float, 0.9);
  14 /* wepimg    */ ATTRIB(MineLayer, model2, string, "weaponminelayer");
  15 /* refname   */ ATTRIB(MineLayer, netname, string, "minelayer");
  16 /* wepname   */ ATTRIB(MineLayer, m_name, string, _("Mine Layer"));
  17 ENDCLASS(MineLayer)
  18 REGISTER_WEAPON(MINE_LAYER, NEW(MineLayer));
  19
  20 #define MINELAYER_SETTINGS(w_cvar,w_prop) MINELAYER_SETTINGS_LIST(w_cvar, w_prop, MINE_LAYER, minelayer)
  21 #define MINELAYER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  22         w_cvar(id, sn, NONE, ammo) \
  23         w_cvar(id, sn, NONE, animtime) \
  24         w_cvar(id, sn, NONE, damage) \
  25         w_cvar(id, sn, NONE, damageforcescale) \
  26         w_cvar(id, sn, NONE, detonatedelay) \
  27         w_cvar(id, sn, NONE, edgedamage) \
  28         w_cvar(id, sn, NONE, force) \
  29         w_cvar(id, sn, NONE, health) \
  30         w_cvar(id, sn, NONE, lifetime) \
  31         w_cvar(id, sn, NONE, lifetime_countdown) \
  32         w_cvar(id, sn, NONE, limit) \
  33         w_cvar(id, sn, NONE, protection) \
  34         w_cvar(id, sn, NONE, proximityradius) \
  35         w_cvar(id, sn, NONE, radius) \
  36         w_cvar(id, sn, NONE, refire) \
  37         w_cvar(id, sn, NONE, remote_damage) \
  38         w_cvar(id, sn, NONE, remote_edgedamage) \
  39         w_cvar(id, sn, NONE, remote_force) \
  40         w_cvar(id, sn, NONE, remote_radius) \
  41         w_cvar(id, sn, NONE, speed) \
  42         w_cvar(id, sn, NONE, time) \
  43         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  44         w_prop(id, sn, float,  reloading_time, reload_time) \
  45         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  46         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  47         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  48         w_prop(id, sn, float,  weaponstart, weaponstart) \
  49         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  50         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  51
  52 #ifdef SVQC
  53 MINELAYER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  54 void W_MineLayer_Think(void);
  55 .float minelayer_detonate, mine_explodeanyway;
  56 .float mine_time;
  57 .vector mine_orientation;
  58 #endif
  59 #endif
  60 #ifdef IMPLEMENTATION
  61 #ifdef SVQC
  62 spawnfunc(weapon_minelayer) { weapon_defaultspawnfunc(this, WEP_MINE_LAYER); }
  63
  64 void W_MineLayer_Stick(entity to)
  65 {SELFPARAM();
  66         spamsound(self, CH_SHOTS, SND(MINE_STICK), VOL_BASE, ATTN_NORM);
  67
  68         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  69
  70         entity newmine = spawn();
  71         newmine.classname = self.classname;
  72
  73         newmine.bot_dodge = self.bot_dodge;
  74         newmine.bot_dodgerating = self.bot_dodgerating;
  75
  76         newmine.owner = self.owner;
  77         newmine.realowner = self.realowner;
  78         setsize(newmine, '-4 -4 -4', '4 4 4');
  79         setorigin(newmine, self.origin);
  80         setmodel(newmine, MDL_MINELAYER_MINE);
  81         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  82
  83         newmine.mine_orientation = -trace_plane_normal;
  84
  85         newmine.takedamage = self.takedamage;
  86         newmine.damageforcescale = self.damageforcescale;
  87         newmine.health = self.health;
  88         newmine.event_damage = self.event_damage;
  89         newmine.spawnshieldtime = self.spawnshieldtime;
  90         newmine.damagedbycontents = true;
  91
  92         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  93         newmine.projectiledeathtype = self.projectiledeathtype;
  94
  95         newmine.mine_time = self.mine_time;
  96
  97         newmine.touch = func_null;
  98         newmine.think = W_MineLayer_Think;
  99         newmine.nextthink = time;
 100         newmine.cnt = self.cnt;
 101         newmine.flags = self.flags;
 102
 103         remove(self);
 104         setself(newmine);
 105
 106         if(to)
 107                 SetMovetypeFollow(self, to);
 108 }
 109
 110 void W_MineLayer_Explode(void)
 111 {SELFPARAM();
 112         if(other.takedamage == DAMAGE_AIM)
 113                 if(IS_PLAYER(other))
 114                         if(DIFF_TEAM(self.realowner, other))
 115                                 if(other.deadflag == DEAD_NO)
 116                                         if(IsFlying(other))
 117                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
 118
 119         self.event_damage = func_null;
 120         self.takedamage = DAMAGE_NO;
 121
 122         RadiusDamage(self, self.realowner, WEP_CVAR(minelayer, damage), WEP_CVAR(minelayer, edgedamage), WEP_CVAR(minelayer, radius), world, world, WEP_CVAR(minelayer, force), self.projectiledeathtype, other);
 123
 124         if(self.realowner.weapon == WEP_MINE_LAYER.m_id)
 125         {
 126                 setself(self.realowner);
 127                 Weapon w = WEP_MINE_LAYER;
 128                 if(!w.wr_checkammo1(w))
 129                 {
 130                         self.cnt = WEP_MINE_LAYER.m_id;
 131                         int slot = 0; // TODO: unhardcode
 132                         ATTACK_FINISHED(self, slot) = time;
 133                         self.switchweapon = w_getbestweapon(self);
 134                 }
 135                 setself(this);
 136         }
 137         self.realowner.minelayer_mines -= 1;
 138         remove(self);
 139 }
 140
 141 void W_MineLayer_DoRemoteExplode(void)
 142 {SELFPARAM();
 143         self.event_damage = func_null;
 144         self.takedamage = DAMAGE_NO;
 145
 146         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 147                 self.velocity = self.mine_orientation; // particle fx and decals need .velocity
 148
 149         RadiusDamage(self, self.realowner, WEP_CVAR(minelayer, remote_damage), WEP_CVAR(minelayer, remote_edgedamage), WEP_CVAR(minelayer, remote_radius), world, world, WEP_CVAR(minelayer, remote_force), self.projectiledeathtype | HITTYPE_BOUNCE, world);
 150
 151         if(self.realowner.weapon == WEP_MINE_LAYER.m_id)
 152         {
 153                 setself(self.realowner);
 154                 Weapon w = WEP_MINE_LAYER;
 155                 if(!w.wr_checkammo1(w))
 156                 {
 157                         self.cnt = WEP_MINE_LAYER.m_id;
 158                         int slot = 0; // TODO: unhardcode
 159                         ATTACK_FINISHED(self, slot) = time;
 160                         self.switchweapon = w_getbestweapon(self);
 161                 }
 162                 setself(this);
 163         }
 164         self.realowner.minelayer_mines -= 1;
 165         remove(self);
 166 }
 167
 168 void W_MineLayer_RemoteExplode(void)
 169 {SELFPARAM();
 170         if(self.realowner.deadflag == DEAD_NO)
 171                 if((self.spawnshieldtime >= 0)
 172                         ? (time >= self.spawnshieldtime) // timer
 173                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > WEP_CVAR(minelayer, remote_radius)) // safety device
 174                 )
 175                 {
 176                         W_MineLayer_DoRemoteExplode();
 177                 }
 178 }
 179
 180 void W_MineLayer_ProximityExplode(void)
 181 {SELFPARAM();
 182         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 183         if(WEP_CVAR(minelayer, protection) && self.mine_explodeanyway == 0)
 184         {
 185                 entity head;
 186                 head = findradius(self.origin, WEP_CVAR(minelayer, radius));
 187                 while(head)
 188                 {
 189                         if(head == self.realowner || SAME_TEAM(head, self.realowner))
 190                                 return;
 191                         head = head.chain;
 192                 }
 193         }
 194
 195         self.mine_time = 0;
 196         W_MineLayer_Explode();
 197 }
 198
 199 int W_MineLayer_Count(entity e)
 200 {
 201         int minecount = 0;
 202         entity mine;
 203         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == e)
 204                 minecount += 1;
 205
 206         return minecount;
 207 }
 208
 209 void W_MineLayer_Think(void)
 210 {SELFPARAM();
 211         entity head;
 212
 213         self.nextthink = time;
 214
 215         if(self.movetype == MOVETYPE_FOLLOW)
 216         {
 217                 if(LostMovetypeFollow(self))
 218                 {
 219                         UnsetMovetypeFollow(self);
 220                         self.movetype = MOVETYPE_NONE;
 221                 }
 222         }
 223
 224         // our lifetime has expired, it's time to die - mine_time just allows us to play a sound for this
 225         // TODO: replace this mine_trigger.wav sound with a real countdown
 226         if((time > self.cnt) && (!self.mine_time) && (self.cnt > 0))
 227         {
 228                 if(WEP_CVAR(minelayer, lifetime_countdown) > 0)
 229                         spamsound(self, CH_SHOTS, SND(MINE_TRIGGER), VOL_BASE, ATTN_NORM);
 230                 self.mine_time = time + WEP_CVAR(minelayer, lifetime_countdown);
 231                 self.mine_explodeanyway = 1; // make the mine super aggressive -- Samual: Rather, make it not care if a team mate is near.
 232         }
 233
 234         // a player's mines shall explode if he disconnects or dies
 235         // TODO: Do this on team change too -- Samual: But isn't a player killed when they switch teams?
 236         if(!IS_PLAYER(self.realowner) || self.realowner.deadflag != DEAD_NO || self.realowner.frozen)
 237         {
 238                 other = world;
 239                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 240                 W_MineLayer_Explode();
 241                 return;
 242         }
 243
 244         // set the mine for detonation when a foe gets close enough
 245         head = findradius(self.origin, WEP_CVAR(minelayer, proximityradius));
 246         while(head)
 247         {
 248                 if(IS_PLAYER(head) && head.deadflag == DEAD_NO && !head.frozen)
 249                 if(head != self.realowner && DIFF_TEAM(head, self.realowner)) // don't trigger for team mates
 250                 if(!self.mine_time)
 251                 {
 252                         spamsound(self, CH_SHOTS, SND(MINE_TRIGGER), VOL_BASE, ATTN_NORM);
 253                         self.mine_time = time + WEP_CVAR(minelayer, time);
 254                 }
 255                 head = head.chain;
 256         }
 257
 258         // explode if it's time to
 259         if(self.mine_time && time >= self.mine_time)
 260         {
 261                 W_MineLayer_ProximityExplode();
 262                 return;
 263         }
 264
 265         // remote detonation
 266         if(self.realowner.weapon == WEP_MINE_LAYER.m_id)
 267         if(self.realowner.deadflag == DEAD_NO)
 268         if(self.minelayer_detonate)
 269                 W_MineLayer_RemoteExplode();
 270 }
 271
 272 void W_MineLayer_Touch(void)
 273 {SELFPARAM();
 274         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 275                 return; // we're already a stuck mine, why do we get called? TODO does this even happen?
 276
 277         if(WarpZone_Projectile_Touch())
 278         {
 279                 if(wasfreed(self))
 280                         self.realowner.minelayer_mines -= 1;
 281                 return;
 282         }
 283
 284         if(other && IS_PLAYER(other) && other.deadflag == DEAD_NO)
 285         {
 286                 // hit a player
 287                 // don't stick
 288         }
 289         else
 290         {
 291                 W_MineLayer_Stick(other);
 292         }
 293 }
 294
 295 void W_MineLayer_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 296 {SELFPARAM();
 297         if(self.health <= 0)
 298                 return;
 299
 300         float is_from_enemy = (inflictor.realowner != self.realowner);
 301
 302         if(!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, (is_from_enemy ? 1 : -1)))
 303                 return; // g_projectiles_damage says to halt
 304
 305         self.health = self.health - damage;
 306         self.angles = vectoangles(self.velocity);
 307
 308         if(self.health <= 0)
 309                 W_PrepareExplosionByDamage(attacker, W_MineLayer_Explode);
 310 }
 311
 312 void W_MineLayer_Attack(Weapon thiswep)
 313 {SELFPARAM();
 314         entity mine;
 315         entity flash;
 316
 317         // scan how many mines we placed, and return if we reached our limit
 318         if(WEP_CVAR(minelayer, limit))
 319         {
 320                 if(self.minelayer_mines >= WEP_CVAR(minelayer, limit))
 321                 {
 322                         // the refire delay keeps this message from being spammed
 323                         Send_Notification(NOTIF_ONE, self, MSG_MULTI, WEAPON_MINELAYER_LIMIT, WEP_CVAR(minelayer, limit));
 324                         play2(self, SND(UNAVAILABLE));
 325                         return;
 326                 }
 327         }
 328
 329         W_DecreaseAmmo(thiswep, self, WEP_CVAR(minelayer, ammo));
 330
 331         W_SetupShot_ProjectileSize(self, '-4 -4 -4', '4 4 4', false, 5, SND(MINE_FIRE), CH_WEAPON_A, WEP_CVAR(minelayer, damage));
 332         Send_Effect(EFFECT_ROCKET_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 333
 334         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 335         mine.owner = mine.realowner = self;
 336         if(WEP_CVAR(minelayer, detonatedelay) >= 0)
 337                 mine.spawnshieldtime = time + WEP_CVAR(minelayer, detonatedelay);
 338         else
 339                 mine.spawnshieldtime = -1;
 340         mine.classname = "mine";
 341         mine.bot_dodge = true;
 342         mine.bot_dodgerating = WEP_CVAR(minelayer, damage) * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 343
 344         mine.takedamage = DAMAGE_YES;
 345         mine.damageforcescale = WEP_CVAR(minelayer, damageforcescale);
 346         mine.health = WEP_CVAR(minelayer, health);
 347         mine.event_damage = W_MineLayer_Damage;
 348         mine.damagedbycontents = true;
 349
 350         mine.movetype = MOVETYPE_TOSS;
 351         PROJECTILE_MAKETRIGGER(mine);
 352         mine.projectiledeathtype = WEP_MINE_LAYER.m_id;
 353         setsize(mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 354
 355         setorigin(mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 356         W_SetupProjVelocity_Basic(mine, WEP_CVAR(minelayer, speed), 0);
 357         mine.angles = vectoangles(mine.velocity);
 358
 359         mine.touch = W_MineLayer_Touch;
 360         mine.think = W_MineLayer_Think;
 361         mine.nextthink = time;
 362         mine.cnt = (WEP_CVAR(minelayer, lifetime) - WEP_CVAR(minelayer, lifetime_countdown));
 363         mine.flags = FL_PROJECTILE;
 364         mine.missile_flags = MIF_SPLASH | MIF_ARC | MIF_PROXY;
 365
 366         if(mine.cnt > 0) { mine.cnt += time; }
 367
 368         CSQCProjectile(mine, true, PROJECTILE_MINE, true);
 369
 370         // muzzle flash for 1st person view
 371         flash = spawn();
 372         setmodel(flash, MDL_MINELAYER_MUZZLEFLASH); // precision set below
 373         SUB_SetFade(flash, time, 0.1);
 374         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 375         W_AttachToShotorg(self, flash, '5 0 0');
 376
 377         // common properties
 378
 379         MUTATOR_CALLHOOK(EditProjectile, self, mine);
 380
 381         self.minelayer_mines = W_MineLayer_Count(self);
 382 }
 383
 384 float W_MineLayer_PlacedMines(float detonate)
 385 {SELFPARAM();
 386         entity mine;
 387         float minfound = 0;
 388
 389         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == self)
 390         {
 391                 if(detonate)
 392                 {
 393                         if(!mine.minelayer_detonate)
 394                         {
 395                                 mine.minelayer_detonate = true;
 396                                 minfound = 1;
 397                         }
 398                 }
 399                 else
 400                         minfound = 1;
 401         }
 402         return minfound;
 403 }
 404
 405                 METHOD(MineLayer, wr_aim, void(entity thiswep))
 406                 {
 407                         // aim and decide to fire if appropriate
 408                         if(self.minelayer_mines >= WEP_CVAR(minelayer, limit))
 409                                 self.BUTTON_ATCK = false;
 410                         else
 411                                 self.BUTTON_ATCK = bot_aim(WEP_CVAR(minelayer, speed), 0, WEP_CVAR(minelayer, lifetime), false);
 412                         if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 413                         {
 414                                 // decide whether to detonate mines
 415                                 entity targetlist, targ;
 416                                 float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 417                                 float selfdamage, teamdamage, enemydamage;
 418                                 edgedamage = WEP_CVAR(minelayer, edgedamage);
 419                                 coredamage = WEP_CVAR(minelayer, damage);
 420                                 edgeradius = WEP_CVAR(minelayer, radius);
 421                                 recipricoledgeradius = 1 / edgeradius;
 422                                 selfdamage = 0;
 423                                 teamdamage = 0;
 424                                 enemydamage = 0;
 425                                 targetlist = findchainfloat(bot_attack, true);
 426                                 entity mine = find(world, classname, "mine");
 427                                 while(mine)
 428                                 {
 429                                         if(mine.realowner != self)
 430                                         {
 431                                                 mine = find(mine, classname, "mine");
 432                                                 continue;
 433                                         }
 434                                         targ = targetlist;
 435                                         while(targ)
 436                                         {
 437                                                 d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 438                                                 d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 439                                                 // count potential damage according to type of target
 440                                                 if(targ == self)
 441                                                         selfdamage = selfdamage + d;
 442                                                 else if(targ.team == self.team && teamplay)
 443                                                         teamdamage = teamdamage + d;
 444                                                 else if(bot_shouldattack(targ))
 445                                                         enemydamage = enemydamage + d;
 446                                                 targ = targ.chain;
 447                                         }
 448                                         mine = find(mine, classname, "mine");
 449                                 }
 450                                 float desirabledamage;
 451                                 desirabledamage = enemydamage;
 452                                 if(time > self.invincible_finished && time > self.spawnshieldtime)
 453                                         desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 454                                 if(teamplay && self.team)
 455                                         desirabledamage = desirabledamage - teamdamage;
 456
 457                                 mine = find(world, classname, "mine");
 458                                 while(mine)
 459                                 {
 460                                         if(mine.realowner != self)
 461                                         {
 462                                                 mine = find(mine, classname, "mine");
 463                                                 continue;
 464                                         }
 465                                         makevectors(mine.v_angle);
 466                                         targ = targetlist;
 467                                         if(skill > 9) // normal players only do this for the target they are tracking
 468                                         {
 469                                                 targ = targetlist;
 470                                                 while(targ)
 471                                                 {
 472                                                         if(
 473                                                                 (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 474                                                                 && desirabledamage > 0.1*coredamage
 475                                                         )self.BUTTON_ATCK2 = true;
 476                                                         targ = targ.chain;
 477                                                 }
 478                                         }else{
 479                                                 float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 480                                                 //As the distance gets larger, a correct detonation gets near imposible
 481                                                 //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 482                                                 if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 483                                                         if(IS_PLAYER(self.enemy))
 484                                                                 if(desirabledamage >= 0.1*coredamage)
 485                                                                         if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 486                                                                                 self.BUTTON_ATCK2 = true;
 487                                         //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 488                                         }
 489
 490                                         mine = find(mine, classname, "mine");
 491                                 }
 492                                 // if we would be doing at X percent of the core damage, detonate it
 493                                 // but don't fire a new shot at the same time!
 494                                 if(desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 495                                         self.BUTTON_ATCK2 = true;
 496                                 if((skill > 6.5) && (selfdamage > self.health))
 497                                         self.BUTTON_ATCK2 = false;
 498                                 //if(self.BUTTON_ATCK2 == true)
 499                                 //      dprint(ftos(desirabledamage),"\n");
 500                                 if(self.BUTTON_ATCK2 == true) self.BUTTON_ATCK = false;
 501                         }
 502                 }
 503                 METHOD(MineLayer, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 504                 {
 505                         if(autocvar_g_balance_minelayer_reload_ammo && actor.clip_load < WEP_CVAR(minelayer, ammo)) // forced reload
 506                         {
 507                                 // not if we're holding the minelayer without enough ammo, but can detonate existing mines
 508                                 if(!(W_MineLayer_PlacedMines(false) && actor.WEP_AMMO(MINE_LAYER) < WEP_CVAR(minelayer, ammo))) {
 509                                         Weapon w = get_weaponinfo(actor.weapon);
 510                                         w.wr_reload(w);
 511                                 }
 512                         }
 513                         else if(fire & 1)
 514                         {
 515                                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(minelayer, refire)))
 516                                 {
 517                                         W_MineLayer_Attack(thiswep);
 518                                         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(minelayer, animtime), w_ready);
 519                                 }
 520                         }
 521
 522                         if(fire & 2)
 523                         {
 524                                 if(W_MineLayer_PlacedMines(true))
 525                                         sound(actor, CH_WEAPON_B, SND_MINE_DET, VOL_BASE, ATTN_NORM);
 526                         }
 527                 }
 528                 METHOD(MineLayer, wr_init, void(entity thiswep))
 529                 {
 530                         MINELAYER_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 531                 }
 532                 METHOD(MineLayer, wr_checkammo1, bool(entity thiswep))
 533                 {
 534                         int slot = 0; // TODO: unhardcode
 535                         // don't switch while placing a mine
 536                         if(ATTACK_FINISHED(self, slot) <= time || self.weapon != WEP_MINE_LAYER.m_id)
 537                         {
 538                                 float ammo_amount = self.WEP_AMMO(MINE_LAYER) >= WEP_CVAR(minelayer, ammo);
 539                                 ammo_amount += self.(weapon_load[WEP_MINE_LAYER.m_id]) >= WEP_CVAR(minelayer, ammo);
 540                                 return ammo_amount;
 541                         }
 542                         return true;
 543                 }
 544                 METHOD(MineLayer, wr_checkammo2, bool(entity thiswep))
 545                 {
 546                         if(W_MineLayer_PlacedMines(false))
 547                                 return true;
 548                         else
 549                                 return false;
 550                 }
 551                 METHOD(MineLayer, wr_config, void(entity thiswep))
 552                 {
 553                         MINELAYER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 554                 }
 555                 METHOD(MineLayer, wr_resetplayers, void(entity thiswep))
 556                 {
 557                         self.minelayer_mines = 0;
 558                 }
 559                 METHOD(MineLayer, wr_reload, void(entity thiswep))
 560                 {
 561                         W_Reload(self, WEP_CVAR(minelayer, ammo), SND(RELOAD));
 562                 }
 563                 METHOD(MineLayer, wr_suicidemessage, int(entity thiswep))
 564                 {
 565                         return WEAPON_MINELAYER_SUICIDE;
 566                 }
 567                 METHOD(MineLayer, wr_killmessage, int(entity thiswep))
 568                 {
 569                         return WEAPON_MINELAYER_MURDER;
 570                 }
 571
 572 #endif
 573 #ifdef CSQC
 574
 575                 METHOD(MineLayer, wr_impacteffect, void(entity thiswep))
 576                 {
 577                         vector org2;
 578                         org2 = w_org + w_backoff * 12;
 579                         pointparticles(EFFECT_ROCKET_EXPLODE, org2, '0 0 0', 1);
 580                         if(!w_issilent)
 581                                 sound(self, CH_SHOTS, SND_MINE_EXP, VOL_BASE, ATTN_NORM);
 582                 }
 583
 584 #endif
 585 #endif