qcsrc/common/weapons/weapon/rifle.qc

   1 #ifndef IMPLEMENTATION
   2 CLASS(Rifle, Weapon)
   3 /* ammotype  */ ATTRIB(Rifle, ammo_field, .int, ammo_nails)
   4 /* impulse   */ ATTRIB(Rifle, impulse, int, 7)
   5 /* flags     */ ATTRIB(Rifle, spawnflags, int, WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN);
   6 /* rating    */ ATTRIB(Rifle, bot_pickupbasevalue, float, BOT_PICKUP_RATING_MID);
   7 /* color     */ ATTRIB(Rifle, wpcolor, vector, '0.5 1 0');
   8 /* modelname */ ATTRIB(Rifle, mdl, string, "campingrifle");
   9 #ifndef MENUQC
  10 /* model     */ ATTRIB(Rifle, m_model, Model, MDL_RIFLE_ITEM);
  11 #endif
  12 /* crosshair */ ATTRIB(Rifle, w_crosshair, string, "gfx/crosshairrifle");
  13 /* crosshair */ ATTRIB(Rifle, w_crosshair_size, float, 0.6);
  14 /* wepimg    */ ATTRIB(Rifle, model2, string, "weaponrifle");
  15 /* refname   */ ATTRIB(Rifle, netname, string, "rifle");
  16 /* wepname   */ ATTRIB(Rifle, m_name, string, _("Rifle"));
  17 ENDCLASS(Rifle)
  18 REGISTER_WEAPON(RIFLE, NEW(Rifle));
  19
  20 #define RIFLE_SETTINGS(w_cvar,w_prop) RIFLE_SETTINGS_LIST(w_cvar, w_prop, RIFLE, rifle)
  21 #define RIFLE_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  22         w_cvar(id, sn, BOTH, ammo) \
  23         w_cvar(id, sn, BOTH, animtime) \
  24         w_cvar(id, sn, BOTH, bullethail) \
  25         w_cvar(id, sn, BOTH, burstcost) \
  26         w_cvar(id, sn, BOTH, damage) \
  27         w_cvar(id, sn, BOTH, force) \
  28         w_cvar(id, sn, BOTH, refire) \
  29         w_cvar(id, sn, BOTH, shots) \
  30         w_cvar(id, sn, BOTH, solidpenetration) \
  31         w_cvar(id, sn, BOTH, spread) \
  32         w_cvar(id, sn, BOTH, tracer) \
  33         w_cvar(id, sn, NONE, bursttime) \
  34         w_cvar(id, sn, NONE, secondary) \
  35         w_cvar(id, sn, SEC,  reload) \
  36         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  37         w_prop(id, sn, float,  reloading_time, reload_time) \
  38         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  39         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  40         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  41         w_prop(id, sn, float,  weaponstart, weaponstart) \
  42         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  43         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  44
  45 #ifdef SVQC
  46 RIFLE_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  47 .float rifle_accumulator;
  48 #endif
  49 #endif
  50 #ifdef IMPLEMENTATION
  51 #ifdef SVQC
  52 spawnfunc(weapon_rifle) { weapon_defaultspawnfunc(this, WEP_RIFLE); }
  53 spawnfunc(weapon_campingrifle) { spawnfunc_weapon_rifle(this); }
  54 spawnfunc(weapon_sniperrifle) { spawnfunc_weapon_rifle(this); }
  55
  56 void W_Rifle_FireBullet(Weapon thiswep, float pSpread, float pDamage, float pForce, float pSolidPenetration, float pAmmo, int deathtype, float pTracer, float pShots, string pSound)
  57 {SELFPARAM();
  58         float i;
  59
  60         W_DecreaseAmmo(thiswep, self, pAmmo);
  61
  62         W_SetupShot(self, true, 2, pSound, CH_WEAPON_A, pDamage * pShots);
  63
  64         Send_Effect(EFFECT_RIFLE_MUZZLEFLASH, w_shotorg, w_shotdir * 2000, 1);
  65
  66         if(self.BUTTON_ZOOM | self.BUTTON_ZOOMSCRIPT) // if zoomed, shoot from the eye
  67         {
  68                 w_shotdir = v_forward;
  69                 w_shotorg = self.origin + self.view_ofs + ((w_shotorg - self.origin - self.view_ofs) * v_forward) * v_forward;
  70         }
  71
  72         for(i = 0; i < pShots; ++i)
  73                 fireBullet(w_shotorg, w_shotdir, pSpread, pSolidPenetration, pDamage, pForce, deathtype, (pTracer ? EF_RED : EF_BLUE));
  74
  75         if(autocvar_g_casings >= 2)
  76                 SpawnCasing(((random() * 50 + 50) * v_right) - (v_forward * (random() * 25 + 25)) - ((random() * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, self);
  77 }
  78
  79 void W_Rifle_Attack(void)
  80 {
  81         W_Rifle_FireBullet(WEP_RIFLE, WEP_CVAR_PRI(rifle, spread), WEP_CVAR_PRI(rifle, damage), WEP_CVAR_PRI(rifle, force), WEP_CVAR_PRI(rifle, solidpenetration), WEP_CVAR_PRI(rifle, ammo), WEP_RIFLE.m_id, WEP_CVAR_PRI(rifle, tracer), WEP_CVAR_PRI(rifle, shots), SND(CAMPINGRIFLE_FIRE));
  82 }
  83
  84 void W_Rifle_Attack2(void)
  85 {
  86         W_Rifle_FireBullet(WEP_RIFLE, WEP_CVAR_SEC(rifle, spread), WEP_CVAR_SEC(rifle, damage), WEP_CVAR_SEC(rifle, force), WEP_CVAR_SEC(rifle, solidpenetration), WEP_CVAR_SEC(rifle, ammo), WEP_RIFLE.m_id | HITTYPE_SECONDARY, WEP_CVAR_SEC(rifle, tracer), WEP_CVAR_SEC(rifle, shots), SND(CAMPINGRIFLE_FIRE2));
  87 }
  88
  89 .void(void) rifle_bullethail_attackfunc;
  90 .WFRAME rifle_bullethail_frame;
  91 .float rifle_bullethail_animtime;
  92 .float rifle_bullethail_refire;
  93 void W_Rifle_BulletHail_Continue(Weapon thiswep, entity actor, .entity weaponentity, int fire)
  94 {
  95         float r, sw, af;
  96
  97         sw = actor.switchweapon; // make it not detect weapon changes as reason to abort firing
  98         int slot = weaponslot(weaponentity);
  99         af = ATTACK_FINISHED(actor, slot);
 100         actor.switchweapon = actor.weapon;
 101         ATTACK_FINISHED(actor, slot) = time;
 102         LOG_INFO(ftos(actor.WEP_AMMO(RIFLE)), "\n");
 103         r = weapon_prepareattack(thiswep, actor, weaponentity, actor.rifle_bullethail_frame == WFRAME_FIRE2, actor.rifle_bullethail_refire);
 104         if(actor.switchweapon == actor.weapon)
 105                 actor.switchweapon = sw;
 106         if(r)
 107         {
 108                 actor.rifle_bullethail_attackfunc();
 109                 weapon_thinkf(actor, weaponentity, actor.rifle_bullethail_frame, actor.rifle_bullethail_animtime, W_Rifle_BulletHail_Continue);
 110                 LOG_INFO("thinkf set\n");
 111         }
 112         else
 113         {
 114                 ATTACK_FINISHED(actor, slot) = af; // reset attack_finished if we didn't fire, so the last shot enforces the refire time
 115                 LOG_INFO("out of ammo... ", ftos(actor.(weaponentity).state), "\n");
 116         }
 117 }
 118
 119 void W_Rifle_BulletHail(.entity weaponentity, float mode, void(void) AttackFunc, WFRAME fr, float animtime, float refire)
 120 {SELFPARAM();
 121         // if we get here, we have at least one bullet to fire
 122         AttackFunc();
 123         if(mode)
 124         {
 125                 // continue hail
 126                 self.rifle_bullethail_attackfunc = AttackFunc;
 127                 self.rifle_bullethail_frame = fr;
 128                 self.rifle_bullethail_animtime = animtime;
 129                 self.rifle_bullethail_refire = refire;
 130                 weapon_thinkf(self, weaponentity, fr, animtime, W_Rifle_BulletHail_Continue);
 131         }
 132         else
 133         {
 134                 // just one shot
 135                 weapon_thinkf(self, weaponentity, fr, animtime, w_ready);
 136         }
 137 }
 138
 139 .float bot_secondary_riflemooth;
 140
 141                 METHOD(Rifle, wr_aim, void(entity thiswep))
 142                 {
 143                         self.BUTTON_ATCK=false;
 144                         self.BUTTON_ATCK2=false;
 145                         if(vlen(self.origin-self.enemy.origin) > 1000)
 146                                 self.bot_secondary_riflemooth = 0;
 147                         if(self.bot_secondary_riflemooth == 0)
 148                         {
 149                                 if(bot_aim(1000000, 0, 0.001, false))
 150                                 {
 151                                         self.BUTTON_ATCK = true;
 152                                         if(random() < 0.01) self.bot_secondary_riflemooth = 1;
 153                                 }
 154                         }
 155                         else
 156                         {
 157                                 if(bot_aim(1000000, 0, 0.001, false))
 158                                 {
 159                                         self.BUTTON_ATCK2 = true;
 160                                         if(random() < 0.03) self.bot_secondary_riflemooth = 0;
 161                                 }
 162                         }
 163                 }
 164                 METHOD(Rifle, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 165                 {
 166                         if(autocvar_g_balance_rifle_reload_ammo && actor.clip_load < min(WEP_CVAR_PRI(rifle, ammo), WEP_CVAR_SEC(rifle, ammo))) { // forced reload
 167                                 Weapon w = get_weaponinfo(actor.weapon);
 168                                 w.wr_reload(w);
 169                         } else
 170                         {
 171                                 actor.rifle_accumulator = bound(time - WEP_CVAR(rifle, bursttime), actor.rifle_accumulator, time);
 172                                 if(fire & 1)
 173                                 if(weapon_prepareattack_check(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(rifle, refire)))
 174                                 if(time >= actor.rifle_accumulator + WEP_CVAR_PRI(rifle, burstcost))
 175                                 {
 176                                         weapon_prepareattack_do(actor, weaponentity, false, WEP_CVAR_PRI(rifle, refire));
 177                                         W_Rifle_BulletHail(weaponentity, WEP_CVAR_PRI(rifle, bullethail), W_Rifle_Attack, WFRAME_FIRE1, WEP_CVAR_PRI(rifle, animtime), WEP_CVAR_PRI(rifle, refire));
 178                                         actor.rifle_accumulator += WEP_CVAR_PRI(rifle, burstcost);
 179                                 }
 180                                 if(fire & 2)
 181                                 {
 182                                         if(WEP_CVAR(rifle, secondary))
 183                                         {
 184                                                 if(WEP_CVAR_SEC(rifle, reload)) {
 185                                                         Weapon w = get_weaponinfo(actor.weapon);
 186                                                         w.wr_reload(w);
 187                                                 } else
 188                                                 {
 189                                                         if(weapon_prepareattack_check(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(rifle, refire)))
 190                                                         if(time >= actor.rifle_accumulator + WEP_CVAR_SEC(rifle, burstcost))
 191                                                         {
 192                                                                 weapon_prepareattack_do(actor, weaponentity, true, WEP_CVAR_SEC(rifle, refire));
 193                                                                 W_Rifle_BulletHail(weaponentity, WEP_CVAR_SEC(rifle, bullethail), W_Rifle_Attack2, WFRAME_FIRE2, WEP_CVAR_SEC(rifle, animtime), WEP_CVAR_PRI(rifle, refire));
 194                                                                 actor.rifle_accumulator += WEP_CVAR_SEC(rifle, burstcost);
 195                                                         }
 196                                                 }
 197                                         }
 198                                 }
 199                         }
 200                 }
 201                 METHOD(Rifle, wr_init, void(entity thiswep))
 202                 {
 203                         RIFLE_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 204                 }
 205                 METHOD(Rifle, wr_checkammo1, bool(entity thiswep))
 206                 {
 207                         float ammo_amount = self.WEP_AMMO(RIFLE) >= WEP_CVAR_PRI(rifle, ammo);
 208                         ammo_amount += self.(weapon_load[WEP_RIFLE.m_id]) >= WEP_CVAR_PRI(rifle, ammo);
 209                         return ammo_amount;
 210                 }
 211                 METHOD(Rifle, wr_checkammo2, bool(entity thiswep))
 212                 {
 213                         float ammo_amount = self.WEP_AMMO(RIFLE) >= WEP_CVAR_SEC(rifle, ammo);
 214                         ammo_amount += self.(weapon_load[WEP_RIFLE.m_id]) >= WEP_CVAR_SEC(rifle, ammo);
 215                         return ammo_amount;
 216                 }
 217                 METHOD(Rifle, wr_config, void(entity thiswep))
 218                 {
 219                         RIFLE_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 220                 }
 221                 METHOD(Rifle, wr_resetplayer, void(entity thiswep))
 222                 {
 223                         self.rifle_accumulator = time - WEP_CVAR(rifle, bursttime);
 224                 }
 225                 METHOD(Rifle, wr_reload, void(entity thiswep))
 226                 {
 227                         W_Reload(self, min(WEP_CVAR_PRI(rifle, ammo), WEP_CVAR_SEC(rifle, ammo)), SND(RELOAD));
 228                 }
 229                 METHOD(Rifle, wr_suicidemessage, int(entity thiswep))
 230                 {
 231                         return WEAPON_THINKING_WITH_PORTALS;
 232                 }
 233                 METHOD(Rifle, wr_killmessage, int(entity thiswep))
 234                 {
 235                         if(w_deathtype & HITTYPE_SECONDARY)
 236                         {
 237                                 if(w_deathtype & HITTYPE_BOUNCE)
 238                                         return WEAPON_RIFLE_MURDER_HAIL_PIERCING;
 239                                 else
 240                                         return WEAPON_RIFLE_MURDER_HAIL;
 241                         }
 242                         else
 243                         {
 244                                 if(w_deathtype & HITTYPE_BOUNCE)
 245                                         return WEAPON_RIFLE_MURDER_PIERCING;
 246                                 else
 247                                         return WEAPON_RIFLE_MURDER;
 248                         }
 249                 }
 250
 251 #endif
 252 #ifdef CSQC
 253
 254                 METHOD(Rifle, wr_impacteffect, void(entity thiswep))
 255                 {
 256                         vector org2;
 257                         org2 = w_org + w_backoff * 2;
 258                         pointparticles(EFFECT_RIFLE_IMPACT, org2, w_backoff * 1000, 1);
 259                         if(!w_issilent)
 260                         {
 261                                 if(w_random < 0.2)
 262                                         sound(self, CH_SHOTS, SND_RIC1, VOL_BASE, ATTN_NORM);
 263                                 else if(w_random < 0.4)
 264                                         sound(self, CH_SHOTS, SND_RIC2, VOL_BASE, ATTN_NORM);
 265                                 else if(w_random < 0.5)
 266                                         sound(self, CH_SHOTS, SND_RIC3, VOL_BASE, ATTN_NORM);
 267                         }
 268                 }
 269                 METHOD(Rifle, wr_init, void(entity thiswep))
 270                 {
 271                         if(autocvar_cl_reticle && autocvar_cl_reticle_weapon)
 272                         {
 273                                 precache_pic("gfx/reticle_nex");
 274                         }
 275                 }
 276                 METHOD(Rifle, wr_zoomreticle, bool(entity thiswep))
 277                 {
 278                         if(button_zoom || zoomscript_caught)
 279                         {
 280                                 reticle_image = "gfx/reticle_nex";
 281                                 return true;
 282                         }
 283                         else
 284                         {
 285                                 // no weapon specific image for this weapon
 286                                 return false;
 287                         }
 288                 }
 289
 290 #endif
 291 #endif